e871aaeb3de6d503ae2dd789604c11b03dd71a08
[WebKit-https.git] / configure.ac
1 AC_INIT([WebKit],[0.1],[http://bugs.webkit.org/])
2
3 AC_PREREQ(2.59)
4
5 AC_CONFIG_HEADERS([aconfig.h])
6 AC_CONFIG_SRCDIR([WebCore/config.h])
7
8 # see http://www.gnu.org/software/libtool/manual.html#Versioning
9 LIBWEBKITGTK_VERSION=1:0:0
10 AC_SUBST([LIBWEBKITGTK_VERSION])
11
12 AM_INIT_AUTOMAKE([foreign subdir-objects])
13
14 AC_CANONICAL_HOST
15
16 # host checking - inspired by the GTK+ configure.in
17 # TODO: os_mac, os_bsd
18 AC_MSG_CHECKING([for native Win32])
19 case "$host" in
20      *-*-mingw*)
21        os_win32=yes
22        ;;
23      *)
24        os_win32=no
25        ;;
26 esac
27 AC_MSG_RESULT([$os_win32])
28
29 case "$host" in
30      *-*-linux*)
31        os_linux=yes
32        ;;
33      *-*-freebsd*)
34        os_freebsd=yes
35        ;;
36      *-*-darwin*)
37        os_darwin=yes
38        ;;
39 esac
40
41 # If CXXFLAGS and CFLAGS are unset, default to -O2
42 # This is to tell automake not to include '-g' if CXXFLAGS is not set
43 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
44 if test -z "$CXXFLAGS"; then
45    CXXFLAGS="-O2"
46 fi
47 if test -z "$CFLAGS"; then
48    CFLAGS="-O2"
49 fi
50
51 AM_PROG_CC_STDC
52 AM_PROG_CC_C_O
53 AC_PROG_CXX
54 AC_PROG_INSTALL
55 AC_DISABLE_STATIC
56 AC_LIBTOOL_WIN32_DLL
57 AC_PROG_LIBTOOL
58 DOLT
59
60 # check for -fvisibility=hidden compiler support (GCC >= 4)
61 saved_CFLAGS="$CFLAGS"
62 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
63 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
64 AC_COMPILE_IFELSE([char foo;],
65       [ AC_MSG_RESULT([yes])
66         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
67         AC_MSG_RESULT([no]))
68 CFLAGS="$saved_CFLAGS"
69 AC_SUBST(SYMBOL_VISIBILITY)
70 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
71
72 AC_PATH_PROG(PERL, perl)
73 if test -z "$PERL"; then
74    AC_MSG_ERROR([You need 'perl' to compile WebKit])
75 fi
76
77 AC_PATH_PROG(BISON, bison)
78 if test -z "$BISON"; then
79    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
80 fi
81
82 AC_PATH_PROG(FLEX, flex)
83 if test -z "$FLEX"; then
84    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
85 fi
86
87 AC_PATH_PROG(GPERF, gperf)
88 if test -z "$GPERF"; then
89    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
90 fi
91
92 AC_PATH_PROG(MV, mv)
93 if test -z "$MV"; then
94    AC_MSG_ERROR([You need 'mv' to compile WebKit])
95 fi
96
97 # GTK+ port only
98 # Check for glib-genmarshal and glib-mkenums
99 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
100 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
101 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
102    AC_MSG_ERROR([You need the GLib dev tools in your path])
103 fi
104
105 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
106 # doesn't exist)
107 AC_LANG_PUSH([C++])
108 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
109 AC_LANG_POP([C++])
110
111 # C/C++ Language Features
112 AC_C_CONST
113 AC_C_INLINE
114 AC_C_VOLATILE
115
116 # C/C++ Headers
117 AC_HEADER_STDC
118 AC_HEADER_STDBOOL
119
120 # pthread (not needed on Windows)
121 if test "$os_win32" = "no"; then
122 AC_CHECK_HEADERS([pthread.h],
123                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
124                  AC_MSG_ERROR([pthread support is required to build WebKit]))
125 fi
126
127 # libjpeg headers
128 AC_CHECK_HEADERS([jpeglib.h])
129
130 # check for pkg-config
131 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
132 if test "$PKG_CONFIG" = "no"; then
133    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
134 fi
135
136 # determine the Unicode backend
137 AC_MSG_CHECKING([the Unicode backend to use])
138 AC_ARG_WITH(unicode_backend,
139             AC_HELP_STRING([--with-unicode-backend=@<:@icu@:>@],
140                            [Select Unicode backend [default=icu]]),
141             [],[unicode_backend="icu"])
142
143 case "$unicode_backend" in
144      icu) ;;
145      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu.]) ;;
146 esac
147
148 AC_MSG_RESULT([$unicode_backend])
149
150 if test "$unicode_backend" = "icu"; then
151         if test "$os_darwin" = "yes"; then
152                 UNICODE_CFLAGS="-I\$(srcdir)/JavaScriptCore/icu -I\$(srcdir)/WebCore/icu"
153                 UNICODE_LIBS="-licucore"
154         elif test "$os_win32" = "yes"; then
155                 UNICODE_CFLAGS=""
156                 UNICODE_LIBS="-licuin -licuuc"
157         else
158                 AC_PATH_PROG(icu_config, icu-config, no)
159                 if test "$icu_config" = "no"; then
160                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
161                 fi
162
163                 # We don't use --cflags as this gives us a lot of things that we don't
164                 # necessarily want, like debugging and optimization flags
165                 # See man (1) icu-config for more info.
166                 UNICODE_CFLAGS=`$icu_config --cppflags`
167                 UNICODE_LIBS=`$icu_config --ldflags`
168         fi
169 fi
170
171 AC_SUBST([UNICODE_CFLAGS])
172 AC_SUBST([UNICODE_LIBS])
173
174 # determine the GDK/GTK+ target
175 AC_MSG_CHECKING([the target windowing system])
176 AC_ARG_WITH(target,
177             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
178                            [Select webkit target [default=x11]]),
179             [],[with_target="x11"])
180
181 case "$with_target" in
182      x11|win32|quartz|directfb) ;;
183      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
184 esac
185
186 AC_MSG_RESULT([$with_target])
187
188 AC_MSG_CHECKING([for Hildon UI extensions])
189 AC_ARG_WITH(hildon,
190             AC_HELP_STRING([--with-hildon],
191                            [Use Hildon UI extensions [default=no]]),
192             [],[with_hildon="no"])
193 AC_MSG_RESULT([$with_hildon])
194
195 if test "$with_hildon" = "yes"; then
196     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
197     PKG_CHECK_MODULES([HILDON], [hildon-1])
198     AC_SUBST([HILDON_CPPFLAGS])
199     AC_SUBST([HILDON_CFLAGS])
200     AC_SUBST([HILDON_LIBS])
201 fi
202
203 # determine the http backend
204 AC_MSG_CHECKING([the HTTP backend to use])
205 AC_ARG_WITH(http_backend,
206             AC_HELP_STRING([--with-http-backend=@<:@curl/soup@:>@],
207                            [Select HTTP backend [default=curl]]),
208             [],[with_http_backend="curl"])
209
210 case "$with_http_backend" in
211      curl|soup) ;;
212      *) AC_MSG_ERROR([Invalid HTTP backend: must be curl, soup.]) ;;
213 esac
214
215 AC_MSG_RESULT([$with_http_backend])
216
217 # minimum base dependencies
218 CAIRO_REQUIRED_VERSION=1.4
219 FONTCONFIG_REQUIRED_VERSION=2.4
220 FREETYPE2_REQUIRED_VERSION=9.0
221 LIBXML_REQUIRED_VERSION=2.6
222
223 # minimum GTK+ base dependencies
224 GLIB_REQUIRED_VERSION=2.0
225 GOBJECT_REQUIRED_VERSION=2.0
226 GTHREAD_REQUIRED_VERSION=2.0
227 PANGO_REQUIRED_VERSION=1.0
228 GTK_REQUIRED_VERSION=2.8
229
230 # optional modules
231 LIBCURL_REQUIRED_VERSION=7.15
232 LIBSOUP_REQUIRED_VERSION=2.23
233 LIBXSLT_REQUIRED_VERSION=1.1.7
234 SQLITE_REQUIRED_VERSION=3.0
235 GSTREAMER_REQUIRED_VERSION=0.10
236 GNOME_VFS_REQUIRED_VERSION=2.0
237
238 PKG_CHECK_MODULES([GLOBALDEPS],
239                   [glib-2.0 >= $GLIB_REQUIRED_VERSION
240                   gobject-2.0 >= $GOBJECT_REQUIRED_VERSION
241                   gthread-2.0 >= $GTHREAD_REQUIRED_VERSION])
242 AC_SUBST([GLOBALDEPS_CFLAGS])
243 AC_SUBST([GLOBALDEPS_LIBS])
244
245 PKG_CHECK_MODULES([WEBKITDEPS],
246                   [gtk+-2.0 >= $GTK_REQUIRED_VERSION
247                   pango >= $PANGO_REQUIRED_VERSION
248                   cairo >= $CAIRO_REQUIRED_VERSION
249                   libxml-2.0 >= $LIBXML_REQUIRED_VERSION])
250 AC_SUBST([WEBKITDEPS_CFLAGS])
251 AC_SUBST([WEBKITDEPS_LIBS])
252
253 # check whether to build with debugging enabled
254 AC_MSG_CHECKING([whether to do a debug build])
255 AC_ARG_ENABLE(debug,
256               AC_HELP_STRING([--enable-debug],
257                              [turn on debugging [default=no]]),
258               [],[enable_debug="no"])
259 AC_MSG_RESULT([$enable_debug])
260
261 # check whether to enable dashboard support
262 AC_MSG_CHECKING([whether to enable Dashboard support])
263 AC_ARG_ENABLE(dashboard_support,
264               AC_HELP_STRING([--enable-dashboard-support],
265                              [enable Dashboard support [default=yes]]),
266               [],[enable_dashboard_support="yes"])
267 AC_MSG_RESULT([$enable_dashboard_support])
268
269 # check whether to enable HTML5 Offline Web Applications support
270 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
271 AC_ARG_ENABLE(offline_web_applications,
272               AC_HELP_STRING([--enable-offline-web-applications],
273                              [enable HTML5 offline web applications support [default=yes]]),
274               [],[enable_offline_web_applications="yes"])
275 AC_MSG_RESULT([$enable_offline_web_applications])
276
277 # check whether to enable HTML5 client-side session and persitent storage support
278 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
279 AC_ARG_ENABLE(dom_storage,
280               AC_HELP_STRING([--enable-dom-storage],
281                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
282               [],[enable_dom_storage="yes"])
283 AC_MSG_RESULT([$enable_dom_storage])
284
285 # check whether to build with database support
286 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
287 AC_ARG_ENABLE(database,
288               AC_HELP_STRING([--enable-database],
289                              [enable HTML5 client-side database storage support [default=yes]]),
290               [],[enable_database="yes"])
291 AC_MSG_RESULT([$enable_database])
292
293 # check whether to build with icon database support
294 AC_MSG_CHECKING([whether to enable icon database support])
295 AC_ARG_ENABLE(icon_database,
296               AC_HELP_STRING([--enable-icon-database],
297                              [enable icon database [default=yes]]),
298               [],[enable_icon_database="yes"])
299 AC_MSG_RESULT([$enable_icon_database])
300
301 # check whether to enable HTML5 audio/video support
302 AC_MSG_CHECKING([whether to enable HTML5 video support])
303 AC_ARG_ENABLE(video,
304               AC_HELP_STRING([--enable-video],
305                              [enable HTML5 video support [default=no]]),
306               [],[enable_video="no"])
307 AC_MSG_RESULT([$enable_video])
308
309 # check whether to enable XPath support
310 AC_MSG_CHECKING([whether to enable XPath support])
311 AC_ARG_ENABLE(xpath,
312               AC_HELP_STRING([--enable-xpath],
313                              [enable support for XPath [default=yes]]),
314               [],[enable_xpath="yes"])
315 AC_MSG_RESULT([$enable_xpath])
316
317 # check whether to enable XSLT support
318 AC_MSG_CHECKING([whether to enable XSLT support])
319 AC_ARG_ENABLE(xslt,
320               AC_HELP_STRING([--enable-xslt],
321                              [enable support for XSLT [default=yes]]),
322               [],[enable_xslt="yes"])
323 AC_MSG_RESULT([$enable_xslt])
324
325 # check whether to enable SVG support
326 AC_MSG_CHECKING([whether to enable SVG support])
327 AC_ARG_ENABLE(svg,
328               AC_HELP_STRING([--enable-svg],
329                              [enable support for SVG [default=yes]]),
330               [],[enable_svg="yes"])
331 AC_MSG_RESULT([$enable_svg])
332
333 # turn off svg features if --disable-svg is requested
334 if test "$enable_svg" = "no"; then
335    enable_svg_animation=no
336    enable_svg_filters=no
337    enable_svg_fonts=no
338    enable_svg_foreign_object=no
339    enable_svg_as_image=no
340    enable_svg_use_element=no
341 fi
342
343 # check whether to enable support for SVG animation
344 AC_MSG_CHECKING([whether to enable support for SVG animation])
345 AC_ARG_ENABLE(svg_animation,
346               AC_HELP_STRING([--enable-svg-animation],
347                              [enable support for SVG animation (experimental) [default=yes]]),
348               [],[enable_svg_animation="yes"])
349 AC_MSG_RESULT([$enable_svg_animation])
350
351 # check whether to enable support for SVG filters
352 AC_MSG_CHECKING([whether to enable support for SVG filters])
353 AC_ARG_ENABLE(svg_filters,
354               AC_HELP_STRING([--enable-svg-filters],
355                              [enable support for SVG filters (experimental) [default=no]]),
356               [],[enable_svg_filters="no"])
357 AC_MSG_RESULT([$enable_svg_filters])
358
359 # check whether to enable support for SVG fonts
360 AC_MSG_CHECKING([whether to enable support for SVG fonts])
361 AC_ARG_ENABLE(svg_fonts,
362               AC_HELP_STRING([--enable-svg-fonts],
363                              [enable support for SVG fonts (experimental) [default=yes]]),
364               [],[enable_svg_fonts="yes"])
365 AC_MSG_RESULT([$enable_svg_fonts])
366
367 # check whether to enable foreign objects support for SVG
368 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
369 AC_ARG_ENABLE(svg_foreign_object,
370               AC_HELP_STRING([--enable-svg-foreign-object],
371                              [enable support for SVG foreign objects (experimental) [default=yes]]),
372               [],[enable_svg_foreign_object="yes"])
373 AC_MSG_RESULT([$enable_svg_foreign_object])
374
375 # check whether to enable SVG As Image support
376 AC_MSG_CHECKING([whether to enable SVG as Image support])
377 AC_ARG_ENABLE(svg_as_image,
378               AC_HELP_STRING([--enable-svg-as-image],
379                              [enable SVG as Image support (experimental) [default=yes]]),
380               [],[enable_svg_as_image="yes"])
381 AC_MSG_RESULT([$enable_svg_as_image])
382
383 # check whether to enable SVG USE element support
384 AC_MSG_CHECKING([whether to enable support for SVG use element])
385 AC_ARG_ENABLE(svg_use_element,
386               AC_HELP_STRING([--enable-svg-use-element],
387                              [enable SVG use element support (experimental) [default=yes]]),
388               [],[enable_svg_use_element="yes"])
389 AC_MSG_RESULT([$enable_svg_use_element])
390
391 # check for SVG features, enabling SVG if necessary
392 if test "$enable_svg_animation" = "yes" || \
393    test "$enable_svg_filters" = "yes" || \
394    test "$enable_svg_fonts" = "yes" || \
395    test "$enable_svg_foreign_object" = "yes" || \
396    test "$enable_svg_as_image" = "yes" || \
397    test "$enable_svg_use_element" = "yes"; then
398    svg_flags=yes
399    if test "$enable_svg" = "no"; then
400        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
401        enable_svg=yes
402    fi
403 fi
404
405 # check whether to enable code coverage
406 AC_MSG_CHECKING([whether to enable code coverage support])
407 AC_ARG_ENABLE(coverage,
408               AC_HELP_STRING([--enable-coverage],
409                              [enable code coverage support [default=no]]),
410               [],[enable_coverage="no"])
411 AC_MSG_RESULT([$enable_coverage])
412
413 # check whether to enable FastMalloc
414 AC_MSG_CHECKING([whether to enable optimized memory allocator])
415 AC_ARG_ENABLE(fast_malloc,
416               AC_HELP_STRING([--enable-fast-malloc],
417                              [enable optimized memory allocator default=yes, default=no for debug builds]),
418               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
419 AC_MSG_RESULT([$enable_fast_malloc])
420
421 # determine the font backend
422 AC_MSG_CHECKING([the font backend to use])
423 AC_ARG_WITH(font_backend,
424             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
425                            [Select font backend [default=freetype]]),
426             [],[with_font_backend="freetype"])
427
428 case "$with_font_backend" in
429      freetype|pango) ;;
430      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
431 esac
432 AC_MSG_RESULT([$with_font_backend])
433
434 # Add '-g' flag to gcc if it's debug build
435 if test "$enable_debug" = "yes"; then
436    CXXFLAGS="$CXXFLAGS -g"
437    CFLAGS="$CFLAGS -g"
438 fi
439
440 # check if curl is available
441 if test "$with_http_backend" = "curl"; then
442    PKG_CHECK_MODULES([LIBCURL],
443                      [libcurl >= $LIBCURL_REQUIRED_VERSION])
444    if test "$os_win32" = "yes"; then
445       LIBCURL_LIBS="$LIBCURL_LIBS -lWs2_32"
446    fi
447    AC_SUBST([LIBCURL_CFLAGS])
448    AC_SUBST([LIBCURL_LIBS])
449 fi
450
451 if test "$with_http_backend" = "soup"; then
452    PKG_CHECK_MODULES([LIBSOUP],
453                      [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
454    AC_SUBST([LIBSOUP_CFLAGS])
455    AC_SUBST([LIBSOUP_LIBS])
456 fi
457
458 # check if FreeType/FontConfig are available
459 if test "$with_font_backend" = "freetype"; then
460    PKG_CHECK_MODULES([FREETYPE],
461                      [cairo-ft
462                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
463                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
464    AC_SUBST([FREETYPE_CFLAGS])
465    AC_SUBST([FREETYPE_LIBS])
466 fi
467
468 # check if sqlite 3 is available
469 if test "$enable_icon_database" = "yes" || \
470    test "$enable_database" = "yes" || \
471    test "$enable_offline_web_applications" = "yes" || \
472    test "$enable_dom_storage" = "yes"; then
473    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
474    AC_SUBST([SQLITE3_CFLAGS])
475    AC_SUBST([SQLITE3_LIBS])
476 fi
477
478 # check if libxslt is available
479 if test "$enable_xslt" = "yes"; then
480    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
481    AC_SUBST([LIBXSLT_CFLAGS])
482    AC_SUBST([LIBXSLT_LIBS])
483 fi
484
485 # check if gstreamer is available
486 if test "$enable_video" = "yes"; then
487    PKG_CHECK_MODULES([GSTREAMER],
488                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
489                      gstreamer-base-0.10,
490                      gstreamer-plugins-base-0.10,
491                      gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED_VERSION])
492    AC_SUBST([GSTREAMER_CFLAGS])
493    AC_SUBST([GSTREAMER_LIBS])
494 fi
495
496 # check for code coverage support
497 if test "$enable_coverage" = "yes"; then
498    COVERAGE_CFLAGS="-MD"
499    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
500    AC_SUBST([COVERAGE_CFLAGS])
501    AC_SUBST([COVERAGE_LDFLAGS])
502 fi
503
504 # check for HTML features
505 if test "$enable_video" = "yes"; then
506     html_flags=yes
507 fi
508
509 # OS conditionals
510 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
511 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
512 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
513 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
514
515 # target conditionals
516 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
517 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
518 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
519 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
520
521 # HTTP backend conditionals
522 AM_CONDITIONAL([USE_CURL], [test "$with_http_backend" = "curl"])
523 AM_CONDITIONAL([USE_SOUP], [test "$with_http_backend" = "soup"])
524
525 # Font backend conditionals
526 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
527 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
528
529 # WebKit feature conditionals
530 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
531 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
532 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
533 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
534 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
535 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
536 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
537 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
538 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
539 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
540 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
541 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
542 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
543 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
544 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
545 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
546 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
547 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
548 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
549 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
550
551 AC_CONFIG_FILES([
552 GNUmakefile
553 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
554 ]
555 )
556
557 AC_OUTPUT
558
559 echo "
560 WebKit was configured with the following options:
561
562 Build configuration:
563  Enable debugging (slow)                                  : $enable_debug
564  Code coverage support                                    : $enable_coverage
565  Unicode backend                                          : $unicode_backend
566  HTTP backend                                             : $with_http_backend
567  Font backend                                             : $with_font_backend
568  Optimized memory allocator                               : $enable_fast_malloc
569 Features:
570  Dashboard support                                        : $enable_dashboard_support
571  HTML5 offline web applications support                   : $enable_offline_web_applications
572  HTML5 client-side session and persistent storage support : $enable_dom_storage
573  HTML5 client-side database storage support               : $enable_database
574  HTML5 video element support                              : $enable_video
575  Icon database support                                    : $enable_icon_database
576  SVG support                                              : $enable_svg
577  SVG animation support                                    : $enable_svg_animation
578  SVG filters support                                      : $enable_svg_filters
579  SVG fonts support                                        : $enable_svg_fonts
580  SVG foreign object support                               : $enable_svg_foreign_object
581  SVG as image support                                     : $enable_svg_as_image
582  SVG use element support                                  : $enable_svg_use_element
583  XPATH support                                            : $enable_xpath
584  XSLT support                                             : $enable_xslt
585 GTK+ configuration:
586  GDK target                                               : $with_target
587  Hildon UI extensions                                     : $with_hildon
588 "