2010-10-08 Balazs Kelemen <kbalazs@webkit.org>
[WebKit-https.git] / WebKitTools / WebKitTestRunner / qt / WebKitTestRunner.pro
1 TARGET = WebKitTestRunner
2 CONFIG -= app_bundle
3
4 BASEDIR = $$PWD/../
5 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../../..
6
7 include(../../../WebKit.pri)
8
9 !CONFIG(release, debug|release) {
10     OBJECTS_DIR = obj/debug
11 } else { # Release
12     OBJECTS_DIR = obj/release
13 }
14
15 DEFINES += USE_SYSTEM_MALLOC
16
17 INCLUDEPATH += \
18     $$BASEDIR \
19     $$BASEDIR/../../JavaScriptCore \
20     $$BASEDIR/../../WebKit2 \
21     $$BASEDIR/../../WebKit2/Shared \
22     $$BASEDIR/../../WebKit2/UIProcess/API/qt \
23     $$BASEDIR/../../WebKit2/UIProcess/API/cpp/qt \
24
25 INCLUDEPATH += \
26     $$OUTPUT_DIR/include \
27
28
29 DESTDIR = $$OUTPUT_DIR/bin
30
31 unix:!mac {
32     CONFIG += link_pkgconfig
33     PKGCONFIG += fontconfig
34 }
35
36 QT = core gui network
37
38 HEADERS = \
39     $$BASEDIR/PlatformWebView.h \
40     $$BASEDIR/StringFunctions.h \
41     $$BASEDIR/TestController.h \
42     $$BASEDIR/TestInvocation.h
43
44 SOURCES = \
45     main.cpp \
46     PlatformWebViewQt.cpp \
47     TestControllerQt.cpp \
48     $$BASEDIR/TestController.cpp \
49     $$BASEDIR/TestInvocation.cpp \
50
51 PREFIX_HEADER = $$BASEDIR/WebKitTestRunnerPrefix.h
52 QMAKE_CXXFLAGS += "-include $$PREFIX_HEADER"
53
54 linux-* {
55     # From Creator's src/rpath.pri:
56     # Do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
57     # this expands to $ORIGIN (after qmake and make), it does NOT read a qmake var.
58     QMAKE_RPATHDIR = \$\$ORIGIN/../lib $$QMAKE_RPATHDIR
59     MY_RPATH = $$join(QMAKE_RPATHDIR, ":")
60
61     QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${MY_RPATH}\'
62     QMAKE_RPATHDIR =
63 } else {
64     QMAKE_RPATHDIR = $$OUTPUT_DIR/lib $$QMAKE_RPATHDIR
65 }
66
67 include(../../../JavaScriptCore/JavaScriptCore.pri)
68 addJavaScriptCoreLib(../../../JavaScriptCore)