WebKit.pro

   1 TEMPLATE = subdirs
   2 CONFIG += ordered
   3
   4 include(WebKit.pri)
   5
   6 SUBDIRS += \
   7         JavaScriptCore \
   8         WebCore
   9
  10 # If the source exists, built it
  11 exists($$PWD/WebKitTools/QtTestBrowser): SUBDIRS += WebKitTools/QtTestBrowser
  12 greaterThan(QT_MINOR_VERSION, 6) {
  13     exists($$PWD/WebKit/qt/declarative): SUBDIRS += WebKit/qt/declarative
  14 }
  15 exists($$PWD/JavaScriptCore/jsc.pro): SUBDIRS += JavaScriptCore/jsc.pro
  16 exists($$PWD/WebKit/qt/tests): SUBDIRS += WebKit/qt/tests
  17 exists($$PWD/WebKitTools/DumpRenderTree/qt/DumpRenderTree.pro): SUBDIRS += WebKitTools/DumpRenderTree/qt/DumpRenderTree.pro
  18 exists($$PWD/WebKitTools/DumpRenderTree/qt/ImageDiff.pro): SUBDIRS += WebKitTools/DumpRenderTree/qt/ImageDiff.pro
  19
  20 !win32:!symbian {
  21     exists($$PWD/WebKitTools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro): SUBDIRS += WebKitTools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro
  22 }
  23
  24 build-qtscript {
  25     SUBDIRS += \
  26         JavaScriptCore/qt/api/QtScript.pro \
  27         JavaScriptCore/qt/tests
  28 }
  29
  30 symbian {
  31     # Forward the install target to WebCore. A workaround since INSTALLS is not implemented for symbian
  32     install.commands = $(MAKE) -C WebCore install
  33     QMAKE_EXTRA_TARGETS += install
  34 }
  35
  36 include(WebKit/qt/docs/docs.pri)