2008-11-20 Simon Fraser <simon.fraser@apple.com>
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.59)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [0])
5 m4_define([webkit_micro_version], [3])
6
7 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
8
9 AC_CONFIG_HEADERS([autotoolsconfig.h])
10 AC_CANONICAL_SYSTEM
11
12 WEBKIT_MAJOR_VERSION=webkit_major_version
13 WEBKIT_MINOR_VERSION=webkit_minor_version
14 WEBKIT_MICRO_VERSION=webkit_micro_version
15 AC_SUBST(WEBKIT_MAJOR_VERSION)
16 AC_SUBST(WEBKIT_MINOR_VERSION)
17 AC_SUBST(WEBKIT_MICRO_VERSION)
18
19 AC_CONFIG_SRCDIR([WebCore/config.h])
20
21 dnl # Libtool library version, not to confuse with API version
22 dnl # see http://www.gnu.org/software/libtool/manual.html#Versioning
23 LIBWEBKITGTK_VERSION=1:0:0
24 AC_SUBST([LIBWEBKITGTK_VERSION])
25
26 AM_INIT_AUTOMAKE([foreign subdir-objects])
27
28 # host checking - inspired by the GTK+ configure.in
29 # TODO: os_mac, os_bsd
30 AC_MSG_CHECKING([for native Win32])
31 case "$host" in
32      *-*-mingw*)
33        os_win32=yes
34        ;;
35      *)
36        os_win32=no
37        ;;
38 esac
39 AC_MSG_RESULT([$os_win32])
40
41 case "$host" in
42      *-*-linux*)
43        os_linux=yes
44        ;;
45      *-*-freebsd*)
46        os_freebsd=yes
47        ;;
48      *-*-darwin*)
49        os_darwin=yes
50        ;;
51 esac
52
53 case "$host_os" in
54      gnu* | linux* | k*bsd*-gnu)
55        os_gnu=yes
56        ;;
57      *)
58        os_gnu=no
59        ;;
60 esac
61
62 # If CXXFLAGS and CFLAGS are unset, default to empty.
63 # This is to tell automake not to include '-g' if CXXFLAGS is not set
64 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
65 if test -z "$CXXFLAGS"; then
66    CXXFLAGS=""
67 fi
68 if test -z "$CFLAGS"; then
69    CFLAGS=""
70 fi
71
72 AM_PROG_CC_STDC
73 AM_PROG_CC_C_O
74 AC_PROG_CXX
75 AC_PROG_INSTALL
76 AC_DISABLE_STATIC
77 AC_LIBTOOL_WIN32_DLL
78 AC_PROG_LIBTOOL
79 AC_SYS_LARGEFILE
80 DOLT
81
82 # check for -fvisibility=hidden compiler support (GCC >= 4)
83 saved_CFLAGS="$CFLAGS"
84 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
85 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
86 AC_COMPILE_IFELSE([char foo;],
87       [ AC_MSG_RESULT([yes])
88         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
89         AC_MSG_RESULT([no]))
90 CFLAGS="$saved_CFLAGS"
91 AC_SUBST(SYMBOL_VISIBILITY)
92 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
93
94 AC_PATH_PROG(PERL, perl)
95 if test -z "$PERL"; then
96    AC_MSG_ERROR([You need 'perl' to compile WebKit])
97 fi
98
99 AC_PATH_PROG(BISON, bison)
100 if test -z "$BISON"; then
101    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
102 fi
103
104 AC_PATH_PROG(FLEX, flex)
105 if test -z "$FLEX"; then
106    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
107 else
108    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
109    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
110       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
111 fi
112
113 AC_PATH_PROG(GPERF, gperf)
114 if test -z "$GPERF"; then
115    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
116 fi
117
118 AC_PATH_PROG(MV, mv)
119 if test -z "$MV"; then
120    AC_MSG_ERROR([You need 'mv' to compile WebKit])
121 fi
122
123 # GTK+ port only
124 # Check for glib-genmarshal and glib-mkenums
125 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
126 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
127 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
128    AC_MSG_ERROR([You need the GLib dev tools in your path])
129 fi
130
131 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
132 # doesn't exist)
133 AC_LANG_PUSH([C++])
134 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
135 AC_LANG_POP([C++])
136
137 # C/C++ Language Features
138 AC_C_CONST
139 AC_C_INLINE
140 AC_C_VOLATILE
141
142 # C/C++ Headers
143 AC_HEADER_STDC
144 AC_HEADER_STDBOOL
145
146 # pthread (not needed on Windows)
147 if test "$os_win32" = "no"; then
148 AC_CHECK_HEADERS([pthread.h],
149                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
150                  AC_MSG_ERROR([pthread support is required to build WebKit]))
151 fi
152
153 # check for libjpeg the way Gtk does it.
154 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
155                    jpeg_ok=yes, jpeg_ok=no
156                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
157 if test "$jpeg_ok" = yes; then
158    AC_MSG_CHECKING([for jpeglib])
159    AC_TRY_CPP(
160 [#include <stdio.h>
161 #undef PACKAGE
162 #undef VERSION
163 #undef HAVE_STDLIB_H
164 #include <jpeglib.h>],
165          jpeg_ok=yes,
166          jpeg_ok=no)
167    AC_MSG_RESULT($jpeg_ok)
168    if test "$jpeg_ok" = yes; then
169       JPEG_LIBS="-ljpeg"
170       # should we check for progressive JPEG like GTK+ as well?
171    else
172       AC_MSG_ERROR([JPEG library (libjpeg) not found])
173    fi
174 fi
175 AC_SUBST([JPEG_LIBS])
176
177 # check for pkg-config
178 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
179 if test "$PKG_CONFIG" = "no"; then
180    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
181 fi
182
183 # Check for libpng the way Gtk+ does it
184 AC_MSG_CHECKING(for libpng12)
185 if $PKG_CONFIG --exists libpng12 ; then
186     AC_MSG_RESULT(yes)
187     PNG_LIBS=`$PKG_CONFIG --libs libpng12`
188 else
189   AC_MSG_RESULT(no)
190   AC_CHECK_LIB(png, png_read_info,
191     [AC_CHECK_HEADER(png.h,
192       png_ok=yes,
193       png_ok=no)],
194     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
195   if test "$png_ok" = yes; then
196     AC_MSG_CHECKING([for png_structp in png.h])
197     AC_TRY_COMPILE([#include <png.h>],
198       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
199       png_ok=yes,
200       png_ok=no)
201     AC_MSG_RESULT($png_ok)
202     if test "$png_ok" = yes; then
203       PNG_LIBS='-lpng -lz'
204     else
205       AC_MSG_ERROR([PNG library (libpng) not found])
206     fi
207   else
208    AC_MSG_ERROR([PNG library (libpng) not found])
209   fi
210 fi
211 AC_SUBST([PNG_LIBS])
212
213 # determine the Unicode backend
214 AC_MSG_CHECKING([the Unicode backend to use])
215 AC_ARG_WITH(unicode_backend,
216             AC_HELP_STRING([--with-unicode-backend=@<:@icu@:>@],
217                            [Select Unicode backend [default=icu]]),
218             [],[unicode_backend="icu"])
219
220 case "$unicode_backend" in
221      icu) ;;
222      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu.]) ;;
223 esac
224
225 AC_MSG_RESULT([$unicode_backend])
226
227 if test "$unicode_backend" = "icu"; then
228         if test "$os_darwin" = "yes"; then
229                 UNICODE_CFLAGS="-I\$(srcdir)/JavaScriptCore/icu -I\$(srcdir)/WebCore/icu"
230                 UNICODE_LIBS="-licucore"
231         elif test "$os_win32" = "yes"; then
232                 UNICODE_CFLAGS=""
233                 UNICODE_LIBS="-licuin -licuuc"
234         else
235                 AC_PATH_PROG(icu_config, icu-config, no)
236                 if test "$icu_config" = "no"; then
237                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
238                 fi
239
240                 # We don't use --cflags as this gives us a lot of things that we don't
241                 # necessarily want, like debugging and optimization flags
242                 # See man (1) icu-config for more info.
243                 UNICODE_CFLAGS=`$icu_config --cppflags`
244                 UNICODE_LIBS=`$icu_config --ldflags`
245         fi
246 fi
247
248 AC_SUBST([UNICODE_CFLAGS])
249 AC_SUBST([UNICODE_LIBS])
250
251 # determine the GDK/GTK+ target
252 AC_MSG_CHECKING([the target windowing system])
253 AC_ARG_WITH(target,
254             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
255                            [Select webkit target [default=x11]]),
256             [],[with_target="x11"])
257
258 case "$with_target" in
259      x11|win32|quartz|directfb) ;;
260      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
261 esac
262
263 AC_MSG_RESULT([$with_target])
264
265 AC_MSG_CHECKING([for Hildon UI extensions])
266 AC_ARG_WITH(hildon,
267             AC_HELP_STRING([--with-hildon],
268                            [Use Hildon UI extensions [default=no]]),
269             [],[with_hildon="no"])
270 AC_MSG_RESULT([$with_hildon])
271
272 if test "$with_hildon" = "yes"; then
273     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
274     PKG_CHECK_MODULES([HILDON], [hildon-1])
275     AC_SUBST([HILDON_CPPFLAGS])
276     AC_SUBST([HILDON_CFLAGS])
277     AC_SUBST([HILDON_LIBS])
278 fi
279
280 # determine the http backend
281 AC_MSG_CHECKING([the HTTP backend to use])
282 AC_ARG_WITH(http_backend,
283             AC_HELP_STRING([--with-http-backend=@<:@curl/soup@:>@],
284                            [Select HTTP backend [default=curl]]),
285             [],[with_http_backend="curl"])
286
287 case "$with_http_backend" in
288      curl|soup) ;;
289      *) AC_MSG_ERROR([Invalid HTTP backend: must be curl, soup.]) ;;
290 esac
291
292 AC_MSG_RESULT([$with_http_backend])
293
294 # minimum base dependencies
295 CAIRO_REQUIRED_VERSION=1.2
296 FONTCONFIG_REQUIRED_VERSION=2.4
297 FREETYPE2_REQUIRED_VERSION=9.0
298 LIBXML_REQUIRED_VERSION=2.6
299
300 # minimum GTK+ base dependencies
301 GLIB_REQUIRED_VERSION=2.0
302 GOBJECT_REQUIRED_VERSION=2.0
303 GTHREAD_REQUIRED_VERSION=2.0
304 PANGO_REQUIRED_VERSION=1.0
305 GTK_REQUIRED_VERSION=2.8
306
307 # optional modules
308 LIBCURL_REQUIRED_VERSION=7.15
309 LIBSOUP_REQUIRED_VERSION=2.23
310 LIBXSLT_REQUIRED_VERSION=1.1.7
311 SQLITE_REQUIRED_VERSION=3.0
312 GSTREAMER_REQUIRED_VERSION=0.10
313
314 PKG_CHECK_MODULES([GLOBALDEPS],
315                   [glib-2.0 >= $GLIB_REQUIRED_VERSION
316                   gobject-2.0 >= $GOBJECT_REQUIRED_VERSION
317                   gthread-2.0 >= $GTHREAD_REQUIRED_VERSION])
318 AC_SUBST([GLOBALDEPS_CFLAGS])
319 AC_SUBST([GLOBALDEPS_LIBS])
320
321 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
322 AC_SUBST(LIBXML_CFLAGS)
323 AC_SUBST(LIBXML_LIBS)
324
325 PKG_CHECK_MODULES(PANGO, pango >= $PANGO_REQUIRED_VERSION)
326 AC_SUBST(PANGO_CFLAGS)
327 AC_SUBST(PANGO_LIBS)
328
329 # check for target-specific dependencies
330 if test "$with_target" = "directfb"; then
331    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
332    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
333    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
334 else
335    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
336    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED_VERSION)
337
338    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
339       # check for XT
340       PKG_CHECK_MODULES([XT],
341                         [xt],
342                         [xt_has_pkg_config=yes],
343                         [xt_has_pkg_config=no])
344       # some old versions of Xt do not provide xt.pc, so try to link against Xt
345       # and if it's installed fall back to just adding -lXt
346       if test "$xt_has_pkg_config" = "no"; then
347          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
348          # we don't care about the XtOpenDisplay symbol but only about the
349          # existence of libXt
350          AC_CHECK_LIB([Xt], [XtOpenDisplay],
351                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
352                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
353       fi
354       AC_SUBST([XT_CFLAGS])
355       AC_SUBST([XT_LIBS])
356       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
357    fi
358 fi
359 AC_SUBST(GTK_CFLAGS)
360 AC_SUBST(GTK_LIBS)
361 AC_SUBST(CAIRO_CFLAGS)
362 AC_SUBST(CAIRO_LIBS)
363
364 # check whether to build with debugging enabled
365 AC_MSG_CHECKING([whether to do a debug build])
366 AC_ARG_ENABLE(debug,
367               AC_HELP_STRING([--enable-debug],
368                              [turn on debugging [default=no]]),
369               [],[enable_debug="no"])
370 AC_MSG_RESULT([$enable_debug])
371
372 # check whether to enable optimized builds
373 AC_MSG_CHECKING([whether to enable optimized builds])
374 AC_ARG_ENABLE(optimizations,
375               AC_HELP_STRING([--enable-optimizations],
376                              [turn on optimize builds (GCC only)
377                              [default=yes]]),
378               [enable_optimizations=$enableval],
379               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
380 AC_MSG_RESULT([$enable_optimizations])
381
382 # check whether to enable dashboard support
383 AC_MSG_CHECKING([whether to enable Dashboard support])
384 AC_ARG_ENABLE(dashboard_support,
385               AC_HELP_STRING([--enable-dashboard-support],
386                              [enable Dashboard support [default=yes]]),
387               [],[enable_dashboard_support="yes"])
388 AC_MSG_RESULT([$enable_dashboard_support])
389
390 # check whether to enable HTML5 Offline Web Applications support
391 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
392 AC_ARG_ENABLE(offline_web_applications,
393               AC_HELP_STRING([--enable-offline-web-applications],
394                              [enable HTML5 offline web applications support [default=yes]]),
395               [],[enable_offline_web_applications="yes"])
396 AC_MSG_RESULT([$enable_offline_web_applications])
397
398 # check whether to enable HTML5 client-side session and persitent storage support
399 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
400 AC_ARG_ENABLE(dom_storage,
401               AC_HELP_STRING([--enable-dom-storage],
402                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
403               [],[enable_dom_storage="yes"])
404 AC_MSG_RESULT([$enable_dom_storage])
405
406 # check whether to build with database support
407 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
408 AC_ARG_ENABLE(database,
409               AC_HELP_STRING([--enable-database],
410                              [enable HTML5 client-side database storage support [default=yes]]),
411               [],[enable_database="yes"])
412 AC_MSG_RESULT([$enable_database])
413
414 # check whether to build with icon database support
415 AC_MSG_CHECKING([whether to enable icon database support])
416 AC_ARG_ENABLE(icon_database,
417               AC_HELP_STRING([--enable-icon-database],
418                              [enable icon database [default=yes]]),
419               [],[enable_icon_database="yes"])
420 AC_MSG_RESULT([$enable_icon_database])
421
422 # check whether to enable HTML5 audio/video support
423 AC_MSG_CHECKING([whether to enable HTML5 video support])
424 AC_ARG_ENABLE(video,
425               AC_HELP_STRING([--enable-video],
426                              [enable HTML5 video support [default=no]]),
427               [],[enable_video="no"])
428 AC_MSG_RESULT([$enable_video])
429
430 # check whether to enable XPath support
431 AC_MSG_CHECKING([whether to enable XPath support])
432 AC_ARG_ENABLE(xpath,
433               AC_HELP_STRING([--enable-xpath],
434                              [enable support for XPath [default=yes]]),
435               [],[enable_xpath="yes"])
436 AC_MSG_RESULT([$enable_xpath])
437
438 # check whether to enable XSLT support
439 AC_MSG_CHECKING([whether to enable XSLT support])
440 AC_ARG_ENABLE(xslt,
441               AC_HELP_STRING([--enable-xslt],
442                              [enable support for XSLT [default=yes]]),
443               [],[enable_xslt="yes"])
444 AC_MSG_RESULT([$enable_xslt])
445
446 # check whether to enable SVG support
447 AC_MSG_CHECKING([whether to enable SVG support])
448 AC_ARG_ENABLE(svg,
449               AC_HELP_STRING([--enable-svg],
450                              [enable support for SVG [default=yes]]),
451               [],[enable_svg="yes"])
452 AC_MSG_RESULT([$enable_svg])
453
454 # check whether to enable WML support
455 AC_MSG_CHECKING([whether to enable WML support])
456 AC_ARG_ENABLE(wml,
457               AC_HELP_STRING([--enable-wml],
458                              [enable support for WML [default=no]]),
459               [],[enable_wml="no"])
460 AC_MSG_RESULT([$enable_wml])
461
462 # turn off svg features if --disable-svg is requested
463 if test "$enable_svg" = "no"; then
464    enable_svg_animation=no
465    enable_svg_filters=no
466    enable_svg_fonts=no
467    enable_svg_foreign_object=no
468    enable_svg_as_image=no
469    enable_svg_use_element=no
470 fi
471
472 # check whether to enable support for SVG animation
473 AC_MSG_CHECKING([whether to enable support for SVG animation])
474 AC_ARG_ENABLE(svg_animation,
475               AC_HELP_STRING([--enable-svg-animation],
476                              [enable support for SVG animation (experimental) [default=yes]]),
477               [],[enable_svg_animation="yes"])
478 AC_MSG_RESULT([$enable_svg_animation])
479
480 # check whether to enable support for SVG filters
481 AC_MSG_CHECKING([whether to enable support for SVG filters])
482 AC_ARG_ENABLE(svg_filters,
483               AC_HELP_STRING([--enable-svg-filters],
484                              [enable support for SVG filters (experimental) [default=no]]),
485               [],[enable_svg_filters="no"])
486 AC_MSG_RESULT([$enable_svg_filters])
487
488 # check whether to enable support for SVG fonts
489 AC_MSG_CHECKING([whether to enable support for SVG fonts])
490 AC_ARG_ENABLE(svg_fonts,
491               AC_HELP_STRING([--enable-svg-fonts],
492                              [enable support for SVG fonts (experimental) [default=yes]]),
493               [],[enable_svg_fonts="yes"])
494 AC_MSG_RESULT([$enable_svg_fonts])
495
496 # check whether to enable foreign objects support for SVG
497 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
498 AC_ARG_ENABLE(svg_foreign_object,
499               AC_HELP_STRING([--enable-svg-foreign-object],
500                              [enable support for SVG foreign objects (experimental) [default=yes]]),
501               [],[enable_svg_foreign_object="yes"])
502 AC_MSG_RESULT([$enable_svg_foreign_object])
503
504 # check whether to enable SVG As Image support
505 AC_MSG_CHECKING([whether to enable SVG as Image support])
506 AC_ARG_ENABLE(svg_as_image,
507               AC_HELP_STRING([--enable-svg-as-image],
508                              [enable SVG as Image support (experimental) [default=yes]]),
509               [],[enable_svg_as_image="yes"])
510 AC_MSG_RESULT([$enable_svg_as_image])
511
512 # check whether to enable SVG USE element support
513 AC_MSG_CHECKING([whether to enable support for SVG use element])
514 AC_ARG_ENABLE(svg_use_element,
515               AC_HELP_STRING([--enable-svg-use-element],
516                              [enable SVG use element support (experimental) [default=yes]]),
517               [],[enable_svg_use_element="yes"])
518 AC_MSG_RESULT([$enable_svg_use_element])
519
520 # check for SVG features, enabling SVG if necessary
521 if test "$enable_svg_animation" = "yes" || \
522    test "$enable_svg_filters" = "yes" || \
523    test "$enable_svg_fonts" = "yes" || \
524    test "$enable_svg_foreign_object" = "yes" || \
525    test "$enable_svg_as_image" = "yes" || \
526    test "$enable_svg_use_element" = "yes"; then
527    svg_flags=yes
528    if test "$enable_svg" = "no"; then
529        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
530        enable_svg=yes
531    fi
532 fi
533
534 # check whether to enable code coverage
535 AC_MSG_CHECKING([whether to enable code coverage support])
536 AC_ARG_ENABLE(coverage,
537               AC_HELP_STRING([--enable-coverage],
538                              [enable code coverage support [default=no]]),
539               [],[enable_coverage="no"])
540 AC_MSG_RESULT([$enable_coverage])
541
542 # check whether to enable FastMalloc
543 AC_MSG_CHECKING([whether to enable optimized memory allocator])
544 AC_ARG_ENABLE(fast_malloc,
545               AC_HELP_STRING([--enable-fast-malloc],
546                              [enable optimized memory allocator default=yes, default=no for debug builds]),
547               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
548 AC_MSG_RESULT([$enable_fast_malloc])
549
550 AC_MSG_CHECKING([whether to enable JIT compilation])
551 AC_ARG_ENABLE([jit],
552               AC_HELP_STRING([--enable-jit],
553                              [Enable JIT compilation default=yes]),
554               [],[enable_jit="yes"])
555 if test "$enable_jit" = "yes"; then
556     case "$target_cpu" in
557         i*86)
558             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
559             AC_DEFINE([ENABLE_WREC], [1], [Define to enable WREC])
560         ;;
561         *)
562             enable_jit="no (CPU '$target_cpu' not supported)"
563         ;;
564     esac
565 fi
566 AC_MSG_RESULT([$enable_jit])
567
568 # determine the font backend
569 AC_MSG_CHECKING([the font backend to use])
570 AC_ARG_WITH(font_backend,
571             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
572                            [Select font backend [default=freetype]]),
573             [],[with_font_backend="freetype"])
574
575 case "$with_font_backend" in
576      freetype|pango) ;;
577      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
578 esac
579 AC_MSG_RESULT([$with_font_backend])
580
581 # Add '-g' flag to gcc if it's debug build
582 if test "$enable_debug" = "yes"; then
583    CXXFLAGS="$CXXFLAGS -g"
584    CFLAGS="$CFLAGS -g"
585 else
586    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
587 fi
588
589 # Add the appropriate 'O' level for optimized builds
590 if test "$enable_optimizations" = "yes"; then
591    CXXFLAGS="$CXXFLAGS -O2"
592    CFLAGS="$CFLAGS -O2"
593 else
594    CXXFLAGS="$CXXFLAGS -O0"
595    CFLAGS="$CFLAGS -O0"
596 fi
597
598 # check if curl is available
599 if test "$with_http_backend" = "curl"; then
600    PKG_CHECK_MODULES([LIBCURL],
601                      [libcurl >= $LIBCURL_REQUIRED_VERSION])
602    if test "$os_win32" = "yes"; then
603       LIBCURL_LIBS="$LIBCURL_LIBS -lws2_32"
604    fi
605    AC_SUBST([LIBCURL_CFLAGS])
606    AC_SUBST([LIBCURL_LIBS])
607 fi
608
609 if test "$with_http_backend" = "soup"; then
610    PKG_CHECK_MODULES([LIBSOUP],
611                      [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
612    AC_SUBST([LIBSOUP_CFLAGS])
613    AC_SUBST([LIBSOUP_LIBS])
614 fi
615
616 # check if FreeType/FontConfig are available
617 if test "$with_font_backend" = "freetype"; then
618    if test "$with_target" = "directfb"; then
619    PKG_CHECK_MODULES([FREETYPE],
620                      [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
621                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
622    else
623    PKG_CHECK_MODULES([FREETYPE],
624                      [cairo-ft
625                      pangoft2
626                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
627                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
628    fi
629    AC_SUBST([FREETYPE_CFLAGS])
630    AC_SUBST([FREETYPE_LIBS])
631 fi
632
633 # check if sqlite 3 is available
634 if test "$enable_icon_database" = "yes" || \
635    test "$enable_database" = "yes" || \
636    test "$enable_offline_web_applications" = "yes" || \
637    test "$enable_dom_storage" = "yes"; then
638    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
639    AC_SUBST([SQLITE3_CFLAGS])
640    AC_SUBST([SQLITE3_LIBS])
641 fi
642
643 # check if libxslt is available
644 if test "$enable_xslt" = "yes"; then
645    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
646    AC_SUBST([LIBXSLT_CFLAGS])
647    AC_SUBST([LIBXSLT_LIBS])
648 fi
649
650 # check if gstreamer is available
651 if test "$enable_video" = "yes"; then
652    PKG_CHECK_MODULES([GSTREAMER],
653                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
654                      gstreamer-base-0.10,
655                      gstreamer-plugins-base-0.10])
656    AC_SUBST([GSTREAMER_CFLAGS])
657    AC_SUBST([GSTREAMER_LIBS])
658 fi
659
660 # check for code coverage support
661 if test "$enable_coverage" = "yes"; then
662    COVERAGE_CFLAGS="-MD"
663    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
664    AC_SUBST([COVERAGE_CFLAGS])
665    AC_SUBST([COVERAGE_LDFLAGS])
666 fi
667
668 # check for HTML features
669 if test "$enable_video" = "yes"; then
670     html_flags=yes
671 fi
672
673 # OS conditionals
674 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
675 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
676 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
677 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
678 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
679
680 # target conditionals
681 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
682 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
683 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
684 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
685
686 # HTTP backend conditionals
687 AM_CONDITIONAL([USE_CURL], [test "$with_http_backend" = "curl"])
688 AM_CONDITIONAL([USE_SOUP], [test "$with_http_backend" = "soup"])
689
690 # Font backend conditionals
691 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
692 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
693
694 # WebKit feature conditionals
695 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
696 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
697 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
698 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
699 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
700 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
701 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
702 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
703 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
704 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
705 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
706 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
707 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
708 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
709 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
710 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
711 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
712 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
713 AM_CONDITIONAL([ENABLE_WML],[test "$enable_wml" = "yes"])
714 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
715 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
716
717 AC_CONFIG_FILES([
718 GNUmakefile
719 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
720 WebKit/gtk/webkit/webkitversion.h
721 ]
722 )
723
724 AC_OUTPUT
725
726 echo "
727 WebKit was configured with the following options:
728
729 Build configuration:
730  Enable debugging (slow)                                  : $enable_debug
731  Enable GCC build optimization                            : $enable_optimizations
732  Code coverage support                                    : $enable_coverage
733  Unicode backend                                          : $unicode_backend
734  HTTP backend                                             : $with_http_backend
735  Font backend                                             : $with_font_backend
736  Optimized memory allocator                               : $enable_fast_malloc
737 Features:
738  JIT compilation                                          : $enable_jit
739  Dashboard support                                        : $enable_dashboard_support
740  HTML5 offline web applications support                   : $enable_offline_web_applications
741  HTML5 client-side session and persistent storage support : $enable_dom_storage
742  HTML5 client-side database storage support               : $enable_database
743  HTML5 video element support                              : $enable_video
744  Icon database support                                    : $enable_icon_database
745  SVG support                                              : $enable_svg
746  SVG animation support                                    : $enable_svg_animation
747  SVG filters support                                      : $enable_svg_filters
748  SVG fonts support                                        : $enable_svg_fonts
749  SVG foreign object support                               : $enable_svg_foreign_object
750  SVG as image support                                     : $enable_svg_as_image
751  SVG use element support                                  : $enable_svg_use_element
752  XPATH support                                            : $enable_xpath
753  XSLT support                                             : $enable_xslt
754  WML support                                              : $enable_wml
755 GTK+ configuration:
756  GDK target                                               : $with_target
757  Hildon UI extensions                                     : $with_hildon
758 "