0c3f903643b9ce18bcfbac216e92f26a491f3746
[WebKit-https.git] / WebKitTools / Scripts / svn-create-patch
1 #!/usr/bin/perl -w
2
3 # Copyright (C) 2005, 2006 Apple Computer, Inc.  All rights reserved.
4 #
5 # Redistribution and use in source and binary forms, with or without
6 # modification, are permitted provided that the following conditions
7 # are met:
8 #
9 # 1.  Redistributions of source code must retain the above copyright
10 #     notice, this list of conditions and the following disclaimer. 
11 # 2.  Redistributions in binary form must reproduce the above copyright
12 #     notice, this list of conditions and the following disclaimer in the
13 #     documentation and/or other materials provided with the distribution. 
14 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
15 #     its contributors may be used to endorse or promote products derived
16 #     from this software without specific prior written permission. 
17 #
18 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
19 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
20 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
21 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
22 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
23 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
24 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
25 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29 # Simplified and improved "svn diff" script for WebKit Open Source Project, used to make patches.
30
31 # Differences from standard "svn diff":
32 #
33 #   Uses the real diff, not svn's built-in diff.
34 #   Always passes "-p" to diff so it will try to include function names.
35 #   Handles binary files (encoded as a base64 chunk of text).
36 #
37 # Missing features:
38 #
39 #   Sort the diffs, since svn emits them in a seemingly-random order.
40 #   Handle moved files.
41
42 use strict;
43 use Cwd;
44 use Getopt::Long;
45 use Time::gmtime;
46 use File::stat;
47 use File::Spec;
48 use POSIX qw(:errno_h);
49 use Config;
50 use MIME::Base64;
51
52 my $startDir = getcwd();
53 my %paths;
54
55 # Create list of paths to diff.
56 if (!@ARGV) {
57     $paths{"."} = 1;
58 } else {
59     for my $file (@ARGV) {
60         die "can't handle absolute paths like \"$file\"\n" if $file =~ m|^/|;
61         die "can't handle empty string path\n" if $file eq "";
62         die "can't handle path with ' in the name like \"$file\"\n" if $file =~ /'/; # ' (keep Xcode syntax highlighting happy)
63
64         my $untouchedFile = $file;
65         
66         # Add a leading and trailing slash to simplify logic below.
67         $file = "/$file/";
68
69         # Remove repeated slashes.
70         $file =~ s|//+|/|g;
71
72         # Remove meaningless sequences involving ".".
73         $file =~ s|/\./|/|g;
74
75         # Remove meaningless sequences involving "..".
76         $file =~ s|/[^./]/\.\./|/|g;
77         $file =~ s|/[^/]+[^./]/\.\./|/|g;
78         $file =~ s|/[^./][^/]+/\.\./|/|g;
79         die "can't handle paths with .. like \"$untouchedFile\"\n" if $file =~ m|/\.\./|;
80
81         # Remove the leading and trailing slash.
82         $file =~ s|^/(.*)/$|$1|;
83
84         $paths{$file} = 1;
85     }
86 }
87
88 # Remove any paths that also have a parent listed.
89 for my $path (keys %paths) {
90     my $parent = $path;
91     while ($parent =~ s|/+[^/]+$||) {
92         if ($paths{$parent}) {
93             delete $paths{$path};
94             last;
95         }
96     }
97 }
98
99 sub getDirAndBase
100 {
101     my ($path) = @_;
102     if (-d $path) {
103         $path =~ s|/+$||;
104         return ($path, ".");
105     }
106     return ($1, $2) if $path =~ m|^(.+)/([^/]+)$|;
107     $path !~ m|/| or die "Could not parse path name $path.\n";
108     return (".", $path);
109 }
110
111 # Function to generate a diff.
112 sub diff
113 {
114     my ($path) = @_;
115     my ($dir, $base) = getDirAndBase($path);
116     my $errors = "";
117     chdir $dir or die;
118     open DIFF, "svn diff --diff-cmd diff -x -uNp '$base' |" or die;
119     my $indexPath;
120     my $binaryPath;
121     while (<DIFF>) {
122         if (/^Index: (.*)/) {
123             # New patch just started
124             $indexPath = $1;
125             if ($dir ne ".") {
126                 $indexPath = "$dir/$indexPath";
127                 s/Index: .*/Index: $indexPath/;
128             }
129             # Output encoded binary contents of last patch before beginning of next patch
130             outputBinaryContent(File::Spec->abs2rel($binaryPath, $dir)) if ($binaryPath);
131             undef $binaryPath;
132         }
133         if ($indexPath) {
134             # Fix paths on diff, ---, and +++ lines to match preceding Index: line.
135             s/\S+$/$indexPath/ if /^diff/;
136             s/^--- \S+/--- $indexPath/;
137             s/^\+\+\+ \S+/+++ $indexPath/ && undef $indexPath;
138         }
139         if ($binaryPath) {
140             # Fix path on "Property changes on:" line to match preceding Index: line.
141             s/^(Property changes on:) \S+/$1 $indexPath/;
142         }
143         $binaryPath = $indexPath if (/^Cannot display: file marked as a binary type\.$/);
144         print;
145     }
146     close DIFF;
147     # Output encoded binary contents if the last patch was binary
148     outputBinaryContent(File::Spec->abs2rel($binaryPath, $dir)) if ($binaryPath);
149     chdir $startDir or die;
150     print STDERR $errors;
151 }
152
153 # Outputs binary content as encoded text
154 sub outputBinaryContent
155 {
156     my ($path) = @_;
157     # Deletion
158     return if (! -e $path);
159     # Addition or Modification
160     my $buffer;
161     open BINARY, $path  or die;
162     while (read(BINARY, $buffer, 60*57)) {
163         print encode_base64($buffer);
164     }
165     close BINARY;
166     print "\n";
167 }
168
169 # Generate the diff for each passed file or directory.
170 for my $path (sort keys %paths) {
171     diff($path);
172 }