[Qt] Build files for the WTR's InjectedBundle

git-svn-id: https://svn.webkit.org/repository/webkit/trunk@69324 268f45cc-cd09-0410-ab3c-d52691b4dbfc

diff --git a/ChangeLog b/ChangeLog
index 727e8b2c19ac3168f5c951897cfd42647caebd4f..1e2ceb7d1babb07a0e4e3a3be18e0485d270d516 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,13 @@
+2010-10-07  Jocelyn Turcotte  <jocelyn.turcotte@nokia.com>, Andras Becsi  <abecsi@webkit.org>, Balazs Kelemen  <kbalazs@webkit.org>
+
+        Reviewed by Kenneth Rohde Christiansen.
+
+        [Qt] Add WTR's InjectedBundle build files.
+        https://bugs.webkit.org/show_bug.cgi?id=47333
+
+        * DerivedSources.pro:
+        * WebKit.pro:
+
 2010-10-07  Sheriff Bot  <webkit.review.bot@gmail.com>
 
         Unreviewed, rolling out r69315.

diff --git a/DerivedSources.pro b/DerivedSources.pro
index 0015af6eb79dd014f01e2c911d3a31d52044f150..76cb37e6cb86e0338fa1483116529c87ad53ac5f 100644 (file)
--- a/DerivedSources.pro
+++ b/DerivedSources.pro
@@ -8,7 +8,9 @@ SUBDIRS += \
 
 webkit2 {
     SUBDIRS += WebKit2/DerivedSources.pro
-    SUBDIRS += WebKitTools/WebKitTestRunner/qt/DerivedSources.pro
+
+    # Uncomment when WTR is ready upstream
+    #SUBDIRS += WebKitTools/WebKitTestRunner/DerivedSources.pro
 }
 
 for(subpro, SUBDIRS) {

diff --git a/WebKit.pro b/WebKit.pro
index 898a4ec071ac7232185165080e4d94e971484e7f..595fde510f3db1a619af9718f55fab0e44224deb 100644 (file)
--- a/WebKit.pro
+++ b/WebKit.pro
@@ -33,7 +33,8 @@ build-qtscript {
 webkit2 {
     exists($$PWD/WebKit2/WebProcess.pro): SUBDIRS += WebKit2/WebProcess.pro
     exists($$PWD/WebKitTools/MiniBrowser/qt/MiniBrowser.pro): SUBDIRS += WebKitTools/MiniBrowser/qt/MiniBrowser.pro
-    exists($$PWD/WebKitTools/WebKitTestRunner/qt/WebKitTestRunner.pro): SUBDIRS += WebKitTools/WebKitTestRunner/qt/WebKitTestRunner.pro
+    # Turn it on after the build has been stabilized.
+    #exists($$PWD/WebKitTools/WebKitTestRunner/qt/WebKitTestRunner.pro): SUBDIRS += WebKitTools/WebKitTestRunner/qt/WebKitTestRunner.pro
 }
 
 symbian {

diff --git a/WebKit2/ChangeLog b/WebKit2/ChangeLog
index 31879a2a57c169dc3dc3084df8428829c181e48b..bdc1de71c2ba26f1815f38b658560fe21921e003 100644 (file)
--- a/WebKit2/ChangeLog
+++ b/WebKit2/ChangeLog
@@ -1,3 +1,12 @@
+2010-10-07  Jocelyn Turcotte  <jocelyn.turcotte@nokia.com>, Andras Becsi  <abecsi@webkit.org>, Balazs Kelemen  <kbalazs@webkit.org>
+
+        Reviewed by Kenneth Rohde Christiansen.
+
+        [Qt] Add WTR's InjectedBundle build files.
+        https://bugs.webkit.org/show_bug.cgi?id=47333
+
+        * WebKit2.pro:
+
 2010-10-07  Brady Eidson  <beidson@apple.com>
 
         Reviewed by Sam Weinig.

diff --git a/WebKit2/WebKit2.pro b/WebKit2/WebKit2.pro
index 6d11cad44d769c0a5f8b105dfa042ab5db5fcfc1..615d2bc3a2451d8642e19f5ee423c4be8a0b7f6f 100644 (file)
--- a/WebKit2/WebKit2.pro
+++ b/WebKit2/WebKit2.pro
@@ -103,6 +103,7 @@ INCLUDEPATH = \
     $$INCLUDEPATH
 
 INCLUDEPATH = \
+    $$PWD \
     Platform \
     Platform/CoreIPC \
     Shared \
@@ -308,6 +309,7 @@ SOURCES += \
     Platform/qt/RunLoopQt.cpp \
     Platform/qt/SharedMemoryQt.cpp \
     Platform/qt/WorkQueueQt.cpp \
+    Shared/API/c/WKArray.cpp \
     Shared/API/c/WKCertificateInfo.cpp \
     Shared/API/c/WKNumber.cpp \
     Shared/API/c/WKSerializedScriptValue.cpp \
@@ -378,7 +380,12 @@ SOURCES += \
     UIProcess/WebProcessManager.cpp \
     UIProcess/WebProcessProxy.cpp \
     UIProcess/WebUIClient.cpp \
+    WebProcess/InjectedBundle/API/c/WKBundle.cpp \
+    WebProcess/InjectedBundle/API/c/WKBundleFrame.cpp \
     WebProcess/InjectedBundle/API/c/WKBundleHitTestResult.cpp \
+    WebProcess/InjectedBundle/API/c/WKBundleNodeHandle.cpp \
+    WebProcess/InjectedBundle/API/c/WKBundlePage.cpp \
+    WebProcess/InjectedBundle/API/c/WKBundleScriptWorld.cpp \
     WebProcess/InjectedBundle/DOM/InjectedBundleNodeHandle.cpp \
     WebProcess/InjectedBundle/DOM/InjectedBundleRangeHandle.cpp \
     WebProcess/InjectedBundle/InjectedBundle.cpp \

diff --git a/WebKitTools/ChangeLog b/WebKitTools/ChangeLog
index a9535b6c959435c4914afbe717d7721666a483d5..eea45c3fabae8836c72ee50b520688f0c122563c 100644 (file)
--- a/WebKitTools/ChangeLog
+++ b/WebKitTools/ChangeLog
@@ -1,3 +1,17 @@
+2010-10-07  Jocelyn Turcotte  <jocelyn.turcotte@nokia.com>, Andras Becsi  <abecsi@webkit.org>, Balazs Kelemen  <kbalazs@webkit.org>
+
+        Reviewed by Kenneth Rohde Christiansen.
+
+        [Qt] Add WTR's InjectedBundle build files.
+        https://bugs.webkit.org/show_bug.cgi?id=47333
+
+        * Scripts/webkitdirs.pm:
+        * WebKitTestRunner/DerivedSources.pro: Added.
+        * WebKitTestRunner/InjectedBundle/qt/InjectedBundle.pro: Added.
+        * WebKitTestRunner/WebKitTestRunner.pro: Added.
+        * WebKitTestRunner/qt/DerivedSources.pro: Removed.
+        Content merged in ../DerivedSources.pro
+
 2010-10-07  Sheriff Bot  <webkit.review.bot@gmail.com>
 
         Unreviewed, rolling out r69315.

diff --git a/WebKitTools/Scripts/webkitdirs.pm b/WebKitTools/Scripts/webkitdirs.pm
index 2df26f79ee54dd7c0362c0df807b62f937d9f4a2..48dadcbf259f632c61ac7df4e96bb32a420cbb0f 100644 (file)
--- a/WebKitTools/Scripts/webkitdirs.pm
+++ b/WebKitTools/Scripts/webkitdirs.pm
@@ -1530,7 +1530,9 @@ sub buildQMakeProject($@)
     my @subdirs = ("JavaScriptCore", "WebCore", "WebKit/qt/Api");
     if (grep { $_ eq "CONFIG+=webkit2"} @buildArgs) {
         push @subdirs, "WebKit2";
-        push @subdirs, "WebKitTools/WebKitTestRunner/qt";
+
+        # Uncomment when WTR is ready upstream
+        #push @subdirs, "WebKitTools/WebKitTestRunner";
     }
 
     for my $subdir (@subdirs) {

diff --git a/WebKitTools/WebKitTestRunner/DerivedSources.pro b/WebKitTools/WebKitTestRunner/DerivedSources.pro
new file mode 100644 (file)
index 0000000..bab70cc
--- /dev/null
+++ b/WebKitTools/WebKitTestRunner/DerivedSources.pro
@@ -0,0 +1,57 @@
+# DerivedSources - qmake build info
+
+CONFIG -= debug_and_release
+
+TEMPLATE = lib
+TARGET = dummy
+
+QMAKE_EXTRA_TARGETS += generated_files
+
+GENERATED_SOURCES_DIR = generated
+
+IDL_BINDINGS += \
+    InjectedBundle/Bindings/EventSendingController.idl \
+    InjectedBundle/Bindings/GCController.idl \
+    InjectedBundle/Bindings/LayoutTestController.idl \
+
+defineTest(addExtraCompiler) {
+    eval($${1}.CONFIG = target_predeps no_link)
+    eval($${1}.variable_out =)
+    eval($${1}.dependency_type = TYPE_C)
+
+    wkScript = $$eval($${1}.wkScript)
+    eval($${1}.depends += $$wkScript)
+
+    export($${1}.CONFIG)
+    export($${1}.variable_out)
+    export($${1}.dependency_type)
+    export($${1}.depends)
+
+    QMAKE_EXTRA_COMPILERS += $$1
+    generated_files.depends += compiler_$${1}_make_all
+    export(QMAKE_EXTRA_COMPILERS)
+    export(generated_files.depends)
+    return(true)
+}
+
+SRC_ROOT_DIR = $$replace(PWD, /WebKitTools/WebKitTestRunner, /)
+
+# Make sure forwarded headers needed by this project are present
+fwheader_generator.commands = perl $${SRC_ROOT_DIR}/WebKitTools/Scripts/generate-forwarding-headers.pl $${SRC_ROOT_DIR}/WebKitTools/WebKitTestRunner $${OUTPUT_DIR}/include qt
+fwheader_generator.depends  = $${SRC_ROOT_DIR}/WebKitTools/Scripts/generate-forwarding-headers.pl
+generated_files.depends     += fwheader_generator
+QMAKE_EXTRA_TARGETS         += fwheader_generator
+
+# GENERATOR 1: IDL compiler
+idl.output = $${GENERATED_SOURCES_DIR}/JS${QMAKE_FILE_BASE}.cpp
+idl.input = IDL_BINDINGS
+idl.wkScript = $$PWD/../../WebCore/bindings/scripts/generate-bindings.pl
+idl.commands = perl -I$$PWD/../../WebCore/bindings/scripts -I$$PWD/InjectedBundle/Bindings $$idl.wkScript --defines \"\" --generator TestRunner --include $$PWD/InjectedBundle/Bindings --outputDir $$GENERATED_SOURCES_DIR --preprocessor \"$${QMAKE_MOC} -E\" ${QMAKE_FILE_NAME}
+idl.depends = $$PWD/../../WebCore/bindings/scripts/CodeGenerator.pm \
+              $$PWD/InjectedBundle/Bindings/CodeGeneratorTestRunner.pm \
+              $$PWD/../../WebCore/bindings/scripts/IDLParser.pm \
+              $$PWD/../../WebCore/bindings/scripts/IDLStructure.pm \
+              $$PWD/../../WebCore/bindings/scripts/InFilesParser.pm \
+              $$PWD/../../WebCore/bindings/scripts/generate-bindings.pl
+addExtraCompiler(idl)
+

diff --git a/WebKitTools/WebKitTestRunner/InjectedBundle/qt/InjectedBundle.pro b/WebKitTools/WebKitTestRunner/InjectedBundle/qt/InjectedBundle.pro
new file mode 100644 (file)
index 0000000..d596f33
--- /dev/null
+++ b/WebKitTools/WebKitTestRunner/InjectedBundle/qt/InjectedBundle.pro
@@ -0,0 +1,69 @@
+TEMPLATE = lib
+
+isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../../../..
+
+SOURCES += \
+    ../InjectedBundle.cpp \
+    ../InjectedBundle.h \
+    ../InjectedBundleMain.cpp \
+    ../InjectedBundlePage.cpp \
+    ../InjectedBundlePage.h \
+    ../EventSendingController.cpp \
+    ../EventSendingController.h \
+    ../GCController.cpp \
+    ../GCController.h \
+    ../LayoutTestController.cpp \
+    ../LayoutTestController.h \
+    ../Bindings/JSWrapper.cpp \
+    ActivateFontsQt.cpp \
+    LayoutTestControllerQt.cpp \
+    $$OUTPUT_DIR/WebKitTools/WebKitTestRunner/generated/JSEventSendingController.cpp \
+    $$OUTPUT_DIR/WebKitTools/WebKitTestRunner/generated/JSGCController.cpp \
+    $$OUTPUT_DIR/WebKitTools/WebKitTestRunner/generated/JSLayoutTestController.cpp \
+
+HEADERS += \
+    ../ActivateFonts.h \
+    ../EventSendingController.h \
+    ../GCController.h \
+    ../InjectedBundle.h \
+    ../InjectedBundlePage.h \
+    ../LayoutTestController.h \
+
+!CONFIG(release, debug|release) {
+    OBJECTS_DIR = obj/debug
+} else { # Release
+    OBJECTS_DIR = obj/release
+}
+
+include(../../../../WebKit.pri)
+include(../../../../JavaScriptCore/JavaScriptCore.pri)
+addJavaScriptCoreLib(../../../../JavaScriptCore)
+include(../../../../WebKit2/WebKit2.pri)
+addWebKit2Lib(../../../../WebKit2)
+
+INCLUDEPATH += \
+    $$PWD \
+    $$PWD/.. \
+    $$PWD/../.. \
+    $$PWD/../Bindings \
+    $$PWD/../../../../JavaScriptCore \
+    $$PWD/../../../../JavaScriptCore/wtf \
+    $$PWD/../../../../WebKit2 \
+    $$PWD/../../../../WebKit2/Shared \
+    $$OUTPUT_DIR/WebKitTools/WebKitTestRunner/generated
+
+INCLUDEPATH += \
+    $$OUTPUT_DIR/include \
+    $$OUTPUT_DIR/WebCore/generated
+
+PREFIX_HEADER = $$PWD/../../WebKitTestRunnerPrefix.h
+QMAKE_CXXFLAGS += "-include $$PREFIX_HEADER"
+
+unix:!mac {
+    CONFIG += link_pkgconfig
+    PKGCONFIG += fontconfig
+}
+
+TARGET = WTRInjectedBundle
+DESTDIR = $$OUTPUT_DIR/lib
+!CONFIG(standalone_package): CONFIG -= app_bundle

diff --git a/WebKitTools/WebKitTestRunner/WebKitTestRunner.pro b/WebKitTools/WebKitTestRunner/WebKitTestRunner.pro
new file mode 100644 (file)
index 0000000..677abb3
--- /dev/null
+++ b/WebKitTools/WebKitTestRunner/WebKitTestRunner.pro
@@ -0,0 +1,5 @@
+TEMPLATE = subdirs
+
+SUBDIRS = qt/WebKitTestRunner.pro \
+          InjectedBundle/qt/InjectedBundle.pro \
+

diff --git a/WebKitTools/WebKitTestRunner/qt/DerivedSources.pro b/WebKitTools/WebKitTestRunner/qt/DerivedSources.pro
deleted file mode 100644 (file)
index 6cd716e..0000000
--- a/WebKitTools/WebKitTestRunner/qt/DerivedSources.pro
+++ /dev/null
@@ -1,18 +0,0 @@
-TEMPLATE = lib
-TARGET = dummy
-
-CONFIG -= debug_and_release
-
-SRC_ROOT_DIR = $$replace(PWD, /WebKitTools/WebKitTestRunner/qt, /)
-
-wtr_fwheader_generator.commands = perl $${SRC_ROOT_DIR}/WebKitTools/Scripts/generate-forwarding-headers.pl $${SRC_ROOT_DIR}/WebKitTools/WebKitTestRunner $${OUTPUT_DIR}/include qt
-wtr_fwheader_generator.depends  = $${SRC_ROOT_DIR}/WebKitTools/Scripts/generate-forwarding-headers.pl
-generated_files.depends     += wtr_fwheader_generator
-QMAKE_EXTRA_TARGETS         += wtr_fwheader_generator
-
-jsc_fwheader_generator.commands = perl $${SRC_ROOT_DIR}/WebKitTools/Scripts/generate-forwarding-headers.pl $${SRC_ROOT_DIR}/JavaScriptCore/API $${OUTPUT_DIR}/include qt
-jsc_fwheader_generator.depends  = $${SRC_ROOT_DIR}/WebKitTools/Scripts/generate-forwarding-headers.pl
-generated_files.depends     += jsc_fwheader_generator
-QMAKE_EXTRA_TARGETS         += jsc_fwheader_generator
-
-QMAKE_EXTRA_TARGETS        += generated_files