dc54541d7f6205f2d2821e2c9d54b3fd7e7efcd9
[WebKit-https.git] / WebKitTools / Scripts / build-webkit
1 #!/usr/bin/perl -w
2
3 # Copyright (C) 2005, 2006 Apple Inc. All rights reserved.
4 # Copyright (C) 2009 Google Inc. All rights reserved.
5 #
6 # Redistribution and use in source and binary forms, with or without
7 # modification, are permitted provided that the following conditions
8 # are met:
9 #
10 # 1.  Redistributions of source code must retain the above copyright
11 #     notice, this list of conditions and the following disclaimer. 
12 # 2.  Redistributions in binary form must reproduce the above copyright
13 #     notice, this list of conditions and the following disclaimer in the
14 #     documentation and/or other materials provided with the distribution. 
15 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
16 #     its contributors may be used to endorse or promote products derived
17 #     from this software without specific prior written permission. 
18 #
19 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
20 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
21 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
22 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
23 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
24 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
25 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
26 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29
30 # Build script wrapper for the WebKit Open Source Project.
31
32 use strict;
33 use File::Basename;
34 use File::Spec;
35 use FindBin;
36 use Getopt::Long qw(:config pass_through);
37 use lib $FindBin::Bin;
38 use webkitdirs;
39 use POSIX;
40
41 sub formatBuildTime($);
42 sub writeCongrats();
43
44 my $originalWorkingDirectory = getcwd();
45 chdirWebKit();
46
47 my $showHelp = 0;
48 my $clean = 0;
49 my $minimal = 0;
50 my $makeArgs;
51 my $startTime = time();
52
53 my ($threeDCanvasSupport, $threeDRenderingSupport, $channelMessagingSupport, $databaseSupport, $datagridSupport, $datalistSupport,
54     $domStorageSupport, $eventsourceSupport, $filtersSupport, $geolocationSupport, $iconDatabaseSupport,
55     $javaScriptDebuggerSupport, $mathmlSupport, $offlineWebApplicationSupport, $sharedWorkersSupport,
56     $svgSupport, $svgAnimationSupport, $svgAsImageSupport, $svgDOMObjCBindingsSupport, $svgFontsSupport,
57     $svgForeignObjectSupport, $svgUseSupport, $videoSupport, $webSocketsSupport, $wmlSupport, $wcssSupport, $xhtmlmpSupport, $workersSupport,
58     $xpathSupport, $xsltSupport, $coverageSupport, $notificationsSupport);
59
60 my @features = (
61     { option => "3d-canvas", desc => "Toggle 3D canvas support",
62       define => "ENABLE_3D_CANVAS", default => (isAppleMacWebKit() && !isTiger()), value => \$threeDCanvasSupport },
63
64     { option => "3d-rendering", desc => "Toggle 3D rendering support",
65       define => "ENABLE_3D_RENDERING", default => (isAppleMacWebKit() && !isTiger()), value => \$threeDRenderingSupport },
66
67     { option => "channel-messaging", desc => "Toggle MessageChannel and MessagePort support",
68       define => "ENABLE_CHANNEL_MESSAGING", default => 1, value => \$channelMessagingSupport },
69
70     { option => "coverage", desc => "Toggle code coverage support",
71       define => "", default => 0, value => \$coverageSupport },
72
73     { option => "database", desc => "Toggle Database Support",
74       define => "ENABLE_DATABASE", default => 1, value => \$databaseSupport },
75
76     { option => "datagrid", desc => "Toggle Datagrid Support",
77       define => "ENABLE_DATAGRID", default => 0, value => \$datagridSupport },
78       
79     { option => "datalist", desc => "Toggle HTML5 datalist support",
80       define => "ENABLE_DATALIST", default => 1, value => \$datalistSupport },
81           
82     { option => "dom-storage", desc => "Toggle DOM Storage Support",
83       define => "ENABLE_DOM_STORAGE", default => 1, value => \$domStorageSupport },
84
85     { option => "eventsource", desc => "Toggle server-sent events support",
86       define => "ENABLE_EVENTSOURCE", default => 1, value => \$eventsourceSupport },
87
88     { option => "filters", desc => "Toggle Filters support",
89       define => "ENABLE_FILTERS", default => (isAppleWebKit() || isGtk() || isQt()), value => \$filtersSupport },
90
91     { option => "geolocation", desc => "Toggle Geolocation support",
92       define => "ENABLE_GEOLOCATION", default => isGtk(), value => \$geolocationSupport },
93
94     { option => "icon-database", desc => "Toggle Icon database support",
95       define => "ENABLE_ICONDATABASE", default => 1, value => \$iconDatabaseSupport },
96
97     { option => "javascript-debugger", desc => "Toggle JavaScript Debugger/Profiler support",
98       define => "ENABLE_JAVASCRIPT_DEBUGGER", default => 1, value => \$javaScriptDebuggerSupport },
99
100     { option => "mathml", desc => "Toggle MathML support",
101       define => "ENABLE_MATHML", default => 0, value => \$mathmlSupport },
102
103     { option => "notifications", desc => "Toggle Desktop Notifications Support",
104       define => "ENABLE_NOTIFICATIONS", default => 0, value => \$notificationsSupport },
105
106     { option => "offline-web-applications", desc => "Toggle Offline Web Application Support",
107       define => "ENABLE_OFFLINE_WEB_APPLICATIONS", default => 1, value => \$offlineWebApplicationSupport },
108
109     { option => "shared-workers", desc => "Toggle SharedWorkers support",
110       define => "ENABLE_SHARED_WORKERS", default => (isAppleWebKit() || isGtk()), value => \$sharedWorkersSupport },
111
112     { option => "svg", desc => "Toggle SVG support",
113       define => "ENABLE_SVG", default => 1, value => \$svgSupport },
114
115     { option => "svg-animation", desc => "Toggle SVG animation support (implies SVG support)",
116       define => "ENABLE_SVG_ANIMATION", default => 1, value => \$svgAnimationSupport },
117
118     { option => "svg-as-image", desc => "Toggle SVG as Image support (implies SVG support)",
119       define => "ENABLE_SVG_AS_IMAGE", default => 1, value => \$svgAsImageSupport },
120
121     { option => "svg-dom-objc-bindings", desc => "Toggle SVG DOM Objective-C bindings support (implies SVG support)",
122       define => "ENABLE_SVG_DOM_OBJC_BINDINGS", default => isAppleMacWebKit(), value => \$svgDOMObjCBindingsSupport },
123
124     { option => "svg-fonts", desc => "Toggle SVG fonts support (imples SVG support)",
125       define => "ENABLE_SVG_FONTS", default => 1, value => \$svgFontsSupport },
126
127     { option => "svg-foreign-object", desc => "Toggle SVG foreign object support (implies SVG support)",
128       define => "ENABLE_SVG_FOREIGN_OBJECT", default => 1, value => \$svgForeignObjectSupport },
129
130     { option => "svg-use", desc => "Toggle SVG use element support (implies SVG support)",
131       define => "ENABLE_SVG_USE", default => 1, value => \$svgUseSupport },
132
133     { option => "video", desc => "Toggle Video support",
134       define => "ENABLE_VIDEO", default => (isAppleWebKit() || isGtk()), value => \$videoSupport },
135
136     { option => "web-sockets", desc => "Toggle Web Sockets support",
137       define => "ENABLE_WEB_SOCKETS", default => 1, value=> \$webSocketsSupport },
138
139     { option => "wml", desc => "Toggle WML support",
140       define => "ENABLE_WML", default => 0, value => \$wmlSupport },
141
142     { option => "xhtmlmp", desc => "Toggle XHTML-MP support",
143       define => "ENABLE_XHTMLMP", default => 0, value => \$xhtmlmpSupport },
144
145     { option => "wcss", desc => "Toggle WCSS support",
146       define => "ENABLE_WCSS", default => 0, value => \$wcssSupport },
147
148     { option => "workers", desc => "Toggle Web Workers support",
149       define => "ENABLE_WORKERS", default => (isAppleWebKit() || isGtk()), value => \$workersSupport },
150
151     { option => "xpath", desc => "Toggle XPath support",
152       define => "ENABLE_XPATH", default => 1, value => \$xpathSupport },
153
154     { option => "xslt", desc => "Toggle XSLT support",
155       define => "ENABLE_XSLT", default => 1, value => \$xsltSupport },
156 );
157
158 # Update defaults from Qt's project file
159 if (isQt()) {
160     my %qtDefaults = qtFeatureDefaults();
161     foreach (@features) {
162         $_->{default} = $qtDefaults{$_->{define}} || 0;
163     }
164 }
165
166 # Initialize values from defaults
167 foreach (@ARGV) {
168     if ($_ eq '--minimal') {
169         $minimal = 1;
170         last;
171     }
172 }
173
174 # Initialize values from defaults
175 foreach (@features) {
176     ${$_->{value}} = ($_->{default} && !$minimal) || 0;
177 }
178
179 $svgSupport = $svgSupport || $svgAnimationSupport || $svgAsImageSupport
180     || $svgDOMObjCBindingsSupport || $svgFontsSupport
181     || $svgForeignObjectSupport || $svgUseSupport;
182
183
184 my $programName = basename($0);
185 my $usage = <<EOF;
186 Usage: $programName [options] [options to pass to build system]
187   --help                            Show this help message
188   --clean                           Cleanup the build directory
189   --debug                           Compile in debug mode
190   --cairo-win32                     Build using Cairo (rather than CoreGraphics) on Windows
191   --chromium                        Build the Chromium port on Mac/Win/Linux
192   --gtk                             Build the GTK+ port
193   --qt                              Build the Qt port
194   --inspector-frontend              Copy changes to the inspector front-end files to the build directory
195
196   --makeargs=<arguments>            Optional Makefile flags
197
198   --minimal                         No optional features, unless explicitly enabled.
199
200 EOF
201
202 my %options = (
203     'help' => \$showHelp,
204     'clean' => \$clean,
205     'makeargs=s' => \$makeArgs,
206     'minimal' => \$minimal,
207 );
208
209 # Build usage text and options list from features
210 foreach (@features) {
211     my $opt = sprintf("%-35s", "  --[no-]$_->{option}");
212     $usage .= "$opt $_->{desc} (default: $_->{default})\n";
213     $options{"$_->{option}!"} = $_->{value};
214 }
215
216 GetOptions(%options);
217
218 if ($showHelp) {
219    print STDERR $usage;
220    exit 1;
221 }
222
223 checkRequiredSystemConfig();
224 setConfiguration();
225
226 my $productDir = productDir();
227
228 # Check that all the project directories are there.
229 my @projects = ("JavaScriptCore", "WebCore", "WebKit");
230 # Only Apple builds JavaScriptGlue, and only on the Mac
231 splice @projects, 1, 0, "JavaScriptGlue" if isAppleMacWebKit();
232
233 my @otherDirs = ("WebKitLibraries");
234 for my $dir (@projects, @otherDirs) {
235     if (! -d $dir) {
236         die "Error: No $dir directory found. Please do a fresh checkout.\n";
237     }
238 }
239
240 my @options = ();
241
242 # enable autotool options accordingly
243 if (isGtk()) {
244     foreach (@features) {
245         push @options, autotoolsFlag(${$_->{value}}, $_->{option});
246     }
247
248     push @options, "--makeargs=" . $makeArgs if defined($makeArgs);
249 } elsif (isAppleMacWebKit()) {
250     push @options, XcodeOptions();
251
252     sub option($$)
253     {
254         my ($feature, $isEnabled) = @_;
255         return $feature . "=" . ($isEnabled ? $feature : " ");
256     }
257
258     foreach (@features) {
259         if ($_->{option} eq "coverage") {
260             push @options, XcodeCoverageSupportOptions() if $coverageSupport;
261         } else {
262             push @options, option($_->{define}, ${$_->{value}});
263         }
264     }
265
266     # Copy library and header from WebKitLibraries to a findable place in the product directory.
267
268     my @librariesToCopy = (
269         "libWebKitSystemInterfaceTiger.a",
270         "libWebKitSystemInterfaceLeopard.a",
271         "libWebKitSystemInterfaceSnowLeopard.a",
272         "libWebCoreSQLite3.a",
273     );
274     foreach my $libName (@librariesToCopy) {
275         my $srcLib = "WebKitLibraries/" . $libName;
276         my $lib = "$productDir/" . $libName;
277         if (!-e $lib || -M $lib > -M $srcLib) {
278             print "Updating $lib\n";
279             system "ditto", $srcLib, $lib;
280             system "ranlib", $lib;
281         }
282     }
283
284     # FIXME: This code should be abstracted to not be copy/paste.
285     my $srcHeader = "WebKitLibraries/WebKitSystemInterface.h";
286     my $header = "$productDir/usr/local/include/WebKitSystemInterface.h";
287     if (!-e $header || -M $header > -M $srcHeader) {
288         print "Updating $header\n";
289         system "mkdir", "-p", "$productDir/usr/local/include";
290         system "ditto", $srcHeader, $header;
291     }
292
293     my $srcHeaderDir = "WebKitLibraries/WebCoreSQLite3";
294     my $headerDir = "$productDir/WebCoreSQLite3";
295     if (!-e $headerDir || -M $headerDir > -M $srcHeaderDir) {
296         print "Updating $headerDir\n";
297         system "ditto", $srcHeaderDir, $headerDir;
298     }
299 } elsif (isAppleWinWebKit()) {
300     # Copy WebKitSupportLibrary to the correct location in WebKitLibraries so it can be found.
301     # Will fail if WebKitSupportLibrary.zip is not in source root.
302     (system("perl WebKitTools/Scripts/update-webkit-support-libs") == 0) or die;
303 } elsif (isQt()) {
304     @options = @ARGV;
305     push @options, "--makeargs=" . $makeArgs if defined($makeArgs);
306
307     foreach (@features) {
308         push @options, "DEFINES+=$_->{define}=${$_->{value}}" if ${$_->{value}} != $_->{default};
309     }
310 }
311
312 # Force re-link of existing libraries if different than expected
313 removeLibraryDependingOnSVG("WebCore", $svgSupport);
314
315 if (isInspectorFrontend()) {
316     exit exitStatus(copyInspectorFrontendFiles());
317 }
318
319 if (isWx()) {
320     downloadWafIfNeeded();
321     push @projects, 'WebKitTools/DumpRenderTree';
322     push @projects, 'WebKitTools/wx/browser';
323     push @projects, 'WebKit/wx/bindings/python';
324 }
325
326 if (isChromium()) {
327     # Chromium doesn't build by project directories.
328     @projects = ();
329     my $result = buildChromium($clean, @options);
330     exit exitStatus($result) if exitStatus($result);
331 }
332
333 # Build, and abort if the build fails.
334 for my $dir (@projects) {
335     chdir $dir or die;
336     my $result = 0;
337
338     # For Gtk and Qt the WebKit project builds all others
339     if ((isGtk() || isQt()) && $dir ne "WebKit") {
340         chdir ".." or die;
341         next;
342     }
343
344     if (isGtk()) {
345         $result = buildGtkProject($dir, $clean,  @options);
346     } elsif (isQt()) {
347         $result = buildQMakeQtProject($dir, $clean, @options);
348     } elsif (isAppleMacWebKit()) {
349         $result = buildXCodeProject($dir, $clean, @options, @ARGV);
350     } elsif (isAppleWinWebKit()) {
351         if ($dir eq "WebKit") {
352             $result = buildVisualStudioProject("win/WebKit.vcproj/WebKit.sln", $clean);
353         }
354     } elsif (isWx()) {
355         @options = ();
356         if (defined($makeArgs)) {
357             @options = split(/ /, $makeArgs);
358         }
359         if ($dir eq "WebKit" && isWx()) {
360             chdir 'wx' or die;
361         }
362             
363         $result = buildWafProject($dir, $clean, @options);
364     }
365
366     if (exitStatus($result)) {
367         if (isAppleWinWebKit()) {
368             print "\n\n===== BUILD FAILED ======\n\n";
369             my $scriptDir = relativeScriptsDir();
370             print "Please ensure you have run $scriptDir/update-webkit to install dependencies.\n\n";
371             my $baseProductDir = baseProductDir();
372             print "You can view build errors by checking the BuildLog.htm files located at:\n$baseProductDir/obj/<project>/<config>.\n";
373         }
374         exit exitStatus($result);
375     }
376     chdirWebKit();
377 }
378
379 # Don't report the "WebKit is now built" message after a clean operation.
380 exit if $clean;
381
382 # Write out congratulations message.
383 writeCongrats();
384
385 exit 0;
386
387 sub formatBuildTime($)
388 {
389     my ($buildTime) = @_;
390
391     my $buildHours = int($buildTime / 3600);
392     my $buildMins = int(($buildTime - $buildHours * 3600) / 60);
393     my $buildSecs = $buildTime - $buildHours * 3600 - $buildMins * 60;
394
395     if ($buildHours) {
396         return sprintf("%dh:%02dm:%02ds", $buildHours, $buildMins, $buildSecs);
397     }
398     return sprintf("%02dm:%02ds", $buildMins, $buildSecs);
399 }
400
401 sub writeCongrats()
402 {
403     my $launcherPath = launcherPath();
404     my $launcherName = launcherName();
405     my $endTime = time();
406     my $buildTime = formatBuildTime($endTime - $startTime);
407
408     print "\n";
409     print "===========================================================\n";
410     print " WebKit is now built ($buildTime). \n";
411     if (!isChromium()) {
412         print " To run $launcherName with this newly-built code, use the\n";
413         print " \"$launcherPath\" script.\n";
414     }
415     print "===========================================================\n";
416 }