118cc0bd489268f6e5c93bbee1d7ce4892fe38d9
[WebKit-https.git] / WebKitTools / Scripts / run-webkit-tests
1 #!/usr/bin/perl
2
3 # Copyright (C) 2005, 2006, 2007 Apple Inc. All rights reserved.
4 # Copyright (C) 2006 Alexey Proskuryakov (ap@nypop.com)
5 #
6 # Redistribution and use in source and binary forms, with or without
7 # modification, are permitted provided that the following conditions
8 # are met:
9 #
10 # 1.  Redistributions of source code must retain the above copyright
11 #     notice, this list of conditions and the following disclaimer. 
12 # 2.  Redistributions in binary form must reproduce the above copyright
13 #     notice, this list of conditions and the following disclaimer in the
14 #     documentation and/or other materials provided with the distribution. 
15 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
16 #     its contributors may be used to endorse or promote products derived
17 #     from this software without specific prior written permission. 
18 #
19 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
20 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
21 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
22 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
23 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
24 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
25 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
26 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29
30 # Script to run the Web Kit Open Source Project layout tests.
31
32 # Run all the tests passed in on the command line.
33 # If no tests are passed, find all the .html, .shtml, .xml, .xhtml, .pl, .php (and svg) files in the test directory.
34
35 # Run each text.
36 # Compare against the existing file xxx-expected.txt.
37 # If there is a mismatch, generate xxx-actual.txt and xxx-diffs.txt.
38
39 # At the end, report:
40 #   the number of tests that got the expected results
41 #   the number of tests that ran, but did not get the expected results
42 #   the number of tests that failed to run
43 #   the number of tests that were run but had no expected results to compare against
44
45 use strict;
46 use warnings;
47
48 use Cwd;
49 use File::Basename;
50 use File::Copy;
51 use File::Find;
52 use File::Path;
53 use File::Spec;
54 use File::Spec::Functions;
55 use FindBin;
56 use Getopt::Long;
57 use IPC::Open2;
58 use Time::HiRes qw(time);
59
60 use lib $FindBin::Bin;
61 use webkitdirs;
62 use POSIX;
63
64 sub openDumpTool();
65 sub closeDumpTool();
66 sub closeHTTPD();
67 sub countAndPrintLeaks($$$);
68 sub fileNameWithNumber($$);
69 sub numericcmp($$);
70 sub openHTTPDIfNeeded();
71 sub pathcmp($$);
72 sub processIgnoreTests($);
73 sub slowestcmp($$);
74 sub splitpath($);
75 sub isTextOnlyTest($);
76 sub expectedDirectoryForTest($);
77 sub toURL($);
78 sub toWindowsPath($);
79 sub closeCygpaths();
80
81 # Argument handling
82 my $shouldCheckLeaks = '';
83 my $configuration = '';
84 my $guardMalloc = '';
85 my $httpdPort = 8000;
86 my $ignoreTests = '';
87 my $launchSafari = 1;
88 my $pixelTests = '';
89 my $quiet = '';
90 my $repaintSweepHorizontally = '';
91 my $repaintTests = '';
92 my $report10Slowest = 0;
93 my $resetResults = 0;
94 my $showHelp = 0;
95 my $treatSkipped = "default";
96 my $testsPerDumpTool = 1000;
97 my $testHTTP = 1;
98 my $testOnlySVGs = '';
99 my $testResultsDirectory = "/tmp/layout-test-results";
100 my $threaded = 0;
101 my $verbose = 0;
102 my $useValgrind = 0;
103 my $strictTesting = 0;
104 my $generateNewResults = 1;
105 my $stripEditingCallbacks = isCygwin();
106 my $root;
107
108 my $expectedTag = "expected";
109 my $actualTag = "actual";
110 my $diffsTag = "diffs";
111
112 my $programName = basename($0);
113 my $launchSafariDefault = $launchSafari ? "launch" : "do not launch";
114 my $httpDefault = $testHTTP ? "run" : "do not run";
115
116 my $usage = <<EOF;
117 Usage: $programName [options] [testdir|testpath ...]
118   -c|--configuration config       Set DumpRenderTree build configuration
119   -g|--guard-malloc               Enable malloc guard
120   --help                          Show this help message
121   -h|--horizontal-sweep           Change repaint to sweep horizontally instead of vertically (implies --repaint-tests)
122   --[no-]http                     Run (or do not run) http tests (default: $httpDefault)
123   -i|--ignore-tests               Comma-separated list of directories or tests to ignore
124   --[no-]launch-safari            Launch (or do not launch) Safari to display test results (default: $launchSafariDefault)
125   -l|--leaks                      Enable leaks checking
126   --[no-]new-test-results         Generate results for new tests
127   -p|--pixel-tests                Enable pixel tests
128   --port                          Web server port to use with http tests
129   -q|--quiet                      Less verbose output
130   -r|--repaint-tests              Run repaint tests (implies --pixel-tests)
131   --reset-results                 Reset ALL results (including pixel tests if --pixel-tests is set)
132   -o|--results-directory          Output results directory (default: $testResultsDirectory)
133   --root                          Path to root tools build
134   -1|--singly                     Isolate each test case run (implies --verbose)
135   --skipped=[default|ignore|only] Specifies how to treat the Skipped file
136                                      default: Tests/directories listed in the Skipped file are not tested
137                                      ignore:  The Skipped file is ignored
138                                      only:    Only those tests/directories listed in the Skipped file will be run
139   --slowest                       Report the 10 slowest tests
140   --strict                        Do a comparison with the output on Mac (Qt only)
141   --[no-]strip-editing-callbacks  Remove editing callbacks from expected results
142   --svg                           Run only SVG tests (implies --pixel-tests)
143   -t|--threaded                   Run a concurrent JavaScript thead with each test
144   --valgrind                      Run DumpRenderTree inside valgrind (Qt/Linux only)
145   -v|--verbose                    More verbose output (overrides --quiet)
146 EOF
147
148 my $getOptionsResult = GetOptions(
149     'c|configuration=s' => \$configuration,
150     'debug|devel' => sub { $configuration = "Debug" },
151     'guard-malloc|g' => \$guardMalloc,
152     'help' => \$showHelp,
153     'horizontal-sweep|h' => \$repaintSweepHorizontally,
154     'http!' => \$testHTTP,
155     'ignore-tests|i=s' => \$ignoreTests,
156     'launch-safari!' => \$launchSafari,
157     'leaks|l' => \$shouldCheckLeaks,
158     'pixel-tests|p' => \$pixelTests,
159     'port=i' => \$httpdPort,
160     'quiet|q' => \$quiet,
161     'release|deploy' => sub { $configuration = "Release" },
162     'repaint-tests|r' => \$repaintTests,
163     'reset-results' => \$resetResults,
164     'new-test-results!' => \$generateNewResults,
165     'results-directory|o=s' => \$testResultsDirectory,
166     'singly|1' => sub { $testsPerDumpTool = 1; },
167     'nthly=i' => \$testsPerDumpTool,
168     'skipped=s' => \$treatSkipped,
169     'slowest' => \$report10Slowest,
170     'svg' => \$testOnlySVGs, 
171     'threaded|t' => \$threaded,
172     'verbose|v' => \$verbose,
173     'valgrind' => \$useValgrind,
174     'strict' => \$strictTesting,
175     'strip-editing-callbacks!' => \$stripEditingCallbacks,
176     'root=s' => \$root,
177 );
178
179 if (!$getOptionsResult || $showHelp || ($treatSkipped ne "default" && $treatSkipped ne "ignore" && $treatSkipped ne "only")) {
180     print STDERR $usage;
181     exit 1;
182 }
183
184 my $ignoreSkipped = $treatSkipped eq "ignore";
185 my $skippedOnly = $treatSkipped eq "only";
186
187 !$skippedOnly || @ARGV == 0 or die "--skipped=only cannot be used when tests are specified on the command line.";
188
189 setConfiguration($configuration);
190
191 my $configurationOption = "--" . lc($configuration);
192
193 $repaintTests = 1 if $repaintSweepHorizontally;
194
195 $pixelTests = 1 if $testOnlySVGs;
196 $pixelTests = 1 if $repaintTests;
197
198 $verbose = 1 if $testsPerDumpTool == 1;
199
200 if ($shouldCheckLeaks && $testsPerDumpTool > 1000) {
201     print STDERR "\nWARNING: Running more than 1000 tests at a time with MallocStackLogging enabled may cause a crash.\n\n";
202 }
203
204 # Force --no-http for Qt/Linux, for now.
205 $testHTTP = 0 if isQt();
206
207 setConfigurationProductDir(Cwd::abs_path($root)) if (defined($root));
208 my $productDir = productDir();
209 $productDir .= "/WebKitTools/DumpRenderTree/DumpRenderTree.qtproj" if (isQt());
210
211 chdirWebKit();
212
213 if(!defined($root)){
214     my $buildResult;
215     if (isCygwin()) {
216         $buildResult = buildVisualStudioProject("WebKitTools/DumpRenderTree/DumpRenderTree.vcproj/DumpRenderTree.sln");
217     } else { 
218         $buildResult = system "WebKitTools/Scripts/build-dumprendertree", $configurationOption;
219     }
220
221     if ($buildResult) {
222         print STDERR "Compiling DumpRenderTree failed!\n";
223         exit WEXITSTATUS($buildResult);
224     }
225 }
226
227 my $dumpToolName = "DumpRenderTree";
228 $dumpToolName .= "_debug" if isCygwin() && $configuration ne "Release";
229 my $dumpTool = "$productDir/$dumpToolName";
230 die "can't find executable $dumpToolName (looked in $productDir)\n" unless -x $dumpTool;
231
232 my $imageDiffTool = "$productDir/ImageDiff";
233 die "can't find executable $imageDiffTool (looked in $productDir)\n" if $pixelTests && !-x $imageDiffTool;
234
235 checkFrameworks() unless isCygwin();
236
237 my $layoutTestsName = "LayoutTests";
238 my $testDirectory = File::Spec->rel2abs($layoutTestsName);
239 my $platformTestDirectory = $testDirectory;
240 my $expectedDirectory = $testDirectory;
241 if (isLeopard()) {
242     $platformTestDirectory = "$testDirectory/mac/leopard";
243 } elsif (isQt()) {
244     $expectedDirectory = "LayoutTests/qt/";
245     $platformTestDirectory = $expectedDirectory;
246 } elsif (isCygwin()) {
247     $expectedDirectory = $testDirectory;
248     $platformTestDirectory = File::Spec->rel2abs("LayoutTests/win/");
249 }
250
251 $expectedDirectory = $ENV{"WebKitExpectedTestResultsDirectory"} if $ENV{"WebKitExpectedTestResultsDirectory"};
252
253 if ($testOnlySVGs) {
254     $testDirectory .= "/svg";
255     $expectedDirectory .= "/svg";
256 }
257
258 my $testResults = catfile($testResultsDirectory, "results.html");
259
260 print "Running tests from $testDirectory\n";
261
262 my @tests = ();
263 my %testType = ();
264
265 system "ln", "-s", $testDirectory, "/tmp/LayoutTests" unless -x "/tmp/LayoutTests";
266
267 my %ignoredFiles = ();
268 my %ignoredDirectories = ();
269 my %ignoredLocalDirectories = map { $_ => 1 } qw(.svn _svn resources);
270 my %supportedFileExtensions = map { $_ => 1 } qw(html shtml xml xhtml pl php);
271 if ($testOnlySVGs) {
272     %supportedFileExtensions = map { $_ => 1 } qw(svg xml);
273 } elsif (checkWebCoreSVGSupport($testOnlySVGs)) { 
274     $supportedFileExtensions{'svg'} = 1;
275 } elsif (isCygwin()) {
276     # FIXME: We should fix webkitdirs.pm:hasSVGSupport() to do the correct
277     # check for Windows instead of forcing this here.
278     $supportedFileExtensions{'svg'} = 1;
279 } else {
280     $ignoredLocalDirectories{'svg'} = 1;
281 }
282 if (!$testHTTP) {
283     $ignoredDirectories{'http'} = 1;
284 }
285
286 if ($ignoreTests) {
287     processIgnoreTests($ignoreTests);
288 }
289
290 if (!$ignoreSkipped && open SKIPPED, "<", "$platformTestDirectory/Skipped") {
291     if ($verbose && !$skippedOnly) {
292         print "Skipped tests:\n";
293     }
294     while (<SKIPPED>) {
295         my $skipped = $_;
296         chomp $skipped;
297         $skipped =~ s/^ +//;
298         $skipped =~ s/ +$//;
299         if ($skipped && $skipped !~ /^#/) {
300             if ($skippedOnly) {
301                 push(@ARGV, $skipped);
302             } else {
303                 if ($verbose) {
304                     print "    $skipped\n";
305                 }
306                 processIgnoreTests($skipped);
307             }
308         }
309     }
310     close SKIPPED;
311 }
312
313
314 my $directoryFilter = sub {
315     return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
316     return () if exists $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)};
317     return @_;
318 };
319
320 my $fileFilter = sub {
321     my $filename = $_;
322     if ($filename =~ /\.([^.]+)$/) {
323         if (exists $supportedFileExtensions{$1}) {
324             my $path = File::Spec->abs2rel(catfile($File::Find::dir, $filename), $testDirectory);
325             push @tests, $path if !exists $ignoredFiles{$path};
326         }
327     }
328 };
329
330 for my $test (@ARGV) {
331     $test =~ s/^($layoutTestsName|$testDirectory)\///;
332     my $fullPath = catfile($testDirectory, $test);
333     if (file_name_is_absolute($test)) {
334         print "can't run test $test outside $testDirectory\n";
335     } elsif (-f $fullPath) {
336         my ($filename, $pathname, $fileExtension) = fileparse($test, qr{\.[^.]+$});
337         if (!exists $supportedFileExtensions{substr($fileExtension, 1)}) {
338             print "test $test does not have a supported extension\n";
339         } elsif ($testHTTP || $pathname !~ /^http\//) {
340             push @tests, $test;
341         }
342     } elsif (-d $fullPath) {
343         find({ preprocess => $directoryFilter, wanted => $fileFilter }, $fullPath);
344     } else {
345         print "test $test not found\n";
346     }
347 }
348 if (!scalar @ARGV) {
349     find({ preprocess => $directoryFilter, wanted => $fileFilter }, $testDirectory);
350 }
351
352 die "no tests to run\n" if !@tests;
353
354 @tests = sort pathcmp @tests;
355
356 my %counts;
357 my %tests;
358 my %imagesPresent;
359 my %durations;
360 my $count = 0;
361 my $leaksOutputFileNumber = 1;
362 my $totalLeaks = 0;
363
364 my @toolArgs = ();
365 push @toolArgs, "--dump-all-pixels" if $pixelTests && $resetResults;
366 push @toolArgs, "--pixel-tests" if $pixelTests;
367 push @toolArgs, "--repaint" if $repaintTests;
368 push @toolArgs, "--horizontal-sweep" if $repaintSweepHorizontally;
369 push @toolArgs, "--threaded" if $threaded;
370 push @toolArgs, "--paint" if $shouldCheckLeaks; # Otherwise, DRT won't exercise painting leaks.
371 push @toolArgs, "-";
372
373 $| = 1;
374
375 my $imageDiffToolPID;
376 if ($pixelTests) {
377     local %ENV;
378     $ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
379     $imageDiffToolPID = open2(\*DIFFIN, \*DIFFOUT, $imageDiffTool, "") or die "unable to open $imageDiffTool\n";
380 }
381
382 my $dumpToolPID;
383 my $isDumpToolOpen = 0;
384
385 my $atLineStart = 1;
386 my $lastDirectory = "";
387
388 my $isHttpdOpen = 0;
389
390 print "Testing ", scalar @tests, " test cases.\n";
391 my $overallStartTime = time;
392
393 for my $test (@tests) {
394     next if $test eq 'results.html';
395
396     openDumpTool();
397
398     my $base = $test;
399     $base =~ s/\.[a-zA-Z]+$//;
400     
401     if ($verbose) {
402         print "running $test -> ";
403         $atLineStart = 0;
404     } elsif (!$quiet) {
405         my $dir = $base;
406         $dir =~ s|/[^/]+$||;
407         if ($dir ne $lastDirectory) {
408             print "\n" unless $atLineStart;
409             print "$dir ";
410             $lastDirectory = $dir;
411         }
412         print ".";
413         $atLineStart = 0;
414     }
415
416     my $result;
417
418     my $startTime = time if $report10Slowest;
419
420     if ($test !~ /^http\//) {
421         my $testPath = "$testDirectory/$test";
422         if (isCygwin()) {
423             $testPath = toWindowsPath($testPath);
424         } else {
425             $testPath = canonpath($testPath);
426         }
427         print OUT "$testPath\n";
428     } else {
429         openHTTPDIfNeeded();
430         if ($test !~ /^http\/tests\/local\//) {
431             my $path = canonpath($test);
432             $path =~ s/^http\/tests\///;
433             print OUT "http://127.0.0.1:$httpdPort/$path\n";
434         } else {
435             my $testPath = "$testDirectory/$test";
436             if (isCygwin()) {
437                 $testPath = toWindowsPath($testPath);
438             }
439             else {
440                 $testPath = canonpath($testPath);
441             }
442             print OUT "$testPath\n";
443         }
444     }
445
446     my $actual = "";
447     while (<IN>) {
448         last if /#EOF/;
449         $actual .= $_;
450     }
451     $actual =~ s/\r//g if isCygwin();
452     
453     my $isText = isTextOnlyTest($actual);
454
455     $durations{$test} = time - $startTime if $report10Slowest;
456
457     my $expected;
458     my $expectedDir = expectedDirectoryForTest($base);
459
460     if (!$resetResults && open EXPECTED, "<", "$expectedDir/$base-$expectedTag.txt") {
461         $expected = "";
462         while (<EXPECTED>) {
463             next if $stripEditingCallbacks && $_ =~ /^EDITING DELEGATE:/;
464             $expected .= $_;
465         }
466         close EXPECTED;
467     }
468     my $expectedMac;
469     if (!isOSX() && $strictTesting && !$isText) {
470       if (!$resetResults && open EXPECTED, "<", "$expectedDirectory/$base-$expectedTag.txt") {
471         $expectedMac = "";
472         while (<EXPECTED>) {
473           $expectedMac .= $_;
474         }
475         close EXPECTED;
476       }
477     }
478
479     if ($shouldCheckLeaks && $testsPerDumpTool == 1) {
480         print "        $test -> ";
481     }
482
483     my $actualPNG = "";
484     my $diffPNG = "";
485     my $diffPercentage = "";
486     my $diffResult = "passed";
487     
488     if ($pixelTests) {
489         die "Pixel tests currently don't work when using a custom expected test results directory" if $testDirectory ne $expectedDir;
490             
491         my $actualHash = "";
492         my $expectedHash = "";
493         my $actualPNGSize = 0;
494         while (<IN>) {
495             last if /#EOF/;
496             if (/ActualHash: ([a-f0-9]{32})/) {
497                 $actualHash = $1;
498             } elsif (/BaselineHash: ([a-f0-9]{32})/) {
499                 $expectedHash = $1;
500             } elsif (/Content-length: (\d+)\s*/) {
501                 $actualPNGSize = $1;
502                 read(IN, $actualPNG, $actualPNGSize);
503             }
504         }
505
506         if ($expectedHash ne $actualHash && -f "$testDirectory/$base-$expectedTag.png") {
507             my $expectedPNGSize = -s "$testDirectory/$base-$expectedTag.png";
508             my $expectedPNG = "";
509             open EXPECTEDPNG, "$testDirectory/$base-$expectedTag.png";
510             read(EXPECTEDPNG, $expectedPNG, $expectedPNGSize);
511
512             print DIFFOUT "Content-length: $actualPNGSize\n";
513             print DIFFOUT $actualPNG;
514
515             print DIFFOUT "Content-length: $expectedPNGSize\n";
516             print DIFFOUT $expectedPNG;
517
518             while (<DIFFIN>) {
519                 last if /^error/ || /^diff:/;
520                 if (/Content-length: (\d+)\s*/) {
521                     read(DIFFIN, $diffPNG, $1);
522                 }
523             }
524
525             if (/^diff: (.+)% (passed|failed)/) {
526                 $diffPercentage = $1;
527                 $diffResult = $2;
528             }
529         }
530
531         if ($actualPNGSize && ($resetResults || !-f "$testDirectory/$base-$expectedTag.png")) {
532             open EXPECTED, ">", "$testDirectory/$base-expected.png" or die "could not create $testDirectory/$base-expected.png\n";
533             print EXPECTED $actualPNG;
534             close EXPECTED;
535         }
536
537         # update the expected hash if the image diff said that there was no difference
538         if ($actualHash ne "" && ($resetResults || !-f "$testDirectory/$base-$expectedTag.checksum")) {
539             open EXPECTED, ">", "$testDirectory/$base-$expectedTag.checksum" or die "could not create $testDirectory/$base-$expectedTag.checksum\n";
540             print EXPECTED $actualHash;
541             close EXPECTED;
542         }
543     }
544
545     if (!isOSX() && $strictTesting && !$isText) {
546       if (defined $expectedMac) {
547         my $simplified_actual;
548         $simplified_actual = $actual;
549         $simplified_actual =~ s/at \(-?[0-9]+,-?[0-9]+\) *//g;
550         $simplified_actual =~ s/size -?[0-9]+x-?[0-9]+ *//g;
551         $simplified_actual =~ s/text run width -?[0-9]+: //g;
552         $simplified_actual =~ s/text run width -?[0-9]+ [a-zA-Z ]+: //g;
553         $simplified_actual =~ s/RenderButton {BUTTON} .*/RenderButton {BUTTON}/g;
554         $simplified_actual =~ s/RenderImage {INPUT} .*/RenderImage {INPUT}/g;
555         $simplified_actual =~ s/RenderBlock {INPUT} .*/RenderBlock {INPUT}/g;
556         $simplified_actual =~ s/RenderTextControl {INPUT} .*/RenderTextControl {INPUT}/g;
557         $simplified_actual =~ s/\([0-9]+px/px/g;
558         $simplified_actual =~ s/ *" *\n +" */ /g;
559         $simplified_actual =~ s/" +$/"/g;
560
561         $simplified_actual =~ s/- /-/g;
562         $simplified_actual =~ s/\n( *)"\s+/\n$1"/g;
563         $simplified_actual =~ s/\s+"\n/"\n/g;
564         
565         $expectedMac =~ s/at \(-?[0-9]+,-?[0-9]+\) *//g;
566         $expectedMac =~ s/size -?[0-9]+x-?[0-9]+ *//g;
567         $expectedMac =~ s/text run width -?[0-9]+: //g;
568         $expectedMac =~ s/text run width -?[0-9]+ [a-zA-Z ]+: //g;
569         $expectedMac =~ s/RenderButton {BUTTON} .*/RenderButton {BUTTON}/g;
570         $expectedMac =~ s/RenderImage {INPUT} .*/RenderImage {INPUT}/g;
571         $expectedMac =~ s/RenderBlock {INPUT} .*/RenderBlock {INPUT}/g;
572         $expectedMac =~ s/RenderTextControl {INPUT} .*/RenderTextControl {INPUT}/g;
573         $expectedMac =~ s/\([0-9]+px/px/g;
574         $expectedMac =~ s/ *" *\n +" */ /g;
575         $expectedMac =~ s/" +$/"/g;
576
577         $expectedMac =~ s/- /-/g;
578         $expectedMac =~ s/\n( *)"\s+/\n$1"/g;
579         $expectedMac =~ s/\s+"\n/"\n/g;
580         
581         if ($simplified_actual ne $expectedMac) {
582           open ACTUAL, ">", "/tmp/actual.txt" or die;
583           print ACTUAL $simplified_actual;
584           close ACTUAL;
585           open ACTUAL, ">", "/tmp/expected.txt" or die;
586           print ACTUAL $expectedMac;
587           close ACTUAL;
588           system "diff -u \"/tmp/expected.txt\" \"/tmp/actual.txt\" > \"/tmp/simplified.diff\"";
589
590           $diffResult = "failed";
591           if($verbose) {
592             print "\n";
593             system "cat /tmp/simplified.diff";
594             print "failed!!!!!";
595           }
596         }
597       }
598     }
599
600     if (!defined $expected) {
601         if ($verbose) {
602             print "new " . ($resetResults ? "result" : "test") ."\n";
603             $atLineStart = 1;
604         }
605         $result = "new";
606
607         if ($generateNewResults || $resetResults) {
608             # Create the path if needed
609             mkpath(catfile($expectedDir, dirname($base))) if $testDirectory ne $expectedDir;
610
611             open EXPECTED, ">", "$expectedDir/$base-$expectedTag.txt" or die "could not create $expectedDir/$base-$expectedTag.txt\n";
612             print EXPECTED $actual;
613             close EXPECTED;
614         }
615         unlink "$testResultsDirectory/$base-$actualTag.txt";
616         unlink "$testResultsDirectory/$base-$diffsTag.txt";
617         unless ($resetResults) {
618             # Always print the file name for new tests, as they will probably need some manual inspection.
619             # in verbose mode we already printed the test case, so no need to do it again.
620             unless ($verbose) {
621                 print "\n" unless $atLineStart;
622                 print "$test -> ";
623             }
624             print "new\n";
625             $atLineStart = 1;
626         }
627     } elsif ($actual eq $expected && $diffResult eq "passed") {
628         if ($verbose) {
629             print "succeeded\n";
630             $atLineStart = 1;
631         }
632         $result = "match";
633         unlink "$testResultsDirectory/$base-$actualTag.txt";
634         unlink "$testResultsDirectory/$base-$diffsTag.txt";
635     } else {
636         unless ($verbose) {
637             print "\n" unless $atLineStart;
638             print "$test -> ";
639         }
640         print "failed\n";
641         $atLineStart = 1;
642
643         $result = "mismatch";
644
645         my $dir = "$testResultsDirectory/$base";
646         $dir =~ s|/([^/]+)$|| or die "Failed to find test name from base\n";
647         my $testName = $1;
648         mkpath $dir;
649
650         open ACTUAL, ">", "$testResultsDirectory/$base-$actualTag.txt" or die;
651         print ACTUAL $actual;
652         close ACTUAL;
653
654         system "diff -u \"$expectedDir/$base-$expectedTag.txt\" \"$testResultsDirectory/$base-$actualTag.txt\" > \"$testResultsDirectory/$base-$diffsTag.txt\"";
655
656         if ($pixelTests && $diffPNG && $diffPNG ne "") {
657             $imagesPresent{$base} = 1;
658
659             open ACTUAL, ">", "$testResultsDirectory/$base-$actualTag.png" or die;
660             print ACTUAL $actualPNG;
661             close ACTUAL;
662
663             open DIFF, ">", "$testResultsDirectory/$base-$diffsTag.png" or die;
664             print DIFF $diffPNG;
665             close DIFF;
666             
667             copy("$expectedDir/$base-$expectedTag.png", "$testResultsDirectory/$base-$expectedTag.png");
668
669             open DIFFHTML, ">$testResultsDirectory/$base-$diffsTag.html" or die;
670             print DIFFHTML "<html>\n";
671             print DIFFHTML "<head>\n";
672             print DIFFHTML "<title>$base Image Compare</title>\n";
673             print DIFFHTML "<script language=\"Javascript\" type=\"text/javascript\">\n";
674             print DIFFHTML "var currentImage = 0;\n";
675             print DIFFHTML "var imageNames = new Array(\"Actual\", \"Expected\");\n";
676             print DIFFHTML "var imagePaths = new Array(\"$testName-$actualTag.png\", \"$testName-$expectedTag.png\");\n";
677             if (-f "$testDirectory/$base-w3c.png") {
678                 copy("$testDirectory/$base-w3c.png", "$testResultsDirectory/$base-w3c.png");
679                 print DIFFHTML "imageNames.push(\"W3C\");\n";
680                 print DIFFHTML "imagePaths.push(\"$testName-w3c.png\");\n";
681             }
682             print DIFFHTML "function animateImage() {\n";
683             print DIFFHTML "    var image = document.getElementById(\"animatedImage\");\n";
684             print DIFFHTML "    var imageText = document.getElementById(\"imageText\");\n";
685             print DIFFHTML "    image.src = imagePaths[currentImage];\n";
686             print DIFFHTML "    imageText.innerHTML = imageNames[currentImage] + \" Image\";\n";
687             print DIFFHTML "    currentImage = (currentImage + 1) % imageNames.length;\n";
688             print DIFFHTML "    setTimeout('animateImage()',2000);\n";
689             print DIFFHTML "}\n";
690             print DIFFHTML "</script>\n";
691             print DIFFHTML "</head>\n";
692             print DIFFHTML "<body onLoad=\"animateImage();\">\n";
693             print DIFFHTML "<table>\n";
694             if ($diffPercentage) {
695                 print DIFFHTML "<tr>\n";
696                 print DIFFHTML "<td>Difference between images: <a href=\"$testName-$diffsTag.png\">$diffPercentage%</a></td>\n";
697                 print DIFFHTML "</tr>\n";
698             }
699             print DIFFHTML "<tr>\n";
700             print DIFFHTML "<td id=\"imageText\" style=\"text-weight: bold;\">Actual Image</td>\n";
701             print DIFFHTML "</tr>\n";
702             print DIFFHTML "<tr>\n";
703             print DIFFHTML "<td><img src=\"$testName-$actualTag.png\" id=\"animatedImage\"></td>\n";
704             print DIFFHTML "</tr>\n";
705             print DIFFHTML "</table>\n";
706             print DIFFHTML "</body>\n";
707             print DIFFHTML "</html>\n";
708         }
709     }
710
711     if (($count + 1) % $testsPerDumpTool == 0 || $count == $#tests) {
712         if ($shouldCheckLeaks) {
713             my $fileName;
714             if ($testsPerDumpTool == 1) {
715                 $fileName = "$testResultsDirectory/$base-leaks.txt";
716             } else {
717                 $fileName = "$testResultsDirectory/" . fileNameWithNumber($dumpToolName, $leaksOutputFileNumber) . "-leaks.txt";
718             }
719             my $leakCount = countAndPrintLeaks($dumpToolName, $dumpToolPID, $fileName);
720             $totalLeaks += $leakCount;
721             $leaksOutputFileNumber++ if ($leakCount);
722         }
723
724         closeDumpTool();
725     }
726
727     $count++;
728     $counts{$result}++;
729     push @{$tests{$result}}, $test;
730     $testType{$test} = $isText;
731 }
732 printf "\n%0.2fs total testing time\n", (time - $overallStartTime) . "";
733
734 !$isDumpToolOpen || die "Failed to close $dumpToolName.\n";
735
736 closeHTTPD();
737
738 # Because multiple instances of this script are running concurrently we cannot 
739 # safely delete this symlink.
740 # system "rm /tmp/LayoutTests";
741
742 # FIXME: Do we really want to check the image-comparison tool for leaks every time?
743 if ($shouldCheckLeaks && $pixelTests) {
744     $totalLeaks += countAndPrintLeaks("ImageDiff", $imageDiffToolPID, "$testResultsDirectory/ImageDiff-leaks.txt");
745 }
746
747 if ($totalLeaks) {
748     print "\nWARNING: $totalLeaks total leaks found!\n";
749     print "See above for individual leaks results.\n" if ($leaksOutputFileNumber > 2);
750 }
751
752 close IN;
753 close OUT;
754
755 if ($report10Slowest) {
756     print "\n\nThe 10 slowest tests:\n\n";
757     my $count = 0;
758     for my $test (sort slowestcmp keys %durations) {
759         printf "%0.2f secs: %s\n", $durations{$test}, $test;
760         last if ++$count == 10;
761     }
762 }
763
764 print "\n";
765
766 if ($skippedOnly && $counts{"match"}) {
767     print "The following tests are in the Skipped file (" . File::Spec->abs2rel("$platformTestDirectory/Skipped", $testDirectory) . "), but succeeded:\n";
768     foreach my $test (@{$tests{"match"}}) {
769         print "  $test\n";
770     }
771 }
772
773 if ($resetResults || ($counts{match} && $counts{match} == $count)) {
774     print "all $count test cases succeeded\n";
775     unlink $testResults;
776     exit;
777 }
778
779
780 my %text = (
781     match => "succeeded",
782     mismatch => "had incorrect layout",
783     new => "were new",
784     fail => "failed (tool did not execute successfully)",
785 );
786
787 for my $type ("match", "mismatch", "new", "fail") {
788     my $c = $counts{$type};
789     if ($c) {
790         my $t = $text{$type};
791         my $message;
792         if ($c == 1) {
793             $t =~ s/were/was/;
794             $message = sprintf "1 test case (%d%%) %s\n", 1 * 100 / $count, $t;
795         } else {
796             $message = sprintf "%d test cases (%d%%) %s\n", $c, $c * 100 / $count, $t;
797         }
798         $message =~ s-\(0%\)-(<1%)-;
799         print $message;
800     }
801 }
802
803 mkpath $testResultsDirectory;
804
805 open HTML, ">", $testResults or die;
806 print HTML "<html>\n";
807 print HTML "<head>\n";
808 print HTML "<title>Layout Test Results</title>\n";
809 print HTML "</head>\n";
810 print HTML "<body>\n";
811
812 if ($counts{mismatch}) {
813     print HTML "<p>Tests where results did not match expected results:</p>\n";
814     print HTML "<table>\n";
815     for my $test (@{$tests{mismatch}}) {
816         my $base = $test;
817         $base =~ s/\.[a-zA-Z]+$//;
818         my $expectedDir = expectedDirectoryForTest($base);
819         copy("$expectedDir/$base-$expectedTag.txt", "$testResultsDirectory/$base-$expectedTag.txt");
820         print HTML "<tr>\n";            
821         print HTML "<td><a href=\"" . toURL("$testDirectory/$test") . "\">$test</a></td>\n";
822         if (-s "$testResultsDirectory/$base-$diffsTag.txt") {
823             print HTML "<td><a href=\"$base-$expectedTag.txt\">expected</a></td>\n";
824             print HTML "<td><a href=\"$base-$actualTag.txt\">actual</a></td>\n";
825             print HTML "<td><a href=\"$base-$diffsTag.txt\">diffs</a></td>\n";
826         } else {
827             print HTML "<td></td><td></td><td></td>\n";
828         }
829         if ($pixelTests) {
830             if ($imagesPresent{$base}) {
831                 print HTML "<td><a href=\"$base-$expectedTag.png\">expected image</a></td>\n";
832                 print HTML "<td><a href=\"$base-$diffsTag.html\">image diffs</a></td>\n";
833             } else {
834                 print HTML "<td></td><td></td>\n";
835             }            
836         }
837         print HTML "</tr>\n";
838     }
839     print HTML "</table>\n";
840 }
841
842 if ($counts{fail}) {
843     print HTML "<p>Tests that caused the DumpRenderTree tool to fail:</p>\n";
844     print HTML "<table>\n";
845     for my $test (@{$tests{fail}}) {
846         my $base = $test;
847         $base =~ s/\.[a-zA-Z]+$//;
848         my $expectedDir = expectedDirectoryForTest($base);
849         print HTML "<tr>\n";
850         print HTML "<td><a href=\"" . toURL("$testDirectory/$test") . "\">$base</a></td>\n";
851         print HTML "</tr>\n";
852     }
853     print HTML "</table>\n";
854 }
855
856 if ($counts{new}) {
857     print HTML "<p>Tests that had no expected results (probably new):</p>\n";
858     print HTML "<table>\n";
859     for my $test (@{$tests{new}}) {
860         my $base = $test;
861         $base =~ s/\.[a-zA-Z]+$//;
862         my $expectedDir = expectedDirectoryForTest($base);
863         print HTML "<tr>\n";
864         print HTML "<td><a href=\"" . toURL("$testDirectory/$test") . "\">$base</a></td>\n";
865         print HTML "<td><a href=\"" . toURL("$expectedDir/$base-$expectedTag.txt") . "\">results</a></td>\n";
866         if ($pixelTests && -f "$expectedDir/$base-$expectedTag.png") {
867             print HTML "<td><a href=\"" . toURL("$expectedDir/$base-$expectedTag.png") . "\">image</a></td>\n";
868         }
869         print HTML "</tr>\n";
870     }
871     print HTML "</table>\n";
872 }
873
874 print HTML "</body>\n";
875 print HTML "</html>\n";
876 close HTML;
877
878 if(isQt()) {
879   system "konqueror", $testResults if $launchSafari;
880 } elsif (isCygwin()) {
881   system "cygstart", $testResults if $launchSafari;
882 } else {
883   system "WebKitTools/Scripts/run-safari", $configurationOption, "-NSOpen", $testResults if $launchSafari;
884 }
885
886 closeCygpaths() if isCygwin();
887
888 exit 1;
889
890 sub countAndPrintLeaks($$$)
891 {
892     my ($dumpToolName, $dumpToolPID, $leaksFilePath) = @_;
893
894     print "\n" unless $atLineStart;
895     $atLineStart = 1;
896
897     # We are excluding the following reported leaks so they don't get in our way when looking for WebKit leaks:
898
899     my @typesToExclude = (
900         "THRD", # bug in 'leaks', Radar 3387783
901         "DRHT" # ditto (endian little hate i)
902     );
903
904     my @callStacksToExclude = (
905         "Flash_EnforceLocalSecurity" # leaks in Flash plug-in code, Radar 4449747
906     );
907
908     if (isTiger()) {
909         push @callStacksToExclude, (
910             "CFRunLoopRunSpecific \\| malloc_zone_malloc", "CFRunLoopRunSpecific \\| CFAllocatorAllocate ", # leak in CFRunLoopRunSpecific, Radar 4670839
911             "CGImageSourceGetPropertiesAtIndex", # leak in ImageIO, Radar 4628809
912             "FOGetCoveredUnicodeChars", # leak in ATS, Radar 3943604
913             "GetLineDirectionPreference", "InitUnicodeUtilities", # leaks tool falsely reporting leak in CFNotificationCenterAddObserver, Radar 4964790
914             "ICCFPrefWrapper::GetPrefDictionary", # leaks in Internet Config. code, Radar 4449794
915             "NSHTTPURLProtocol setResponseHeader:", # leak in multipart/mixed-replace handling in Foundation, no Radar, but fixed in Leopard
916             "NSURLCache cachedResponseForRequest", # leak in CFURL cache, Radar 4768430
917             "PCFragPrepareClosureFromFile", # leak in Code Fragment Manager, Radar 3426998
918             "WebCore::Selection::toRange", # bug in 'leaks', Radar 4967949
919             "WebCore::SubresourceLoader::create", # bug in 'leaks', Radar 4985806
920             "_CFPreferencesDomainDeepCopyDictionary", # leak in CFPreferences, Radar 4220786
921             "_objc_msgForward", # leak in NSSpellChecker, Radar 4965278
922             "gldGetString" # leak in OpenGL, Radar 5013699
923         );
924     }
925
926     if (isLeopard()) {
927         push @callStacksToExclude, (
928             "glvmInitializeLLVM", # leak in OpenGL, Radar 5329956
929             "GetProcessForPID", # leak in Process Manager, Radar 5329842
930             "HIView::SendGetPartRegionOrShape", # leak in High Level Toolbox, Radars 5329755 & 5329717
931             "AddImageByTypeInfo", # leak in Launch Services, Radar 5329735
932             "fileProtocolStart \\| _LSCopyTypeIdentifierForItemRefInfo", # leak in CFNetwork, Radar 5329625
933             "CGContextDrawImage", # leak in CoreGraphics, Radar 5002510
934         );
935     }
936
937     my $leaksTool = sourceDir() . "/WebKitTools/Scripts/run-leaks";
938     my $excludeString = "--exclude-callstack '" . (join "' --exclude-callstack '", @callStacksToExclude) . "' " .
939                         "--exclude-type '" . (join "' --exclude-type '", @typesToExclude) . "'";
940
941     print " ? checking for leaks in $dumpToolName\n";
942     my $leaksOutput = `$leaksTool $excludeString $dumpToolPID`;
943     my ($count, $bytes) = $leaksOutput =~ /Process $dumpToolPID: (\d+) leaks? for (\d+) total/;
944     my ($excluded) = $leaksOutput =~ /(\d+) leaks? excluded/;
945
946     my $adjustedCount = $count;
947     $adjustedCount -= $excluded if $excluded;
948
949     if (!$adjustedCount) {
950         print " - no leaks found\n";
951         unlink $leaksFilePath;
952         return 0;
953     } else {
954         my $dir = $leaksFilePath;
955         $dir =~ s|/[^/]+$|| or die;
956         mkpath $dir;
957
958         if ($excluded) {
959             print " + $adjustedCount leaks ($bytes bytes including $excluded excluded leaks) were found, details in $leaksFilePath\n";
960         } else {
961             print " + $count leaks ($bytes bytes) were found, details in $leaksFilePath\n";
962         }
963
964         open LEAKS, ">", $leaksFilePath or die;
965         print LEAKS $leaksOutput;
966         close LEAKS;
967     }
968
969     return $adjustedCount;
970 }
971
972 # Break up a path into the directory (with slash) and base name.
973 sub splitpath($)
974 {
975     my ($path) = @_;
976
977     my $pathSeparator = "/";
978     my $dirname = dirname($path) . $pathSeparator;
979     $dirname = "" if $dirname eq "." . $pathSeparator;
980
981     return ($dirname, basename($path));
982 }
983
984 # Sort first by directory, then by file, so all paths in one directory are grouped
985 # rather than being interspersed with items from subdirectories.
986 # Use numericcmp to sort directory and filenames to make order logical.
987 sub pathcmp($$)
988 {
989     my ($patha, $pathb) = @_;
990
991     my ($dira, $namea) = splitpath($patha);
992     my ($dirb, $nameb) = splitpath($pathb);
993
994     return numericcmp($dira, $dirb) if $dira ne $dirb;
995     return numericcmp($namea, $nameb);
996 }
997
998 # Sort numeric parts of strings as numbers, other parts as strings.
999 # Makes 1.33 come after 1.3, which is cool.
1000 sub numericcmp($$)
1001 {
1002     my ($aa, $bb) = @_;
1003
1004     my @a = split /(\d+)/, $aa;
1005     my @b = split /(\d+)/, $bb;
1006
1007     # Compare one chunk at a time.
1008     # Each chunk is either all numeric digits, or all not numeric digits.
1009     while (@a && @b) {
1010         my $a = shift @a;
1011         my $b = shift @b;
1012         
1013         # Use numeric comparison if chunks are non-equal numbers.
1014         return $a <=> $b if $a =~ /^\d/ && $b =~ /^\d/ && $a != $b;
1015
1016         # Use string comparison if chunks are any other kind of non-equal string.
1017         return $a cmp $b if $a ne $b;
1018     }
1019     
1020     # One of the two is now empty; compare lengths for result in this case.
1021     return @a <=> @b;
1022 }
1023
1024 # Sort slowest tests first.
1025 sub slowestcmp($$)
1026 {
1027     my ($testa, $testb) = @_;
1028
1029     my $dura = $durations{$testa};
1030     my $durb = $durations{$testb};
1031     return $durb <=> $dura if $dura != $durb;
1032     return pathcmp($testa, $testb);
1033 }
1034
1035 sub openDumpTool()
1036 {
1037     return if $isDumpToolOpen;
1038
1039     # Save some requires variables for the linux environment...
1040     my $homeDir = $ENV{'HOME'};
1041     my $libraryPath = $ENV{'LD_LIBRARY_PATH'};
1042     my $dbusAddress = $ENV{'DBUS_SESSION_BUS_ADDRESS'};
1043     my $display = $ENV{'DISPLAY'};
1044     my $testfonts = $ENV{'WEBKIT_TESTFONTS'};
1045
1046     my $homeDrive = $ENV{'HOMEDRIVE'};
1047     my $homePath = $ENV{'HOMEPATH'};
1048         
1049     my $isQt = isQt();
1050     local %ENV;
1051     if ($isQt) {
1052         if (defined $display) {
1053             $ENV{DISPLAY} = $display;
1054         } else {
1055             $ENV{DISPLAY} = ":1";
1056         }
1057         $ENV{'WEBKIT_TESTFONTS'} = $testfonts;
1058         $ENV{HOME} = $homeDir;
1059         if (defined $libraryPath) {
1060             $ENV{LD_LIBRARY_PATH} = $libraryPath;
1061         }
1062         if (defined $dbusAddress) {
1063             $ENV{DBUS_SESSION_BUS_ADDRESS} = $dbusAddress;
1064         }
1065     }
1066     $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
1067     $ENV{XML_CATALOG_FILES} = ""; # work around missing /etc/catalog <rdar://problem/4292995>
1068     $ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
1069     $ENV{DYLD_INSERT_LIBRARIES} = "/usr/lib/libgmalloc.dylib" if $guardMalloc;
1070     
1071     if (isCygwin()) {
1072         $ENV{HOMEDRIVE} = $homeDrive;
1073         $ENV{HOMEPATH} = $homePath;
1074     }
1075         
1076     my @args = ();
1077     if ($useValgrind) {
1078       push @args, $dumpTool;
1079     }
1080     push @args, @toolArgs;
1081     if ($useValgrind) {
1082       $dumpTool = "valgrind";
1083     }
1084     $dumpToolPID = open2(\*IN, \*OUT, $dumpTool, @args) or die "Failed to start tool: $dumpTool\n";
1085     $isDumpToolOpen = 1;
1086 }
1087
1088 sub closeDumpTool()
1089 {
1090     return if !$isDumpToolOpen;
1091
1092     close IN;
1093     close OUT;
1094     waitpid $dumpToolPID, 0;
1095     $isDumpToolOpen = 0;
1096 }
1097
1098 sub openHTTPDIfNeeded()
1099 {
1100     return if $isHttpdOpen;
1101
1102     mkdir "/tmp/WebKit";
1103     
1104     if (-f "/tmp/WebKit/httpd.pid") {
1105         my $oldPid = `cat /tmp/WebKit/httpd.pid`;
1106         chomp $oldPid;
1107         if (0 != kill 0, $oldPid) {
1108             print "\nhttpd is already running: pid $oldPid, killing...\n";
1109             kill 15, $oldPid;
1110             
1111             my $retryCount = 20;
1112             while ((0 != kill 0, $oldPid) && $retryCount) {
1113                 sleep 1;
1114                 --$retryCount;
1115             }
1116             
1117             die "Timed out waiting for httpd to quit" unless $retryCount;
1118         }
1119     }
1120     
1121     my $httpdPath = "/usr/sbin/httpd";
1122     my $httpdConfig;
1123     if (isCygwin()) {
1124         my $windowsConfDirectory = "$testDirectory/http/conf/";
1125         unless (-x "/usr/lib/apache/libphp4.dll") {
1126             copy("$windowsConfDirectory/libphp4.dll", "/usr/lib/apache/libphp4.dll");
1127             chmod(0755, "/usr/lib/apache/libphp4.dll");
1128         }
1129         $httpdConfig = "$windowsConfDirectory/cygwin-httpd.conf";
1130     } else {
1131         $httpdConfig = "$testDirectory/http/conf/httpd.conf";
1132         $httpdConfig = "$testDirectory/http/conf/apache2-httpd.conf" if `$httpdPath -v` =~ m|Apache/2|;
1133     }
1134     my $documentRoot = "$testDirectory/http/tests";
1135     my $typesConfig = "$testDirectory/http/conf/mime.types";
1136     my $listen = "127.0.0.1:$httpdPort";
1137     my $absTestResultsDirectory = File::Spec->rel2abs(glob $testResultsDirectory);
1138
1139     mkpath $absTestResultsDirectory;
1140
1141     open2(\*HTTPDIN, \*HTTPDOUT, $httpdPath, 
1142         "-f", "$httpdConfig",
1143         "-C", "DocumentRoot \"$documentRoot\"",
1144         "-C", "Listen $listen",
1145         "-c", "TypesConfig \"$typesConfig\"",
1146         "-c", "CustomLog \"$absTestResultsDirectory/access_log.txt\" common",
1147         "-c", "ErrorLog \"$absTestResultsDirectory/error_log.txt\"",
1148         # Apache wouldn't run CGIs with permissions==700 otherwise
1149         "-c", "User \"#$<\"");
1150
1151     my $retryCount = 20;
1152     while (system("/usr/bin/curl -q --silent --stderr - --output /dev/null $listen") && $retryCount) {
1153         sleep 1;
1154         --$retryCount;
1155     }
1156     
1157     die "Timed out waiting for httpd to start" unless $retryCount;
1158     
1159     $isHttpdOpen = 1;
1160 }
1161
1162 sub closeHTTPD()
1163 {
1164     return if !$isHttpdOpen;
1165
1166     close HTTPDIN;
1167     close HTTPDOUT;
1168
1169     kill 15, `cat /tmp/WebKit/httpd.pid` if -f "/tmp/WebKit/httpd.pid";
1170
1171     $isHttpdOpen = 0;
1172 }
1173
1174 sub fileNameWithNumber($$)
1175 {
1176     my ($base, $number) = @_;
1177     return "$base$number" if ($number > 1);
1178     return $base;
1179 }
1180
1181 sub processIgnoreTests($) {
1182     my @ignoreList = split(/\s*,\s*/, shift);
1183     my $addIgnoredDirectories = sub {
1184         return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
1185         $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)} = 1;
1186         return @_;
1187     };
1188     foreach my $item (@ignoreList) {
1189         my $path = catfile($testDirectory, $item); 
1190         if (-d $path) {
1191             $ignoredDirectories{$item} = 1;
1192             find({ preprocess => $addIgnoredDirectories, wanted => sub {} }, $path);
1193         }
1194         elsif (-f $path) {
1195             $ignoredFiles{$item} = 1;
1196         }
1197         else {
1198             print "ignoring '$item' on ignore-tests list\n";
1199         }
1200     }
1201 }
1202
1203 sub isTextOnlyTest($)
1204 {
1205     my ($actual) = @_;
1206     my $isText;
1207     if ($actual =~ /^layer at/ms) {
1208         $isText = 0;
1209     } else {
1210         $isText = 1;
1211     }
1212     return $isText;
1213 }
1214
1215 sub expectedDirectoryForTest($)
1216 {
1217     my ($base) = @_;
1218     return (-f "$platformTestDirectory/$base-$expectedTag.txt") ? $platformTestDirectory : $expectedDirectory;
1219 }
1220
1221 my %cygpaths = ();
1222
1223 sub openCygpathIfNeeded($)
1224 {
1225     my ($options) = @_;
1226
1227     return unless isCygwin();
1228     return $cygpaths{$options} if $cygpaths{$options} && $cygpaths{$options}->{"open"};
1229
1230     local (*CYGPATHIN, *CYGPATHOUT);
1231     my $pid = open2(\*CYGPATHIN, \*CYGPATHOUT, "cygpath -f - $options");
1232     my $cygpath =  {
1233         "pid" => $pid,
1234         "in" => *CYGPATHIN,
1235         "out" => *CYGPATHOUT,
1236         "open" => 1
1237     };
1238
1239     $cygpaths{$options} = $cygpath;
1240
1241     return $cygpath;
1242 }
1243
1244 sub closeCygpaths()
1245 {
1246     return unless isCygwin();
1247
1248     foreach my $cygpath (values(%cygpaths)) {
1249         close $cygpath->{"in"};
1250         close $cygpath->{"out"};
1251         waitpid($cygpath->{"pid"}, 0);
1252         $cygpath->{"open"} = 0;
1253
1254     }
1255 }
1256
1257 sub convertPathUsingCygpath($$)
1258 {
1259     my ($path, $options) = @_;
1260
1261     my $cygpath = openCygpathIfNeeded($options);
1262     local *inFH = $cygpath->{"in"};
1263     local *outFH = $cygpath->{"out"};
1264     print outFH $path . "\n";
1265     chomp(my $convertedPath = <inFH>);
1266     return $convertedPath;
1267 }
1268
1269 sub toWindowsPath($)
1270 {
1271     my ($path) = @_;
1272     return unless isCygwin();
1273
1274     return convertPathUsingCygpath($path, "-w");
1275 }
1276
1277 sub toURL($)
1278 {
1279     my ($path) = @_;
1280     return $path unless isCygwin();
1281     
1282     return "file:///" . convertPathUsingCygpath($path, "-m");
1283 }