WebKit.pro

   1 TEMPLATE = subdirs
   2 CONFIG += ordered
   3
   4 include(WebKit.pri)
   5
   6 SUBDIRS += JavaScriptCore
   7 webkit2 {
   8     SUBDIRS += WebKit2
   9 }
  10 SUBDIRS += WebCore
  11
  12 # If the source exists, built it
  13 exists($$PWD/WebKitTools/QtTestBrowser): SUBDIRS += WebKitTools/QtTestBrowser
  14 contains(QT_CONFIG, declarative) {
  15     exists($$PWD/WebKit/qt/declarative): SUBDIRS += WebKit/qt/declarative
  16 }
  17 exists($$PWD/JavaScriptCore/jsc.pro): SUBDIRS += JavaScriptCore/jsc.pro
  18 exists($$PWD/WebKit/qt/tests): SUBDIRS += WebKit/qt/tests
  19 exists($$PWD/WebKitTools/DumpRenderTree/qt/DumpRenderTree.pro): SUBDIRS += WebKitTools/DumpRenderTree/qt/DumpRenderTree.pro
  20 exists($$PWD/WebKitTools/DumpRenderTree/qt/ImageDiff.pro): SUBDIRS += WebKitTools/DumpRenderTree/qt/ImageDiff.pro
  21
  22 !win32:!symbian {
  23     exists($$PWD/WebKitTools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro): SUBDIRS += WebKitTools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro
  24 }
  25
  26 build-qtscript {
  27     SUBDIRS += \
  28         JavaScriptCore/qt/api/QtScript.pro \
  29         JavaScriptCore/qt/tests \
  30         JavaScriptCore/qt/benchmarks
  31 }
  32
  33 webkit2 {
  34     exists($$PWD/WebKit2/WebProcess.pro): SUBDIRS += WebKit2/WebProcess.pro
  35     exists($$PWD/WebKitTools/MiniBrowser/qt/MiniBrowser.pro): SUBDIRS += WebKitTools/MiniBrowser/qt/MiniBrowser.pro
  36 }
  37
  38 symbian {
  39     # Forward the install target to WebCore. A workaround since INSTALLS is not implemented for symbian
  40     install.commands = $(MAKE) -C WebCore install
  41     QMAKE_EXTRA_TARGETS += install
  42 }
  43
  44 include(WebKit/qt/docs/docs.pri)