.: [Qt] [WK2] Disable the build with Qt versions older than 5.0
[WebKit.git] / Source / WebKit.pro
1 TEMPLATE = subdirs
2 CONFIG += ordered
3
4 include(WebKit.pri)
5
6 !v8 {
7     exists($$PWD/JavaScriptCore/JavaScriptCore.pro): SUBDIRS += JavaScriptCore/JavaScriptCore.pro
8     exists($$PWD/JavaScriptCore/jsc.pro): SUBDIRS += JavaScriptCore/jsc.pro
9 }
10
11 webkit2 {
12     lessThan(QT_MAJOR_VERSION, 5) {
13         message("Building WebKit2 with Qt versions older than 5.0 is no longer supported.")
14         message("Read http://www.mail-archive.com/webkit-qt@lists.webkit.org/msg01674.html for more information.")
15         error("Aborting build.")
16     }
17     exists($$PWD/WebKit2/WebKit2.pro): SUBDIRS += WebKit2/WebKit2.pro
18 }
19
20 SUBDIRS += WebCore
21 SUBDIRS += WebKit/qt/QtWebKit.pro
22
23 webkit2 {
24     exists($$PWD/WebKit2/WebProcess.pro): SUBDIRS += WebKit2/WebProcess.pro
25     exists($$PWD/WebKit2/UIProcess/API/qt/tests): SUBDIRS += WebKit2/UIProcess/API/qt/tests
26 }
27
28 contains(QT_CONFIG, declarative) {
29     exists($$PWD/WebKit/qt/declarative): SUBDIRS += WebKit/qt/declarative
30 }
31
32 exists($$PWD/WebKit/qt/tests): SUBDIRS += WebKit/qt/tests
33
34 build-qtscript {
35     SUBDIRS += \
36         JavaScriptCore/qt/api/QtScript.pro \
37         JavaScriptCore/qt/tests \
38         JavaScriptCore/qt/benchmarks
39 }
40
41 symbian {
42     exists($$PWD/WebKit/qt/symbian/platformplugin): SUBDIRS += WebKit/qt/symbian/platformplugin
43
44     # Forward the install target to WebCore. A workaround since INSTALLS is not implemented for symbian
45     install.commands = $(MAKE) -C WebCore install
46     QMAKE_EXTRA_TARGETS += install
47 }
48
49 include(WebKit/qt/docs/docs.pri)