749a7326908d8effcc3f07db084c21a533498d25
[WebKit.git] / Tools / Scripts / build-webkit
1 #!/usr/bin/perl -w
2
3 # Copyright (C) 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012, 2013, 2014 Apple Inc. All rights reserved.
4 # Copyright (C) 2009 Google Inc. All rights reserved.
5 # Copyright (C) 2010 moiji-mobile.com All rights reserved.
6 # Copyright (C) 2011 Research In Motion Limited. All rights reserved.
7 # Copyright (C) 2013 Nokia Corporation and/or its subsidiary(-ies).
8 #
9 # Redistribution and use in source and binary forms, with or without
10 # modification, are permitted provided that the following conditions
11 # are met:
12 #
13 # 1.  Redistributions of source code must retain the above copyright
14 #     notice, this list of conditions and the following disclaimer. 
15 # 2.  Redistributions in binary form must reproduce the above copyright
16 #     notice, this list of conditions and the following disclaimer in the
17 #     documentation and/or other materials provided with the distribution. 
18 # 3.  Neither the name of Apple Inc. ("Apple") nor the names of
19 #     its contributors may be used to endorse or promote products derived
20 #     from this software without specific prior written permission. 
21 #
22 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
23 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
24 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
25 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
26 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
27 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
28 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
29 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
32
33 # Build script wrapper for the WebKit Open Source Project.
34
35 use strict;
36 use File::Basename;
37 use File::Find;
38 use File::Spec;
39 use FindBin;
40 use Getopt::Long qw(:config pass_through no_auto_abbrev);
41 use lib $FindBin::Bin;
42 use webkitdirs;
43 use List::Util qw(first);
44 use webkitperl::FeatureList qw(getFeatureOptionList);
45 use POSIX;
46
47 sub cMakeArgsFromFeatures();
48 sub writeCongrats();
49
50 my $originalWorkingDirectory = getcwd();
51 chdirWebKit();
52
53 my $showHelp = 0;
54 my $clean = 0;
55 my $defaultCMakeFeatures = 0;
56 my $minimal = 0;
57 my $installHeaders;
58 my $installLibs;
59 my $prefixPath;
60 my $makeArgs = "";
61 my @cmakeArgs;
62 my $onlyWebKitProject = 0;
63 my $coverageSupport = 0;
64 my $shouldRunStaticAnalyzer = 0;
65 my $startTime = time();
66 my $archsi386 = 0;
67
68 my @features = getFeatureOptionList();
69
70 # Additional environment parameters
71 push @ARGV, split(/ /, $ENV{'BUILD_WEBKIT_ARGS'}) if ($ENV{'BUILD_WEBKIT_ARGS'});
72
73 # Initialize values from defaults
74 foreach (@ARGV) {
75     if ($_ eq '--minimal') {
76         $minimal = 1;
77     } elsif ($_ eq 'ARCHS=i386') {
78         $archsi386 = 1;
79     }
80 }
81
82 # Initialize values from defaults
83 foreach (@features) {
84     ${$_->{value}} = ($minimal ? 0 : $_->{default});
85 }
86
87 my $programName = basename($0);
88 my $usage = <<EOF;
89 Usage: $programName [options] [options to pass to build system]
90   --help                            Show this help message
91   --clean                           Cleanup the build directory
92   --debug                           Compile with Debug configuration
93   --release                         Compile with Release configuration
94   --sdk=<sdk>                       Use a specific Xcode SDK (iOS and Mac only)
95   --device                          Use "iphoneos.internal" SDK if installed, else "iphoneos" SDK (iOS only)
96   --ios-simulator                   Use the current iphonesimulator SDK (iOS only)
97   --coverage                        Enable code coverage support (Mac only)
98   --analyze                         Enable static anaylsis (iOS and Mac only)
99
100   --efl                             Build the EFL port
101   --gtk                             Build the GTK+ port
102   --wincairo                        Build using Cairo (rather than CoreGraphics) on Windows
103
104   --inspector-frontend              Copy Web Inspector user interface resources to the build directory
105
106   --prefix=<path>                   Set installation prefix to the given path (Gtk/Efl only)
107   --makeargs=<arguments>            Optional Makefile flags
108   --cmakeargs=<arguments>           One or more optional CMake flags (e.g. --cmakeargs="-DFOO=bar -DCMAKE_PREFIX_PATH=/usr/local")
109
110   --minimal                         No optional features, unless explicitly enabled
111   --default-cmake-features          Use the default CMake features enabled for the port (CMake based ports)
112
113   --only-webkit                     Build only the WebKit project
114
115 EOF
116
117 my %options = (
118     'help' => \$showHelp,
119     'clean' => \$clean,
120     'install-headers=s' => \$installHeaders,
121     'install-libs=s' => \$installLibs,
122     'prefix=s' => \$prefixPath,
123     'makeargs=s' => \$makeArgs,
124     'cmakeargs=s' => \@cmakeArgs,
125     'minimal' => \$minimal,
126     'only-webkit' => \$onlyWebKitProject,
127     'coverage' => \$coverageSupport,
128     'analyze' => \$shouldRunStaticAnalyzer,
129     'default-cmake-features' => \$defaultCMakeFeatures,
130 );
131
132 # Build usage text and options list from features
133 foreach (@features) {
134     my $opt = sprintf("%-35s", "  --[no-]$_->{option}");
135     $usage .= "$opt $_->{desc} (default: $_->{default})\n";
136     $options{"$_->{option}!"} = $_->{value};
137 }
138
139 GetOptions(%options);
140
141 if ($showHelp) {
142    print STDERR $usage;
143    exit 1;
144 }
145
146 checkRequiredSystemConfig();
147 setConfiguration();
148
149 my $productDir = productDir();
150
151 # Check that all the project directories are there.
152 my @projects = ("Source/JavaScriptCore", "Source/WebCore", "Source/WebKit");
153
154 # Build WTF as a separate static library on ports which support it.
155 splice @projects, 0, 0, "Source/WTF" if isAppleWebKit() or isWinCairo();
156
157 splice @projects, 0, 0, "Source/bmalloc" if isAppleCocoaWebKit();
158
159 # Ports using CMake will check if directories exist in the CMake configuration.
160 if (!isCMakeBuild()) {
161     for my $dir (@projects) {
162         if (! -d $dir) {
163             die "Error: No $dir directory found. Please do a fresh checkout.\n";
164         }
165     }
166 }
167
168 if ((isAppleWebKit() || isWinCairo()) && !-d "WebKitLibraries") {
169     die "Error: No WebKitLibraries directory found. Please do a fresh checkout.\n";
170 }
171
172 my @options = ();
173
174 if (isAppleCocoaWebKit()) {
175     push @options, XcodeOptions();
176     sub option($$$)
177     {
178         my ($feature, $isEnabled, $defaultValue) = @_;
179         return "" if $defaultValue == $isEnabled;
180         return $feature . "=" . ($isEnabled ? $feature : "");
181     }
182
183     foreach (@features) {
184         my $option = option($_->{define}, ${$_->{value}}, $_->{default});
185         push @options, $option unless $option eq "";
186     }
187
188     # ANGLE and libwebrtc must come before WebCore
189     splice @projects, 0, 0, ("Source/ThirdParty/ANGLE");
190     if (portName() eq Mac and not architecture() eq "i386" and not $archsi386) {
191         splice @projects, 0, 0, ("Source/ThirdParty/libwebrtc");
192     }
193
194     push @projects, ("Source/WebKit2");
195
196     if (!isIOSWebKit()) {
197         push @projects, ("Tools/MiniBrowser");
198
199         # WebInspectorUI must come after JavaScriptCore and WebCore but before WebKit and WebKit2
200         my $webKitIndex = first { $projects[$_] eq "Source/WebKit" } 0..$#projects;
201         splice(@projects, $webKitIndex, 0, "Source/WebInspectorUI");
202
203         # Copy library and header from WebKitLibraries to a findable place in the product directory.
204         my @copyLibrariesArgs = ("perl", "Tools/Scripts/copy-webkitlibraries-to-product-directory", "--wksi",  productDir());
205         print(join(" ", @copyLibrariesArgs) . "\n");
206         (system(@copyLibrariesArgs) == 0) or die;
207     } else {
208         my @copyLibrariesArgs = ("perl", "Tools/Scripts/copy-webkitlibraries-to-product-directory", "--sdk", xcodeSDK(), "--wksi");
209         push @copyLibrariesArgs, productDir();
210         print(join(" ", @copyLibrariesArgs) . "\n");
211         (system(@copyLibrariesArgs) == 0) or die;
212     }
213
214     # Build Tools needed for Apple ports
215     push @projects, ("Tools/DumpRenderTree", "Tools/WebKitTestRunner", "Source/ThirdParty/gtest", "Tools/TestWebKitAPI");
216
217 } elsif (isWinCairo()) {
218     (system("perl Tools/Scripts/update-webkit-wincairo-libs") == 0) or die;
219 } elsif (isAppleWinWebKit()) {
220     # Copy WebKitSupportLibrary to the correct location in WebKitLibraries so it can be found.
221     # Will fail if WebKitSupportLibrary.zip is not in source root.
222     (system("perl Tools/Scripts/update-webkit-support-libs") == 0) or die;
223 }
224
225 # If asked to build just the WebKit project, overwrite the projects
226 # list after all of the port specific tweaks have been made to
227 # build options, etc.
228 @projects = ("Source/WebKit") if $onlyWebKitProject;
229
230 my $result = 0;
231
232 if (isInspectorFrontend()) {
233     die "The --inspector-frontend option is not supported for CMake-based builds." if isCMakeBuild();
234     @projects = ("Source/WebInspectorUI");
235 }
236
237 if (isCMakeBuild() && !isAnyWindows()) {
238
239     # By default we build using all of the available CPUs.
240     $makeArgs .= ($makeArgs ? " " : "") . "-j" . numberOfCPUs() if $makeArgs !~ /-j\s*\d+/;
241     my $maxCPULoad = maxCPULoad() if $makeArgs !~ /-l\s*\d+\.?\d*/;
242     $makeArgs .= " -l" . maxCPULoad() if defined $maxCPULoad;
243
244     # We remove CMakeCache to avoid the bots to reuse cached flags when
245     # we enable new features. This forces a reconfiguration.
246     my @featureArgs = cMakeArgsFromFeatures();
247     removeCMakeCache(@featureArgs);
248
249     buildCMakeProjectOrExit($clean, $prefixPath, $makeArgs, (cmakeBasedPortArguments(), @featureArgs), @cmakeArgs);
250 }
251
252 my $baseProductDir = baseProductDir();
253 if (isAppleWinWebKit() || isWinCairo()) {
254     my @featureArgs = cMakeArgsFromFeatures();
255     removeCMakeCache(@featureArgs);
256
257     chdirWebKit();
258     if (exitStatus(generateBuildSystemFromCMakeProject())) {
259         die "Run \"C:/Program Files (x86)/Microsoft Visual Studio 14.0/VC/vcvarsall.bat\" before build-webkit when using ninja";
260     }
261     chdirWebKit();
262     if (canUseNinja()) {
263         chdir File::Spec->catdir($baseProductDir, configuration());
264         $result = system("ninja");
265     } else {
266         $result = buildVisualStudioProject(File::Spec->catfile("WebKitBuild", configuration(), "WebKit.sln"), $clean);
267     }
268     if (exitStatus($result)) {
269         my $scriptDir = relativeScriptsDir();
270         if (isAppleWinWebKit() || isWinCairo()) {
271             print "\n\n===== BUILD FAILED ======\n\n";
272             print "Please ensure you have run $scriptDir/update-webkit to install dependencies.\n\n";
273             print "You can view build errors by checking the BuildLog.htm files located at:\n$baseProductDir/obj/<project>/<config>.\n";
274         }
275         exit exitStatus($result);
276     }
277 } elsif (isAppleCocoaWebKit() && !isCMakeBuild()) {
278     # Build, and abort if the build fails.
279     for my $dir (@projects) {
280         chdir $dir or die;
281         $result = 0;
282
283         my $project = basename($dir);
284         
285         my @local_options = @options;
286         push @local_options, XcodeCoverageSupportOptions() if $coverageSupport;
287         push @local_options, XcodeStaticAnalyzerOption() if $shouldRunStaticAnalyzer;
288         my $projectPath = $project =~ /gtest/ ? "xcode/gtest" : $project;
289         $result = buildXCodeProject($projectPath, $clean, @local_options, @ARGV);
290
291         # Various build* calls above may change the CWD.
292         chdirWebKit();
293
294         if (exitStatus($result)) {
295             exit exitStatus($result);
296         }
297     }
298 }
299
300 # Don't report the "WebKit is now built" message after a clean operation.
301 exit if $clean;
302
303 # Don't report congrats message if build was interrupted by the user.
304 exit if ($result & 127) == SIGINT;
305
306 # Explicitly chdir back to where exit will take us anyway, since the following "launcher"
307 # message is relative to that directory.
308 chdir $originalWorkingDirectory;
309
310 # Write out congratulations message.
311 writeCongrats();
312
313 exit 0;
314
315 sub cMakeArgsFromFeatures()
316 {
317     my @args;
318     if (!$defaultCMakeFeatures) {
319         foreach (@features) {
320             my $featureName = $_->{define};
321             if ($featureName) {
322                 my $featureEnabled = ${$_->{value}} ? "ON" : "OFF";
323                 push @args, "-D$featureName=$featureEnabled";
324             }
325         }
326     }
327     return @args;
328 }
329
330 sub writeCongrats()
331 {
332     my $launcherPath = launcherPath();
333     my $launcherName = launcherName();
334     my $endTime = time();
335     my $buildTime = formatBuildTime($endTime - $startTime);
336
337     print "\n";
338     print "====================================================================\n";
339     print " WebKit is now built ($buildTime). \n";
340     if ($launcherPath && $launcherName) {
341         print " To run $launcherName with this newly-built code, use the\n";
342         print " \"$launcherPath\" script.\n";
343     }
344     print "====================================================================\n";
345 }