[Qt] Split the build process in two different .pro files.
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3 # Detect that we are building as a standalone package by the presence of
4 # either the generated files directory or as part of the Qt package through
5 # QTDIR_build
6 CONFIG(QTDIR_build): CONFIG += standalone_package
7 else:exists($$PWD/WebCore/generated): CONFIG += standalone_package
8
9 CONFIG(standalone_package) {
10     OUTPUT_DIR=$$PWD
11 }
12
13 isEmpty(OUTPUT_DIR) {
14     CONFIG(debug, debug|release) {
15         OUTPUT_DIR=$$PWD/WebKitBuild/Debug
16     } else { # Release
17         OUTPUT_DIR=$$PWD/WebKitBuild/Release
18     }
19 }
20
21 DEFINES += BUILDING_QT__=1
22 building-libs {
23     win32-msvc*|win32-icc: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
24 } else {
25     CONFIG(QTDIR_build) {
26         QT += webkit
27     } else {
28         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
29         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
30             LIBS += -framework QtWebKit
31             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
32         } else {
33             win32-*|wince* {
34                 LIBS += -lQtWebKit$${QT_MAJOR_VERSION}
35             } else {
36                 LIBS += -lQtWebKit
37                 symbian {
38                     TARGET.EPOCSTACKSIZE = 0x14000 // 80 kB
39                     TARGET.EPOCHEAPSIZE = 0x20000 0x2000000 // Min 128kB, Max 32MB
40                 }
41             }
42         }
43     }
44     DEPENDPATH += $$PWD/WebKit/qt/Api
45 }
46
47 !mac:!unix|symbian {
48     DEFINES += USE_SYSTEM_MALLOC
49 }
50
51 CONFIG(release, debug|release) {
52     DEFINES += NDEBUG
53 }
54
55 BASE_DIR = $$PWD
56 INCLUDEPATH += $$PWD/WebKit/qt/Api
57
58 CONFIG -= warn_on
59 *-g++*:QMAKE_CXXFLAGS += -Wall -Wreturn-type -fno-strict-aliasing -Wcast-align -Wchar-subscripts -Wformat-security -Wreturn-type -Wno-unused-parameter -Wno-sign-compare -Wno-switch -Wno-switch-enum -Wundef -Wmissing-noreturn -Winit-self
60
61 # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
62 symbian|*-armcc {
63     RVCT_COMMON_CFLAGS = --gnu --diag_suppress 68,111,177,368,830,1293
64     RVCT_COMMON_CXXFLAGS = $$RVCT_COMMON_CFLAGS --no_parse_templates
65     DEFINES *= QT_NO_UITOOLS
66 }
67
68 *-armcc {
69     QMAKE_CFLAGS += $$RVCT_COMMON_CFLAGS
70     QMAKE_CXXFLAGS += $$RVCT_COMMON_CXXFLAGS
71 }
72
73 symbian {
74     QMAKE_CXXFLAGS.ARMCC += $$RVCT_COMMON_CXXFLAGS
75 }
76
77 contains(DEFINES, QT_NO_UITOOLS): CONFIG -= uitools
78
79 # Disable a few warnings on Windows. The warnings are also
80 # disabled in WebKitLibraries/win/tools/vsprops/common.vsprops
81 win32-msvc*: QMAKE_CXXFLAGS += -wd4291 -wd4344 -wd4396 -wd4503 -wd4800 -wd4819 -wd4996
82