Add new renderer for SVGRectElement.
[WebKit.git] / Source / WebKit.pro
1 TEMPLATE = subdirs
2 CONFIG += ordered
3
4 include(WebKit.pri)
5
6 !v8 {
7     SUBDIRS += \
8         JavaScriptCore/JavaScriptCore.pro \
9         JavaScriptCore/jsc.pro
10 }
11
12 webkit2 {
13     !qt5 {
14         message("Building WebKit2 with Qt versions older than 5.0 is no longer supported.")
15         message("Read http://www.mail-archive.com/webkit-qt@lists.webkit.org/msg01674.html for more information.")
16         error("Aborting build.")
17     }
18
19     SUBDIRS += WebKit2/WebKit2.pro
20 }
21
22 qt5 {
23     isEmpty(QT.widgets.name)|isEmpty(QT.printsupport.name) {
24         message("Building WebKit against Qt 5.0 requires the QtWidgets and QtPrintSupport modules.")
25         error("Aborting build.")
26     }
27 }
28
29 SUBDIRS += WebCore
30 SUBDIRS += WebKit/qt/QtWebKit.pro
31
32 webkit2 {
33     SUBDIRS += \
34         WebKit2/WebProcess.pro \
35         WebKit2/UIProcess/API/qt/tests
36 }
37
38 exists($$PWD/WebKit/qt/declarative) {
39     qt5 {
40         contains(QT_CONFIG, qtquick1): SUBDIRS += WebKit/qt/declarative
41     } else {
42         contains(QT_CONFIG, declarative): SUBDIRS += WebKit/qt/declarative
43     }
44 }
45
46 SUBDIRS += WebKit/qt/tests
47
48 build-qtscript {
49     SUBDIRS += \
50         JavaScriptCore/qt/api/QtScript.pro \
51         JavaScriptCore/qt/tests \
52         JavaScriptCore/qt/benchmarks
53 }
54
55 include(WebKit/qt/docs/docs.pri)