WebKit.pri

   1 # Include file to make it easy to include WebKit into Qt projects
   2
   3
   4 isEmpty(OUTPUT_DIR) {
   5     CONFIG(release):OUTPUT_DIR=$$PWD/WebKitBuild/Release
   6     CONFIG(debug):OUTPUT_DIR=$$PWD/WebKitBuild/Debug
   7 }
   8
   9 !gtk-port:CONFIG += qt-port
  10 qt-port:DEFINES += BUILDING_QT__=1
  11 qt-port:!building-libs {
  12     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
  13     LIBS += -lQtWebKit
  14     DEPENDPATH += $$PWD/WebKit/qt/Api
  15 }
  16
  17 gtk-port:!building-libs {
  18     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
  19     LIBS += -lWebKitGtk
  20     DEPENDPATH += $$PWD/WebKit/gtk/WebView $$PWD/WebKit/gtk/WebCoreSupport
  21 }
  22
  23 gtk-port {
  24     CONFIG += link_pkgconfig
  25
  26     DEFINES += BUILDING_CAIRO__=1 BUILDING_GTK__=1
  27
  28     directfb: PKGCONFIG += cairo-directfb gtk+-directfb-2.0
  29     else: PKGCONFIG += cairo gtk+-2.0
  30
  31     # Set a CONFIG flag for the GTK+ target (x11, quartz, win32, directfb)
  32     CONFIG += $$system(pkg-config --variable=target $$PKGCONFIG)
  33
  34     # We use the curl http backend on all platforms
  35     PKGCONFIG += libcurl
  36
  37     LIBS += -lWebKitGtk -ljpeg -lpng
  38
  39     QMAKE_CXXFLAGS += $$system(icu-config --cppflags)
  40     QMAKE_LIBS += $$system(icu-config --ldflags)
  41
  42     # This set of warnings is borrowed from the Mac build
  43     QMAKE_CXXFLAGS += -Wall -W -Wcast-align -Wchar-subscripts -Wformat-security -Wmissing-format-attribute -Wpointer-arith -Wwrite-strings -Wno-format-y2k -Wno-unused-parameter -Wundef
  44
  45     # These flags are based on optimization experience from the Mac port:
  46     # Helps code size significantly and speed a little
  47     QMAKE_CXXFLAGS += -fno-exceptions -fno-rtti
  48
  49     DEPENDPATH += $$PWD/JavaScriptCore/API
  50     INCLUDEPATH += $$PWD
  51 }
  52
  53 DEFINES += USE_SYSTEM_MALLOC
  54 CONFIG(release) {
  55     DEFINES += NDEBUG
  56 }
  57
  58 BASE_DIR = $$PWD
  59 qt-port:INCLUDEPATH += \
  60     $$PWD/WebKit/qt/Api
  61 gtk-port:INCLUDEPATH += \
  62     $$BASE_DIR/WebCore/platform/gtk \
  63     $$BASE_DIR/WebCore/platform/network/curl \
  64     $$BASE_DIR/WebCore/platform/graphics/cairo \
  65     $$BASE_DIR/WebCore/loader/gtk \
  66     $$BASE_DIR/WebCore/page/gtk \
  67     $$BASE_DIR/WebKit/gtk/WebView \
  68     $$BASE_DIR/WebKit/gtk/WebCoreSupport
  69 INCLUDEPATH += \
  70     $$BASE_DIR/JavaScriptCore/ \
  71     $$BASE_DIR/JavaScriptCore/kjs \
  72     $$BASE_DIR/JavaScriptCore/bindings \
  73     $$BASE_DIR/JavaScriptCore/bindings/c \
  74     $$BASE_DIR/JavaScriptCore/wtf \
  75     $$BASE_DIR/JavaScriptCore/ForwardingHeaders \
  76     $$BASE_DIR/WebCore \
  77     $$BASE_DIR/WebCore/ForwardingHeaders \
  78     $$BASE_DIR/WebCore/platform \
  79     $$BASE_DIR/WebCore/platform/network \
  80     $$BASE_DIR/WebCore/platform/graphics \
  81     $$BASE_DIR/WebCore/loader \
  82     $$BASE_DIR/WebCore/page \
  83     $$BASE_DIR/WebCore/css \
  84     $$BASE_DIR/WebCore/dom \
  85     $$BASE_DIR/WebCore/bridge \
  86     $$BASE_DIR/WebCore/editing \
  87     $$BASE_DIR/WebCore/rendering \
  88     $$BASE_DIR/WebCore/history \
  89     $$BASE_DIR/WebCore/xml \
  90     $$BASE_DIR/WebCore/html
  91
  92
  93 macx {
  94         INCLUDEPATH += /usr/include/libxml2
  95         LIBS += -lxml2 -lxslt
  96 }