WebKit.pri

   1 # Include file to make it easy to include WebKit into Qt projects
   2
   3
   4 isEmpty(OUTPUT_DIR) {
   5     CONFIG(release):OUTPUT_DIR=$$PWD/WebKitBuild/Release
   6     CONFIG(debug):OUTPUT_DIR=$$PWD/WebKitBuild/Debug
   7 }
   8
   9 !gtk-port:CONFIG += qt-port
  10 qt-port:DEFINES += BUILDING_QT__=1
  11 qt-port:!building-libs {
  12     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
  13     LIBS += -lQtWebKit
  14     DEPENDPATH += $$PWD/WebKit/qt/Api
  15 }
  16
  17 gtk-port:!building-libs {
  18     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
  19     LIBS += -lWebKitGtk
  20     DEPENDPATH += $$PWD/WebKit/gtk/WebView $$PWD/WebKit/gtk/WebCoreSupport
  21 }
  22
  23 gtk-port {
  24     CONFIG += link_pkgconfig
  25
  26     DEFINES += BUILDING_CAIRO__=1 BUILDING_GTK__=1
  27
  28     # We use FreeType directly with Cairo
  29     PKGCONFIG += cairo-ft
  30
  31     directfb: PKGCONFIG += cairo-directfb gtk+-directfb-2.0
  32     else: PKGCONFIG += cairo gtk+-2.0
  33
  34     # Set a CONFIG flag for the GTK+ target (x11, quartz, win32, directfb)
  35     CONFIG += $$system(pkg-config --variable=target $$PKGCONFIG)
  36
  37     # We use the curl http backend on all platforms
  38     PKGCONFIG += libcurl
  39
  40     LIBS += -lWebKitGtk -ljpeg -lpng
  41
  42     QMAKE_CXXFLAGS += $$system(icu-config --cppflags)
  43     QMAKE_LIBS += $$system(icu-config --ldflags)
  44
  45     # This set of warnings is borrowed from the Mac build
  46     QMAKE_CXXFLAGS += -Wall -W -Wcast-align -Wchar-subscripts -Wformat-security -Wmissing-format-attribute -Wpointer-arith -Wwrite-strings -Wno-format-y2k -Wno-unused-parameter -Wundef
  47
  48     DEPENDPATH += $$PWD/JavaScriptCore/API
  49     INCLUDEPATH += $$PWD
  50 }
  51
  52 DEFINES += USE_SYSTEM_MALLOC
  53 CONFIG(release) {
  54     DEFINES += NDEBUG
  55 }
  56
  57 BASE_DIR = $$PWD
  58 qt-port:INCLUDEPATH += \
  59     $$PWD/WebKit/qt/Api
  60 gtk-port:INCLUDEPATH += \
  61     $$BASE_DIR/WebCore/platform/gtk \
  62     $$BASE_DIR/WebCore/platform/network/curl \
  63     $$BASE_DIR/WebCore/platform/graphics/cairo \
  64     $$BASE_DIR/WebCore/loader/gtk \
  65     $$BASE_DIR/WebCore/page/gtk \
  66     $$BASE_DIR/WebKit/gtk/WebView \
  67     $$BASE_DIR/WebKit/gtk/WebCoreSupport
  68 INCLUDEPATH += \
  69     $$BASE_DIR/JavaScriptCore/ \
  70     $$BASE_DIR/JavaScriptCore/kjs \
  71     $$BASE_DIR/JavaScriptCore/bindings \
  72     $$BASE_DIR/JavaScriptCore/bindings/c \
  73     $$BASE_DIR/JavaScriptCore/wtf \
  74     $$BASE_DIR/JavaScriptCore/ForwardingHeaders \
  75     $$BASE_DIR/WebCore \
  76     $$BASE_DIR/WebCore/ForwardingHeaders \
  77     $$BASE_DIR/WebCore/platform \
  78     $$BASE_DIR/WebCore/platform/network \
  79     $$BASE_DIR/WebCore/platform/graphics \
  80     $$BASE_DIR/WebCore/loader \
  81     $$BASE_DIR/WebCore/page \
  82     $$BASE_DIR/WebCore/css \
  83     $$BASE_DIR/WebCore/dom \
  84     $$BASE_DIR/WebCore/bridge \
  85     $$BASE_DIR/WebCore/editing \
  86     $$BASE_DIR/WebCore/rendering \
  87     $$BASE_DIR/WebCore/history \
  88     $$BASE_DIR/WebCore/xml \
  89     $$BASE_DIR/WebCore/html
  90
  91
  92 macx {
  93         INCLUDEPATH += /usr/include/libxml2
  94         LIBS += -lxml2 -lxslt
  95 }