WebCore/WebCore.pro

   1 # WebCore - Qt4 build info
   2
   3 TEMPLATE = lib
   4 TARGET = WebKitQt
   5 OBJECTS_DIR = tmp
   6 INCLUDEPATH += tmp
   7
   8 isEmpty(OUTPUT_DIR):OUTPUT_DIR=$$PWD/..
   9 DESTDIR = $$OUTPUT_DIR/lib
  10
  11 include($$OUTPUT_DIR/config.pri)
  12
  13 CONFIG -= warn_on
  14 #QMAKE_CXXFLAGS_RELEASE += -Wall -Wno-undef -Wno-unused-parameter
  15
  16 # PRE-BUILD: make the required config.h file
  17 #config_h.target = config.h
  18 #config_h.commands = cp config.h.qmake config.h
  19 #config_h.depends = config.h.qmake
  20 #QMAKE_EXTRA_TARGETS += config_h
  21 #PRE_TARGETDEPS += config.h
  22
  23 # Optional components (look for defs in config.h and included files!)
  24 #DEFINES += XPATH_SUPPORT=1
  25 DEFINES += XSLT_SUPPORT=1
  26 #DEFINES += XBL_SUPPORT=1
  27 #DEFINES += SVG_SUPPORT=1
  28
  29 DEFINES += WTF_CHANGES=1 BUILDING_QT__=1
  30
  31 INCLUDEPATH += $$PWD/../JavaScriptCore
  32 LIBS += -L$$OUTPUT_DIR/lib -lJavaScriptCore
  33
  34 macx {
  35         INCLUDEPATH += /opt/local/include /opt/local/include/libxml2
  36         INCLUDEPATH += /usr/include/libxml2
  37         LIBS += -L/opt/local/lib -lxml2 -lxslt
  38 }
  39
  40 INCLUDEPATH +=  $$PWD \
  41                 $$[QT_INSTALL_PREFIX]/src/3rdparty/sqlite/ \
  42                 $$PWD/ForwardingHeaders \
  43                 $$PWD/../JavaScriptCore/kjs \
  44                 $$PWD/../JavaScriptCore/bindings \
  45                 $$PWD/platform \
  46                 $$PWD/platform/qt \
  47                 $$PWD/platform/network \
  48                 $$PWD/platform/network/qt \
  49                 $$PWD/platform/graphics \
  50                 $$PWD/platform/graphics/qt \
  51                 $$PWD/platform/graphics/svg \
  52                 $$PWD/loader $$PWD/loader/icon $$PWD/loader/qt \
  53                 $$PWD/css \
  54                 $$PWD/dom \
  55                 $$PWD/page \
  56                 $$PWD/bridge \
  57                 $$PWD/editing \
  58                 $$PWD/kwq \
  59                 $$PWD/rendering \
  60                 $$PWD/xml \
  61                 $$PWD/html \
  62                 $$PWD/bindings/js \
  63                 $$PWD/kcanvas $$PWD/kcanvas/device $$PWD/kcanvas/device/qt \
  64                 $$PWD/ksvg2 $$PWD/ksvg2/css $$PWD/ksvg2/svg $$PWD/ksvg2/misc $$PWD/ksvg2/events \
  65                 $$PWD/platform/image-decoders \
  66                 $$PWD/WebCore+SVG
  67 QT += network
  68 !mac:CONFIG += link_pkgconfig
  69 PKGCONFIG += libxslt
  70 LIBS += -lsqlite3
  71
  72
  73 FEATURE_DEFINES_JAVASCRIPT = LANGUAGE_JAVASCRIPT
  74
  75
  76
  77 TOKENIZER = $$PWD/css/tokenizer.flex
  78
  79 CSSBISON = $$PWD/css/CSSGrammar.y
  80
  81 HTML_NAMES = $$PWD/html/HTMLTagNames.in
  82
  83 ENTITIES_GPERF = $$PWD/html/HTMLEntityNames.gperf
  84
  85 COLORDAT_GPERF = $$PWD/platform/ColorData.gperf
  86
  87 WALDOCSSPROPS = $$PWD/css/CSSPropertyNames.in
  88
  89 WALDOCSSVALUES = $$PWD/css/CSSValueKeywords.in
  90
  91 SVGCSSPROPERTIES = $$PWD/ksvg2/css/CSSPropertyNames.in
  92
  93 SVGCSSVALUES = $$PWD/ksvg2/css/CSSValueKeywords.in
  94
  95 STYLESHEETS_EMBED = $$PWD/css/html4.css
  96
  97 MANUALMOC += \
  98     $$PWD/platform/qt/SharedTimerQt.h \
  99     $$PWD/platform/qt/ScrollViewCanvasQt.h \
 100     $$PWD/platform/network/qt/ResourceHandleManager.h \
 101
 102 LUT_FILES += \
 103     bindings/js/kjs_window.cpp \
 104     bindings/js/kjs_css.cpp \
 105     bindings/js/kjs_dom.cpp \
 106     bindings/js/kjs_html.cpp \
 107     bindings/js/kjs_events.cpp \
 108     bindings/js/kjs_navigator.cpp \
 109     bindings/js/kjs_traversal.cpp \
 110     bindings/js/JSXMLHttpRequest.cpp \
 111     bindings/js/JSXSLTProcessor.cpp
 112
 113 LUT_TABLE_FILES += \
 114     bindings/js/JSHTMLInputElementBase.cpp
 115
 116 IDL_BINDINGS += \
 117     css/CSSValue.idl \
 118     css/CSSRuleList.idl \
 119     css/CSSValueList.idl \
 120     css/CSSStyleDeclaration.idl \
 121     css/CSSPrimitiveValue.idl \
 122     css/CSSRule.idl \
 123     css/Counter.idl \
 124     css/MediaList.idl \
 125     dom/Event.idl \
 126     dom/Range.idl \
 127     dom/Text.idl \
 128     dom/DOMImplementation.idl \
 129     dom/NodeFilter.idl \
 130     dom/MouseEvent.idl \
 131     dom/CharacterData.idl \
 132     dom/DocumentFragment.idl \
 133     dom/Entity.idl \
 134     dom/UIEvent.idl \
 135     dom/Node.idl \
 136     dom/ProcessingInstruction.idl \
 137     dom/Notation.idl \
 138     dom/Element.idl \
 139     dom/DocumentType.idl \
 140     dom/Document.idl \
 141     dom/Attr.idl \
 142     dom/MutationEvent.idl \
 143     dom/KeyboardEvent.idl \
 144     dom/WheelEvent.idl \
 145     dom/OverflowEvent.idl \
 146     dom/NodeIterator.idl \
 147     dom/TreeWalker.idl \
 148     dom/RangeException.idl \
 149     html/CanvasGradient.idl \
 150     html/CanvasPattern.idl \
 151     html/CanvasRenderingContext2D.idl \
 152     html/HTMLAnchorElement.idl \
 153     html/HTMLAppletElement.idl \
 154     html/HTMLAreaElement.idl \
 155     html/HTMLBaseElement.idl \
 156     html/HTMLBaseFontElement.idl \
 157     html/HTMLBlockquoteElement.idl \
 158     html/HTMLBodyElement.idl \
 159     html/HTMLBRElement.idl \
 160     html/HTMLButtonElement.idl \
 161     html/HTMLCanvasElement.idl \
 162     html/HTMLDirectoryElement.idl \
 163     html/HTMLDivElement.idl \
 164     html/HTMLDListElement.idl \
 165     html/HTMLDocument.idl \
 166     html/HTMLElement.idl \
 167     html/HTMLFieldSetElement.idl \
 168     html/HTMLFontElement.idl \
 169     html/HTMLFormElement.idl \
 170     html/HTMLHeadElement.idl \
 171     html/HTMLHeadingElement.idl \
 172     html/HTMLHRElement.idl \
 173     html/HTMLHtmlElement.idl \
 174     html/HTMLImageElement.idl \
 175     html/HTMLInputElement.idl \
 176     html/HTMLIsIndexElement.idl \
 177     html/HTMLLabelElement.idl \
 178     html/HTMLLegendElement.idl \
 179     html/HTMLLIElement.idl \
 180     html/HTMLLinkElement.idl \
 181     html/HTMLMapElement.idl \
 182     html/HTMLMenuElement.idl \
 183     html/HTMLMetaElement.idl \
 184     html/HTMLModElement.idl \
 185     html/HTMLOListElement.idl \
 186     html/HTMLOptGroupElement.idl \
 187     html/HTMLOptionElement.idl \
 188     html/HTMLParagraphElement.idl \
 189     html/HTMLParamElement.idl \
 190     html/HTMLPreElement.idl \
 191     html/HTMLQuoteElement.idl \
 192     html/HTMLScriptElement.idl \
 193     html/HTMLStyleElement.idl \
 194     html/HTMLTextAreaElement.idl \
 195     html/HTMLTitleElement.idl \
 196     html/HTMLUListElement.idl \
 197     html/HTMLOptionsCollection.idl \
 198     xml/DOMParser.idl \
 199     xml/XMLSerializer.idl \
 200     page/DOMWindow.idl
 201
 202 SOURCES += \
 203     bindings/js/kjs_binding.cpp \
 204     bindings/js/kjs_css.cpp \
 205     bindings/js/kjs_dom.cpp \
 206     bindings/js/kjs_events.cpp \
 207     bindings/js/kjs_html.cpp \
 208     bindings/js/kjs_navigator.cpp \
 209     bindings/js/kjs_proxy.cpp \
 210     bindings/js/kjs_traversal.cpp \
 211     bindings/js/kjs_window.cpp \
 212     bindings/js/JSCanvasRenderingContext2DCustom.cpp \
 213     bindings/js/JSHTMLElementWrapperFactory.cpp \
 214     bindings/js/JSHTMLFormElementCustom.cpp \
 215     bindings/js/JSHTMLOptionElementConstructor.cpp \
 216     bindings/js/JSHTMLOptionsCollectionCustom.cpp \
 217     bindings/js/JSHTMLInputElementBase.cpp \
 218     bindings/js/JSXMLHttpRequest.cpp \
 219     bindings/js/JSNodeIteratorCustom.cpp \
 220     bindings/js/JSTreeWalkerCustom.cpp \
 221     bindings/js/JSXSLTProcessor.cpp \
 222     css/cssparser.cpp \
 223     css/cssstyleselector.cpp \
 224     css/csshelper.cpp \
 225     css/FontValue.cpp \
 226     css/CSSSelector.cpp \
 227     css/MediaFeatureNames.cpp \
 228     css/CSSRuleList.cpp \
 229     css/CSSCharsetRule.cpp \
 230     css/MediaQueryExp.cpp \
 231     css/CSSImportRule.cpp \
 232     css/CSSValueList.cpp \
 233     css/CSSStyleDeclaration.cpp \
 234     css/CSSPrimitiveValue.cpp \
 235     css/CSSProperty.cpp \
 236     css/CSSCursorImageValue.cpp \
 237     css/CSSBorderImageValue.cpp \
 238     css/MediaQuery.cpp \
 239     css/StyleSheet.cpp \
 240     css/CSSPageRule.cpp \
 241     css/StyleSheetList.cpp \
 242     css/MediaQueryEvaluator.cpp \
 243     css/StyleBase.cpp \
 244     css/CSSRule.cpp \
 245     css/CSSStyleSheet.cpp \
 246     css/CSSInitialValue.cpp \
 247     css/CSSImageValue.cpp \
 248     css/CSSStyleRule.cpp \
 249     css/CSSInheritedValue.cpp \
 250     css/StyleList.cpp \
 251     css/FontFamilyValue.cpp \
 252     css/CSSMediaRule.cpp \
 253     css/CSSComputedStyleDeclaration.cpp \
 254     css/CSSMutableStyleDeclaration.cpp \
 255     css/MediaList.cpp \
 256     css/CSSFontFaceRule.cpp \
 257     css/ShadowValue.cpp \
 258     dom/Event.cpp \
 259     dom/Range.cpp \
 260     dom/Text.cpp \
 261     dom/DOMImplementation.cpp \
 262     dom/NodeFilter.cpp \
 263     dom/MouseEvent.cpp \
 264     dom/EntityReference.cpp \
 265     dom/NameNodeList.cpp \
 266     dom/CharacterData.cpp \
 267     dom/XMLTokenizer.cpp \
 268     dom/StyleElement.cpp \
 269     dom/StyledElement.cpp \
 270     dom/MappedAttribute.cpp \
 271     dom/NamedAttrMap.cpp \
 272     dom/ContainerNode.cpp \
 273     dom/NamedMappedAttrMap.cpp \
 274     dom/EventNames.cpp \
 275     dom/Comment.cpp \
 276     dom/EditingText.cpp \
 277     dom/DocumentFragment.cpp \
 278     dom/ChildNodeList.cpp \
 279     dom/Entity.cpp \
 280     dom/BeforeTextInsertedEvent.cpp \
 281     dom/UIEvent.cpp \
 282     dom/Node.cpp \
 283     dom/Attribute.cpp \
 284     dom/Position.cpp \
 285     dom/ProcessingInstruction.cpp \
 286     dom/TreeWalker.cpp \
 287     dom/Notation.cpp \
 288     dom/Element.cpp \
 289     dom/NodeFilterCondition.cpp \
 290     dom/CDATASection.cpp \
 291     dom/DocumentType.cpp \
 292     dom/NodeList.cpp \
 293     dom/CSSMappedAttributeDeclaration.cpp \
 294     dom/QualifiedName.cpp \
 295     dom/Document.cpp \
 296     dom/Attr.cpp \
 297     dom/OverflowEvent.cpp \
 298     dom/RegisteredEventListener.cpp \
 299     dom/EventTargetNode.cpp \
 300     dom/BeforeUnloadEvent.cpp \
 301     dom/MutationEvent.cpp \
 302     dom/MouseRelatedEvent.cpp \
 303     dom/KeyboardEvent.cpp \
 304     dom/NodeIterator.cpp \
 305     dom/ClipboardEvent.cpp \
 306     dom/Traversal.cpp \
 307     dom/WheelEvent.cpp \
 308     dom/UIEventWithKeyState.cpp \
 309     editing/DeleteButtonController.cpp \
 310     editing/DeleteButton.cpp \
 311     editing/Editor.cpp \
 312     editing/CommandByName.cpp \
 313     editing/InsertIntoTextNodeCommand.cpp \
 314     editing/WrapContentsInDummySpanCommand.cpp \
 315     editing/ReplaceSelectionCommand.cpp \
 316     editing/MoveSelectionCommand.cpp \
 317     editing/RemoveNodePreservingChildrenCommand.cpp \
 318     editing/HTMLInterchange.cpp \
 319     editing/UnlinkCommand.cpp \
 320     editing/InsertLineBreakCommand.cpp \
 321     editing/FormatBlockCommand.cpp \
 322     editing/AppendNodeCommand.cpp \
 323     editing/BreakBlockquoteCommand.cpp \
 324     editing/htmlediting.cpp \
 325     editing/markup.cpp \
 326     editing/InsertParagraphSeparatorCommand.cpp \
 327     editing/ModifySelectionListLevel.cpp \
 328     editing/JSEditor.cpp \
 329     editing/Selection.cpp \
 330     editing/TextIterator.cpp \
 331     editing/InsertListCommand.cpp \
 332     editing/IndentOutdentCommand.cpp \
 333     editing/InsertNodeBeforeCommand.cpp \
 334     editing/SplitTextNodeContainingElementCommand.cpp \
 335     editing/TypingCommand.cpp \
 336     editing/MergeIdenticalElementsCommand.cpp \
 337     editing/EditCommand.cpp \
 338     editing/SplitTextNodeCommand.cpp \
 339     editing/RemoveCSSPropertyCommand.cpp \
 340     editing/JoinTextNodesCommand.cpp \
 341     editing/InsertTextCommand.cpp \
 342     editing/SelectionController.cpp \
 343     editing/DeleteSelectionCommand.cpp \
 344     editing/SplitElementCommand.cpp \
 345     editing/VisiblePosition.cpp \
 346     editing/ApplyStyleCommand.cpp \
 347     editing/visible_units.cpp \
 348     editing/RemoveNodeAttributeCommand.cpp \
 349     editing/DeleteFromTextNodeCommand.cpp \
 350     editing/RemoveNodeCommand.cpp \
 351     editing/CompositeEditCommand.cpp \
 352     editing/SetNodeAttributeCommand.cpp \
 353     editing/CreateLinkCommand.cpp \
 354     editing/qt/EditorQt.cpp \
 355 #    kwq/KWQWMatrix.cpp \
 356 #    kwq/KWQCString.cpp \
 357 #    kwq/KWQTextStream.cpp \
 358     xml/XSLStyleSheet.cpp \
 359     xml/XSLTProcessor.cpp \
 360     xml/XSLImportRule.cpp \
 361     xml/DOMParser.cpp \
 362     xml/XMLSerializer.cpp \
 363     xml/xmlhttprequest.cpp \
 364 #    icon/IconDatabase.cpp \
 365 #    icon/SQLTransaction.cpp \
 366 #    icon/SQLStatement.cpp \
 367 #    icon/SiteIcon.cpp \
 368 #    icon/SQLDatabase.cpp \
 369     html/HTMLParser.cpp \
 370     html/HTMLFontElement.cpp \
 371     html/HTMLEmbedElement.cpp \
 372     html/HTMLLinkElement.cpp \
 373     html/HTMLOptGroupElement.cpp \
 374     html/HTMLCanvasElement.cpp \
 375     html/HTMLTitleElement.cpp \
 376     html/CanvasRenderingContext2D.cpp \
 377     html/HTMLObjectElement.cpp \
 378     html/HTMLAppletElement.cpp \
 379     html/HTMLKeygenElement.cpp \
 380     html/HTMLDivElement.cpp \
 381     html/HTMLMapElement.cpp \
 382     html/HTMLScriptElement.cpp \
 383     html/HTMLHtmlElement.cpp \
 384     html/HTMLTokenizer.cpp \
 385     html/HTMLOptionElement.cpp \
 386     html/HTMLTableCaptionElement.cpp \
 387     html/HTMLImageLoader.cpp \
 388     html/FormDataList.cpp \
 389     html/HTMLLabelElement.cpp \
 390     html/HTMLTableColElement.cpp \
 391     html/HTMLDListElement.cpp \
 392     html/HTMLTablePartElement.cpp \
 393     html/HTMLTableSectionElement.cpp \
 394     html/HTMLTextAreaElement.cpp \
 395     html/HTMLTextFieldInnerElement.cpp \
 396     html/HTMLAreaElement.cpp \
 397     html/CanvasStyle.cpp \
 398     html/HTMLIsIndexElement.cpp \
 399     html/HTMLHeadElement.cpp \
 400     html/HTMLFrameSetElement.cpp \
 401     html/HTMLBodyElement.cpp \
 402     html/HTMLBRElement.cpp \
 403     html/HTMLNameCollection.cpp \
 404     html/HTMLLegendElement.cpp \
 405     html/HTMLLIElement.cpp \
 406     html/HTMLParamElement.cpp \
 407     html/HTMLMetaElement.cpp \
 408     html/HTMLHeadingElement.cpp \
 409     html/HTMLUListElement.cpp \
 410     html/HTMLInputElement.cpp \
 411     html/HTMLElementFactory.cpp \
 412     html/HTMLPlugInElement.cpp \
 413     html/HTMLFieldSetElement.cpp \
 414     html/HTMLParagraphElement.cpp \
 415     html/HTMLStyleElement.cpp \
 416     html/HTMLMarqueeElement.cpp \
 417     html/HTMLGenericFormElement.cpp \
 418     html/HTMLElement.cpp \
 419     html/HTMLDocument.cpp \
 420     html/HTMLOListElement.cpp \
 421     html/HTMLFormElement.cpp \
 422     html/HTMLPreElement.cpp \
 423     html/HTMLTableElement.cpp \
 424     html/CanvasGradient.cpp \
 425     html/HTMLViewSourceDocument.cpp \
 426     html/HTMLFrameElement.cpp \
 427     html/HTMLFrameElementBase.cpp \
 428     html/HTMLAnchorElement.cpp \
 429     html/HTMLTableCellElement.cpp \
 430     html/CanvasPattern.cpp \
 431     html/HTMLBlockquoteElement.cpp \
 432     html/HTMLIFrameElement.cpp \
 433     html/HTMLMenuElement.cpp \
 434     html/HTMLCollection.cpp \
 435     html/HTMLModElement.cpp \
 436     html/HTMLQuoteElement.cpp \
 437     html/HTMLDirectoryElement.cpp \
 438     html/HTMLSelectElement.cpp \
 439     html/HTMLImageElement.cpp \
 440     html/HTMLOptionsCollection.cpp \
 441     html/HTMLTableRowElement.cpp \
 442     html/HTMLBaseFontElement.cpp \
 443     html/HTMLHRElement.cpp \
 444     html/HTMLButtonElement.cpp \
 445     html/HTMLFormCollection.cpp \
 446     html/HTMLBaseElement.cpp \
 447     page/FrameTree.cpp \
 448     page/DOMWindow.cpp \
 449     page/MouseEventWithHitTestResults.cpp \
 450     page/Frame.cpp \
 451     page/Page.cpp \
 452     page/Chrome.cpp \
 453     page/FrameView.cpp \
 454     page/PageState.cpp \
 455     page/ContextMenuController.cpp \
 456     page/EventHandler.cpp \
 457     page/qt/EventHandlerQt.cpp \
 458     xml/XPathUtil.cpp \
 459     xml/XPathPredicate.cpp \
 460     xml/XPathVariableReference.cpp \
 461     xml/XPathValue.cpp \
 462     xml/XPathPath.cpp \
 463     xml/XPathFunctions.cpp \
 464     xml/XPathParser.cpp \
 465     xml/XPathStep.cpp \
 466     xml/XPathExpressionNode.cpp \
 467     xml/XPathNamespace.cpp \
 468     xml/XPathNSResolver.cpp \
 469     xml/XPathExpression.cpp \
 470     xml/XPathResult.cpp \
 471     xml/XPathEvaluator.cpp \
 472     loader/Cache.cpp \
 473     loader/CachedCSSStyleSheet.cpp \
 474     loader/CachedImage.cpp \
 475     loader/CachedResource.cpp \
 476     loader/CachedResourceClientWalker.cpp \
 477     loader/CachedScript.cpp \
 478     loader/CachedXSLStyleSheet.cpp \
 479     loader/DocLoader.cpp \
 480     loader/DocumentLoader.cpp \
 481     loader/FormState.cpp \
 482     loader/FrameLoader.cpp \
 483     loader/ImageDocument.cpp \
 484     loader/MainResourceLoader.cpp \
 485     loader/NetscapePlugInStreamLoader.cpp \
 486     loader/PluginDocument.cpp \
 487     loader/Request.cpp \
 488     loader/ResourceLoader.cpp \
 489     loader/SubresourceLoader.cpp \
 490     loader/TextDocument.cpp \
 491     loader/TextResourceDecoder.cpp \
 492     loader/loader.cpp \
 493     loader/icon/IconLoader.cpp \
 494     loader/icon/IconDatabase.cpp \
 495     loader/icon/IconDataCache.cpp \
 496     loader/icon/SQLTransaction.cpp \
 497     loader/icon/SQLStatement.cpp \
 498     loader/icon/SQLDatabase.cpp \
 499     loader/qt/FrameLoaderQt.cpp \
 500     loader/qt/FrameLoaderClientQt.cpp \
 501     loader/qt/DocumentLoaderQt.cpp \
 502     loader/qt/NavigationActionQt.cpp \
 503     loader/qt/ResourceLoaderQt.cpp \
 504     platform/CString.cpp \
 505     platform/AtomicString.cpp \
 506     platform/graphics/AffineTransform.cpp \
 507     platform/TextStream.cpp \
 508     platform/Widget.cpp \
 509     platform/GlyphWidthMap.cpp \
 510     platform/graphics/Pen.cpp \
 511     platform/graphics/Image.cpp \
 512     platform/DeprecatedStringList.cpp \
 513     platform/graphics/FloatSize.cpp \
 514     platform/String.cpp \
 515     platform/DeprecatedValueListImpl.cpp \
 516     platform/graphics/IntRect.cpp \
 517     platform/Arena.cpp \
 518     platform/ArrayImpl.cpp \
 519     platform/graphics/FloatPoint.cpp \
 520     platform/SegmentedString.cpp \
 521     platform/TextCodec.cpp \
 522     platform/qt/TextCodecQt.cpp \
 523     platform/DeprecatedString.cpp \
 524     platform/DeprecatedCString.cpp \
 525     platform/qt/TextBreakIteratorQt.cpp \
 526     platform/TextCodecLatin1.cpp \
 527     platform/TextCodecUTF16.cpp \
 528     platform/TextDecoder.cpp \
 529     platform/TextEncoding.cpp \
 530     platform/TextEncodingRegistry.cpp \
 531     platform/Logging.cpp \
 532     platform/graphics/Color.cpp \
 533     platform/DeprecatedPtrListImpl.cpp \
 534     platform/KURL.cpp \
 535     platform/StringImpl.cpp \
 536     platform/graphics/FloatRect.cpp \
 537     platform/graphics/Path.cpp \
 538     platform/MimeTypeRegistry.cpp \
 539     platform/qt/MimeTypeRegistryQt.cpp \
 540     platform/qt/EditorClientQt.cpp \
 541     platform/qt/SoundQt.cpp \
 542     platform/qt/LoaderFunctionsQt.cpp \
 543     platform/qt/FileChooserQt.cpp \
 544     platform/graphics/qt/IconQt.cpp \
 545     platform/graphics/qt/AffineTransformQt.cpp \
 546     platform/qt/StringQt.cpp \
 547     platform/graphics/qt/ColorQt.cpp \
 548     platform/qt/GlyphMapQt.cpp \
 549     platform/qt/CookieJarQt.cpp \
 550     platform/qt/FontPlatformDataQt.cpp \
 551     platform/qt/ScrollViewQt.cpp \
 552     platform/qt/TemporaryLinkStubs.cpp \
 553     platform/qt/CursorQt.cpp \
 554     platform/qt/WidgetQt.cpp \
 555     platform/qt/SystemTimeQt.cpp \
 556     platform/qt/RenderThemeQt.cpp \
 557     platform/qt/FontDataQt.cpp \
 558     platform/qt/SharedTimerQt.cpp \
 559     platform/qt/PopupMenuQt.cpp \
 560     platform/qt/ChromeClientQt.cpp \
 561     platform/qt/ContextMenuQt.cpp \
 562     platform/qt/ContextMenuItemQt.cpp \
 563     platform/qt/ContextMenuClientQt.cpp \
 564     platform/qt/PasteBoardQt.cpp \
 565     platform/ContextMenu.cpp \
 566     platform/network/FormData.cpp \
 567     platform/network/ResourceHandle.cpp \
 568     platform/network/ResourceRequest.cpp \
 569     platform/network/ResourceResponse.cpp \
 570     platform/network/qt/ResourceHandleQt.cpp \
 571     platform/network/HTTPParsers.cpp \
 572     platform/network/qt/ResourceHandleManager.cpp \
 573     platform/graphics/qt/FloatPointQt.cpp \
 574     platform/graphics/qt/FloatRectQt.cpp \
 575     platform/graphics/qt/GraphicsContextQt.cpp \
 576     platform/graphics/qt/IntPointQt.cpp \
 577     platform/graphics/qt/IntRectQt.cpp \
 578     platform/graphics/qt/IntSizeQt.cpp \
 579     platform/graphics/qt/PathQt.cpp \
 580     platform/graphics/qt/ImageQt.cpp \
 581     platform/graphics/qt/ImageSourceQt.cpp \
 582     platform/graphics/qt/ImageDecoderQt.cpp \
 583     platform/qt/FontCacheQt.cpp \
 584     platform/qt/FontQt.cpp \
 585 #    platform/qt/LineEditQt.cpp \
 586     platform/qt/ScreenQt.cpp \
 587 #    platform/qt/FileButtonQt.cpp \
 588     platform/qt/FrameQt.cpp \
 589     platform/qt/FrameQtClient.cpp \
 590 #    platform/qt/TextEditQt.cpp \
 591     platform/qt/ScrollViewCanvasQt.cpp \
 592     platform/qt/PlatformMouseEventQt.cpp \
 593     platform/qt/PlatformKeyboardEventQt.cpp \
 594     platform/qt/TextBoundaries.cpp \
 595     platform/graphics/GraphicsTypes.cpp \
 596     platform/graphics/GraphicsContext.cpp \
 597     platform/FontFamily.cpp \
 598     platform/Timer.cpp \
 599     platform/FontCache.cpp \
 600     platform/FontFallbackList.cpp \
 601     platform/RegularExpression.cpp \
 602     platform/GlyphMap.cpp \
 603     platform/Font.cpp \
 604     platform/FontData.cpp \
 605     rendering/HitTestResult.cpp \
 606     rendering/RenderCounter.cpp \
 607     rendering/CounterNode.cpp \
 608     rendering/CounterResetNode.cpp \
 609     rendering/RenderListBox.cpp \
 610     rendering/RenderReplaced.cpp \
 611     rendering/RenderPartObject.cpp \
 612     rendering/RenderView.cpp \
 613     rendering/RenderMenuList.cpp \
 614     rendering/InlineFlowBox.cpp \
 615     rendering/RenderListMarker.cpp \
 616     rendering/RenderImage.cpp \
 617     rendering/RenderTheme.cpp \
 618     rendering/RenderLayer.cpp \
 619     rendering/RenderTableCell.cpp \
 620     rendering/RenderListItem.cpp \
 621     rendering/AutoTableLayout.cpp \
 622     rendering/RenderArena.cpp \
 623     rendering/RenderWidget.cpp \
 624     rendering/break_lines.cpp \
 625     rendering/RenderStyle.cpp \
 626     rendering/RenderContainer.cpp \
 627     rendering/EllipsisBox.cpp \
 628     rendering/RenderFieldset.cpp \
 629     rendering/RenderFrameSet.cpp \
 630     rendering/RenderTable.cpp \
 631     rendering/RenderPart.cpp \
 632     rendering/RenderBlock.cpp \
 633     rendering/InlineBox.cpp \
 634     rendering/RenderText.cpp \
 635     rendering/RenderFrame.cpp \
 636     rendering/RenderLineEdit.cpp \
 637     rendering/FixedTableLayout.cpp \
 638     rendering/RenderTableCol.cpp \
 639     rendering/RenderObject.cpp \
 640     rendering/RenderTreeAsText.cpp \
 641     rendering/SVGRenderTreeAsText.cpp \
 642     rendering/RootInlineBox.cpp \
 643     rendering/RenderFormElement.cpp \
 644     rendering/RenderBox.cpp \
 645     rendering/RenderButton.cpp \
 646     rendering/RenderTableSection.cpp \
 647     rendering/ListMarkerBox.cpp \
 648     rendering/RenderLabel.cpp \
 649     rendering/RenderTableRow.cpp \
 650     rendering/RenderInline.cpp \
 651     rendering/RenderFileUploadControl.cpp \
 652     rendering/RenderHTMLCanvas.cpp \
 653     rendering/bidi.cpp \
 654     rendering/RenderFlexibleBox.cpp \
 655     rendering/RenderApplet.cpp \
 656     rendering/RenderLegend.cpp \
 657     rendering/RenderTextControl.cpp \
 658     rendering/RenderTextFragment.cpp \
 659     rendering/RenderBR.cpp \
 660     rendering/InlineTextBox.cpp \
 661     rendering/RenderFlow.cpp \
 662     rendering/RenderSlider.cpp
 663
 664 contains(DEFINES, XPATH_SUPPORT=1) {
 665     FEATURE_DEFINES_JAVASCRIPT += XPATH_SUPPORT
 666
 667     # TODO: convert to generator
 668     !exists(xml/XPathGrammar.cpp) {
 669         message("generating xpath grammar")
 670         !system( bison -d -p xpathyy xml/XPathGrammar.y ): error("error executing bison")
 671         !system( mv XPathGrammar.tab.c xml/XPathGrammar.cpp ): error("error renaming XPathGrammar.cpp")
 672         !system( mv XPathGrammar.tab.h xml/XPathGrammar.h ): error("error renaming XPathGrammar.h")
 673     }
 674
 675     IDL_BINDINGS += \
 676         xpath/XPathNSResolver.idl \
 677         xpath/XPathExpression.idl \
 678         xpath/XPathResult.idl \
 679         xpath/XPathEvaluator.idl
 680
 681     SOURCES += xml/XPathGrammar.cpp
 682 }
 683
 684 contains(DEFINES, XSLT_SUPPORT=1) {
 685     FEATURE_DEFINES_JAVASCRIPT += XSLT_SUPPORT
 686 }
 687
 688 contains(DEFINES, XBL_SUPPORT=1) {
 689     FEATURE_DEFINES_JAVASCRIPT += XBL_SUPPORT
 690 }
 691
 692 contains(DEFINES, SVG_SUPPORT=1) {
 693     FEATURE_DEFINES_JAVASCRIPT += SVG_SUPPORT
 694
 695     SVG_NAMES = $$PWD/ksvg2/svg/svgtags.in
 696
 697     XML_NAMES = $$PWD/xml/xmlattrs.in
 698
 699     XLINK_NAMES = $$PWD/ksvg2/misc/xlinkattrs.in
 700
 701     IDL_BINDINGS += ksvg2/svg/SVGAElement.idl \
 702         ksvg2/svg/SVGAngle.idl \
 703         ksvg2/svg/SVGAnimateColorElement.idl \
 704         ksvg2/svg/SVGAnimateElement.idl \
 705         ksvg2/svg/SVGAnimateTransformElement.idl \
 706         ksvg2/svg/SVGAnimatedAngle.idl \
 707         ksvg2/svg/SVGAnimatedBoolean.idl \
 708         ksvg2/svg/SVGAnimatedEnumeration.idl \
 709         ksvg2/svg/SVGAnimatedInteger.idl \
 710         ksvg2/svg/SVGAnimatedLength.idl \
 711         ksvg2/svg/SVGAnimatedLengthList.idl \
 712         ksvg2/svg/SVGAnimatedNumber.idl \
 713         ksvg2/svg/SVGAnimatedNumberList.idl \
 714         ksvg2/svg/SVGAnimatedPreserveAspectRatio.idl \
 715         ksvg2/svg/SVGAnimatedRect.idl \
 716         ksvg2/svg/SVGAnimatedString.idl \
 717         ksvg2/svg/SVGAnimatedTransformList.idl \
 718         ksvg2/svg/SVGAnimationElement.idl \
 719         ksvg2/svg/SVGCircleElement.idl \
 720         ksvg2/svg/SVGClipPathElement.idl \
 721         ksvg2/svg/SVGColor.idl \
 722         ksvg2/svg/SVGComponentTransferFunctionElement.idl \
 723         ksvg2/svg/SVGCursorElement.idl \
 724         ksvg2/svg/SVGDefsElement.idl \
 725         ksvg2/svg/SVGDescElement.idl \
 726         ksvg2/svg/SVGDocument.idl \
 727         ksvg2/svg/SVGElement.idl \
 728         ksvg2/svg/SVGEllipseElement.idl \
 729         ksvg2/svg/SVGFEBlendElement.idl \
 730         ksvg2/svg/SVGFEColorMatrixElement.idl \
 731         ksvg2/svg/SVGFEComponentTransferElement.idl \
 732         ksvg2/svg/SVGFECompositeElement.idl \
 733         ksvg2/svg/SVGFEDiffuseLightingElement.idl \
 734         ksvg2/svg/SVGFEDisplacementMapElement.idl \
 735         ksvg2/svg/SVGFEDistantLightElement.idl \
 736         ksvg2/svg/SVGFEFloodElement.idl \
 737         ksvg2/svg/SVGFEFuncAElement.idl \
 738         ksvg2/svg/SVGFEFuncBElement.idl \
 739         ksvg2/svg/SVGFEFuncGElement.idl \
 740         ksvg2/svg/SVGFEFuncRElement.idl \
 741         ksvg2/svg/SVGFEGaussianBlurElement.idl \
 742         ksvg2/svg/SVGFEImageElement.idl \
 743         ksvg2/svg/SVGFEMergeElement.idl \
 744         ksvg2/svg/SVGFEMergeNodeElement.idl \
 745         ksvg2/svg/SVGFEOffsetElement.idl \
 746         ksvg2/svg/SVGFEPointLightElement.idl \
 747         ksvg2/svg/SVGFESpecularLightingElement.idl \
 748         ksvg2/svg/SVGFESpotLightElement.idl \
 749         ksvg2/svg/SVGFETileElement.idl \
 750         ksvg2/svg/SVGFETurbulenceElement.idl \
 751         ksvg2/svg/SVGFilterElement.idl \
 752         ksvg2/svg/SVGForeignObjectElement.idl \
 753         ksvg2/svg/SVGGElement.idl \
 754         ksvg2/svg/SVGGradientElement.idl \
 755         ksvg2/svg/SVGImageElement.idl \
 756         ksvg2/svg/SVGLength.idl \
 757         ksvg2/svg/SVGLengthList.idl \
 758         ksvg2/svg/SVGLineElement.idl \
 759         ksvg2/svg/SVGLinearGradientElement.idl \
 760         ksvg2/svg/SVGMaskElement.idl \
 761         ksvg2/svg/SVGMarkerElement.idl \
 762         ksvg2/svg/SVGMatrix.idl \
 763         ksvg2/svg/SVGMetadataElement.idl \
 764         ksvg2/svg/SVGNumberList.idl \
 765         ksvg2/svg/SVGPaint.idl \
 766         ksvg2/svg/SVGPathElement.idl \
 767         ksvg2/svg/SVGPathSeg.idl \
 768         ksvg2/svg/SVGPathSegArcAbs.idl \
 769         ksvg2/svg/SVGPathSegArcRel.idl \
 770         ksvg2/svg/SVGPathSegClosePath.idl \
 771         ksvg2/svg/SVGPathSegCurvetoCubicAbs.idl \
 772         ksvg2/svg/SVGPathSegCurvetoCubicRel.idl \
 773         ksvg2/svg/SVGPathSegCurvetoCubicSmoothAbs.idl \
 774         ksvg2/svg/SVGPathSegCurvetoCubicSmoothRel.idl \
 775         ksvg2/svg/SVGPathSegCurvetoQuadraticAbs.idl \
 776         ksvg2/svg/SVGPathSegCurvetoQuadraticRel.idl \
 777         ksvg2/svg/SVGPathSegCurvetoQuadraticSmoothAbs.idl \
 778         ksvg2/svg/SVGPathSegCurvetoQuadraticSmoothRel.idl \
 779         ksvg2/svg/SVGPathSegLinetoAbs.idl \
 780         ksvg2/svg/SVGPathSegLinetoHorizontalAbs.idl \
 781         ksvg2/svg/SVGPathSegLinetoHorizontalRel.idl \
 782         ksvg2/svg/SVGPathSegLinetoRel.idl \
 783         ksvg2/svg/SVGPathSegLinetoVerticalAbs.idl \
 784         ksvg2/svg/SVGPathSegLinetoVerticalRel.idl \
 785         ksvg2/svg/SVGPathSegList.idl \
 786         ksvg2/svg/SVGPathSegMovetoAbs.idl \
 787         ksvg2/svg/SVGPathSegMovetoRel.idl \
 788         ksvg2/svg/SVGPatternElement.idl \
 789         ksvg2/svg/SVGPointList.idl \
 790         ksvg2/svg/SVGPolygonElement.idl \
 791         ksvg2/svg/SVGPolylineElement.idl \
 792         ksvg2/svg/SVGPreserveAspectRatio.idl \
 793         ksvg2/svg/SVGRadialGradientElement.idl \
 794         ksvg2/svg/SVGRectElement.idl \
 795         ksvg2/svg/SVGRenderingIntent.idl \
 796         ksvg2/svg/SVGSetElement.idl \
 797         ksvg2/svg/SVGScriptElement.idl \
 798         ksvg2/svg/SVGStyleElement.idl \
 799         ksvg2/svg/SVGSwitchElement.idl \
 800         ksvg2/svg/SVGStopElement.idl \
 801         ksvg2/svg/SVGStringList.idl \
 802         ksvg2/svg/SVGSymbolElement.idl \
 803         ksvg2/svg/SVGSVGElement.idl \
 804         ksvg2/svg/SVGTRefElement.idl \
 805         ksvg2/svg/SVGTSpanElement.idl \
 806         ksvg2/svg/SVGTextElement.idl \
 807         ksvg2/svg/SVGTextContentElement.idl \
 808         ksvg2/svg/SVGTextPositioningElement.idl \
 809         ksvg2/svg/SVGTitleElement.idl \
 810         ksvg2/svg/SVGTransform.idl \
 811         ksvg2/svg/SVGTransformList.idl \
 812         ksvg2/svg/SVGUnitTypes.idl \
 813         ksvg2/svg/SVGUseElement.idl \
 814         ksvg2/svg/SVGViewElement.idl \
 815         ksvg2/events/SVGZoomEvent.idl
 816
 817     LUT_TABLE_FILES += \
 818         bindings/js/JSSVGNumber.cpp \
 819         bindings/js/JSSVGPoint.cpp \
 820         bindings/js/JSSVGRect.cpp
 821
 822     SOURCES += \
 823 # TODO: this-one-is-not-auto-added! FIXME! tmp/SVGElementFactory.cpp \
 824         bindings/js/JSSVGPoint.cpp \
 825         bindings/js/JSSVGRect.cpp \
 826         bindings/js/JSSVGNumber.cpp \
 827         bindings/js/JSSVGElementWrapperFactory.cpp \
 828         ksvg2/css/SVGCSSParser.cpp \
 829         ksvg2/css/SVGRenderStyleDefs.cpp \
 830         ksvg2/css/SVGRenderStyle.cpp \
 831         ksvg2/css/SVGCSSStyleSelector.cpp \
 832         ksvg2/svg/SVGHelper.cpp \
 833         ksvg2/svg/SVGFEFuncBElement.cpp \
 834         ksvg2/svg/SVGPathSeg.cpp \
 835         ksvg2/svg/SVGColor.cpp \
 836         ksvg2/svg/SVGSwitchElement.cpp \
 837         ksvg2/svg/SVGFETileElement.cpp \
 838         ksvg2/svg/SVGDOMImplementation.cpp \
 839         ksvg2/svg/SVGMarkerElement.cpp \
 840         ksvg2/svg/SVGFECompositeElement.cpp \
 841         ksvg2/svg/SVGImageElement.cpp \
 842         ksvg2/svg/SVGAnimateElement.cpp \
 843         ksvg2/svg/SVGURIReference.cpp \
 844         ksvg2/svg/SVGLength.cpp \
 845         ksvg2/svg/SVGPathSegCurvetoCubic.cpp \
 846         ksvg2/svg/SVGExternalResourcesRequired.cpp \
 847         ksvg2/svg/SVGPolylineElement.cpp \
 848         ksvg2/svg/SVGFEOffsetElement.cpp \
 849         ksvg2/svg/SVGFETurbulenceElement.cpp \
 850         ksvg2/svg/SVGZoomAndPan.cpp \
 851         ksvg2/svg/SVGFilterPrimitiveStandardAttributes.cpp \
 852         ksvg2/svg/SVGStyledLocatableElement.cpp \
 853         ksvg2/svg/SVGLineElement.cpp \
 854         ksvg2/svg/SVGTransform.cpp \
 855         ksvg2/svg/SVGPathSegLinetoVertical.cpp \
 856         ksvg2/svg/SVGFitToViewBox.cpp \
 857         ksvg2/svg/SVGRadialGradientElement.cpp \
 858         ksvg2/svg/SVGMatrix.cpp \
 859         ksvg2/svg/SVGMaskElement.cpp \
 860         ksvg2/svg/SVGTitleElement.cpp \
 861         ksvg2/svg/SVGTRefElement.cpp \
 862         ksvg2/svg/SVGLangSpace.cpp \
 863         ksvg2/svg/SVGTransformList.cpp \
 864         ksvg2/svg/SVGStylable.cpp \
 865         ksvg2/svg/SVGPolyElement.cpp \
 866         ksvg2/svg/SVGPolygonElement.cpp \
 867 #        ksvg2/svg/SVGElementInstanceList.cpp \
 868         ksvg2/svg/SVGTSpanElement.cpp \
 869         ksvg2/svg/SVGFEFuncRElement.cpp \
 870         ksvg2/svg/SVGFEFloodElement.cpp \
 871         ksvg2/svg/SVGPointList.cpp \
 872         ksvg2/svg/SVGAnimatedPoints.cpp \
 873         ksvg2/svg/SVGAnimatedPathData.cpp \
 874         ksvg2/svg/SVGUseElement.cpp \
 875         ksvg2/svg/SVGNumberList.cpp \
 876         ksvg2/svg/SVGFEPointLightElement.cpp \
 877         ksvg2/svg/SVGPathSegLineto.cpp \
 878         ksvg2/svg/SVGRectElement.cpp \
 879         ksvg2/svg/SVGTextContentElement.cpp \
 880         ksvg2/svg/SVGFESpotLightElement.cpp \
 881         ksvg2/svg/SVGLocatable.cpp \
 882         ksvg2/svg/SVGEllipseElement.cpp \
 883         ksvg2/svg/SVGPathElement.cpp \
 884         ksvg2/svg/SVGStyledElement.cpp \
 885         ksvg2/svg/SVGFEMergeNodeElement.cpp \
 886         ksvg2/svg/svgpathparser.cpp \
 887         ksvg2/svg/SVGFEGaussianBlurElement.cpp \
 888         ksvg2/svg/SVGLinearGradientElement.cpp \
 889         ksvg2/svg/SVGFEDisplacementMapElement.cpp \
 890         ksvg2/svg/SVGFEImageElement.cpp \
 891         ksvg2/svg/SVGFEDiffuseLightingElement.cpp \
 892         ksvg2/svg/SVGSymbolElement.cpp \
 893         ksvg2/svg/SVGForeignObjectElement.cpp \
 894         ksvg2/svg/SVGAngle.cpp \
 895         ksvg2/svg/SVGPathSegCurvetoQuadratic.cpp \
 896         ksvg2/svg/SVGSVGElement.cpp \
 897         ksvg2/svg/SVGFESpecularLightingElement.cpp \
 898         ksvg2/svg/SVGAnimateColorElement.cpp \
 899         ksvg2/svg/SVGGElement.cpp \
 900         ksvg2/svg/SVGFEFuncGElement.cpp \
 901         ksvg2/svg/SVGFEComponentTransferElement.cpp \
 902         ksvg2/svg/SVGSetElement.cpp \
 903         ksvg2/svg/SVGFEBlendElement.cpp \
 904         ksvg2/svg/SVGFEMergeElement.cpp \
 905         ksvg2/svg/SVGCursorElement.cpp \
 906         ksvg2/svg/SVGStringList.cpp \
 907 #        ksvg2/svg/SVGElementInstance.cpp \
 908         ksvg2/svg/SVGFilterElement.cpp \
 909         ksvg2/svg/SVGPathSegCurvetoCubicSmooth.cpp \
 910         ksvg2/svg/SVGPatternElement.cpp \
 911         ksvg2/svg/SVGPathSegList.cpp \
 912         ksvg2/svg/SVGStyleElement.cpp \
 913         ksvg2/svg/SVGPaint.cpp \
 914         ksvg2/svg/SVGFEDistantLightElement.cpp \
 915         ksvg2/svg/SVGTextPositioningElement.cpp \
 916         ksvg2/svg/SVGPreserveAspectRatio.cpp \
 917         ksvg2/svg/SVGScriptElement.cpp \
 918         ksvg2/svg/SVGComponentTransferFunctionElement.cpp \
 919         ksvg2/svg/SVGTextElement.cpp \
 920         ksvg2/svg/SVGViewElement.cpp \
 921         ksvg2/svg/SVGLengthList.cpp \
 922         ksvg2/svg/SVGStyledTransformableElement.cpp \
 923         ksvg2/svg/SVGPathSegArc.cpp \
 924         ksvg2/svg/SVGDescElement.cpp \
 925         ksvg2/svg/SVGTransformable.cpp \
 926         ksvg2/svg/SVGDocument.cpp \
 927         ksvg2/svg/SVGClipPathElement.cpp \
 928         ksvg2/svg/SVGPathSegMoveto.cpp \
 929         ksvg2/svg/SVGAElement.cpp \
 930         ksvg2/svg/SVGCircleElement.cpp \
 931         ksvg2/svg/SVGFEFuncAElement.cpp \
 932         ksvg2/svg/SVGTests.cpp \
 933         ksvg2/svg/SVGPathSegCurvetoQuadraticSmooth.cpp \
 934         ksvg2/svg/SVGElement.cpp \
 935         ksvg2/svg/SVGAnimateTransformElement.cpp \
 936         ksvg2/svg/SVGFEColorMatrixElement.cpp \
 937         ksvg2/svg/SVGGradientElement.cpp \
 938         ksvg2/svg/SVGAnimationElement.cpp \
 939         ksvg2/svg/SVGFELightElement.cpp \
 940         ksvg2/svg/SVGPathSegClosePath.cpp \
 941         ksvg2/svg/SVGPathSegLinetoHorizontal.cpp \
 942         ksvg2/svg/SVGStopElement.cpp \
 943         ksvg2/svg/SVGDefsElement.cpp \
 944         ksvg2/svg/SVGMetadataElement.cpp \
 945         ksvg2/misc/SVGImageLoader.cpp \
 946         ksvg2/misc/SVGDocumentExtensions.cpp \
 947         ksvg2/misc/KSVGTimeScheduler.cpp \
 948         ksvg2/misc/KCanvasRenderingStyle.cpp \
 949         ksvg2/events/JSSVGLazyEventListener.cpp \
 950         ksvg2/events/SVGZoomEvent.cpp \
 951         kcanvas/KCanvasFilters.cpp \
 952         kcanvas/device/KRenderingPaintServerGradient.cpp \
 953         kcanvas/device/KRenderingPaintServerSolid.cpp \
 954         kcanvas/device/KRenderingPaintServerPattern.cpp \
 955         kcanvas/device/KRenderingDevice.cpp \
 956         kcanvas/device/qt/RenderPathQt.cpp \
 957         kcanvas/device/qt/KRenderingDeviceQt.cpp \
 958         kcanvas/device/qt/KRenderingPaintServerSolidQt.cpp \
 959         kcanvas/device/qt/KRenderingPaintServerGradientQt.cpp \
 960         kcanvas/device/qt/KRenderingPaintServerPatternQt.cpp \
 961         kcanvas/device/qt/KRenderingPaintServerQt.cpp \
 962 #        kcanvas/device/qt/KCanvasFilterQt.cpp \
 963 #        kcanvas/device/qt/KCanvasImageItemQt.cpp \
 964         platform/graphics/svg/SVGResource.cpp \
 965         platform/graphics/svg/SVGResourceClipper.cpp \
 966         platform/graphics/svg/SVGResourceMasker.cpp \
 967         platform/graphics/svg/SVGResourceMarker.cpp \
 968         platform/graphics/svg/qt/SVGResourceClipperQt.cpp \
 969         platform/graphics/svg/qt/SVGResourceImageQt.cpp \
 970         platform/graphics/svg/qt/SVGResourceMaskerQt.cpp \
 971         rendering/RenderForeignObject.cpp \
 972         rendering/RenderPath.cpp \
 973         rendering/RenderSVGContainer.cpp \
 974         rendering/RenderSVGImage.cpp \
 975         rendering/RenderSVGInline.cpp \
 976         rendering/RenderSVGInlineText.cpp \
 977         rendering/RenderSVGText.cpp \
 978         rendering/RenderSVGTSpan.cpp \
 979         rendering/SVGInlineFlowBox.cpp \
 980         rendering/SVGRootInlineBox.cpp
 981
 982         # GENERATOR 5-B:
 983         svgnames_a.output = tmp/SVGNames.cpp
 984         svgnames_a.commands = perl $$PWD/ksvg2/scripts/make_names.pl --tags $$PWD/ksvg2/svg/svgtags.in --attrs $$PWD/ksvg2/svg/svgattrs.in --namespace SVG --cppNamespace WebCore --namespaceURI 'http://www.w3.org/2000/svg' --factory --attrsNullNamespace --output tmp
 985         svgnames_a.input = SVG_NAMES
 986         svgnames_a.dependency_type = TYPE_C
 987         svgnames_a.CONFIG = target_predeps
 988         svgnames_a.variable_out = GENERATED_SOURCES
 989         QMAKE_EXTRA_COMPILERS += svgnames_a
 990         svgnames_b.output = tmp/SVGElementFactory.cpp
 991         svgnames_b.commands = @echo -n ''
 992         svgnames_b.input = SVG_NAMES
 993         svgnames_b.depends = tmp/SVGNames.cpp
 994         svgnames_b.CONFIG = target_predeps
 995         svgnames_b.variable_out = GENERATED_SOURCES
 996         QMAKE_EXTRA_COMPILERS += svgnames_b
 997
 998         # GENERATOR 5-C:
 999         xlinknames.output = tmp/XLinkNames.cpp
1000         xlinknames.commands = perl $$PWD/ksvg2/scripts/make_names.pl --attrs $$PWD/ksvg2/misc/xlinkattrs.in --namespace XLink --cppNamespace WebCore --namespaceURI 'http://www.w3.org/1999/xlink' --output tmp
1001         xlinknames.input = XLINK_NAMES
1002         xlinknames.dependency_type = TYPE_C
1003         xlinknames.CONFIG = target_predeps
1004         xlinknames.variable_out = GENERATED_SOURCES
1005         QMAKE_EXTRA_COMPILERS += xlinknames
1006
1007         # GENERATOR 5-D:
1008         xmlnames.output = tmp/XMLNames.cpp
1009         xmlnames.commands = perl $$PWD/ksvg2/scripts/make_names.pl --attrs $$PWD/xml/xmlattrs.in --namespace XML --cppNamespace WebCore --namespaceURI 'http://www.w3.org/XML/1998/namespace' --output tmp
1010         xmlnames.input = XML_NAMES
1011         xmlnames.dependency_type = TYPE_C
1012         xmlnames.CONFIG = target_predeps
1013         xmlnames.variable_out = GENERATED_SOURCES
1014         QMAKE_EXTRA_COMPILERS += xmlnames
1015 }
1016
1017
1018 # GENERATOR 1: IDL compiler
1019 idl.output = tmp/JS${QMAKE_FILE_BASE}.cpp
1020 idl.variable_out = GENERATED_SOURCES
1021 idl.input = IDL_BINDINGS
1022 idl.commands = perl -I$$PWD/bindings/scripts $$PWD/bindings/scripts/generate-bindings.pl --defines \"$${FEATURE_DEFINES_JAVASCRIPT}\" --generator JS --include $$PWD/dom --include $$PWD/html --include $$PWD/xml --include $$PWD/ksvg2/svg --outputdir tmp ${QMAKE_FILE_NAME}
1023 idl.CONFIG += target_predeps
1024 QMAKE_EXTRA_COMPILERS += idl
1025
1026 # GENERATOR 2-A: LUT creator
1027 lut.output = tmp/${QMAKE_FILE_BASE}.lut.h
1028 lut.commands = perl $$PWD/../JavaScriptCore/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
1029 lut.depend = ${QMAKE_FILE_NAME}
1030 lut.input = LUT_FILES
1031 lut.CONFIG += no_link
1032 QMAKE_EXTRA_COMPILERS += lut
1033
1034 # GENERATOR 2-B: like JavaScriptCore/LUT Generator, but rename output
1035 luttable.output = tmp/${QMAKE_FILE_BASE}Table.cpp
1036 luttable.commands = perl $$PWD/../JavaScriptCore/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
1037 luttable.depend = ${QMAKE_FILE_NAME}
1038 luttable.input = LUT_TABLE_FILES
1039 luttable.CONFIG += no_link
1040 luttable.dependency_type = TYPE_C
1041 QMAKE_EXTRA_COMPILERS += luttable
1042
1043 # GENERATOR 3: tokenizer (flex)
1044 tokenizer.output = tmp/${QMAKE_FILE_BASE}.cpp
1045 tokenizer.commands = flex -t < ${QMAKE_FILE_NAME} | perl $$PWD/css/maketokenizer > ${QMAKE_FILE_OUT}
1046 tokenizer.dependency_Type = TYPE_C
1047 tokenizer.input = TOKENIZER
1048 tokenizer.CONFIG += target_predeps no_link
1049 QMAKE_EXTRA_COMPILERS += tokenizer
1050
1051 # GENERATOR 4: CSS grammar
1052 cssbison.output = tmp/${QMAKE_FILE_BASE}.cpp
1053 macx:cssbison.commands = bison -d -p cssyy ${QMAKE_FILE_NAME} && mv css/${QMAKE_FILE_BASE}.tab.c tmp/${QMAKE_FILE_BASE}.cpp && mv css/${QMAKE_FILE_BASE}.tab.h tmp/${QMAKE_FILE_BASE}.h
1054 !macx:cssbison.commands = bison -d -p cssyy ${QMAKE_FILE_NAME} && mv ${QMAKE_FILE_BASE}.tab.c tmp/${QMAKE_FILE_BASE}.cpp && mv ${QMAKE_FILE_BASE}.tab.h tmp/${QMAKE_FILE_BASE}.h
1055 cssbison.depend = ${QMAKE_FILE_NAME}
1056 cssbison.input = CSSBISON
1057 cssbison.CONFIG = target_predeps
1058 cssbison.dependency_type = TYPE_C
1059 cssbison.variable_out = GENERATED_SOURCES
1060 QMAKE_EXTRA_COMPILERS += cssbison
1061 #PRE_TARGETDEPS += tmp/CSSGrammar.cpp
1062
1063 # GENERATOR 5-A:
1064 htmlnames.output = tmp/HTMLNames.cpp
1065 htmlnames.commands = perl $$PWD/ksvg2/scripts/make_names.pl --tags $$PWD/html/HTMLTagNames.in --attrs $$PWD/html/HTMLAttributeNames.in --namespace HTML --namespacePrefix xhtml --cppNamespace WebCore --namespaceURI 'http://www.w3.org/1999/xhtml' --attrsNullNamespace --output tmp
1066 htmlnames.input = HTML_NAMES
1067 htmlnames.dependency_type = TYPE_C
1068 htmlnames.CONFIG = target_predeps
1069 htmlnames.variable_out = GENERATED_SOURCES
1070 QMAKE_EXTRA_COMPILERS += htmlnames
1071
1072 # GENERATOR 6-A:
1073 cssprops.output = tmp/CSSPropertyNames.c
1074 cssprops.input = WALDOCSSPROPS
1075 cssprops.commands = cp ${QMAKE_FILE_NAME} tmp && cd tmp && sh $$PWD/css/makeprop
1076 cssprops.CONFIG = target_predeps no_link
1077 QMAKE_EXTRA_COMPILERS += cssprops
1078
1079 # GENERATOR 6-B:
1080 cssvalues.output = tmp/CSSValueKeywords.c
1081 cssvalues.input = WALDOCSSVALUES
1082 cssvalues.commands = cp ${QMAKE_FILE_NAME} tmp && cd tmp && sh $$PWD/css/makevalues
1083 cssvalues.CONFIG = target_predeps no_link
1084 QMAKE_EXTRA_COMPILERS += cssvalues
1085
1086 # GENERATOR 7-A:
1087 svgcssproperties.output = tmp/ksvgcssproperties.h
1088 svgcssproperties.input = SVGCSSPROPERTIES
1089 svgcssproperties.commands = cp $$PWD/ksvg2/css/CSSPropertyNames.in tmp/ksvgcssproperties.in && cd tmp && perl $$PWD/ksvg2/scripts/cssmakeprops -n SVG -f ksvgcssproperties.in
1090 svgcssproperties.CONFIG = target_predeps no_link
1091 QMAKE_EXTRA_COMPILERS += svgcssproperties
1092
1093 # GENERATOR 7-B:
1094 svgcssvalues.output = tmp/ksvgcssvalues.h
1095 svgcssvalues.input = SVGCSSVALUES
1096 svgcssvalues.commands = perl -ne \'print lc\' $$PWD/ksvg2/css/CSSValueKeywords.in > tmp/ksvgcssvalues.in && cd tmp && perl $$PWD/ksvg2/scripts/cssmakevalues -n SVG -f ksvgcssvalues.in
1097 svgcssvalues.CONFIG = target_predeps no_link
1098 QMAKE_EXTRA_COMPILERS += svgcssvalues
1099
1100 # GENERATOR 8-A:
1101 entities.output = tmp/HTMLEntityNames.c
1102 entities.commands = gperf -a -L ANSI-C -C -G -c -o -t -k '\*' -N findEntity -D -s 2 < $$PWD/html/HTMLEntityNames.gperf > tmp/HTMLEntityNames.c
1103 entities.input = ENTITIES_GPERF
1104 entities.dependency_type = TYPE_C
1105 entities.CONFIG = target_predeps no_link
1106 QMAKE_EXTRA_COMPILERS += entities
1107
1108 # PRE-GENERATOR 8-B:
1109 doctypestrings.target = $$OUTPUT_DIR/WebCore/tmp/DocTypeStrings.cpp
1110 doctypestrings.commands = echo \"$${LITERAL_HASH}include <string.h>\" > $$doctypestrings.target && gperf -CEot -L ANSI-C -k \'*\' -N findDoctypeEntry -F ,PubIDInfo::eAlmostStandards,PubIDInfo::eAlmostStandards < $$PWD/html/DocTypeStrings.gperf >> $$doctypestrings.target
1111 QMAKE_EXTRA_TARGETS += doctypestrings
1112 PRE_TARGETDEPS += $$OUTPUT_DIR/WebCore/tmp/DocTypeStrings.cpp
1113
1114 # GENERATOR 8-C:
1115 colordata.output = tmp/ColorData.c
1116 colordata.commands = echo \"$${LITERAL_HASH}include <string.h>\" > ${QMAKE_FILE_OUT} && gperf -CDEot -L ANSI-C -k \'*\' -N findColor -D -s 2 < ${QMAKE_FILE_NAME} >> ${QMAKE_FILE_OUT}
1117 colordata.input = COLORDAT_GPERF
1118 colordata.CONFIG = target_predeps no_link
1119 QMAKE_EXTRA_COMPILERS += colordata
1120
1121 # GENERATOR 9:
1122 stylesheets.output = tmp/UserAgentStyleSheetsData.cpp
1123 stylesheets.commands = perl $$PWD/css/make-css-file-arrays.pl tmp/UserAgentStyleSheets.h tmp/UserAgentStyleSheetsData.cpp $$PWD/css/html4.css $$PWD/css/quirks.css $$PWD/css/svg.css $$PWD/css/view-source.css
1124 stylesheets.input = STYLESHEETS_EMBED
1125 stylesheets.CONFIG = target_predeps
1126 stylesheets.variable_out = GENERATED_SOURCES
1127 QMAKE_EXTRA_COMPILERS += stylesheets
1128
1129 # GENERATOR M
1130 manual_moc.output = tmp/${QMAKE_FILE_BASE}.moc
1131 manual_moc.commands = $$QMAKE_MOC ${QMAKE_FILE_NAME} -o ${QMAKE_FILE_OUT}
1132 manual_moc.input = MANUALMOC
1133 manual_moc.CONFIG += target_predeps no_link
1134 QMAKE_EXTRA_COMPILERS += manual_moc