2011-02-07 Maciej Stachowiak <mjs@apple.com>
[WebKit.git] / Source / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3 # Detect that we are building as a standalone package by the presence of
4 # either the generated files directory or as part of the Qt package through
5 # QTDIR_build
6 CONFIG(QTDIR_build): CONFIG += standalone_package
7 else:exists($$PWD/WebCore/generated): CONFIG += standalone_package
8
9 CONFIG += depend_includepath
10 DEPENDPATH += $$OUT_PWD
11
12 DEFINES += BUILDING_QT__=1
13 building-libs {
14     win32-msvc*|win32-icc: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
15 } else {
16     CONFIG(QTDIR_build) {
17         QT += webkit
18     } else {
19         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
20         QTWEBKITLIBNAME = QtWebKit
21         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
22             LIBS += -framework $$QTWEBKITLIBNAME
23             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
24         } else {
25             build_pass: win32-*|wince* {
26                 !CONFIG(release, debug|release): QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}d
27                 QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}$${QT_MAJOR_VERSION}
28                 win32-g++*: LIBS += -l$$QTWEBKITLIBNAME
29                 else: LIBS += $${QTWEBKITLIBNAME}.lib
30             } else {
31                 LIBS += -lQtWebKit
32                 symbian {
33                     TARGET.EPOCSTACKSIZE = 0x14000 // 80 kB
34                     # For EXEs only: set heap to usable value
35                     TARGET.EPOCHEAPSIZE =
36                     heapSizeRule = \
37                     "$${LITERAL_HASH}ifdef WINSCW" \
38                         "EPOCHEAPSIZE  0x40000 0x2000000 // Min 256kB, Max 32MB" \
39                     "$${LITERAL_HASH}else" \
40                         "EPOCHEAPSIZE  0x40000 0x10000000 // Min 256kB, Max 256MB" \
41                     "$${LITERAL_HASH}endif"
42                     MMP_RULES += heapSizeRule
43                 }
44             }
45         }
46     }
47     DEPENDPATH += $$PWD/WebKit/qt/Api
48 }
49
50 CONFIG(release, debug|release) {
51     DEFINES += NDEBUG
52 }
53
54 INCLUDEPATH += $$OUTPUT_DIR/include/QtWebKit
55
56 CONFIG -= warn_on
57 *-g++*:QMAKE_CXXFLAGS += -Wall -Wextra -Wreturn-type -fno-strict-aliasing -Wcast-align -Wchar-subscripts -Wformat-security -Wreturn-type -Wno-unused-parameter -Wno-sign-compare -Wno-switch -Wno-switch-enum -Wundef -Wmissing-noreturn -Winit-self
58
59 # Treat warnings as errors on x86/Linux/GCC
60 linux-g++* {
61     isEqual(QT_ARCH,x86_64)|isEqual(QT_ARCH,i386): QMAKE_CXXFLAGS += -Werror
62 }
63
64 symbian|*-armcc {
65     # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
66     RVCT_COMMON_CFLAGS = --gnu --diag_suppress 68,111,177,368,830,1293
67     RVCT_COMMON_CXXFLAGS = $$RVCT_COMMON_CFLAGS --no_parse_templates
68     # Make debug symbols leaner in RVCT4.x. Ignored by compiler for release builds
69     QMAKE_CXXFLAGS.ARMCC_4_0 += --remove_unneeded_entities
70 }
71
72 *-armcc {
73     QMAKE_CFLAGS += $$RVCT_COMMON_CFLAGS
74     QMAKE_CXXFLAGS += $$RVCT_COMMON_CXXFLAGS
75 }
76
77 symbian {
78     QMAKE_CXXFLAGS.ARMCC += $$RVCT_COMMON_CXXFLAGS
79 }
80
81 valgrind {
82     contains(JAVASCRIPTCORE_JIT,yes): error("'JAVASCRIPTCORE_JIT=yes' not supported with valgrind")
83     QMAKE_CXXFLAGS += -g
84     QMAKE_LFLAGS += -g
85     DEFINES += USE_SYSTEM_MALLOC=1
86     DEFINES += ENABLE_JIT=0
87     JAVASCRIPTCORE_JIT = no
88 }
89
90 ##### Defaults for some mobile platforms
91 symbian|maemo5|maemo6 {
92     CONFIG += disable_uitools
93     CONFIG += enable_fast_mobile_scrolling
94     CONFIG += use_qt_mobile_theme
95     maemo6: CONFIG += include_webinspector
96 } else {
97     CONFIG += include_webinspector
98 }
99
100 ####
101
102 disable_uitools: DEFINES *= QT_NO_UITOOLS
103
104 # Disable a few warnings on Windows. The warnings are also
105 # disabled in WebKitLibraries/win/tools/vsprops/common.vsprops
106 win32-msvc*|wince*: QMAKE_CXXFLAGS += -wd4291 -wd4344 -wd4396 -wd4503 -wd4800 -wd4819 -wd4996
107
108 CONFIG(qt_minimal) {
109     DEFINES *= QT_NO_ANIMATION
110     DEFINES *= QT_NO_BEARERMANAGEMENT
111     DEFINES *= QT_NO_CLIPBOARD
112     DEFINES *= QT_NO_COMBOBOX
113     DEFINES *= QT_NO_CONCURRENT
114     DEFINES *= QT_NO_CRASHHANDLER
115     DEFINES *= QT_NO_CURSOR
116     DEFINES *= QT_NO_DESKTOPSERVICES
117     DEFINES *= QT_NO_FILEDIALOG
118     DEFINES *= QT_NO_GRAPHICSEFFECT
119     DEFINES *= QT_NO_IM
120     DEFINES *= QT_NO_INPUTDIALOG
121     DEFINES *= QT_NO_LINEEDIT
122     DEFINES *= QT_NO_MESSAGEBOX
123     DEFINES *= QT_NO_OPENSSL
124     DEFINES *= QT_NO_PRINTER
125     DEFINES *= QT_NO_QUUID_STRING
126     DEFINES *= QT_NO_SHORTCUT
127     DEFINES *= QT_NO_STYLE_STYLESHEET
128     DEFINES *= QT_NO_SYSTEMTRAYICON
129     DEFINES *= QT_NO_TEMPORARYFILE
130     DEFINES *= QT_NO_TOOLTIP
131     DEFINES *= QT_NO_UITOOLS
132     DEFINES *= QT_NO_UNDOCOMMAND
133     DEFINES *= QT_NO_UNDOSTACK
134     DEFINES *= QT_NO_XRENDER
135 }
136
137 contains(DEFINES, QT_NO_UITOOLS): CONFIG -= uitools