Source/WebCore/DerivedSources.pro

   1 # DerivedSources - qmake build info
   2
   3 TEMPLATE = lib
   4 TARGET = dummy
   5
   6 CONFIG -= debug_and_release
   7
   8 QMAKE_EXTRA_TARGETS += generated_files
   9
  10 defineTest(addExtraCompiler) {
  11     eval($${1}.CONFIG = target_predeps no_link)
  12     eval($${1}.variable_out =)
  13     eval($${1}.dependency_type = TYPE_C)
  14
  15     wkScript = $$eval($${1}.wkScript)
  16     eval($${1}.depends += $$wkScript)
  17
  18     export($${1}.CONFIG)
  19     export($${1}.variable_out)
  20     export($${1}.dependency_type)
  21     export($${1}.depends)
  22
  23     QMAKE_EXTRA_COMPILERS += $$1
  24     generated_files.depends += compiler_$${1}_make_all
  25     export(QMAKE_EXTRA_COMPILERS)
  26     export(generated_files.depends)
  27     return(true)
  28 }
  29
  30 mac {
  31     SRC_ROOT_DIR = $$replace(PWD, /Source/WebCore, "")
  32     fwheader_generator.commands = perl $${SRC_ROOT_DIR}/Source/WebKit2/Scripts/generate-forwarding-headers.pl $${SRC_ROOT_DIR}/Source/WebKit2 ../include mac
  33     fwheader_generator.depends  = $${SRC_ROOT_DIR}/Source/WebKit2/Scripts/generate-forwarding-headers.pl
  34     generated_files.depends     += fwheader_generator
  35     QMAKE_EXTRA_TARGETS         += fwheader_generator
  36 }
  37
  38 include(CodeGenerators.pri)