JavaScriptCore:
[WebKit.git] / WebKitTools / Scripts / webkitdirs.pm
1 # Copyright (C) 2005, 2006 Apple Computer, Inc.  All rights reserved.
2 #
3 # Redistribution and use in source and binary forms, with or without
4 # modification, are permitted provided that the following conditions
5 # are met:
6 #
7 # 1.  Redistributions of source code must retain the above copyright
8 #     notice, this list of conditions and the following disclaimer. 
9 # 2.  Redistributions in binary form must reproduce the above copyright
10 #     notice, this list of conditions and the following disclaimer in the
11 #     documentation and/or other materials provided with the distribution. 
12 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
13 #     its contributors may be used to endorse or promote products derived
14 #     from this software without specific prior written permission. 
15 #
16 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
17 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
18 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
19 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
20 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
21 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
22 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
23 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
24 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
25 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
26
27 # Module to share code to get to WebKit directories.
28
29 use strict;
30 use warnings;
31 use FindBin;
32
33 BEGIN {
34    use Exporter   ();
35    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
36    $VERSION     = 1.00;
37    @ISA         = qw(Exporter);
38    @EXPORT      = qw(&chdirWebKit &baseProductDir &productDir &XcodeOptions &XcodeOptionString &XcodeOptionStringNoConfig &passedConfiguration &setConfiguration &safariPath &checkFrameworks);
39    %EXPORT_TAGS = ( );
40    @EXPORT_OK   = ();
41 }
42
43 our @EXPORT_OK;
44
45 my $baseProductDir;
46 my @baseProductDirOption;
47 my $configuration;
48 my $configurationProductDir;
49 my $sourceDir;
50
51 sub determineSourceDir
52 {
53     return if $sourceDir;
54     $sourceDir = $FindBin::Bin;
55     if ($sourceDir !~ s|/[^/]+/[^/]+$||) {
56         die "Could not find two levels above source directory using FindBin.\n";
57     }
58 }
59
60 sub determineBaseProductDir
61 {
62     return if defined $baseProductDir;
63     determineSourceDir();
64     open PRODUCT, "defaults read com.apple.Xcode PBXProductDirectory 2> /dev/null |" or die;
65     $baseProductDir = <PRODUCT>;
66     close PRODUCT;
67     if ($baseProductDir) {
68         chomp $baseProductDir;
69         $baseProductDir =~ s|^\Q$(SRCROOT)/..\E$|$sourceDir|;
70         $baseProductDir =~ s|^\Q$(SRCROOT)/../|$sourceDir/|;
71         $baseProductDir =~ s|^~/|$ENV{HOME}/|;
72         die "Can't handle Xcode product directory with a ~ in it.\n" if $baseProductDir =~ /~/;
73         die "Can't handle Xcode product directory with a variable in it.\n" if $baseProductDir =~ /\$/;
74         @baseProductDirOption = ();
75     } else {
76         $baseProductDir = "$sourceDir/WebKitBuild";
77         @baseProductDirOption = ("SYMROOT=$baseProductDir");
78     }
79 }
80
81 sub determineConfiguration
82 {
83     return if defined $configuration;
84     determineBaseProductDir();
85     if (open CONFIGURATION, "$baseProductDir/Configuration") {
86         $configuration = <CONFIGURATION>;
87         close CONFIGURATION;
88     }
89     if ($configuration) {
90         chomp $configuration;
91     } else {
92         $configuration = "Release";
93     }
94 }
95
96 sub determineConfigurationProductDir
97 {
98     return if defined $configurationProductDir;
99     determineBaseProductDir();
100     determineConfiguration();
101     $configurationProductDir = "$baseProductDir/$configuration";
102 }
103
104 sub chdirWebKit
105 {
106     determineSourceDir();
107     chdir $sourceDir or die;
108 }
109
110 sub baseProductDir
111 {
112     determineBaseProductDir();
113     return $baseProductDir;
114 }
115
116 sub productDir
117 {
118     determineConfigurationProductDir();
119     return $configurationProductDir;
120 }
121
122 sub XcodeOptions
123 {
124     determineBaseProductDir();
125     determineConfiguration();
126     return (@baseProductDirOption, "-configuration", $configuration);
127 }
128
129 sub XcodeOptionString
130 {
131     return join " ", XcodeOptions();
132 }
133
134 sub XcodeOptionStringNoConfig
135 {
136     return join " ", @baseProductDirOption;
137 }
138
139 my $passedConfiguration;
140 my $searchedForPassedConfiguration;
141 sub determinePassedConfiguration
142 {
143     return if $searchedForPassedConfiguration;
144     $searchedForPassedConfiguration = 1;
145     for my $i (0 .. $#ARGV) {
146         my $opt = $ARGV[$i];
147         if ($opt =~ /^--debug$/i || $opt =~ /^--devel/i) {
148             splice(@ARGV, $i, 1);
149             $passedConfiguration = "Debug";
150             return;
151         }
152         if ($opt =~ /^--release$/i || $opt =~ /^--deploy/i) {
153             splice(@ARGV, $i, 1);
154             $passedConfiguration = "Release";
155             return;
156         }
157     }
158     $passedConfiguration = undef;
159 }
160
161 sub passedConfiguration
162 {
163     determinePassedConfiguration();
164     return $passedConfiguration;
165 }
166
167 sub setConfiguration
168 {
169     determinePassedConfiguration();
170     $configuration = $passedConfiguration if $passedConfiguration;
171 }
172
173 # Locate Safari.
174 sub safariPath
175 {
176     # Use WEBKIT_SAFARI environment variable if present.
177     my $safariBundle = $ENV{WEBKIT_SAFARI};
178     if (!$safariBundle) {
179         determineConfigurationProductDir();
180         # Use Safari.app in product directory if present (good for Safari development team).
181         if (-d "$configurationProductDir/Safari.app") {
182             $safariBundle = "$configurationProductDir/Safari.app";
183         } else {
184             # Otherwise use Safari.app in Applications directory.
185             $safariBundle = "/Applications/Safari.app";
186         }
187     }
188     my $safariPath = "$safariBundle/Contents/MacOS/Safari";
189     die "Can't find executable at $safariPath.\n" unless -x $safariPath;
190     return $safariPath;
191 }
192
193 sub builtDylibPathForName
194 {
195     my $framework = shift;
196     determineConfigurationProductDir();
197     return "$configurationProductDir/$framework.framework/Versions/A/$framework";
198 }
199
200 # Check to see that all the frameworks are built.
201 sub checkFrameworks
202 {
203     for my $framework ("JavaScriptCore", "WebCore", "WebKit") {
204         my $path = builtDylibPathForName($framework);
205         die "Can't find built framework at \"$path\".\n" unless -x $path;
206     }
207 }
208
209 sub hasSVGSupport
210 {
211     my $path = shift;
212     open NM, "-|", "nm", $path or die;
213     my $hasSVGSupport = 0;
214     while (<NM>) {
215         $hasSVGSupport = 1 if /SVGElement/;
216     }
217     close NM;
218     return $hasSVGSupport;
219 }
220
221 sub removeLibraryDependingOnSVG
222 {
223     my $frameworkName = shift;
224     my $shouldHaveSVG = shift;
225     
226     my $path = builtDylibPathForName($frameworkName);
227     return unless -x $path;
228     
229     my $hasSVG = hasSVGSupport($path);
230     system "rm -f $path" if ($shouldHaveSVG xor $hasSVG);
231 }
232
233 sub checkWebCoreSVGSupport
234 {
235     my $required = shift;
236     my $framework = "WebCore";
237     my $path = builtDylibPathForName($framework);
238     my $hasSVG = hasSVGSupport($path);
239     if ($required && !$hasSVG) {
240         die "$framework at \"$path\" does not include SVG Support, please run build-webkit --svg\n";
241     }
242     return $hasSVG;
243 }
244
245 sub checkRequiredSystemConfig
246 {
247     chomp(my $productVersion = `sw_vers -productVersion`);
248     if ($productVersion lt "10.4") {
249         print "*************************************************************\n";
250         print "Mac OS X Version 10.4.0 or later is required to build WebKit.\n";
251         print "You have " . $productVersion . ", thus the build will most likely fail.\n";
252         print "*************************************************************\n";
253     }
254     my $xcodeVersion = `xcodebuild -version`;
255     if ($xcodeVersion !~ /DevToolsCore-(\d+)/ || $1 < 620) {
256         print "*************************************************************\n";
257         print "Xcode Version 2.1 or later is required to build WebKit.\n";
258         print "You have an earlier version of Xcode, thus the build will\n";
259         print "most likely fail.  The latest Xcode is available from the web:\n";
260         print "http://developer.apple.com/tools/xcode\n";
261         print "*************************************************************\n";
262     }
263 }
264
265 1;