Gtk qmake build fix. Fix perl's complaint about an odd number of elements in anonymo...
[WebKit-https.git] / WebKitTools / Scripts / webkitdirs.pm
1 # Copyright (C) 2005, 2006, 2007 Apple Inc. All rights reserved.
2 #
3 # Redistribution and use in source and binary forms, with or without
4 # modification, are permitted provided that the following conditions
5 # are met:
6 #
7 # 1.  Redistributions of source code must retain the above copyright
8 #     notice, this list of conditions and the following disclaimer. 
9 # 2.  Redistributions in binary form must reproduce the above copyright
10 #     notice, this list of conditions and the following disclaimer in the
11 #     documentation and/or other materials provided with the distribution. 
12 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
13 #     its contributors may be used to endorse or promote products derived
14 #     from this software without specific prior written permission. 
15 #
16 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
17 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
18 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
19 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
20 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
21 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
22 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
23 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
24 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
25 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
26
27 # Module to share code to get to WebKit directories.
28
29 use strict;
30 use warnings;
31 use FindBin;
32 use File::Basename;
33 use POSIX;
34 use VCSUtils;
35
36 BEGIN {
37    use Exporter   ();
38    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
39    $VERSION     = 1.00;
40    @ISA         = qw(Exporter);
41    @EXPORT      = qw(&chdirWebKit &baseProductDir &productDir &XcodeOptions &XcodeOptionString &XcodeOptionStringNoConfig &passedConfiguration &setConfiguration &safariPath &checkFrameworks &currentSVNRevision);
42    %EXPORT_TAGS = ( );
43    @EXPORT_OK   = ();
44 }
45
46 our @EXPORT_OK;
47
48 my $baseProductDir;
49 my @baseProductDirOption;
50 my $configuration;
51 my $configurationForVisualStudio;
52 my $configurationProductDir;
53 my $sourceDir;
54 my $currentSVNRevision;
55 my $osXVersion;
56 my $isQt;
57 my $isGtk;
58 my $isWx;
59
60 # Variables for Win32 support
61 my $vcBuildPath;
62 my $windowsTmpPath;
63
64 sub determineSourceDir
65 {
66     return if $sourceDir;
67     $sourceDir = $FindBin::Bin;
68     
69     # walks up path checking each directory to see if it is the main WebKit project dir, 
70     # defined by containing JavaScriptCore, WebCore, and WebKit
71     until ((-d "$sourceDir/JavaScriptCore" && -d "$sourceDir/WebCore" && -d "$sourceDir/WebKit") || (-d "$sourceDir/Internal" && -d "$sourceDir/OpenSource"))
72     {
73         if ($sourceDir !~ s|/[^/]+$||) {
74             die "Could not find top level webkit directory above source directory using FindBin.\n";
75         }
76     }
77
78     $sourceDir = "$sourceDir/OpenSource" if -d "$sourceDir/OpenSource";
79 }
80
81 # used for scripts which are stored in a non-standard location
82 sub setSourceDir($)
83 {
84     ($sourceDir) = @_;
85 }
86
87 sub determineBaseProductDir
88 {
89     return if defined $baseProductDir;
90     determineSourceDir();
91     if (isOSX()) {
92         open PRODUCT, "defaults read com.apple.Xcode PBXApplicationwideBuildSettings 2> /dev/null |" or die;
93         $baseProductDir = join '', <PRODUCT>;
94         close PRODUCT;
95
96         $baseProductDir = $1 if $baseProductDir =~ /SYMROOT\s*=\s*\"(.*?)\";/s;
97         undef $baseProductDir unless $baseProductDir =~ /^\//;
98
99         if (!defined($baseProductDir)) {
100             open PRODUCT, "defaults read com.apple.Xcode PBXProductDirectory 2> /dev/null |" or die;
101             $baseProductDir = <PRODUCT>;
102             close PRODUCT;
103             if ($baseProductDir) {
104                 chomp $baseProductDir;
105                 undef $baseProductDir unless $baseProductDir =~ /^\//;
106             }
107         }
108     } else {
109         $baseProductDir = $ENV{"WEBKITOUTPUTDIR"};
110         if (isCygwin() && $baseProductDir) {
111             my $unixBuildPath = `cygpath --unix \"$baseProductDir\"`;
112             chomp $unixBuildPath;
113             $baseProductDir = $unixBuildPath;
114         }
115     }
116
117     if ($baseProductDir && isOSX()) {
118         $baseProductDir =~ s|^\Q$(SRCROOT)/..\E$|$sourceDir|;
119         $baseProductDir =~ s|^\Q$(SRCROOT)/../|$sourceDir/|;
120         $baseProductDir =~ s|^~/|$ENV{HOME}/|;
121         die "Can't handle Xcode product directory with a ~ in it.\n" if $baseProductDir =~ /~/;
122         die "Can't handle Xcode product directory with a variable in it.\n" if $baseProductDir =~ /\$/;
123         @baseProductDirOption = ();
124     }
125
126     if (!defined($baseProductDir)) {
127         $baseProductDir = "$sourceDir/WebKitBuild";
128
129         if (isGit() && isGitBranchBuild()) {
130             my $branch = gitBranch();
131             $baseProductDir = "$baseProductDir/$branch";
132         }
133
134         @baseProductDirOption = ("SYMROOT=$baseProductDir", "OBJROOT=$baseProductDir") if (isOSX());
135         if (isCygwin()) {
136             my $dosBuildPath = `cygpath --windows \"$baseProductDir\"`;
137             chomp $dosBuildPath;
138             $ENV{"WEBKITOUTPUTDIR"} = $dosBuildPath;
139         }
140     }
141 }
142
143 sub setBaseProductDir($)
144 {
145     ($baseProductDir) = @_;
146 }
147
148 sub determineConfiguration
149 {
150     return if defined $configuration;
151     determineBaseProductDir();
152     if (open CONFIGURATION, "$baseProductDir/Configuration") {
153         $configuration = <CONFIGURATION>;
154         close CONFIGURATION;
155     }
156     if ($configuration) {
157         chomp $configuration;
158         # compatibility for people who have old Configuration files
159         $configuration = "Release" if $configuration eq "Deployment";
160         $configuration = "Debug" if $configuration eq "Development";
161     } else {
162         $configuration = "Release";
163     }
164 }
165
166 sub determineConfigurationForVisualStudio
167 {
168     return if defined $configurationForVisualStudio;
169     determineConfiguration();
170     $configurationForVisualStudio = $configuration;
171     return unless $configuration eq "Debug";
172     setupCygwinEnv();
173     chomp(my $dir = `cygpath -ua '$ENV{WEBKITLIBRARIESDIR}'`);
174     $configurationForVisualStudio = "Debug_Internal" if -f "$dir/bin/CoreFoundation_debug.dll";
175 }
176
177 sub determineConfigurationProductDir
178 {
179     return if defined $configurationProductDir;
180     determineBaseProductDir();
181     if(isCygwin() && !isWx()) {
182         $configurationProductDir = "$baseProductDir/bin";
183     } else {
184         determineConfiguration();
185         $configurationProductDir = "$baseProductDir/$configuration";
186     }
187 }
188
189 sub setConfigurationProductDir($)
190 {
191     ($configurationProductDir) = @_;
192 }
193
194 sub determineCurrentSVNRevision
195 {
196     return if defined $currentSVNRevision;
197     determineSourceDir();
198     my $svnInfo = `LC_ALL=C svn info $sourceDir | grep Revision:`;
199     ($currentSVNRevision) = ($svnInfo =~ m/Revision: (\d+).*/g);
200     die "Unable to determine current SVN revision in $sourceDir" unless (defined $currentSVNRevision);
201     return $currentSVNRevision;
202 }
203
204
205 sub chdirWebKit
206 {
207     determineSourceDir();
208     chdir $sourceDir or die;
209 }
210
211 sub baseProductDir
212 {
213     determineBaseProductDir();
214     return $baseProductDir;
215 }
216
217 sub sourceDir
218 {
219     determineSourceDir();
220     return $sourceDir;
221 }
222
223 sub productDir
224 {
225     determineConfigurationProductDir();
226     return $configurationProductDir;
227 }
228
229 sub configuration()
230 {
231     determineConfiguration();
232     return $configuration;
233 }
234
235 sub configurationForVisualStudio()
236 {
237     determineConfigurationForVisualStudio();
238     return $configurationForVisualStudio;
239 }
240
241 sub currentSVNRevision
242 {
243     determineCurrentSVNRevision();
244     return $currentSVNRevision;
245 }
246
247 sub XcodeOptions
248 {
249     determineBaseProductDir();
250     determineConfiguration();
251     return (@baseProductDirOption, "-configuration", $configuration);
252 }
253
254 sub XcodeOptionString
255 {
256     return join " ", XcodeOptions();
257 }
258
259 sub XcodeOptionStringNoConfig
260 {
261     return join " ", @baseProductDirOption;
262 }
263
264 my $passedConfiguration;
265 my $searchedForPassedConfiguration;
266 sub determinePassedConfiguration
267 {
268     return if $searchedForPassedConfiguration;
269     $searchedForPassedConfiguration = 1;
270     for my $i (0 .. $#ARGV) {
271         my $opt = $ARGV[$i];
272         if ($opt =~ /^--debug$/i || $opt =~ /^--devel/i) {
273             splice(@ARGV, $i, 1);
274             $passedConfiguration = "Debug";
275             return;
276         }
277         if ($opt =~ /^--release$/i || $opt =~ /^--deploy/i) {
278             splice(@ARGV, $i, 1);
279             $passedConfiguration = "Release";
280             return;
281         }
282     }
283     $passedConfiguration = undef;
284 }
285
286 sub passedConfiguration
287 {
288     determinePassedConfiguration();
289     return $passedConfiguration;
290 }
291
292 sub setConfiguration
293 {
294     if (my $config = shift @_) {
295         $configuration = $config;
296         return;
297     }
298
299     determinePassedConfiguration();
300     $configuration = $passedConfiguration if $passedConfiguration;
301 }
302
303 sub safariPathFromSafariBundle
304 {
305     my ($safariBundle) = @_;
306
307     return "$safariBundle/Contents/MacOS/Safari" if isOSX();
308     return $safariBundle if isCygwin();
309 }
310
311 sub installedSafariPath
312 {
313     my $safariBundle;
314
315     if (isOSX()) {
316         $safariBundle = "/Applications/Safari.app";
317     } elsif (isCygwin()) {
318         my $findSafariName = "FindSafari";
319         $findSafariName .= "_debug" if $configuration ne "Release";
320         $findSafariName .= ".exe";
321
322         $safariBundle = `"$configurationProductDir/$findSafariName"`;
323         $safariBundle =~ s/[\r\n]+$//;
324         $safariBundle = `cygpath -u '$safariBundle'`;
325         $safariBundle =~ s/[\r\n]+$//;
326         $safariBundle .= "Safari.exe";
327     }
328
329     return safariPathFromSafariBundle($safariBundle);
330 }
331
332 # Locate Safari.
333 sub safariPath
334 {
335     # Use WEBKIT_SAFARI environment variable if present.
336     my $safariBundle = $ENV{WEBKIT_SAFARI};
337     if (!$safariBundle) {
338         determineConfigurationProductDir();
339         # Use Safari.app in product directory if present (good for Safari development team).
340         if (isOSX() && -d "$configurationProductDir/Safari.app") {
341             $safariBundle = "$configurationProductDir/Safari.app";
342         } elsif (isCygwin() && -x "$configurationProductDir/bin/Safari.exe") {
343             $safariBundle = "$configurationProductDir/bin/Safari.exe";
344         } else {
345             return installedSafariPath();
346         }
347     }
348     my $safariPath = safariPathFromSafariBundle($safariBundle);
349     die "Can't find executable at $safariPath.\n" if isOSX() && !-x $safariPath;
350     return $safariPath;
351 }
352
353 sub builtDylibPathForName
354 {
355     my $framework = shift;
356     determineConfigurationProductDir();
357     if (isQt() or isGtk()) {
358         return "$configurationProductDir/$framework";
359     }
360     if (isOSX()) {
361         return "$configurationProductDir/$framework.framework/Versions/A/$framework";
362     }
363     if (isCygwin()) {
364         if ($framework eq "JavaScriptCore") {
365                 return "$baseProductDir/lib/$framework.lib";
366         } else {
367             return "$baseProductDir/$framework.intermediate/$configuration/$framework.intermediate/$framework.lib";
368         }
369     }
370
371     die "Unsupported platform, can't determine built library locations.";
372 }
373
374 # Check to see that all the frameworks are built.
375 sub checkFrameworks
376 {
377     return if isCygwin();
378     my @frameworks = ("JavaScriptCore", "WebCore");
379     push(@frameworks, "WebKit") if isOSX();
380     for my $framework (@frameworks) {
381         my $path = builtDylibPathForName($framework);
382         die "Can't find built framework at \"$path\".\n" unless -x $path;
383     }
384 }
385
386 sub hasSVGSupport
387 {
388     return 0 if isCygwin();
389
390     my $path = shift;
391
392     if (isQt()) {
393         return 1;
394     }
395
396     if (isGtk() and $path =~ /WebCore/) {
397         $path .= "/../lib/libWebKitGtk.so" if !$ENV{WEBKITAUTOTOOLS};
398         $path .= "/../.libs/libWebKitGtk.so" if $ENV{WEBKITAUTOTOOLS};
399     }
400
401     my $hasSVGSupport = 0;
402     if (-e $path) {
403         open NM, "-|", "nm", $path or die;
404         while (<NM>) {
405             $hasSVGSupport = 1 if /SVGElement/;
406         }
407         close NM;
408     }
409     return $hasSVGSupport;
410 }
411
412 sub removeLibraryDependingOnSVG
413 {
414     my $frameworkName = shift;
415     my $shouldHaveSVG = shift;
416
417     my $path = builtDylibPathForName($frameworkName);
418     return unless -x $path;
419
420     my $hasSVG = hasSVGSupport($path);
421     system "rm -f $path" if ($shouldHaveSVG xor $hasSVG);
422 }
423
424 sub checkWebCoreSVGSupport
425 {
426     my $required = shift;
427     my $framework = "WebCore";
428     my $path = builtDylibPathForName($framework);
429     my $hasSVG = hasSVGSupport($path);
430     if ($required && !$hasSVG) {
431         die "$framework at \"$path\" does not include SVG Support, please run build-webkit --svg\n";
432     }
433     return $hasSVG;
434 }
435
436 sub isQt()
437 {
438     determineIsQt();
439     return $isQt;
440 }
441
442 sub checkArgv($)
443 {
444     my $argToCheck = shift;
445     foreach my $opt (@ARGV) {
446         if ($opt =~ /^$argToCheck/i ) {
447             @ARGV = grep(!/^$argToCheck/i, @ARGV);
448             return 1;
449         }
450     }
451     return 0;
452 }
453
454 sub determineIsQt()
455 {
456     return if defined($isQt);
457
458     # Allow override in case QTDIR is not set.
459     if (checkArgv("--qt")) {
460         $isQt = 1;
461         return;
462     }
463
464     # The presence of QTDIR only means Qt if --gtk is not on the command-line
465     if (isGtk()) {
466         $isQt = 0;
467         return;
468     }
469     
470     $isQt = defined($ENV{'QTDIR'});
471 }
472
473 sub isGtk()
474 {
475     determineIsGtk();
476     return $isGtk;
477 }
478
479 sub determineIsGtk()
480 {
481     return if defined($isGtk);
482
483     if (checkArgv("--gtk")) {
484         $isGtk = 1;
485     } else {
486         $isGtk = 0;
487     }
488 }
489
490 sub isWx()
491 {
492     determineIsWx();
493     return $isWx;
494 }
495
496 sub determineIsWx()
497 {
498     return if defined($isWx);
499
500     if (checkArgv("--wx")) {
501         $isWx = 1;
502     } else {
503         $isWx = 0;
504     }
505 }
506
507 # Determine if this is debian, ubuntu, linspire, or something similar.
508 sub isDebianBased()
509 {
510     return -e "/etc/debian_version";
511 }
512
513 sub isCygwin()
514 {
515     return ($^O eq "cygwin");
516 }
517
518 sub isDarwin()
519 {
520     return ($^O eq "darwin");
521 }
522
523 sub isOSX()
524 {
525     return isDarwin() unless (isQt() or isGtk() or isWx());
526     return 0;
527 }
528
529 sub determineOSXVersion()
530 {
531     return if $osXVersion;
532
533     if (!isOSX()) {
534         $osXVersion = -1;
535         return;
536     }
537
538     my $version = `sw_vers -productVersion`;
539     my @splitVersion = split(/\./, $version);
540     @splitVersion >= 2 or die "Invalid version $version";
541     $osXVersion = {
542             "major" => $splitVersion[0],
543             "minor" => $splitVersion[1],
544             "subminor" => (defined($splitVersion[2]) ? $splitVersion[2] : 0),
545     };
546 }
547
548 sub osXVersion()
549 {
550     determineOSXVersion();
551     return $osXVersion;
552 }
553
554 sub isTiger()
555 {
556     return isOSX() && osXVersion()->{"minor"} == 4;
557 }
558
559 sub isLeopard()
560 {
561     return isOSX() && osXVersion()->{"minor"} == 5;
562 }
563
564 sub relativeScriptsDir()
565 {
566     my $scriptDir = File::Spec->catpath("", File::Spec->abs2rel(dirname($0), getcwd()), "");
567     if ($scriptDir eq "") {
568         $scriptDir = ".";
569     }
570     return $scriptDir;
571 }
572
573 sub launcherPath()
574 {
575     my $relativeScriptsPath = relativeScriptsDir();
576     if (isGtk() || isQt()) {
577         return "$relativeScriptsPath/run-launcher";
578     } elsif (isOSX() || isCygwin()) {
579         return "$relativeScriptsPath/run-safari";
580     }
581 }
582
583 sub launcherName()
584 {
585     if (isGtk()) {
586         return "GtkLauncher";
587     } elsif (isQt()) {
588         return "QtLauncher";
589     } elsif (isOSX() || isCygwin()) {
590         return "Safari";
591     }
592 }
593
594 sub checkRequiredSystemConfig
595 {
596     if (isOSX()) {
597         chomp(my $productVersion = `sw_vers -productVersion`);
598         if ($productVersion lt "10.4") {
599             print "*************************************************************\n";
600             print "Mac OS X Version 10.4.0 or later is required to build WebKit.\n";
601             print "You have " . $productVersion . ", thus the build will most likely fail.\n";
602             print "*************************************************************\n";
603         }
604         my $xcodeVersion = `xcodebuild -version`;
605         if ($xcodeVersion !~ /DevToolsCore-(\d+)/ || $1 < 747) {
606             print "*************************************************************\n";
607             print "Xcode Version 2.3 or later is required to build WebKit.\n";
608             print "You have an earlier version of Xcode, thus the build will\n";
609             print "most likely fail.  The latest Xcode is available from the web:\n";
610             print "http://developer.apple.com/tools/xcode\n";
611             print "*************************************************************\n";
612         }
613     } elsif (isGtk() or isQt() or isWx()) {
614         my @cmds = qw(flex bison gperf);
615         my @missing = ();
616         foreach my $cmd (@cmds) {
617             if (not `$cmd --version`) {
618                 push @missing, $cmd;
619             }
620         }
621         if (@missing) {
622             my $list = join ", ", @missing;
623             die "ERROR: $list missing but required to build WebKit.\n";
624         }
625     }
626     # Win32 and other platforms may want to check for minimum config
627 }
628
629 sub setupCygwinEnv()
630 {
631     return if !isCygwin();
632     return if $vcBuildPath;
633
634     my $programFilesPath = `cygpath "$ENV{'PROGRAMFILES'}"`;
635     chomp $programFilesPath;
636     $vcBuildPath = "$programFilesPath/Microsoft Visual Studio 8/Common7/IDE/devenv.com";
637     if (! -e $vcBuildPath) {
638         # VC++ not found, try VC++ Express
639         my $vsInstallDir;
640         if ($ENV{'VSINSTALLDIR'}) {
641             $vsInstallDir = $ENV{'VSINSTALLDIR'};
642         } else {
643             $programFilesPath = $ENV{'PROGRAMFILES'} || "C:\\Program Files";
644             $vsInstallDir = "$programFilesPath/Microsoft Visual Studio 8";
645         }
646         $vsInstallDir = `cygpath "$vsInstallDir"`;
647         chomp $vsInstallDir;
648         $vcBuildPath = "$vsInstallDir/Common7/IDE/VCExpress.exe";
649         if (! -e $vcBuildPath) {
650             print "*************************************************************\n";
651             print "Cannot find '$vcBuildPath'\n";
652             print "Please execute the file 'vcvars32.bat' from\n";
653             print "'$programFilesPath\\Microsoft Visual Studio 8\\VC\\bin\\'\n";
654             print "to setup the necessary environment variables.\n";
655             print "*************************************************************\n";
656             die;
657         }
658     }
659
660     my $qtSDKPath = "$programFilesPath/QuickTime SDK";
661     if (0 && ! -e $qtSDKPath) {
662         print "*************************************************************\n";
663         print "Cannot find '$qtSDKPath'\n";
664         print "Please download the QuickTime SDK for Windows from\n";
665         print "http://developer.apple.com/quicktime/download/\n";
666         print "*************************************************************\n";
667         die;
668     }
669     
670     chomp($ENV{'WEBKITLIBRARIESDIR'} = `cygpath -wa "$sourceDir/WebKitLibraries/win"`) unless $ENV{'WEBKITLIBRARIESDIR'};
671
672     $windowsTmpPath = `cygpath -w /tmp`;
673     chomp $windowsTmpPath;
674     print "Building results into: ", baseProductDir(), "\n";
675     print "WEBKITOUTPUTDIR is set to: ", $ENV{"WEBKITOUTPUTDIR"}, "\n";
676     print "WEBKITLIBRARIESDIR is set to: ", $ENV{"WEBKITLIBRARIESDIR"}, "\n";
677 }
678
679 sub buildVisualStudioProject
680 {
681     my ($project, $clean) = @_;
682     setupCygwinEnv();
683
684     my $config = configurationForVisualStudio();
685
686     chomp(my $winProjectPath = `cygpath -w "$project"`);
687     
688     my $command = "/build";
689     if ($clean) {
690         $command = "/clean";
691     }
692
693     print "$vcBuildPath $winProjectPath /build $config\n";
694     return system $vcBuildPath, $winProjectPath, $command, $config;
695 }
696
697 sub qtMakeCommand($)
698 {
699     my ($qmakebin) = @_;
700     chomp(my $mkspec = `$qmakebin -query QMAKE_MKSPECS`);
701     $mkspec .= "/default";
702
703     my $compiler = "";
704     open SPEC, "<$mkspec/qmake.conf" or return "make";
705     while (<SPEC>) {
706         if ($_ =~ /QMAKE_CC\s*=\s*([^\s]+)/) {
707             $compiler = $1;
708         }
709     }
710     close SPEC;
711
712     #print "default spec: " . $mkspec . "\n";
713     #print "compiler found: " . $compiler . "\n";
714
715     if ($compiler eq "cl") {
716         return "nmake";
717     }
718
719     return "make";
720 }
721
722 sub autotoolsFlag($$)
723 {
724     my ($flag, $feature) = @_;
725     my $prefix = $flag ? "--enable" : "--disable";
726
727     return $prefix . '-' . $feature;
728 }
729
730 sub buildAutotoolsProject($@)
731 {
732     my ($clean, @buildArgs) = @_;
733
734     my $make = 'make';
735     my $dir = productDir();
736     my $config = passedConfiguration() || configuration();
737     my $prefix = $ENV{"WebKitInstallationPrefix"};
738
739     # check if configuration is Debug
740     if ($config =~ m/debug/i) {
741         push @buildArgs, "--enable-debug";
742     } else {
743         push @buildArgs, "--disable-debug";
744     }
745
746     if (! -d $dir) {
747         system "mkdir", "-p", "$dir";
748         if (! -d $dir) {
749             die "Failed to create build directory " . $dir;
750         }
751     }
752
753     chdir $dir or die "Failed to cd into " . $dir . "\n";
754
755     my $result;
756     if ($clean) {
757         $result = system $make, "distclean";
758         return $result;
759     }
760
761     print "Calling configure in " . $dir . "\n\n";
762     print "Installation directory: $prefix\n" if(defined($prefix));
763      
764     $result = system "$sourceDir/autogen.sh", @buildArgs;
765     if ($result ne 0) {
766         die "Failed to setup build environment using 'autotools'!\n";
767     }
768
769     $result = system $make;
770     if ($result ne 0) {
771         die "\nFailed to build WebKit using '$make'!\n";
772     }
773
774     chdir ".." or die;
775     return $result;
776 }
777
778 sub buildQMakeProject($@)
779 {
780     my ($clean, @buildArgs) = @_;
781
782     push @buildArgs, "-r";
783
784     my $qmakebin = "qmake"; # Allow override of the qmake binary from $PATH
785     for my $i (0 .. $#ARGV) {
786         my $opt = $ARGV[$i];
787         if ($opt =~ /^--qmake=(.*)/i ) {
788             $qmakebin = $1;
789         } elsif ($opt =~ /^--qmakearg=(.*)/i ) {
790             push @buildArgs, $1;
791         }
792     }
793
794     my $make = qtMakeCommand($qmakebin);
795     my $config = configuration();
796     my $prefix = $ENV{"WebKitInstallationPrefix"};
797
798     push @buildArgs, "OUTPUT_DIR=" . baseProductDir() . "/$config";
799     push @buildArgs, sourceDir() . "/WebKit.pro";
800     if ($config =~ m/debug/i) {
801         push @buildArgs, "CONFIG-=release";
802         push @buildArgs, "CONFIG+=debug";
803     } else {
804         push @buildArgs, "CONFIG+=release";
805         push @buildArgs, "CONFIG-=debug";
806     }
807
808     my $dir = baseProductDir();
809     if (! -d $dir) {
810         system "mkdir", "-p", "$dir";
811         if (! -d $dir) {
812             die "Failed to create product directory " . $dir;
813         }
814     }
815     $dir = $dir . "/$config";
816     if (! -d $dir) {
817         system "mkdir", "-p", "$dir";
818         if (! -d $dir) {
819             die "Failed to create build directory " . $dir;
820         }
821     }
822
823     chdir $dir or die "Failed to cd into " . $dir . "\n";
824
825     print "Calling '$qmakebin @buildArgs' in " . $dir . "\n\n";
826     print "Installation directory: $prefix\n" if(defined($prefix));
827
828     my $result = system $qmakebin, @buildArgs;
829     if ($result ne 0) {
830        die "Failed to setup build environment using $qmakebin!\n";
831     }
832
833     if ($clean) {
834       $result = system "$make distclean";
835     } else {
836       $result = system "$make";
837     }
838
839     chdir ".." or die;
840     return $result;
841 }
842
843 sub buildQMakeQtProject($$)
844 {
845     my ($project, $clean) = @_;
846
847     my @buildArgs = ("CONFIG+=qt-port");
848     return buildQMakeProject($clean, @buildArgs);
849 }
850
851 sub buildGtkProject($$@)
852 {
853     my ($project, $clean, @buildArgs) = @_;
854
855     if ($project ne "WebKit") {
856         die "The Gtk port builds JavaScriptCore, WebCore and WebKit in one shot! Only call it for 'WebKit'.\n";
857     }
858
859     if ($ENV{WEBKITAUTOTOOLS}) {
860         return buildAutotoolsProject($clean, @buildArgs);
861     } else {
862         my @buildArgs = ("CONFIG+=gtk-port", "CONFIG-=qt");
863         return buildQMakeProject($clean, @buildArgs);
864     }
865 }
866
867 sub setPathForRunningWebKitApp
868 {
869     my ($env) = @_;
870
871     return unless isCygwin();
872
873     $env->{PATH} = join(':', productDir(), dirname(installedSafariPath()), $env->{PATH} || "");
874 }
875
876 sub exitStatus($)
877 {
878     my ($returnvalue) = @_;
879     if ($^O eq "MSWin32") {
880         return $returnvalue >> 8;
881     }
882     return WEXITSTATUS($returnvalue);
883 }
884
885 sub runSafari
886 {
887     my ($debugger) = @_;
888
889     if (isOSX()) {
890         return system "$FindBin::Bin/gdb-safari", @ARGV if $debugger;
891
892         my $productDir = productDir();
893         print "Starting Safari with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
894         $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
895         $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
896         return system safariPath(), @ARGV;
897     }
898
899     if (isCygwin()) {
900         my $script = "run-webkit-nightly.cmd";
901         my $result = system "cp", "$FindBin::Bin/$script", productDir();
902         return $result if $result;
903
904         my $cwd = getcwd();
905         chdir productDir();
906
907         my $debuggerFlag = $debugger ? "/debugger" : "";
908         $result = system "cmd", "/c", "call $script $debuggerFlag";
909         chdir $cwd;
910         return $result;
911     }
912
913     return 1;
914 }
915
916 sub runDrosera
917 {
918     my ($debugger) = @_;
919
920     if (isOSX()) {
921         return system "$FindBin::Bin/gdb-drosera", @ARGV if $debugger;
922
923         my $productDir = productDir();
924         print "Starting Drosera with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
925         $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
926         $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
927
928         my $droseraPath = "$productDir/Drosera.app/Contents/MacOS/Drosera";
929         return system $droseraPath, @ARGV;
930     }
931
932     if (isCygwin()) {
933         print "Running Drosera\n";
934         my $script = "run-drosera-nightly.cmd";
935         my $prodDir = productDir();
936         my $result = system "cp", "$FindBin::Bin/$script", $prodDir;
937         return $result if $result;
938
939         my $cwd = getcwd();
940         chdir $prodDir;
941
942         my $debuggerFlag = $debugger ? "/debugger" : "";
943         $result = system "cmd", "/c", "call $script $debuggerFlag";
944         chdir $cwd;
945         return $result;
946     }
947
948     return 1;
949 }
950
951 1;