Remove the --64-bit argument from scripts in favor of them detecting when 64-bit...
[WebKit-https.git] / WebKitTools / Scripts / run-webkit-tests
1 #!/usr/bin/perl
2
3 # Copyright (C) 2005, 2006, 2007, 2008, 2009 Apple Inc. All rights reserved.
4 # Copyright (C) 2006 Alexey Proskuryakov (ap@nypop.com)
5 # Copyright (C) 2007 Matt Lilek (pewtermoose@gmail.com)
6 # Copyright (C) 2007 Eric Seidel <eric@webkit.org>
7 #
8 # Redistribution and use in source and binary forms, with or without
9 # modification, are permitted provided that the following conditions
10 # are met:
11 #
12 # 1.  Redistributions of source code must retain the above copyright
13 #     notice, this list of conditions and the following disclaimer. 
14 # 2.  Redistributions in binary form must reproduce the above copyright
15 #     notice, this list of conditions and the following disclaimer in the
16 #     documentation and/or other materials provided with the distribution. 
17 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
18 #     its contributors may be used to endorse or promote products derived
19 #     from this software without specific prior written permission. 
20 #
21 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
22 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
23 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
24 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
25 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
26 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
27 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
28 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
31
32 # Script to run the WebKit Open Source Project layout tests.
33
34 # Run all the tests passed in on the command line.
35 # If no tests are passed, find all the .html, .shtml, .xml, .xhtml, .pl, .php (and svg) files in the test directory.
36
37 # Run each text.
38 # Compare against the existing file xxx-expected.txt.
39 # If there is a mismatch, generate xxx-actual.txt and xxx-diffs.txt.
40
41 # At the end, report:
42 #   the number of tests that got the expected results
43 #   the number of tests that ran, but did not get the expected results
44 #   the number of tests that failed to run
45 #   the number of tests that were run but had no expected results to compare against
46
47 use strict;
48 use warnings;
49
50 use Cwd;
51 use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
52 use File::Basename;
53 use File::Copy;
54 use File::Find;
55 use File::Path;
56 use File::Spec;
57 use File::Spec::Functions;
58 use FindBin;
59 use Getopt::Long;
60 use IPC::Open2;
61 use IPC::Open3;
62 use Time::HiRes qw(time usleep);
63
64 use List::Util 'shuffle';
65
66 use lib $FindBin::Bin;
67 use webkitdirs;
68 use POSIX;
69
70 sub openDumpTool();
71 sub closeDumpTool();
72 sub dumpToolDidCrash();
73 sub closeHTTPD();
74 sub countAndPrintLeaks($$$);
75 sub fileNameWithNumber($$);
76 sub numericcmp($$);
77 sub openHTTPDIfNeeded();
78 sub pathcmp($$);
79 sub processIgnoreTests($$);
80 sub slowestcmp($$);
81 sub splitpath($);
82 sub stripExtension($);
83 sub isTextOnlyTest($);
84 sub expectedDirectoryForTest($;$;$);
85 sub countFinishedTest($$$$);
86 sub testCrashedOrTimedOut($$$$$);
87 sub sampleDumpTool();
88 sub printFailureMessageForTest($$);
89 sub toURL($);
90 sub toWindowsPath($);
91 sub closeCygpaths();
92 sub validateSkippedArg($$;$);
93 sub htmlForResultsSection(\@$&);
94 sub deleteExpectedAndActualResults($);
95 sub recordActualResultsAndDiff($$);
96 sub buildPlatformHierarchy();
97 sub epiloguesAndPrologues($$);
98 sub parseLeaksandPrintUniqueLeaks();
99 sub readFromDumpToolWithTimer(*;$);
100 sub setFileHandleNonBlocking(*$);
101 sub writeToFile($$);
102
103 # Argument handling
104 my $addPlatformExceptions = 0;
105 my $complexText = 0;
106 my $guardMalloc = '';
107 my $httpdPort = 8000;
108 my $httpdSSLPort = 8443;
109 my $ignoreTests = '';
110 my $launchSafari = 1;
111 my $platform;
112 my $pixelTests = '';
113 my $quiet = '';
114 my $report10Slowest = 0;
115 my $resetResults = 0;
116 my $shouldCheckLeaks = 0;
117 my $showHelp = 0;
118 my $testsPerDumpTool;
119 my $testHTTP = 1;
120 my $testMedia = 1;
121 my $testResultsDirectory = "/tmp/layout-test-results";
122 my $threaded = 0;
123 my $tolerance = 0;
124 my $treatSkipped = "default";
125 my $verbose = 0;
126 my $useValgrind = 0;
127 my $strictTesting = 0;
128 my $generateNewResults = isAppleMacWebKit() ? 1 : 0;
129 my $stripEditingCallbacks = isCygwin();
130 my $runSample = 1;
131 my $root;
132 my $reverseTests = 0;
133 my $randomizeTests = 0;
134 my $mergeDepth;
135 my @leaksFilenames;
136
137 # Default to --no-http for Qt, Gtk and wx for now.
138 $testHTTP = 0 if (isQt() || isGtk() || isWx());
139
140 my $expectedTag = "expected";
141 my $actualTag = "actual";
142 my $diffsTag = "diffs";
143 my $errorTag = "stderr";
144
145 if (isTiger()) {
146     $platform = "mac-tiger";
147     $tolerance = 1.0;
148 } elsif (isLeopard()) {
149     $platform = "mac-leopard";
150     $tolerance = 0.1;
151 } elsif (isSnowLeopard()) {
152     $platform = "mac-snowleopard";
153     $tolerance = 0.1;
154 } elsif (isAppleMacWebKit()) {
155     $platform = "mac";
156 } elsif (isQt()) {
157     $platform = "qt";
158 } elsif (isGtk()) {
159     $platform = "gtk";
160 } elsif (isCygwin()) {
161     $platform = "win";
162 }
163
164 if (!defined($platform)) {
165     print "WARNING: Your platform is not recognized. Any platform-specific results will be generated in platform/undefined.\n";
166     $platform = "undefined";
167 }
168
169 my $programName = basename($0);
170 my $launchSafariDefault = $launchSafari ? "launch" : "do not launch";
171 my $httpDefault = $testHTTP ? "run" : "do not run";
172 my $sampleDefault = $runSample ? "run" : "do not run";
173
174 # FIXME: "--strict" should be renamed to qt-mac-comparison, or something along those lines.
175 my $usage = <<EOF;
176 Usage: $programName [options] [testdir|testpath ...]
177   --add-platform-exceptions       Put new results for non-platform-specific failing tests into the platform-specific results directory
178   --complex-text                  Use the complex text code path for all text (Mac OS X and Windows only)
179   -c|--configuration config       Set DumpRenderTree build configuration
180   -g|--guard-malloc               Enable malloc guard
181   --help                          Show this help message
182   --[no-]http                     Run (or do not run) http tests (default: $httpDefault)
183   -i|--ignore-tests               Comma-separated list of directories or tests to ignore
184   --[no-]launch-safari            Launch (or do not launch) Safari to display test results (default: $launchSafariDefault)
185   -l|--leaks                      Enable leaks checking
186   --[no-]new-test-results         Generate results for new tests
187   -p|--pixel-tests                Enable pixel tests
188   --tolerance t                   Ignore image differences less than this percentage (default: $tolerance)
189   --platform                      Override the detected platform to use for tests and results (default: $platform)
190   --port                          Web server port to use with http tests
191   -q|--quiet                      Less verbose output
192   --reset-results                 Reset ALL results (including pixel tests if --pixel-tests is set)
193   -o|--results-directory          Output results directory (default: $testResultsDirectory)
194   --random                        Run the tests in a random order
195   --reverse                       Run the tests in reverse alphabetical order
196   --root                          Path to root tools build
197   --[no-]sample-on-timeout        Run sample on timeout (default: $sampleDefault) (Mac OS X only)
198   -1|--singly                     Isolate each test case run (implies --verbose)
199   --skipped=[default|ignore|only] Specifies how to treat the Skipped file
200                                      default: Tests/directories listed in the Skipped file are not tested
201                                      ignore:  The Skipped file is ignored
202                                      only:    Only those tests/directories listed in the Skipped file will be run
203   --slowest                       Report the 10 slowest tests
204   --strict                        Do a comparison with the output on Mac (Qt only)
205   --[no-]strip-editing-callbacks  Remove editing callbacks from expected results
206   -t|--threaded                   Run a concurrent JavaScript thead with each test
207   --valgrind                      Run DumpRenderTree inside valgrind (Qt/Linux only)
208   -v|--verbose                    More verbose output (overrides --quiet)
209   -m|--merge-leak-depth arg       Merges leak callStacks and prints the number of unique leaks beneath a callstack depth of arg.  Defaults to 5.
210 EOF
211
212 setConfiguration();
213
214 my $getOptionsResult = GetOptions(
215     'complex-text' => \$complexText,
216     'guard-malloc|g' => \$guardMalloc,
217     'help' => \$showHelp,
218     'http!' => \$testHTTP,
219     'ignore-tests|i=s' => \$ignoreTests,
220     'launch-safari!' => \$launchSafari,
221     'leaks|l' => \$shouldCheckLeaks,
222     'pixel-tests|p' => \$pixelTests,
223     'platform=s' => \$platform,
224     'port=i' => \$httpdPort,
225     'quiet|q' => \$quiet,
226     'reset-results' => \$resetResults,
227     'new-test-results!' => \$generateNewResults,
228     'results-directory|o=s' => \$testResultsDirectory,
229     'singly|1' => sub { $testsPerDumpTool = 1; },
230     'nthly=i' => \$testsPerDumpTool,
231     'skipped=s' => \&validateSkippedArg,
232     'slowest' => \$report10Slowest,
233     'threaded|t' => \$threaded,
234     'tolerance=f' => \$tolerance,
235     'verbose|v' => \$verbose,
236     'valgrind' => \$useValgrind,
237     'sample-on-timeout!' => \$runSample,
238     'strict' => \$strictTesting,
239     'strip-editing-callbacks!' => \$stripEditingCallbacks,
240     'random' => \$randomizeTests,
241     'reverse' => \$reverseTests,
242     'root=s' => \$root,
243     'add-platform-exceptions' => \$addPlatformExceptions,
244     'merge-leak-depth|m:5' => \$mergeDepth,
245 );
246
247 if (!$getOptionsResult || $showHelp) {
248     print STDERR $usage;
249     exit 1;
250 }
251
252 my $ignoreSkipped = $treatSkipped eq "ignore";
253 my $skippedOnly = $treatSkipped eq "only";
254
255 !$skippedOnly || @ARGV == 0 or die "--skipped=only cannot be used when tests are specified on the command line.";
256
257 my $configuration = configuration();
258
259 $testsPerDumpTool = 1000 if !$testsPerDumpTool;
260
261 $verbose = 1 if $testsPerDumpTool == 1;
262
263 if ($shouldCheckLeaks && $testsPerDumpTool > 1000) {
264     print STDERR "\nWARNING: Running more than 1000 tests at a time with MallocStackLogging enabled may cause a crash.\n\n";
265 }
266
267 # Stack logging does not play well with QuickTime on Tiger (rdar://problem/5537157)
268 $testMedia = 0 if $shouldCheckLeaks && isTiger();
269
270 setConfigurationProductDir(Cwd::abs_path($root)) if (defined($root));
271 my $productDir = productDir();
272 $productDir .= "/bin" if isQt();
273 $productDir .= "/Programs" if isGtk();
274
275 chdirWebKit();
276
277 if (!defined($root)) {
278     # Push the parameters to build-dumprendertree as an array
279     my @args = argumentsForConfiguration();
280
281     my $buildResult = system "WebKitTools/Scripts/build-dumprendertree", @args;
282     if ($buildResult) {
283         print STDERR "Compiling DumpRenderTree failed!\n";
284         exit exitStatus($buildResult);
285     }
286 }
287
288 my $dumpToolName = "DumpRenderTree";
289 $dumpToolName .= "_debug" if isCygwin() && $configuration ne "Release";
290 my $dumpTool = "$productDir/$dumpToolName";
291 die "can't find executable $dumpToolName (looked in $productDir)\n" unless -x $dumpTool;
292
293 my $imageDiffTool = "$productDir/ImageDiff";
294 $imageDiffTool .= "_debug" if isCygwin() && $configuration ne "Release";
295 die "can't find executable $imageDiffTool (looked in $productDir)\n" if $pixelTests && !-x $imageDiffTool;
296
297 checkFrameworks() unless isCygwin();
298
299 my $layoutTestsName = "LayoutTests";
300 my $testDirectory = File::Spec->rel2abs($layoutTestsName);
301 my $expectedDirectory = $testDirectory;
302 my $platformBaseDirectory = catdir($testDirectory, "platform");
303 my $platformTestDirectory = catdir($platformBaseDirectory, $platform);
304 my @platformHierarchy = buildPlatformHierarchy();
305
306 $expectedDirectory = $ENV{"WebKitExpectedTestResultsDirectory"} if $ENV{"WebKitExpectedTestResultsDirectory"};
307
308 my $testResults = catfile($testResultsDirectory, "results.html");
309
310 print "Running tests from $testDirectory\n";
311 if ($pixelTests) {
312     print "Enabling pixel tests with a tolerance of $tolerance%\n";
313     if (isDarwin()) {
314         print "WARNING: Temporarily changing the main display color profile:\n";
315         print "\tThe colors on your screen will change for the duration of the testing.\n";
316         print "\tThis allows the pixel tests to have consistent color values across all machines.\n";
317         
318         if (isPerianInstalled()) {
319             print "WARNING: Perian's QuickTime component is installed and this may affect pixel test results!\n";
320             print "\tYou should avoid generating new pixel results in this environment.\n";
321             print "\tSee https://bugs.webkit.org/show_bug.cgi?id=22615 for details.\n";
322         }
323     }
324 }
325
326 my @tests = ();
327 my %testType = ();
328
329 system "ln", "-s", $testDirectory, "/tmp/LayoutTests" unless -x "/tmp/LayoutTests";
330
331 my %ignoredFiles = ();
332 my %ignoredDirectories = map { $_ => 1 } qw(platform);
333 my %ignoredLocalDirectories = map { $_ => 1 } qw(.svn _svn resources);
334 my %supportedFileExtensions = map { $_ => 1 } qw(html shtml xml xhtml pl php);
335
336 # FIXME: We should fix webkitdirs.pm:hasSVG/WMLSupport() to do the correct feature detection for Cygwin.
337 if (checkWebCoreSVGSupport(0)) { 
338     $supportedFileExtensions{'svg'} = 1;
339 } elsif (isCygwin()) {
340     $supportedFileExtensions{'svg'} = 1;
341 } else {
342     $ignoredLocalDirectories{'svg'} = 1;
343 }
344
345 if (checkWebCoreWMLSupport(0)) { 
346     $supportedFileExtensions{'wml'} = 1;
347 } else {
348     $ignoredDirectories{'http/tests/wml'} = 1;
349     $ignoredDirectories{'fast/wml'} = 1;
350     $ignoredDirectories{'wml'} = 1;
351 }
352
353 if (!$testHTTP) {
354     $ignoredDirectories{'http'} = 1;
355 }
356
357 if (!$testMedia) {
358     $ignoredDirectories{'media'} = 1;
359     $ignoredDirectories{'http/tests/media'} = 1;
360 }
361
362 if (!checkWebCoreAcceleratedCompositingSupport(0)) {
363     $ignoredDirectories{'compositing'} = 1;
364 }
365
366 if (!checkWebCore3DTransformsSupport(0)) {
367     $ignoredDirectories{'animations/3d'} = 1;
368     $ignoredDirectories{'transforms/3d'} = 1;
369 }
370
371 if ($ignoreTests) {
372     processIgnoreTests($ignoreTests, "ignore-tests");
373 }
374
375 if (!$ignoreSkipped) {
376     foreach my $level (@platformHierarchy) {
377         if (open SKIPPED, "<", "$level/Skipped") {
378             if ($verbose && !$skippedOnly) {
379                 my ($dir, $name) = splitpath($level);
380                 print "Skipped tests in $name:\n";
381             }
382
383             while (<SKIPPED>) {
384                 my $skipped = $_;
385                 chomp $skipped;
386                 $skipped =~ s/^[ \n\r]+//;
387                 $skipped =~ s/[ \n\r]+$//;
388                 if ($skipped && $skipped !~ /^#/) {
389                     if ($skippedOnly) {
390                         push(@ARGV, $skipped);
391                     } else {
392                         if ($verbose) {
393                             print "    $skipped\n";
394                         }
395                         processIgnoreTests($skipped, "Skipped");
396                     }
397                 }
398             }
399             close SKIPPED;
400         }
401     }
402 }
403
404
405 my $directoryFilter = sub {
406     return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
407     return () if exists $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)};
408     return @_;
409 };
410
411 my $fileFilter = sub {
412     my $filename = $_;
413     if ($filename =~ /\.([^.]+)$/) {
414         if (exists $supportedFileExtensions{$1}) {
415             my $path = File::Spec->abs2rel(catfile($File::Find::dir, $filename), $testDirectory);
416             push @tests, $path if !exists $ignoredFiles{$path};
417         }
418     }
419 };
420
421 for my $test (@ARGV) {
422     $test =~ s/^($layoutTestsName|$testDirectory)\///;
423     my $fullPath = catfile($testDirectory, $test);
424     if (file_name_is_absolute($test)) {
425         print "can't run test $test outside $testDirectory\n";
426     } elsif (-f $fullPath) {
427         my ($filename, $pathname, $fileExtension) = fileparse($test, qr{\.[^.]+$});
428         if (!exists $supportedFileExtensions{substr($fileExtension, 1)}) {
429             print "test $test does not have a supported extension\n";
430         } elsif ($testHTTP || $pathname !~ /^http\//) {
431             push @tests, $test;
432         }
433     } elsif (-d $fullPath) {
434         find({ preprocess => $directoryFilter, wanted => $fileFilter }, $fullPath);
435
436         for my $level (@platformHierarchy) {
437             my $platformPath = catfile($level, $test);
438             find({ preprocess => $directoryFilter, wanted => $fileFilter }, $platformPath) if (-d $platformPath);
439         }
440     } else {
441         print "test $test not found\n";
442     }
443 }
444 if (!scalar @ARGV) {
445     find({ preprocess => $directoryFilter, wanted => $fileFilter }, $testDirectory);
446
447     for my $level (@platformHierarchy) {
448         find({ preprocess => $directoryFilter, wanted => $fileFilter }, $level);
449     }
450 }
451
452 die "no tests to run\n" if !@tests;
453
454 @tests = sort pathcmp @tests;
455
456 my %counts;
457 my %tests;
458 my %imagesPresent;
459 my %imageDifferences;
460 my %durations;
461 my $count = 0;
462 my $leaksOutputFileNumber = 1;
463 my $totalLeaks = 0;
464
465 my @toolArgs = ();
466 push @toolArgs, "--pixel-tests" if $pixelTests;
467 push @toolArgs, "--threaded" if $threaded;
468 push @toolArgs, "--complex-text" if $complexText;
469 push @toolArgs, "-";
470
471 my @diffToolArgs = ();
472 push @diffToolArgs, "--tolerance", $tolerance;
473
474 $| = 1;
475
476 my $imageDiffToolPID;
477 if ($pixelTests) {
478     local %ENV;
479     $ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
480     $imageDiffToolPID = open2(\*DIFFIN, \*DIFFOUT, $imageDiffTool, @diffToolArgs) or die "unable to open $imageDiffTool\n";
481     $ENV{MallocStackLogging} = 0 if $shouldCheckLeaks;
482 }
483
484 my $dumpToolPID;
485 my $isDumpToolOpen = 0;
486 my $dumpToolCrashed = 0;
487
488 my $atLineStart = 1;
489 my $lastDirectory = "";
490
491 my $isHttpdOpen = 0;
492
493 sub catch_pipe { $dumpToolCrashed = 1; }
494 $SIG{"PIPE"} = "catch_pipe";
495
496 print "Testing ", scalar @tests, " test cases.\n";
497 my $overallStartTime = time;
498
499 my %expectedResultPaths;
500
501 # Reverse the tests
502 @tests = reverse @tests if $reverseTests;
503
504 # Shuffle the array
505 @tests = shuffle(@tests) if $randomizeTests;
506
507 for my $test (@tests) {
508     next if $test eq 'results.html';
509
510     my $newDumpTool = not $isDumpToolOpen;
511     openDumpTool();
512
513     my $base = stripExtension($test);
514     my $expectedExtension = ".txt";
515     
516     my $dir = $base;
517     $dir =~ s|/[^/]+$||;
518
519     if ($newDumpTool || $dir ne $lastDirectory) {
520         foreach my $logue (epiloguesAndPrologues($newDumpTool ? "" : $lastDirectory, $dir)) {
521             if (isCygwin()) {
522                 $logue = toWindowsPath($logue);
523             } else {
524                 $logue = canonpath($logue);
525             }
526             if ($verbose) {
527                 print "running epilogue or prologue $logue\n";
528             }
529             print OUT "$logue\n";
530             # Throw away output from DumpRenderTree.
531             # Once for the test output and once for pixel results (empty)
532             while (<IN>) {
533                 last if /#EOF/;
534             }
535             while (<IN>) {
536                 last if /#EOF/;
537             }
538         }
539     }
540
541     if ($verbose) {
542         print "running $test -> ";
543         $atLineStart = 0;
544     } elsif (!$quiet) {
545         if ($dir ne $lastDirectory) {
546             print "\n" unless $atLineStart;
547             print "$dir ";
548         }
549         print ".";
550         $atLineStart = 0;
551     }
552
553     $lastDirectory = $dir;
554
555     my $result;
556
557     my $startTime = time if $report10Slowest;
558
559     # Try to read expected hash file for pixel tests
560     my $suffixExpectedHash = "";
561     if ($pixelTests && !$resetResults) {
562         my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
563         if (open EXPECTEDHASH, "$expectedPixelDir/$base-$expectedTag.checksum") {
564             my $expectedHash = <EXPECTEDHASH>;
565             chomp($expectedHash);
566             close EXPECTEDHASH;
567             
568             # Format expected hash into a suffix string that is appended to the path / URL passed to DRT
569             $suffixExpectedHash = "'$expectedHash";
570         }
571     }
572
573     if ($test !~ /^http\//) {
574         my $testPath = "$testDirectory/$test";
575         if (isCygwin()) {
576             $testPath = toWindowsPath($testPath);
577         } else {
578             $testPath = canonpath($testPath);
579         }
580         print OUT "$testPath$suffixExpectedHash\n";
581     } else {
582         openHTTPDIfNeeded();
583         if ($test !~ /^http\/tests\/local\// && $test !~ /^http\/tests\/ssl\// && $test !~ /^http\/tests\/wml\// && $test !~ /^http\/tests\/media\//) {
584             my $path = canonpath($test);
585             $path =~ s/^http\/tests\///;
586             print OUT "http://127.0.0.1:$httpdPort/$path$suffixExpectedHash\n";
587         } elsif ($test =~ /^http\/tests\/ssl\//) {
588             my $path = canonpath($test);
589             $path =~ s/^http\/tests\///;
590             print OUT "https://127.0.0.1:$httpdSSLPort/$path$suffixExpectedHash\n";
591         } else {
592             my $testPath = "$testDirectory/$test";
593             if (isCygwin()) {
594                 $testPath = toWindowsPath($testPath);
595             } else {
596                 $testPath = canonpath($testPath);
597             }
598             print OUT "$testPath$suffixExpectedHash\n";
599         }
600     }
601
602     # DumpRenderTree is expected to dump two "blocks" to stdout for each test.
603     # Each block is terminated by a #EOF on a line by itself.
604     # The first block is the output of the test (in text, RenderTree or other formats).
605     # The second block is for optional pixel data in PNG format, and may be empty if
606     # pixel tests are not being run, or the test does not dump pixels (e.g. text tests).
607     
608     my $actualRead = readFromDumpToolWithTimer(IN);
609     my $errorRead = readFromDumpToolWithTimer(ERROR, $actualRead->{status} eq "timedOut");
610
611     my $actual = $actualRead->{output};
612     my $error = $errorRead->{output};
613
614     $expectedExtension = $actualRead->{extension};
615     my $expectedFileName = "$base-$expectedTag.$expectedExtension";
616
617     my $isText = isTextOnlyTest($actual);
618
619     my $expectedDir = expectedDirectoryForTest($base, $isText, $expectedExtension);
620     $expectedResultPaths{$base} = "$expectedDir/$expectedFileName";
621
622     unless ($actualRead->{status} eq "success" && $errorRead->{status} eq "success") {
623         my $crashed = $actualRead->{status} eq "crashed" || $errorRead->{status} eq "crashed";
624         testCrashedOrTimedOut($test, $base, $crashed, $actual, $error);
625         countFinishedTest($test, $base, $crashed ? "crash" : "timedout", 0);
626         next;
627      }
628
629     $durations{$test} = time - $startTime if $report10Slowest;
630
631     my $expected;
632
633     if (!$resetResults && open EXPECTED, "<", "$expectedDir/$expectedFileName") {
634         $expected = "";
635         while (<EXPECTED>) {
636             next if $stripEditingCallbacks && $_ =~ /^EDITING DELEGATE:/;
637             $expected .= $_;
638         }
639         close EXPECTED;
640     }
641     my $expectedMac;
642     if (!isAppleMacWebKit() && $strictTesting && !$isText) {
643       if (!$resetResults && open EXPECTED, "<", "$testDirectory/platform/mac/$expectedFileName") {
644         $expectedMac = "";
645         while (<EXPECTED>) {
646           $expectedMac .= $_;
647         }
648         close EXPECTED;
649       }
650     }
651
652     if ($shouldCheckLeaks && $testsPerDumpTool == 1) {
653         print "        $test -> ";
654     }
655
656     my $actualPNG = "";
657     my $diffPNG = "";
658     my $diffPercentage = "";
659     my $diffResult = "passed";
660
661     my $actualHash = "";
662     my $expectedHash = "";
663     my $actualPNGSize = 0;
664
665     while (<IN>) {
666         last if /#EOF/;
667         if (/ActualHash: ([a-f0-9]{32})/) {
668             $actualHash = $1;
669         } elsif (/ExpectedHash: ([a-f0-9]{32})/) {
670             $expectedHash = $1;
671         } elsif (/Content-Length: (\d+)\s*/) {
672             $actualPNGSize = $1;
673             read(IN, $actualPNG, $actualPNGSize);
674         }
675     }
676
677     if ($verbose && $pixelTests && !$resetResults && $actualPNGSize) {
678         if ($actualHash eq "" && $expectedHash eq "") {
679             printFailureMessageForTest($test, "WARNING: actual & expected pixel hashes are missing!");
680         } elsif ($actualHash eq "") {
681             printFailureMessageForTest($test, "WARNING: actual pixel hash is missing!");
682         } elsif ($expectedHash eq "") {
683             printFailureMessageForTest($test, "WARNING: expected pixel hash is missing!");
684         }
685     }
686
687     if ($actualPNGSize > 0) {
688         my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
689
690         if (!$resetResults && ($expectedHash ne $actualHash || ($actualHash eq "" && $expectedHash eq ""))) {
691             if (-f "$expectedPixelDir/$base-$expectedTag.png") {
692                 my $expectedPNGSize = -s "$expectedPixelDir/$base-$expectedTag.png";
693                 my $expectedPNG = "";
694                 open EXPECTEDPNG, "$expectedPixelDir/$base-$expectedTag.png";
695                 read(EXPECTEDPNG, $expectedPNG, $expectedPNGSize);
696
697                 print DIFFOUT "Content-Length: $actualPNGSize\n";
698                 print DIFFOUT $actualPNG;
699
700                 print DIFFOUT "Content-Length: $expectedPNGSize\n";
701                 print DIFFOUT $expectedPNG;
702
703                 while (<DIFFIN>) {
704                     last if /^error/ || /^diff:/;
705                     if (/Content-Length: (\d+)\s*/) {
706                         read(DIFFIN, $diffPNG, $1);
707                     }
708                 }
709
710                 if (/^diff: (.+)% (passed|failed)/) {
711                     $diffPercentage = $1;
712                     $imageDifferences{$base} = $diffPercentage;
713                     $diffResult = $2;
714                 }
715                 
716                 if ($diffPercentage == 0) {
717                     printFailureMessageForTest($test, "pixel hash failed (but pixel test still passes)");
718                 }
719             } elsif ($verbose) {
720                 printFailureMessageForTest($test, "WARNING: expected image is missing!");
721             }
722         }
723
724         if ($resetResults || !-f "$expectedPixelDir/$base-$expectedTag.png") {
725             mkpath catfile($expectedPixelDir, dirname($base)) if $testDirectory ne $expectedPixelDir;
726             writeToFile("$expectedPixelDir/$base-$expectedTag.png", $actualPNG);
727         }
728
729         if ($actualHash ne "" && ($resetResults || !-f "$expectedPixelDir/$base-$expectedTag.checksum")) {
730             writeToFile("$expectedPixelDir/$base-$expectedTag.checksum", $actualHash);
731         }
732     }
733
734     if (!isAppleMacWebKit() && $strictTesting && !$isText) {
735       if (defined $expectedMac) {
736         my $simplified_actual;
737         $simplified_actual = $actual;
738         $simplified_actual =~ s/at \(-?[0-9]+,-?[0-9]+\) *//g;
739         $simplified_actual =~ s/size -?[0-9]+x-?[0-9]+ *//g;
740         $simplified_actual =~ s/text run width -?[0-9]+: //g;
741         $simplified_actual =~ s/text run width -?[0-9]+ [a-zA-Z ]+: //g;
742         $simplified_actual =~ s/RenderButton {BUTTON} .*/RenderButton {BUTTON}/g;
743         $simplified_actual =~ s/RenderImage {INPUT} .*/RenderImage {INPUT}/g;
744         $simplified_actual =~ s/RenderBlock {INPUT} .*/RenderBlock {INPUT}/g;
745         $simplified_actual =~ s/RenderTextControl {INPUT} .*/RenderTextControl {INPUT}/g;
746         $simplified_actual =~ s/\([0-9]+px/px/g;
747         $simplified_actual =~ s/ *" *\n +" */ /g;
748         $simplified_actual =~ s/" +$/"/g;
749
750         $simplified_actual =~ s/- /-/g;
751         $simplified_actual =~ s/\n( *)"\s+/\n$1"/g;
752         $simplified_actual =~ s/\s+"\n/"\n/g;
753         
754         $expectedMac =~ s/at \(-?[0-9]+,-?[0-9]+\) *//g;
755         $expectedMac =~ s/size -?[0-9]+x-?[0-9]+ *//g;
756         $expectedMac =~ s/text run width -?[0-9]+: //g;
757         $expectedMac =~ s/text run width -?[0-9]+ [a-zA-Z ]+: //g;
758         $expectedMac =~ s/RenderButton {BUTTON} .*/RenderButton {BUTTON}/g;
759         $expectedMac =~ s/RenderImage {INPUT} .*/RenderImage {INPUT}/g;
760         $expectedMac =~ s/RenderBlock {INPUT} .*/RenderBlock {INPUT}/g;
761         $expectedMac =~ s/RenderTextControl {INPUT} .*/RenderTextControl {INPUT}/g;
762         $expectedMac =~ s/\([0-9]+px/px/g;
763         $expectedMac =~ s/ *" *\n +" */ /g;
764         $expectedMac =~ s/" +$/"/g;
765
766         $expectedMac =~ s/- /-/g;
767         $expectedMac =~ s/\n( *)"\s+/\n$1"/g;
768         $expectedMac =~ s/\s+"\n/"\n/g;
769         
770         if ($simplified_actual ne $expectedMac) {
771           writeToFile("/tmp/actual.txt", $simplified_actual);
772           writeToFile("/tmp/expected.txt", $expectedMac);
773           system "diff -u \"/tmp/expected.txt\" \"/tmp/actual.txt\" > \"/tmp/simplified.diff\"";
774
775           $diffResult = "failed";
776           if ($verbose) {
777             print "\n";
778             system "cat /tmp/simplified.diff";
779             print "failed!!!!!";
780           }
781         }
782       }
783     }
784
785     if (dumpToolDidCrash()) {
786         $result = "crash";
787         testCrashedOrTimedOut($test, $base, 1, $actual, $error);
788     } elsif (!defined $expected) {
789         if ($verbose) {
790             print "new " . ($resetResults ? "result" : "test") ."\n";
791             $atLineStart = 1;
792         }
793         $result = "new";
794
795         if ($generateNewResults || $resetResults) {
796             mkpath catfile($expectedDir, dirname($base)) if $testDirectory ne $expectedDir;
797             writeToFile("$expectedDir/$expectedFileName", $actual);
798         }
799         deleteExpectedAndActualResults($base);
800         if ($generateNewResults && !$resetResults) {
801             # Always print the file name for new tests, as they will probably need some manual inspection.
802             # in verbose mode we already printed the test case, so no need to do it again.
803             unless ($verbose) {
804                 print "\n" unless $atLineStart;
805                 print "$test -> ";
806             }
807             my $resultsDir = catdir($expectedDir, dirname($base));
808             print "new (results generated in $resultsDir)\n";
809             $atLineStart = 1;
810         }
811     } elsif ($actual eq $expected && $diffResult eq "passed") {
812         if ($verbose) {
813             print "succeeded\n";
814             $atLineStart = 1;
815         }
816         $result = "match";
817         deleteExpectedAndActualResults($base);
818     } else {
819         $result = "mismatch";
820
821         my $message = $actual eq $expected ? "pixel test failed" : "failed";
822
823         if ($actual ne $expected && $addPlatformExceptions) {
824             my $testBase = catfile($testDirectory, $base);
825             my $expectedBase = catfile($expectedDir, $base);
826             my $testIsMaximallyPlatformSpecific = $testBase =~ m|^\Q$platformTestDirectory\E/|;
827             my $expectedResultIsMaximallyPlatformSpecific = $expectedBase =~ m|^\Q$platformTestDirectory\E/|;
828             if (!$testIsMaximallyPlatformSpecific && !$expectedResultIsMaximallyPlatformSpecific) {
829                 mkpath catfile($platformTestDirectory, dirname($base));
830                 my $expectedFile = catfile($platformTestDirectory, "$expectedFileName");
831                 writeToFile("$expectedFile", $actual);
832                 $message .= " (results generated in $platformTestDirectory)";
833             }
834         }
835
836         printFailureMessageForTest($test, $message);
837
838         my $dir = "$testResultsDirectory/$base";
839         $dir =~ s|/([^/]+)$|| or die "Failed to find test name from base\n";
840         my $testName = $1;
841         mkpath $dir;
842
843         deleteExpectedAndActualResults($base);
844         recordActualResultsAndDiff($base, $actual);
845
846         if ($pixelTests && $diffPNG && $diffPNG ne "") {
847             $imagesPresent{$base} = 1;
848
849             writeToFile("$testResultsDirectory/$base-$actualTag.png", $actualPNG);
850             writeToFile("$testResultsDirectory/$base-$diffsTag.png", $diffPNG);
851
852             my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
853             copy("$expectedPixelDir/$base-$expectedTag.png", "$testResultsDirectory/$base-$expectedTag.png");
854
855             open DIFFHTML, ">$testResultsDirectory/$base-$diffsTag.html" or die;
856             print DIFFHTML "<html>\n";
857             print DIFFHTML "<head>\n";
858             print DIFFHTML "<title>$base Image Compare</title>\n";
859             print DIFFHTML "<script language=\"Javascript\" type=\"text/javascript\">\n";
860             print DIFFHTML "var currentImage = 0;\n";
861             print DIFFHTML "var imageNames = new Array(\"Actual\", \"Expected\");\n";
862             print DIFFHTML "var imagePaths = new Array(\"$testName-$actualTag.png\", \"$testName-$expectedTag.png\");\n";
863             if (-f "$testDirectory/$base-w3c.png") {
864                 copy("$testDirectory/$base-w3c.png", "$testResultsDirectory/$base-w3c.png");
865                 print DIFFHTML "imageNames.push(\"W3C\");\n";
866                 print DIFFHTML "imagePaths.push(\"$testName-w3c.png\");\n";
867             }
868             print DIFFHTML "function animateImage() {\n";
869             print DIFFHTML "    var image = document.getElementById(\"animatedImage\");\n";
870             print DIFFHTML "    var imageText = document.getElementById(\"imageText\");\n";
871             print DIFFHTML "    image.src = imagePaths[currentImage];\n";
872             print DIFFHTML "    imageText.innerHTML = imageNames[currentImage] + \" Image\";\n";
873             print DIFFHTML "    currentImage = (currentImage + 1) % imageNames.length;\n";
874             print DIFFHTML "    setTimeout('animateImage()',2000);\n";
875             print DIFFHTML "}\n";
876             print DIFFHTML "</script>\n";
877             print DIFFHTML "</head>\n";
878             print DIFFHTML "<body onLoad=\"animateImage();\">\n";
879             print DIFFHTML "<table>\n";
880             if ($diffPercentage) {
881                 print DIFFHTML "<tr>\n";
882                 print DIFFHTML "<td>Difference between images: <a href=\"$testName-$diffsTag.png\">$diffPercentage%</a></td>\n";
883                 print DIFFHTML "</tr>\n";
884             }
885             print DIFFHTML "<tr>\n";
886             print DIFFHTML "<td><a href=\"" . toURL("$testDirectory/$test") . "\">test file</a></td>\n";
887             print DIFFHTML "</tr>\n";
888             print DIFFHTML "<tr>\n";
889             print DIFFHTML "<td id=\"imageText\" style=\"text-weight: bold;\">Actual Image</td>\n";
890             print DIFFHTML "</tr>\n";
891             print DIFFHTML "<tr>\n";
892             print DIFFHTML "<td><img src=\"$testName-$actualTag.png\" id=\"animatedImage\"></td>\n";
893             print DIFFHTML "</tr>\n";
894             print DIFFHTML "</table>\n";
895             print DIFFHTML "</body>\n";
896             print DIFFHTML "</html>\n";
897         }
898     }
899
900     if ($error) {
901         my $dir = "$testResultsDirectory/$base";
902         $dir =~ s|/([^/]+)$|| or die "Failed to find test name from base\n";
903         mkpath $dir;
904         
905         writeToFile("$testResultsDirectory/$base-$errorTag.txt", $error);
906         
907         $counts{error}++;
908         push @{$tests{error}}, $test;
909     }
910
911     countFinishedTest($test, $base, $result, $isText);
912 }
913 printf "\n%0.2fs total testing time\n", (time - $overallStartTime) . "";
914
915 !$isDumpToolOpen || die "Failed to close $dumpToolName.\n";
916
917 closeHTTPD();
918
919 # Because multiple instances of this script are running concurrently we cannot 
920 # safely delete this symlink.
921 # system "rm /tmp/LayoutTests";
922
923 # FIXME: Do we really want to check the image-comparison tool for leaks every time?
924 if ($shouldCheckLeaks && $pixelTests) {
925     $totalLeaks += countAndPrintLeaks("ImageDiff", $imageDiffToolPID, "$testResultsDirectory/ImageDiff-leaks.txt");
926 }
927
928 if ($totalLeaks) {
929     if ($mergeDepth) {
930         parseLeaksandPrintUniqueLeaks();
931     }
932     else { 
933         print "\nWARNING: $totalLeaks total leaks found!\n";
934         print "See above for individual leaks results.\n" if ($leaksOutputFileNumber > 2);
935     }
936 }
937
938 close IN;
939 close OUT;
940 close ERROR;
941
942 if ($report10Slowest) {
943     print "\n\nThe 10 slowest tests:\n\n";
944     my $count = 0;
945     for my $test (sort slowestcmp keys %durations) {
946         printf "%0.2f secs: %s\n", $durations{$test}, $test;
947         last if ++$count == 10;
948     }
949 }
950
951 print "\n";
952
953 if ($skippedOnly && $counts{"match"}) {
954     print "The following tests are in the Skipped file (" . File::Spec->abs2rel("$platformTestDirectory/Skipped", $testDirectory) . "), but succeeded:\n";
955     foreach my $test (@{$tests{"match"}}) {
956         print "  $test\n";
957     }
958 }
959
960 if ($resetResults || ($counts{match} && $counts{match} == $count)) {
961     print "all $count test cases succeeded\n";
962     unlink $testResults;
963     exit;
964 }
965
966
967 my %text = (
968     match => "succeeded",
969     mismatch => "had incorrect layout",
970     new => "were new",
971     timedout => "timed out",
972     crash => "crashed",
973     error => "had stderr output"
974 );
975
976 for my $type ("match", "mismatch", "new", "timedout", "crash", "error") {
977     my $c = $counts{$type};
978     if ($c) {
979         my $t = $text{$type};
980         my $message;
981         if ($c == 1) {
982             $t =~ s/were/was/;
983             $message = sprintf "1 test case (%d%%) %s\n", 1 * 100 / $count, $t;
984         } else {
985             $message = sprintf "%d test cases (%d%%) %s\n", $c, $c * 100 / $count, $t;
986         }
987         $message =~ s-\(0%\)-(<1%)-;
988         print $message;
989     }
990 }
991
992 mkpath $testResultsDirectory;
993
994 open HTML, ">", $testResults or die;
995 print HTML "<html>\n";
996 print HTML "<head>\n";
997 print HTML "<title>Layout Test Results</title>\n";
998 print HTML "</head>\n";
999 print HTML "<body>\n";
1000
1001 print HTML htmlForResultsSection(@{$tests{mismatch}}, "Tests where results did not match expected results", \&linksForMismatchTest);
1002 print HTML htmlForResultsSection(@{$tests{timedout}}, "Tests that timed out", \&linksForErrorTest);
1003 print HTML htmlForResultsSection(@{$tests{crash}}, "Tests that caused the DumpRenderTree tool to crash", \&linksForErrorTest);
1004 print HTML htmlForResultsSection(@{$tests{error}}, "Tests that had stderr output", \&linksForErrorTest);
1005 print HTML htmlForResultsSection(@{$tests{new}}, "Tests that had no expected results (probably new)", \&linksForNewTest);
1006
1007 print HTML "</body>\n";
1008 print HTML "</html>\n";
1009 close HTML;
1010
1011 my @configurationArgs = argumentsForConfiguration();
1012
1013 if (isQt() || isGtk()) {
1014   system "WebKitTools/Scripts/run-launcher", @configurationArgs, "file://".$testResults if $launchSafari;
1015 } elsif (isCygwin()) {
1016   system "cygstart", $testResults if $launchSafari;
1017 } else {
1018   system "WebKitTools/Scripts/run-safari", @configurationArgs, "-NSOpen", $testResults if $launchSafari;
1019 }
1020
1021 closeCygpaths() if isCygwin();
1022
1023 exit 1;
1024
1025 sub countAndPrintLeaks($$$)
1026 {
1027     my ($dumpToolName, $dumpToolPID, $leaksFilePath) = @_;
1028
1029     print "\n" unless $atLineStart;
1030     $atLineStart = 1;
1031
1032     # We are excluding the following reported leaks so they don't get in our way when looking for WebKit leaks:
1033     # This allows us ignore known leaks and only be alerted when new leaks occur. Some leaks are in the old
1034     # versions of the system frameworks that are being used by the leaks bots. Even though a leak has been
1035     # fixed, it will be listed here until the bot has been updated with the newer frameworks.
1036
1037     my @typesToExclude = (
1038     );
1039
1040     my @callStacksToExclude = (
1041         "Flash_EnforceLocalSecurity" # leaks in Flash plug-in code, rdar://problem/4449747
1042     );
1043
1044     if (isTiger()) {
1045         # Leak list for the version of Tiger used on the build bot.
1046         push @callStacksToExclude, (
1047             "CFRunLoopRunSpecific \\| malloc_zone_malloc", "CFRunLoopRunSpecific \\| CFAllocatorAllocate ", # leak in CFRunLoopRunSpecific, rdar://problem/4670839
1048             "CGImageSourceGetPropertiesAtIndex", # leak in ImageIO, rdar://problem/4628809
1049             "FOGetCoveredUnicodeChars", # leak in ATS, rdar://problem/3943604
1050             "GetLineDirectionPreference", "InitUnicodeUtilities", # leaks tool falsely reporting leak in CFNotificationCenterAddObserver, rdar://problem/4964790
1051             "ICCFPrefWrapper::GetPrefDictionary", # leaks in Internet Config. code, rdar://problem/4449794
1052             "NSHTTPURLProtocol setResponseHeader:", # leak in multipart/mixed-replace handling in Foundation, no Radar, but fixed in Leopard
1053             "NSURLCache cachedResponseForRequest", # leak in CFURL cache, rdar://problem/4768430
1054             "PCFragPrepareClosureFromFile", # leak in Code Fragment Manager, rdar://problem/3426998
1055             "WebCore::Selection::toRange", # bug in 'leaks', rdar://problem/4967949
1056             "WebCore::SubresourceLoader::create", # bug in 'leaks', rdar://problem/4985806
1057             "_CFPreferencesDomainDeepCopyDictionary", # leak in CFPreferences, rdar://problem/4220786
1058             "_objc_msgForward", # leak in NSSpellChecker, rdar://problem/4965278
1059             "gldGetString", # leak in OpenGL, rdar://problem/5013699
1060             "_setDefaultUserInfoFromURL", # leak in NSHTTPAuthenticator, rdar://problem/5546453 
1061             "SSLHandshake", # leak in SSL, rdar://problem/5546440 
1062             "SecCertificateCreateFromData", # leak in SSL code, rdar://problem/4464397
1063         );
1064         push @typesToExclude, (
1065             "THRD", # bug in 'leaks', rdar://problem/3387783
1066             "DRHT", # ditto (endian little hate i)
1067         );
1068     }
1069
1070     if (isLeopard()) {
1071         # Leak list for the version of Leopard used on the build bot.
1072         push @callStacksToExclude, (
1073             "CFHTTPMessageAppendBytes", # leak in CFNetwork, rdar://problem/5435912
1074             "sendDidReceiveDataCallback", # leak in CFNetwork, rdar://problem/5441619
1075             "_CFHTTPReadStreamReadMark", # leak in CFNetwork, rdar://problem/5441468
1076             "httpProtocolStart", # leak in CFNetwork, rdar://problem/5468837
1077             "_CFURLConnectionSendCallbacks", # leak in CFNetwork, rdar://problem/5441600
1078             "DispatchQTMsg", # leak in QuickTime, PPC only, rdar://problem/5667132
1079             "QTMovieContentView createVisualContext", # leak in QuickTime, PPC only, rdar://problem/5667132
1080             "_CopyArchitecturesForJVMVersion", # leak in Java, rdar://problem/5910823
1081         );
1082     }
1083
1084     my $leaksTool = sourceDir() . "/WebKitTools/Scripts/run-leaks";
1085     my $excludeString = "--exclude-callstack '" . (join "' --exclude-callstack '", @callStacksToExclude) . "'";
1086     $excludeString .= " --exclude-type '" . (join "' --exclude-type '", @typesToExclude) . "'" if @typesToExclude;
1087
1088     print " ? checking for leaks in $dumpToolName\n";
1089     my $leaksOutput = `$leaksTool $excludeString $dumpToolPID`;
1090     my ($count, $bytes) = $leaksOutput =~ /Process $dumpToolPID: (\d+) leaks? for (\d+) total/;
1091     my ($excluded) = $leaksOutput =~ /(\d+) leaks? excluded/;
1092
1093     my $adjustedCount = $count;
1094     $adjustedCount -= $excluded if $excluded;
1095
1096     if (!$adjustedCount) {
1097         print " - no leaks found\n";
1098         unlink $leaksFilePath;
1099         return 0;
1100     } else {
1101         my $dir = $leaksFilePath;
1102         $dir =~ s|/[^/]+$|| or die;
1103         mkpath $dir;
1104
1105         if ($excluded) {
1106             print " + $adjustedCount leaks ($bytes bytes including $excluded excluded leaks) were found, details in $leaksFilePath\n";
1107         } else {
1108             print " + $count leaks ($bytes bytes) were found, details in $leaksFilePath\n";
1109         }
1110
1111         writeToFile($leaksFilePath, $leaksOutput);
1112         
1113         push( @leaksFilenames, $leaksFilePath );
1114     }
1115
1116     return $adjustedCount;
1117 }
1118
1119 sub writeToFile($$)
1120 {
1121     my ($filePath, $contents) = @_;
1122     open NEWFILE, ">", "$filePath" or die "could not create $filePath\n";
1123     print NEWFILE $contents;
1124     close NEWFILE;
1125 }
1126
1127 # Break up a path into the directory (with slash) and base name.
1128 sub splitpath($)
1129 {
1130     my ($path) = @_;
1131
1132     my $pathSeparator = "/";
1133     my $dirname = dirname($path) . $pathSeparator;
1134     $dirname = "" if $dirname eq "." . $pathSeparator;
1135
1136     return ($dirname, basename($path));
1137 }
1138
1139 # Sort first by directory, then by file, so all paths in one directory are grouped
1140 # rather than being interspersed with items from subdirectories.
1141 # Use numericcmp to sort directory and filenames to make order logical.
1142 sub pathcmp($$)
1143 {
1144     my ($patha, $pathb) = @_;
1145
1146     my ($dira, $namea) = splitpath($patha);
1147     my ($dirb, $nameb) = splitpath($pathb);
1148
1149     return numericcmp($dira, $dirb) if $dira ne $dirb;
1150     return numericcmp($namea, $nameb);
1151 }
1152
1153 # Sort numeric parts of strings as numbers, other parts as strings.
1154 # Makes 1.33 come after 1.3, which is cool.
1155 sub numericcmp($$)
1156 {
1157     my ($aa, $bb) = @_;
1158
1159     my @a = split /(\d+)/, $aa;
1160     my @b = split /(\d+)/, $bb;
1161
1162     # Compare one chunk at a time.
1163     # Each chunk is either all numeric digits, or all not numeric digits.
1164     while (@a && @b) {
1165         my $a = shift @a;
1166         my $b = shift @b;
1167         
1168         # Use numeric comparison if chunks are non-equal numbers.
1169         return $a <=> $b if $a =~ /^\d/ && $b =~ /^\d/ && $a != $b;
1170
1171         # Use string comparison if chunks are any other kind of non-equal string.
1172         return $a cmp $b if $a ne $b;
1173     }
1174     
1175     # One of the two is now empty; compare lengths for result in this case.
1176     return @a <=> @b;
1177 }
1178
1179 # Sort slowest tests first.
1180 sub slowestcmp($$)
1181 {
1182     my ($testa, $testb) = @_;
1183
1184     my $dura = $durations{$testa};
1185     my $durb = $durations{$testb};
1186     return $durb <=> $dura if $dura != $durb;
1187     return pathcmp($testa, $testb);
1188 }
1189
1190 sub openDumpTool()
1191 {
1192     return if $isDumpToolOpen;
1193
1194     # Save some requires variables for the linux environment...
1195     my $homeDir = $ENV{'HOME'};
1196     my $libraryPath = $ENV{'LD_LIBRARY_PATH'};
1197     my $dyldLibraryPath = $ENV{'DYLD_LIBRARY_PATH'};
1198     my $dbusAddress = $ENV{'DBUS_SESSION_BUS_ADDRESS'};
1199     my $display = $ENV{'DISPLAY'};
1200     my $testfonts = $ENV{'WEBKIT_TESTFONTS'};
1201
1202     my $homeDrive = $ENV{'HOMEDRIVE'};
1203     my $homePath = $ENV{'HOMEPATH'};
1204         
1205     local %ENV;
1206     if (isQt() || isGtk()) {
1207         if (defined $display) {
1208             $ENV{DISPLAY} = $display;
1209         } else {
1210             $ENV{DISPLAY} = ":1";
1211         }
1212         $ENV{'WEBKIT_TESTFONTS'} = $testfonts if defined($testfonts);
1213         $ENV{HOME} = $homeDir;
1214         if (defined $libraryPath) {
1215             $ENV{LD_LIBRARY_PATH} = $libraryPath;
1216         }
1217         if (defined $dyldLibraryPath) {
1218             $ENV{DYLD_LIBRARY_PATH} = $dyldLibraryPath;
1219         }
1220         if (defined $dbusAddress) {
1221             $ENV{DBUS_SESSION_BUS_ADDRESS} = $dbusAddress;
1222         }
1223     }
1224     $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
1225     $ENV{XML_CATALOG_FILES} = ""; # work around missing /etc/catalog <rdar://problem/4292995>
1226     $ENV{DYLD_INSERT_LIBRARIES} = "/usr/lib/libgmalloc.dylib" if $guardMalloc;
1227     
1228     if (isCygwin()) {
1229         $ENV{HOMEDRIVE} = $homeDrive;
1230         $ENV{HOMEPATH} = $homePath;
1231         if ($testfonts) {
1232             $ENV{WEBKIT_TESTFONTS} = $testfonts;
1233         }
1234         setPathForRunningWebKitApp(\%ENV) if isCygwin();
1235     }
1236
1237     my @args = ($dumpTool, @toolArgs);
1238
1239     if ($useValgrind) {
1240         unshift @args, "valgrind";
1241     } 
1242     
1243     $ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
1244     $dumpToolPID = open3(\*OUT, \*IN, \*ERROR, @args) or die "Failed to start tool: $dumpTool\n";
1245     $ENV{MallocStackLogging} = 0 if $shouldCheckLeaks;
1246     $isDumpToolOpen = 1;
1247     $dumpToolCrashed = 0;
1248 }
1249
1250 sub closeDumpTool()
1251 {
1252     return if !$isDumpToolOpen;
1253
1254     close IN;
1255     close OUT;
1256     waitpid $dumpToolPID, 0;
1257     
1258     # check for WebCore counter leaks.
1259     if ($shouldCheckLeaks) {
1260         while (<ERROR>) {
1261             print;
1262         }
1263     }
1264     close ERROR;
1265     $isDumpToolOpen = 0;
1266 }
1267
1268 sub dumpToolDidCrash()
1269 {
1270     return 1 if $dumpToolCrashed;
1271     return 0 unless $isDumpToolOpen;
1272
1273     my $pid = waitpid(-1, WNOHANG);
1274     return 1 if ($pid == $dumpToolPID);
1275
1276     # On Mac OS X, crashing may be significantly delayed by crash reporter.
1277     return 0 unless isAppleMacWebKit();
1278
1279     my $tryingToExit = 0;
1280     open PS, "ps -o state -p $dumpToolPID |";
1281     <PS>; # skip header
1282     $tryingToExit = 1 if <PS> =~ /E/;
1283     close PS;
1284     return $tryingToExit;
1285 }
1286
1287 sub openHTTPDIfNeeded()
1288 {
1289     return if $isHttpdOpen;
1290
1291     mkdir "/tmp/WebKit";
1292     
1293     if (-f "/tmp/WebKit/httpd.pid") {
1294         my $oldPid = `cat /tmp/WebKit/httpd.pid`;
1295         chomp $oldPid;
1296         if (0 != kill 0, $oldPid) {
1297             print "\nhttpd is already running: pid $oldPid, killing...\n";
1298             kill 15, $oldPid;
1299             
1300             my $retryCount = 20;
1301             while ((0 != kill 0, $oldPid) && $retryCount) {
1302                 sleep 1;
1303                 --$retryCount;
1304             }
1305             
1306             die "Timed out waiting for httpd to quit" unless $retryCount;
1307         }
1308     }
1309     
1310     my $httpdPath = "/usr/sbin/httpd";
1311     my $httpdConfig;
1312     if (isCygwin()) {
1313         my $windowsConfDirectory = "$testDirectory/http/conf/";
1314         unless (-x "/usr/lib/apache/libphp4.dll") {
1315             copy("$windowsConfDirectory/libphp4.dll", "/usr/lib/apache/libphp4.dll");
1316             chmod(0755, "/usr/lib/apache/libphp4.dll");
1317         }
1318         $httpdConfig = "$windowsConfDirectory/cygwin-httpd.conf";
1319     } elsif (isDebianBased()) {
1320         $httpdPath = "/usr/sbin/apache2";
1321         $httpdConfig = "$testDirectory/http/conf/apache2-debian-httpd.conf";
1322     } else {
1323         $httpdConfig = "$testDirectory/http/conf/httpd.conf";
1324         $httpdConfig = "$testDirectory/http/conf/apache2-httpd.conf" if `$httpdPath -v` =~ m|Apache/2|;
1325     }
1326     my $documentRoot = "$testDirectory/http/tests";
1327     my $typesConfig = "$testDirectory/http/conf/mime.types";
1328     my $listen = "127.0.0.1:$httpdPort";
1329     my $absTestResultsDirectory = File::Spec->rel2abs(glob $testResultsDirectory);
1330     my $sslCertificate = "$testDirectory/http/conf/webkit-httpd.pem";
1331
1332     mkpath $absTestResultsDirectory;
1333
1334     my @args = (
1335         "-f", "$httpdConfig",
1336         "-C", "DocumentRoot \"$documentRoot\"",
1337         "-C", "Listen $listen",
1338         "-c", "TypesConfig \"$typesConfig\"",
1339         "-c", "CustomLog \"$absTestResultsDirectory/access_log.txt\" common",
1340         "-c", "ErrorLog \"$absTestResultsDirectory/error_log.txt\"",
1341         # Apache wouldn't run CGIs with permissions==700 otherwise
1342         "-c", "User \"#$<\""
1343     );
1344
1345     # FIXME: Enable this on Windows once <rdar://problem/5345985> is fixed
1346     # The version of Apache we use with Cygwin does not support SSL
1347     push(@args, "-c", "SSLCertificateFile \"$sslCertificate\"") unless isCygwin();
1348
1349     open2(\*HTTPDIN, \*HTTPDOUT, $httpdPath, @args);
1350
1351     my $retryCount = 20;
1352     while (system("/usr/bin/curl -q --silent --stderr - --output /dev/null $listen") && $retryCount) {
1353         sleep 1;
1354         --$retryCount;
1355     }
1356     
1357     die "Timed out waiting for httpd to start" unless $retryCount;
1358     
1359     $isHttpdOpen = 1;
1360 }
1361
1362 sub closeHTTPD()
1363 {
1364     return if !$isHttpdOpen;
1365
1366     close HTTPDIN;
1367     close HTTPDOUT;
1368
1369     kill 15, `cat /tmp/WebKit/httpd.pid` if -f "/tmp/WebKit/httpd.pid";
1370
1371     $isHttpdOpen = 0;
1372 }
1373
1374 sub fileNameWithNumber($$)
1375 {
1376     my ($base, $number) = @_;
1377     return "$base$number" if ($number > 1);
1378     return $base;
1379 }
1380
1381 sub processIgnoreTests($$) {
1382     my @ignoreList = split(/\s*,\s*/, shift);
1383     my $listName = shift;
1384
1385     my $disabledSuffix = "-disabled";
1386
1387     my $addIgnoredDirectories = sub {
1388         return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
1389         $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)} = 1;
1390         return @_;
1391     };
1392     foreach my $item (@ignoreList) {
1393         my $path = catfile($testDirectory, $item); 
1394         if (-d $path) {
1395             $ignoredDirectories{$item} = 1;
1396             find({ preprocess => $addIgnoredDirectories, wanted => sub {} }, $path);
1397         }
1398         elsif (-f $path) {
1399             $ignoredFiles{$item} = 1;
1400         } elsif (-f $path . $disabledSuffix) {
1401             # The test is disabled, so do nothing.
1402         } else {
1403             print "$listName list contained '$item', but no file of that name could be found\n";
1404         }
1405     }
1406 }
1407
1408 sub stripExtension($)
1409 {
1410     my ($test) = @_;
1411
1412     $test =~ s/\.[a-zA-Z]+$//;
1413     return $test;
1414 }
1415
1416 sub isTextOnlyTest($)
1417 {
1418     my ($actual) = @_;
1419     my $isText;
1420     if ($actual =~ /^layer at/ms) {
1421         $isText = 0;
1422     } else {
1423         $isText = 1;
1424     }
1425     return $isText;
1426 }
1427
1428 sub expectedDirectoryForTest($;$;$)
1429 {
1430     my ($base, $isText, $expectedExtension) = @_;
1431
1432     my @directories = @platformHierarchy;
1433     push @directories, map { catdir($platformBaseDirectory, $_) } qw(mac-leopard mac) if isCygwin();
1434     push @directories, $expectedDirectory;
1435
1436     # If we already have expected results, just return their location.
1437     foreach my $directory (@directories) {
1438         return $directory if (-f "$directory/$base-$expectedTag.$expectedExtension");
1439     }
1440
1441     # For platform-specific tests, the results should go right next to the test itself.
1442     # Note: The return value of this subroutine will be concatenated with $base
1443     # to determine the location of the new results, so returning $expectedDirectory
1444     # will put the results right next to the test.
1445     # FIXME: We want to allow platform/mac tests with platform/mac-leopard results,
1446     # so this needs to be enhanced.
1447     return $expectedDirectory if $base =~ /^platform/;
1448
1449     # For cross-platform tests, text-only results should go in the cross-platform directory,
1450     # while render tree dumps should go in the least-specific platform directory.
1451     return $isText ? $expectedDirectory : $platformHierarchy[$#platformHierarchy];
1452 }
1453
1454 sub countFinishedTest($$$$) {
1455     my ($test, $base, $result, $isText) = @_;
1456
1457     if (($count + 1) % $testsPerDumpTool == 0 || $count == $#tests) {
1458         if ($shouldCheckLeaks) {
1459             my $fileName;
1460             if ($testsPerDumpTool == 1) {
1461                 $fileName = "$testResultsDirectory/$base-leaks.txt";
1462             } else {
1463                 $fileName = "$testResultsDirectory/" . fileNameWithNumber($dumpToolName, $leaksOutputFileNumber) . "-leaks.txt";
1464             }
1465             my $leakCount = countAndPrintLeaks($dumpToolName, $dumpToolPID, $fileName);
1466             $totalLeaks += $leakCount;
1467             $leaksOutputFileNumber++ if ($leakCount);
1468         }
1469
1470         closeDumpTool();
1471     }
1472     
1473     $count++;
1474     $counts{$result}++;
1475     push @{$tests{$result}}, $test;
1476     $testType{$test} = $isText;
1477 }
1478
1479 sub testCrashedOrTimedOut($$$$$)
1480 {
1481     my ($test, $base, $didCrash, $actual, $error) = @_;
1482
1483     printFailureMessageForTest($test, $didCrash ? "crashed" : "timed out");
1484
1485     sampleDumpTool() unless $didCrash;
1486
1487     my $dir = "$testResultsDirectory/$base";
1488     $dir =~ s|/([^/]+)$|| or die "Failed to find test name from base\n";
1489     mkpath $dir;
1490
1491     deleteExpectedAndActualResults($base);
1492
1493     if (defined($error) && length($error)) {
1494         writeToFile("$testResultsDirectory/$base-$errorTag.txt", $error);
1495     }
1496
1497     recordActualResultsAndDiff($base, $actual);
1498
1499     kill 9, $dumpToolPID unless $didCrash;
1500
1501     closeDumpTool();
1502 }
1503
1504 sub printFailureMessageForTest($$)
1505 {
1506     my ($test, $description) = @_;
1507
1508     unless ($verbose) {
1509         print "\n" unless $atLineStart;
1510         print "$test -> ";
1511     }
1512     print "$description\n";
1513     $atLineStart = 1;
1514 }
1515
1516 my %cygpaths = ();
1517
1518 sub openCygpathIfNeeded($)
1519 {
1520     my ($options) = @_;
1521
1522     return unless isCygwin();
1523     return $cygpaths{$options} if $cygpaths{$options} && $cygpaths{$options}->{"open"};
1524
1525     local (*CYGPATHIN, *CYGPATHOUT);
1526     my $pid = open2(\*CYGPATHIN, \*CYGPATHOUT, "cygpath -f - $options");
1527     my $cygpath =  {
1528         "pid" => $pid,
1529         "in" => *CYGPATHIN,
1530         "out" => *CYGPATHOUT,
1531         "open" => 1
1532     };
1533
1534     $cygpaths{$options} = $cygpath;
1535
1536     return $cygpath;
1537 }
1538
1539 sub closeCygpaths()
1540 {
1541     return unless isCygwin();
1542
1543     foreach my $cygpath (values(%cygpaths)) {
1544         close $cygpath->{"in"};
1545         close $cygpath->{"out"};
1546         waitpid($cygpath->{"pid"}, 0);
1547         $cygpath->{"open"} = 0;
1548
1549     }
1550 }
1551
1552 sub convertPathUsingCygpath($$)
1553 {
1554     my ($path, $options) = @_;
1555
1556     my $cygpath = openCygpathIfNeeded($options);
1557     local *inFH = $cygpath->{"in"};
1558     local *outFH = $cygpath->{"out"};
1559     print outFH $path . "\n";
1560     chomp(my $convertedPath = <inFH>);
1561     return $convertedPath;
1562 }
1563
1564 sub toWindowsPath($)
1565 {
1566     my ($path) = @_;
1567     return unless isCygwin();
1568
1569     return convertPathUsingCygpath($path, "-w");
1570 }
1571
1572 sub toURL($)
1573 {
1574     my ($path) = @_;
1575     return $path unless isCygwin();
1576     
1577     return "file:///" . convertPathUsingCygpath($path, "-m");
1578 }
1579
1580 sub validateSkippedArg($$;$)
1581 {
1582     my ($option, $value, $value2) = @_;
1583     my %validSkippedValues = map { $_ => 1 } qw(default ignore only);
1584     $value = lc($value);
1585     die "Invalid argument '" . $value . "' for option $option" unless $validSkippedValues{$value};
1586     $treatSkipped = $value;
1587 }
1588
1589 sub htmlForResultsSection(\@$&)
1590 {
1591     my ($tests, $description, $linkGetter) = @_;
1592
1593     my @html = ();
1594     return join("\n", @html) unless @{$tests};
1595
1596     push @html, "<p>$description:</p>";
1597     push @html, "<table>";
1598     foreach my $test (@{$tests}) {
1599         push @html, "<tr>";
1600         push @html, "<td><a href=\"" . toURL("$testDirectory/$test") . "\">$test</a></td>";
1601         foreach my $link (@{&{$linkGetter}($test)}) {
1602             push @html, "<td><a href=\"$link->{href}\">$link->{text}</a></td>";
1603         }
1604         push @html, "</tr>";
1605     }
1606     push @html, "</table>";
1607
1608     return join("\n", @html);
1609 }
1610
1611 sub linksForExpectedAndActualResults($)
1612 {
1613     my ($base) = @_;
1614
1615     my @links = ();
1616
1617     return \@links unless -s "$testResultsDirectory/$base-$diffsTag.txt";
1618     
1619     my $expectedResultPath = $expectedResultPaths{$base};
1620     my ($expectedResultFileName, $expectedResultsDirectory, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
1621
1622     push @links, { href => "$base-$expectedTag$expectedResultExtension", text => "expected" };
1623     push @links, { href => "$base-$actualTag$expectedResultExtension", text => "actual" };
1624     push @links, { href => "$base-$diffsTag.txt", text => "diffs" };
1625
1626     return \@links;
1627 }
1628
1629 sub linksForMismatchTest
1630 {
1631     my ($test) = @_;
1632
1633     my @links = ();
1634
1635     my $base = stripExtension($test);
1636
1637     push @links, @{linksForExpectedAndActualResults($base)};
1638     return \@links unless $pixelTests && $imagesPresent{$base};
1639
1640     push @links, { href => "$base-$expectedTag.png", text => "expected image" };
1641     push @links, { href => "$base-$diffsTag.html", text => "image diffs" };
1642     push @links, { href => "$base-$diffsTag.png", text => "$imageDifferences{$base}%" };
1643
1644     return \@links;
1645 }
1646
1647 sub linksForErrorTest
1648 {
1649     my ($test) = @_;
1650
1651     my @links = ();
1652
1653     my $base = stripExtension($test);
1654
1655     push @links, @{linksForExpectedAndActualResults($base)};
1656     push @links, { href => "$base-$errorTag.txt", text => "stderr" };
1657
1658     return \@links;
1659 }
1660
1661 sub linksForNewTest
1662 {
1663     my ($test) = @_;
1664
1665     my @links = ();
1666
1667     my $base = stripExtension($test);
1668     my $expectedResultPath = $expectedResultPaths{$base};
1669     my $expectedResultPathMinusExtension = stripExtension($expectedResultPath);
1670
1671     push @links, { href => toURL($expectedResultPath), text => "results" };
1672     if ($pixelTests && -f "$expectedResultPathMinusExtension.png") {
1673         push @links, { href => toURL("$expectedResultPathMinusExtension.png"), text => "image" };
1674     }
1675
1676     return \@links;
1677 }
1678
1679 sub deleteExpectedAndActualResults($)
1680 {
1681     my ($base) = @_;
1682
1683     unlink "$testResultsDirectory/$base-$actualTag.txt";
1684     unlink "$testResultsDirectory/$base-$diffsTag.txt";
1685     unlink "$testResultsDirectory/$base-$errorTag.txt";
1686 }
1687
1688 sub recordActualResultsAndDiff($$)
1689 {
1690     my ($base, $actualResults) = @_;
1691
1692     return unless defined($actualResults) && length($actualResults);
1693
1694     my $expectedResultPath = $expectedResultPaths{$base};
1695     my ($expectedResultFileNameMinusExtension, $expectedResultDirectoryPath, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
1696     my $actualResultsPath = "$testResultsDirectory/$base-$actualTag$expectedResultExtension";
1697     my $copiedExpectedResultsPath = "$testResultsDirectory/$base-$expectedTag$expectedResultExtension";
1698     writeToFile("$actualResultsPath", $actualResults);
1699     copy("$expectedResultPath", "$copiedExpectedResultsPath");
1700
1701     system "diff -u \"$copiedExpectedResultsPath\" \"$actualResultsPath\" > \"$testResultsDirectory/$base-$diffsTag.txt\"";
1702 }
1703
1704 sub buildPlatformHierarchy()
1705 {
1706     mkpath($platformTestDirectory) if ($platform eq "undefined" && !-d "$platformTestDirectory");
1707
1708     my @platforms = split('-', $platform);
1709     my @hierarchy;
1710     for (my $i=0; $i < @platforms; $i++) {
1711         my $scoped = catdir($platformBaseDirectory, join('-', @platforms[0..($#platforms - $i)]));
1712         push(@hierarchy, $scoped) if (-d $scoped);
1713     }
1714
1715     return @hierarchy;
1716 }
1717
1718 sub epiloguesAndPrologues($$) {
1719     my ($lastDirectory, $directory) = @_;
1720     my @lastComponents = split('/', $lastDirectory);
1721     my @components = split('/', $directory);
1722
1723     while (@lastComponents) {
1724         if (!defined($components[0]) || $lastComponents[0] ne $components[0]) {
1725             last;
1726         }
1727         shift @components;
1728         shift @lastComponents;
1729     }
1730
1731     my @result;
1732     my $leaving = $lastDirectory;
1733     foreach (@lastComponents) {
1734         my $epilogue = $leaving . "/resources/run-webkit-tests-epilogue.html";
1735         foreach (@platformHierarchy) {
1736             push @result, catdir($_, $epilogue) if (stat(catdir($_, $epilogue)));
1737         }
1738         push @result, catdir($testDirectory, $epilogue) if (stat(catdir($testDirectory, $epilogue)));
1739         $leaving =~ s|(^\|/)[^/]+$||;
1740     }
1741
1742     my $entering = $leaving;
1743     foreach (@components) {
1744         $entering .= '/' . $_;
1745         my $prologue = $entering . "/resources/run-webkit-tests-prologue.html";
1746         push @result, catdir($testDirectory, $prologue) if (stat(catdir($testDirectory, $prologue)));
1747         foreach (reverse @platformHierarchy) {
1748             push @result, catdir($_, $prologue) if (stat(catdir($_, $prologue)));
1749         }
1750     }
1751     return @result;
1752 }
1753     
1754 sub parseLeaksandPrintUniqueLeaks() {
1755     return unless @leaksFilenames;
1756      
1757     my $mergedFilenames = join " ", @leaksFilenames;
1758     my $parseMallocHistoryTool = sourceDir() . "/WebKitTools/Scripts/parse-malloc-history";
1759     
1760     open MERGED_LEAKS, "cat $mergedFilenames | $parseMallocHistoryTool --merge-depth $mergeDepth  - |" ;
1761     my @leakLines = <MERGED_LEAKS>;
1762     close MERGED_LEAKS;
1763     
1764     my $uniqueLeakCount = 0;
1765     my $totalBytes;
1766     foreach my $line (@leakLines) {
1767         ++$uniqueLeakCount if ($line =~ /^(\d*)\scalls/);
1768         $totalBytes = $1 if $line =~ /^total\:\s(.*)\s\(/;
1769     }
1770     
1771     print "\nWARNING: $totalLeaks total leaks found for a total of $totalBytes!\n";
1772     print "WARNING: $uniqueLeakCount unique leaks found!\n";
1773     print "See above for individual leaks results.\n" if ($leaksOutputFileNumber > 2);
1774     
1775 }
1776
1777 sub extensionForMimeType($)
1778 {
1779     my ($mimeType) = @_;
1780
1781     if ($mimeType eq "application/x-webarchive") {
1782         return "webarchive";
1783     } elsif ($mimeType eq "application/pdf") {
1784         return "pdf";
1785     }
1786     return "txt";
1787 }
1788
1789 # Read up to the first #EOF (the content block of the test), or until detecting crashes or timeouts.
1790 sub readFromDumpToolWithTimer(*;$)
1791 {
1792     my ($fh, $dontWaitForTimeOut) = @_;
1793
1794     setFileHandleNonBlocking($fh, 1);
1795
1796     my $maximumSecondsWithoutOutput = 60;
1797     $maximumSecondsWithoutOutput *= 10 if $guardMalloc;
1798     my $microsecondsToWaitBeforeReadingAgain = 1000;
1799
1800     my $timeOfLastSuccessfulRead = time;
1801
1802     my @output = ();
1803     my $status = "success";
1804     my $mimeType = "text/plain";
1805     # We don't have a very good way to know when the "headers" stop
1806     # and the content starts, so we use this as a hack:
1807     my $haveSeenContentType = 0;
1808
1809     while (1) {
1810         if (time - $timeOfLastSuccessfulRead > $maximumSecondsWithoutOutput) {
1811             $status = dumpToolDidCrash() ? "crashed" : "timedOut";
1812             last;
1813         }
1814
1815         my $line = readline($fh);
1816         if (!defined($line)) {
1817             if ($! != EAGAIN) {
1818                 $status = "crashed";
1819                 last;
1820             }
1821
1822             if ($dontWaitForTimeOut) {
1823                 last;
1824             }
1825
1826             # No data ready
1827             usleep($microsecondsToWaitBeforeReadingAgain);
1828             next;
1829         }
1830
1831         $timeOfLastSuccessfulRead = time;
1832         
1833         if (!$haveSeenContentType && $line =~ /^Content-Type: (\S+)$/) {
1834             $mimeType = $1;
1835             $haveSeenContentType = 1;
1836             next;
1837         }
1838         last  if ($line =~ /#EOF/);
1839         
1840         push @output, $line;
1841     }
1842
1843     setFileHandleNonBlocking($fh, 0);
1844     return {
1845         output => join("", @output),
1846         status => $status,
1847         mimeType => $mimeType,
1848         extension => extensionForMimeType($mimeType)
1849     };
1850 }
1851
1852 sub setFileHandleNonBlocking(*$)
1853 {
1854     my ($fh, $nonBlocking) = @_;
1855
1856     my $flags = fcntl($fh, F_GETFL, 0) or die "Couldn't get filehandle flags";
1857
1858     if ($nonBlocking) {
1859         $flags |= O_NONBLOCK;
1860     } else {
1861         $flags &= ~O_NONBLOCK;
1862     }
1863
1864     fcntl($fh, F_SETFL, $flags) or die "Couldn't set filehandle flags";
1865
1866     return 1;
1867 }
1868
1869 sub sampleDumpTool()
1870 {
1871     return unless isAppleMacWebKit();
1872     return unless $runSample;
1873
1874     my $outputDirectory = "$ENV{HOME}/Library/Logs/DumpRenderTree";
1875     -d $outputDirectory or mkdir $outputDirectory;
1876
1877     my $outputFile = "$outputDirectory/HangReport.txt";
1878     system "/usr/bin/sample", $dumpToolPID, qw(10 10 -file), $outputFile;
1879 }