[Qt] another stab at fixing the windows build
[WebKit.git] / Source / WebKit / WebKit1.pro
1 # -------------------------------------------------------------------
2 # Target file for the WebKit1 static library
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = lib
8 TARGET = WebKit1
9
10 include(WebKit1.pri)
11
12 WEBKIT += wtf javascriptcore webcore
13 QT += gui
14
15 # This is relied upon by our export macros and seems not to be properly
16 # defined by the logic in qt_module.prf as it should
17 DEFINES += QT_BUILD_WEBKIT_LIB
18
19 CONFIG += staticlib
20
21 SOURCES += \
22     $$PWD/qt/Api/qhttpheader.cpp \
23     $$PWD/qt/Api/qwebdatabase.cpp \
24     $$PWD/qt/Api/qwebelement.cpp \
25     $$PWD/qt/Api/qwebhistory.cpp \
26     $$PWD/qt/Api/qwebhistoryinterface.cpp \
27     $$PWD/qt/Api/qwebkitglobal.cpp \
28     $$PWD/qt/Api/qwebplugindatabase.cpp \
29     $$PWD/qt/Api/qwebpluginfactory.cpp \
30     $$PWD/qt/Api/qwebsecurityorigin.cpp \
31     $$PWD/qt/Api/qwebsettings.cpp \
32     $$PWD/qt/Api/qwebscriptworld.cpp \
33     $$PWD/qt/WebCoreSupport/ChromeClientQt.cpp \
34     $$PWD/qt/WebCoreSupport/ContextMenuClientQt.cpp \
35     $$PWD/qt/WebCoreSupport/DragClientQt.cpp \
36     $$PWD/qt/WebCoreSupport/DumpRenderTreeSupportQt.cpp \
37     $$PWD/qt/WebCoreSupport/EditorClientQt.cpp \
38     $$PWD/qt/WebCoreSupport/FrameLoaderClientQt.cpp \
39     $$PWD/qt/WebCoreSupport/FrameNetworkingContextQt.cpp \
40     $$PWD/qt/WebCoreSupport/GeolocationPermissionClientQt.cpp \
41     $$PWD/qt/WebCoreSupport/InitWebCoreQt.cpp \
42     $$PWD/qt/WebCoreSupport/InspectorClientQt.cpp \
43     $$PWD/qt/WebCoreSupport/InspectorServerQt.cpp \
44     $$PWD/qt/WebCoreSupport/NotificationPresenterClientQt.cpp \
45     $$PWD/qt/WebCoreSupport/PlatformStrategiesQt.cpp \
46     $$PWD/qt/WebCoreSupport/PopupMenuQt.cpp \
47     $$PWD/qt/WebCoreSupport/QtPlatformPlugin.cpp \
48     $$PWD/qt/WebCoreSupport/QtPluginWidgetAdapter.cpp \
49     $$PWD/qt/WebCoreSupport/QtPrintContext.cpp \
50     $$PWD/qt/WebCoreSupport/QWebFrameAdapter.cpp \
51     $$PWD/qt/WebCoreSupport/QWebPageAdapter.cpp \
52     $$PWD/qt/WebCoreSupport/SearchPopupMenuQt.cpp \
53     $$PWD/qt/WebCoreSupport/TextCheckerClientQt.cpp \
54     $$PWD/qt/WebCoreSupport/TextureMapperLayerClientQt.cpp \
55     $$PWD/qt/WebCoreSupport/UndoStepQt.cpp \
56     $$PWD/qt/WebCoreSupport/WebEventConversion.cpp
57
58 HEADERS += \
59     $$PWD/qt/Api/qhttpheader_p.h \
60     $$PWD/qt/Api/qwebdatabase.h \
61     $$PWD/qt/Api/qwebelement.h \
62     $$PWD/qt/Api/qwebelement_p.h \
63     $$PWD/qt/Api/qwebhistory.h \
64     $$PWD/qt/Api/qwebhistory_p.h \
65     $$PWD/qt/Api/qwebhistoryinterface.h \
66     $$PWD/qt/Api/qwebplugindatabase_p.h \
67     $$PWD/qt/Api/qwebpluginfactory.h \
68     $$PWD/qt/Api/qwebsecurityorigin.h \
69     $$PWD/qt/Api/qwebsettings.h \
70     $$PWD/qt/Api/qwebscriptworld_p.h \
71     $$PWD/qt/Api/qwebkitplatformplugin.h \
72     $$PWD/qt/WebCoreSupport/ChromeClientQt.h \
73     $$PWD/qt/WebCoreSupport/ContextMenuClientQt.h \
74     $$PWD/qt/WebCoreSupport/DragClientQt.h \
75     $$PWD/qt/WebCoreSupport/EditorClientQt.h \
76     $$PWD/qt/WebCoreSupport/FrameLoaderClientQt.h \
77     $$PWD/qt/WebCoreSupport/FrameNetworkingContextQt.h \
78     $$PWD/qt/WebCoreSupport/GeolocationPermissionClientQt.h \
79     $$PWD/qt/WebCoreSupport/InitWebCoreQt.h \
80     $$PWD/qt/WebCoreSupport/InspectorClientQt.h \
81     $$PWD/qt/WebCoreSupport/InspectorServerQt.h \
82     $$PWD/qt/WebCoreSupport/NotificationPresenterClientQt.h \
83     $$PWD/qt/WebCoreSupport/PlatformStrategiesQt.h \
84     $$PWD/qt/WebCoreSupport/PopupMenuQt.h \
85     $$PWD/qt/WebCoreSupport/QtPlatformPlugin.h \
86     $$PWD/qt/WebCoreSupport/QtPluginWidgetAdapter.h \
87     $$PWD/qt/WebCoreSupport/QtPrintContext.h \
88     $$PWD/qt/WebCoreSupport/QWebFrameAdapter.h \
89     $$PWD/qt/WebCoreSupport/QWebPageAdapter.h \
90     $$PWD/qt/WebCoreSupport/SearchPopupMenuQt.h \
91     $$PWD/qt/WebCoreSupport/TextCheckerClientQt.h \
92     $$PWD/qt/WebCoreSupport/TextureMapperLayerClientQt.h \
93     $$PWD/qt/WebCoreSupport/UndoStepQt.h \
94     $$PWD/qt/WebCoreSupport/WebEventConversion.h
95
96 INCLUDEPATH += \
97     $$PWD/qt/WebCoreSupport
98
99 use?(3D_GRAPHICS): WEBKIT += angle
100
101 enable?(GEOLOCATION) {
102      HEADERS += \
103         $$PWD/qt/WebCoreSupport/GeolocationClientQt.h
104      SOURCES += \
105         $$PWD/qt/WebCoreSupport/GeolocationClientQt.cpp
106 }
107
108 enable?(ICONDATABASE) {
109     HEADERS += \
110         $$PWD/../WebCore/loader/icon/IconDatabaseClient.h \
111         $$PWD/qt/WebCoreSupport/IconDatabaseClientQt.h
112
113     SOURCES += \
114         $$PWD/qt/WebCoreSupport/IconDatabaseClientQt.cpp
115 }
116
117 enable?(VIDEO) {
118     use?(QTKIT) | use?(GSTREAMER) | use?(QT_MULTIMEDIA) {
119         HEADERS += $$PWD/qt/WebCoreSupport/FullScreenVideoQt.h
120         SOURCES += $$PWD/qt/WebCoreSupport/FullScreenVideoQt.cpp
121     }
122
123     use?(QTKIT) {
124         INCLUDEPATH += \
125             $$PWD/../WebCore/platform/qt/ \
126             $$PWD/../WebCore/platform/mac/ \
127             $$PWD/../../WebKitLibraries/
128
129         DEFINES += NSGEOMETRY_TYPES_SAME_AS_CGGEOMETRY_TYPES
130
131         contains(CONFIG, "x86") {
132             DEFINES+=NS_BUILD_32_LIKE_64
133         }
134
135         HEADERS += \
136             $$PWD/qt/WebCoreSupport/WebSystemInterface.h \
137             $$PWD/qt/WebCoreSupport/QTKitFullScreenVideoHandler.h
138
139         OBJECTIVE_SOURCES += \
140             $$PWD/qt/WebCoreSupport/WebSystemInterface.mm \
141             $$PWD/qt/WebCoreSupport/QTKitFullScreenVideoHandler.mm
142     }
143 }
144
145