2010-07-12 Ilya Tikhonovsky <loislo@chromium.org>
[WebKit-https.git] / WebCore / WebCore.pri
1
2 include(../common.pri)
3
4 CONFIG(standalone_package) {
5     isEmpty(WC_GENERATED_SOURCES_DIR):WC_GENERATED_SOURCES_DIR = $$PWD/generated
6 } else {
7     isEmpty(WC_GENERATED_SOURCES_DIR):WC_GENERATED_SOURCES_DIR = generated
8 }
9
10 CONFIG(minimal) {
11   DEFINES += ENABLE_NETSCAPE_PLUGIN_API=0
12 }
13
14 ## load mobilityconfig if mobility is available 
15 load(mobilityconfig, true)
16
17 ## Define default features macros for optional components
18 ## (look for defs in config.h and included files!)
19 # Try to locate sqlite3 source
20 CONFIG(QTDIR_build) {
21     SQLITE3SRCDIR = $$QT_SOURCE_TREE/src/3rdparty/sqlite/
22 } else {
23     SQLITE3SRCDIR = $$(SQLITE3SRCDIR)
24     isEmpty(SQLITE3SRCDIR) {
25         SQLITE3SRCDIR = $$[QT_INSTALL_PREFIX]/src/3rdparty/sqlite/
26     }
27 }
28
29 contains(DEFINES, ENABLE_SINGLE_THREADED=1) {
30     DEFINES+=ENABLE_DATABASE=0 ENABLE_DOM_STORAGE=0 ENABLE_ICONDATABASE=0 ENABLE_WORKERS=0 ENABLE_SHARED_WORKERS=0
31 }
32
33 # turn off SQLITE support if we do not have sqlite3 available
34 !CONFIG(QTDIR_build):win32-*:!exists( $${SQLITE3SRCDIR}/sqlite3.c ): DEFINES += ENABLE_SQLITE=0 ENABLE_DATABASE=0 ENABLE_WORKERS=0 ENABLE_SHARED_WORKERS=0 ENABLE_ICONDATABASE=0 ENABLE_OFFLINE_WEB_APPLICATIONS=0 ENABLE_DOM_STORAGE=0
35
36 !contains(DEFINES, ENABLE_JAVASCRIPT_DEBUGGER=.): DEFINES += ENABLE_JAVASCRIPT_DEBUGGER=1
37 !contains(DEFINES, ENABLE_DATABASE=.): DEFINES += ENABLE_DATABASE=1
38 !contains(DEFINES, ENABLE_EVENTSOURCE=.): DEFINES += ENABLE_EVENTSOURCE=1
39 !contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=.): DEFINES += ENABLE_OFFLINE_WEB_APPLICATIONS=1
40 !contains(DEFINES, ENABLE_DOM_STORAGE=.): DEFINES += ENABLE_DOM_STORAGE=1
41 !contains(DEFINES, ENABLE_ICONDATABASE=.): DEFINES += ENABLE_ICONDATABASE=1
42 !contains(DEFINES, ENABLE_CHANNEL_MESSAGING=.): DEFINES += ENABLE_CHANNEL_MESSAGING=1
43 !contains(DEFINES, ENABLE_ORIENTATION_EVENTS=.): DEFINES += ENABLE_ORIENTATION_EVENTS=0
44 !contains(DEFINES, ENABLE_DIRECTORY_UPLOAD=.): DEFINES += ENABLE_DIRECTORY_UPLOAD=0
45
46 # turn on SQLITE support if any of the dependent features are turned on
47 !contains(DEFINES, ENABLE_SQLITE=.) {
48   contains(DEFINES, ENABLE_DATABASE=1)|contains(DEFINES, ENABLE_ICONDATABASE=1)|contains(DEFINES, ENABLE_DOM_STORAGE=1)|contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=1) {
49     DEFINES += ENABLE_SQLITE=1
50   } else {
51     DEFINES += ENABLE_SQLITE=0
52   }
53 }
54
55 !contains(DEFINES, ENABLE_DASHBOARD_SUPPORT=.): DEFINES += ENABLE_DASHBOARD_SUPPORT=0
56 !contains(DEFINES, ENABLE_FILTERS=.): DEFINES += ENABLE_FILTERS=1
57 !contains(DEFINES, ENABLE_XPATH=.): DEFINES += ENABLE_XPATH=1
58 #!contains(DEFINES, ENABLE_XBL=.): DEFINES += ENABLE_XBL=1
59 !contains(DEFINES, ENABLE_WCSS=.): DEFINES += ENABLE_WCSS=0
60 !contains(DEFINES, ENABLE_WML=.): DEFINES += ENABLE_WML=0
61 !contains(DEFINES, ENABLE_SHARED_WORKERS=.): DEFINES += ENABLE_SHARED_WORKERS=1
62 !contains(DEFINES, ENABLE_WORKERS=.): DEFINES += ENABLE_WORKERS=1
63 !contains(DEFINES, ENABLE_XHTMLMP=.): DEFINES += ENABLE_XHTMLMP=0
64 !contains(DEFINES, ENABLE_DATAGRID=.): DEFINES += ENABLE_DATAGRID=0
65 !contains(DEFINES, ENABLE_RUBY=.): DEFINES += ENABLE_RUBY=1
66 !contains(DEFINES, ENABLE_SANDBOX=.): DEFINES += ENABLE_SANDBOX=1
67 !contains(DEFINES, ENABLE_METER_TAG=.): DEFINES += ENABLE_METER_TAG=1
68 !contains(DEFINES, ENABLE_PROGRESS_TAG=.): DEFINES += ENABLE_PROGRESS_TAG=1
69 !contains(DEFINES, ENABLE_BLOB_SLICE=.): DEFINES += ENABLE_BLOB_SLICE=0
70 !contains(DEFINES, ENABLE_NOTIFICATIONS=.): DEFINES += ENABLE_NOTIFICATIONS=1
71 !contains(DEFINES, ENABLE_IMAGE_RESIZER=.): DEFINES += ENABLE_IMAGE_RESIZER=0
72 !contains(DEFINES, ENABLE_INPUT_SPEECH=.): DEFINES += ENABLE_INPUT_SPEECH=0
73
74 greaterThan(QT_MINOR_VERSION, 5) {
75     !contains(DEFINES, ENABLE_3D_RENDERING=.): DEFINES += ENABLE_3D_RENDERING=1
76 }
77
78 # SVG support
79 !contains(DEFINES, ENABLE_SVG=0) {
80     !contains(DEFINES, ENABLE_SVG=.): DEFINES += ENABLE_SVG=1
81     !contains(DEFINES, ENABLE_SVG_FONTS=.): DEFINES += ENABLE_SVG_FONTS=1
82     !contains(DEFINES, ENABLE_SVG_FOREIGN_OBJECT=.): DEFINES += ENABLE_SVG_FOREIGN_OBJECT=1
83     !contains(DEFINES, ENABLE_SVG_ANIMATION=.): DEFINES += ENABLE_SVG_ANIMATION=1
84     !contains(DEFINES, ENABLE_SVG_AS_IMAGE=.): DEFINES += ENABLE_SVG_AS_IMAGE=1
85     !contains(DEFINES, ENABLE_SVG_USE=.): DEFINES += ENABLE_SVG_USE=1
86 } else {
87     DEFINES += ENABLE_SVG_FONTS=0 ENABLE_SVG_FOREIGN_OBJECT=0 ENABLE_SVG_ANIMATION=0 ENABLE_SVG_AS_IMAGE=0 ENABLE_SVG_USE=0
88 }
89
90 # HTML5 datalist support
91 !contains(DEFINES, ENABLE_DATALIST=.): DEFINES += ENABLE_DATALIST=1
92
93 # Tiled Backing Store support
94 greaterThan(QT_MINOR_VERSION, 5) {
95     !contains(DEFINES, ENABLE_TILED_BACKING_STORE=.): DEFINES += ENABLE_TILED_BACKING_STORE=1
96 }
97
98 # Nescape plugins support (NPAPI)
99 !contains(DEFINES, ENABLE_NETSCAPE_PLUGIN_API=.) {
100     unix|win32-*:!embedded:!wince*: {
101         DEFINES += ENABLE_NETSCAPE_PLUGIN_API=1
102     } else {
103         DEFINES += ENABLE_NETSCAPE_PLUGIN_API=0
104     }
105 }
106
107 # Web Socket support.
108 !contains(DEFINES, ENABLE_WEB_SOCKETS=.): DEFINES += ENABLE_WEB_SOCKETS=1
109
110 # Web Timing support.
111 !contains(DEFINES, ENABLE_WEB_TIMING=.): DEFINES += ENABLE_WEB_TIMING=0
112
113 # XSLT support with QtXmlPatterns
114 !contains(DEFINES, ENABLE_XSLT=.) {
115     contains(QT_CONFIG, xmlpatterns):DEFINES += ENABLE_XSLT=1
116     else:DEFINES += ENABLE_XSLT=0
117 }
118
119 # geolocation support if QtMobility exists
120 !CONFIG(QTDIR_build):!contains(DEFINES, ENABLE_GEOLOCATION=.) {
121     contains(MOBILITY_CONFIG, location) {
122        DEFINES += ENABLE_GEOLOCATION=1
123     }
124 }
125
126 # Bearer management is part of Qt 4.7
127 # for older version, check for mobility with bearer 
128 !contains(DEFINES, ENABLE_QT_BEARER=.) {
129      !lessThan(QT_MINOR_VERSION, 7) {
130         DEFINES += ENABLE_QT_BEARER=1
131      } else {
132         contains(MOBILITY_CONFIG, bearer) {
133             DEFINES += ENABLE_QT_BEARER=1
134         }
135     }
136 }
137
138 # Enable touch event support with Qt 4.6
139 !lessThan(QT_MINOR_VERSION, 6): DEFINES += ENABLE_TOUCH_EVENTS=1
140
141 # HTML5 Media Support
142 # We require QtMultimedia or Phonon
143 !contains(DEFINES, ENABLE_VIDEO=.) {
144     DEFINES -= ENABLE_VIDEO=1
145     DEFINES += ENABLE_VIDEO=0
146
147     !lessThan(QT_MINOR_VERSION, 6):contains(MOBILITY_CONFIG, multimedia) {
148         DEFINES -= ENABLE_VIDEO=0
149         DEFINES += ENABLE_VIDEO=1
150     } else:contains(QT_CONFIG, phonon) {
151         DEFINES -= ENABLE_VIDEO=0
152         DEFINES += ENABLE_VIDEO=1
153     }
154 }
155
156 # Used to compute defaults for the build-webkit script
157 CONFIG(compute_defaults) {
158     message($$DEFINES)
159     error("Done computing defaults")
160 }
161
162 contains(DEFINES, ENABLE_WCSS=1) {
163     contains(DEFINES, ENABLE_XHTMLMP=0) {
164         DEFINES -= ENABLE_XHTMLMP=0
165         DEFINES += ENABLE_XHTMLMP=1
166     }
167 }
168
169 ## Forward enabled feature macros to JavaScript enabled features macros
170 FEATURE_DEFINES_JAVASCRIPT = LANGUAGE_JAVASCRIPT=1
171 contains(DEFINES, ENABLE_CHANNEL_MESSAGING=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_CHANNEL_MESSAGING=1
172 contains(DEFINES, ENABLE_ORIENTATION_EVENTS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_ORIENTATION_EVENTS=1
173 contains(DEFINES, ENABLE_DASHBOARD_SUPPORT=0): DASHBOARDSUPPORTCSSPROPERTIES -= $$PWD/css/DashboardSupportCSSPropertyNames.in
174 contains(DEFINES, ENABLE_DATAGRID=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DATAGRID=1
175 contains(DEFINES, ENABLE_EVENTSOURCE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_EVENTSOURCE=1
176 contains(DEFINES, ENABLE_DATABASE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DATABASE=1
177 contains(DEFINES, ENABLE_DATALIST=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DATALIST=1
178 contains(DEFINES, ENABLE_DOM_STORAGE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DOM_STORAGE=1
179 contains(DEFINES, ENABLE_SHARED_SCRIPT=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_SHARED_SCRIPT=1
180 contains(DEFINES, ENABLE_WORKERS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WORKERS=1
181 contains(DEFINES, ENABLE_SHARED_WORKERS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_SHARED_WORKERS=1
182 contains(DEFINES, ENABLE_VIDEO=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_VIDEO=1
183 contains(DEFINES, ENABLE_XPATH=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XPATH=1
184 contains(DEFINES, ENABLE_XSLT=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XSLT=1
185 contains(DEFINES, ENABLE_XBL=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XBL=1
186 contains(DEFINES, ENABLE_FILTERS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_FILTERS=1
187 contains(DEFINES, ENABLE_WCSS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WCSS=1
188 contains(DEFINES, ENABLE_WML=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WML=1
189 contains(DEFINES, ENABLE_XHTMLMP=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XHTMLMP=1
190 contains(DEFINES, ENABLE_SVG=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_SVG=1
191 contains(DEFINES, ENABLE_JAVASCRIPT_DEBUGGER=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_JAVASCRIPT_DEBUGGER=1
192 contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_OFFLINE_WEB_APPLICATIONS=1
193 contains(DEFINES, ENABLE_WEB_SOCKETS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WEB_SOCKETS=1
194 contains(DEFINES, ENABLE_WEB_TIMING=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WEB_TIMING=1
195 contains(DEFINES, ENABLE_TOUCH_EVENTS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_TOUCH_EVENTS=1
196 contains(DEFINES, ENABLE_TILED_BACKING_STORE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_TILED_BACKING_STORE=1
197 contains(DEFINES, ENABLE_NOTIFICATIONS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_NOTIFICATIONS=1
198 contains(DEFINES, ENABLE_METER_TAG=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_METER_TAG=1
199 contains(DEFINES, ENABLE_PROGRESS_TAG=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_PROGRESS_TAG=1
200 contains(DEFINES, ENABLE_GEOLOCATION=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_GEOLOCATION=1
201
202 ## Derived source generators
203 MATHML_NAMES = $$PWD/mathml/mathtags.in
204
205 WML_NAMES = $$PWD/wml/WMLTagNames.in
206
207 SVG_NAMES = $$PWD/svg/svgtags.in
208
209 XLINK_NAMES = $$PWD/svg/xlinkattrs.in
210
211 TOKENIZER = $$PWD/css/tokenizer.flex
212
213 DOCTYPESTRINGS_GPERF = $$PWD/html/DocTypeStrings.gperf
214
215 CSSBISON = $$PWD/css/CSSGrammar.y
216
217 HTML_NAMES = $$PWD/html/HTMLTagNames.in
218
219 XML_NAMES = $$PWD/xml/xmlattrs.in
220
221 XMLNS_NAMES = $$PWD/xml/xmlnsattrs.in
222
223 ENTITIES_GPERF = $$PWD/html/HTMLEntityNames.gperf
224
225 COLORDATA_GPERF = $$PWD/platform/ColorData.gperf
226
227 WALDOCSSPROPS = $$PWD/css/CSSPropertyNames.in
228
229 WALDOCSSVALUES = $$PWD/css/CSSValueKeywords.in
230
231 DASHBOARDSUPPORTCSSPROPERTIES = $$PWD/css/DashboardSupportCSSPropertyNames.in
232
233 XPATHBISON = $$PWD/xml/XPathGrammar.y
234
235 contains(DEFINES, ENABLE_SVG=1) {
236     EXTRACSSPROPERTIES += $$PWD/css/SVGCSSPropertyNames.in
237     EXTRACSSVALUES += $$PWD/css/SVGCSSValueKeywords.in
238 }
239
240 contains(DEFINES, ENABLE_WCSS=1) {
241     EXTRACSSPROPERTIES += $$PWD/css/WCSSPropertyNames.in
242     EXTRACSSVALUES += $$PWD/css/WCSSValueKeywords.in
243 }
244
245 STYLESHEETS_EMBED = \
246     $$PWD/css/html.css \
247     $$PWD/css/quirks.css \
248     $$PWD/css/mathml.css \
249     $$PWD/css/svg.css \
250     $$PWD/css/view-source.css \
251     $$PWD/css/wml.css \
252     $$PWD/css/mediaControls.css \
253     $$PWD/css/mediaControlsQt.css \
254     $$PWD/css/themeQtNoListboxes.css \
255     $$PWD/css/themeQtMaemo5.css
256
257 IDL_BINDINGS += \
258     css/Counter.idl \
259     css/CSSCharsetRule.idl \
260     css/CSSFontFaceRule.idl \
261     css/CSSImportRule.idl \
262     css/CSSMediaRule.idl \
263     css/CSSPageRule.idl \
264     css/CSSPrimitiveValue.idl \
265     css/CSSRule.idl \
266     css/CSSRuleList.idl \
267     css/CSSStyleDeclaration.idl \
268     css/CSSStyleRule.idl \
269     css/CSSStyleSheet.idl \
270     css/CSSValue.idl \
271     css/CSSValueList.idl \
272     css/CSSVariablesDeclaration.idl \
273     css/CSSVariablesRule.idl \
274     css/MediaList.idl \
275     css/Rect.idl \
276     css/RGBColor.idl \
277     css/StyleMedia.idl \
278     css/StyleSheet.idl \
279     css/StyleSheetList.idl \
280     css/WebKitCSSKeyframeRule.idl \
281     css/WebKitCSSKeyframesRule.idl \
282     css/WebKitCSSMatrix.idl \
283     css/WebKitCSSTransformValue.idl \
284     dom/Attr.idl \
285     dom/BeforeLoadEvent.idl \
286     dom/BeforeProcessEvent.idl \
287     dom/CharacterData.idl \
288     dom/ClientRect.idl \
289     dom/ClientRectList.idl \
290     dom/Clipboard.idl \
291     dom/CDATASection.idl \
292     dom/Comment.idl \
293     dom/CompositionEvent.idl \
294     dom/CustomEvent.idl \
295     dom/DeviceOrientationEvent.idl \
296     dom/DocumentFragment.idl \
297     dom/Document.idl \
298     dom/DocumentType.idl \
299     dom/DOMCoreException.idl \
300     dom/DOMImplementation.idl \
301     dom/DOMStringList.idl \
302     dom/DOMStringMap.idl \
303     dom/Element.idl \
304     dom/Entity.idl \
305     dom/EntityReference.idl \
306     dom/ErrorEvent.idl \
307     dom/Event.idl \
308     dom/EventException.idl \
309 #    dom/EventListener.idl \
310 #    dom/EventTarget.idl \
311     dom/KeyboardEvent.idl \
312     dom/MouseEvent.idl \
313     dom/MessageChannel.idl \
314     dom/MessageEvent.idl \
315     dom/MessagePort.idl \
316     dom/MutationEvent.idl \
317     dom/NamedNodeMap.idl \
318     dom/Node.idl \
319     dom/NodeFilter.idl \
320     dom/NodeIterator.idl \
321     dom/NodeList.idl \
322     dom/Notation.idl \
323     dom/OverflowEvent.idl \
324     dom/PageTransitionEvent.idl \
325     dom/PopStateEvent.idl \
326     dom/ProcessingInstruction.idl \
327     dom/ProgressEvent.idl \
328     dom/RangeException.idl \
329     dom/Range.idl \
330     dom/Text.idl \
331     dom/TextEvent.idl \
332     dom/Touch.idl \
333     dom/TouchEvent.idl \
334     dom/TouchList.idl \
335     dom/TreeWalker.idl \
336     dom/UIEvent.idl \
337     dom/WebKitAnimationEvent.idl \
338     dom/WebKitTransitionEvent.idl \
339     dom/WheelEvent.idl \
340     html/Blob.idl \
341     html/BlobBuilder.idl \
342     html/canvas/ArrayBufferView.idl \
343     html/canvas/ArrayBuffer.idl \
344     html/canvas/Int8Array.idl \
345     html/canvas/Float32Array.idl \
346     html/canvas/CanvasGradient.idl \
347     html/canvas/Int32Array.idl \
348     html/canvas/CanvasPattern.idl \
349     html/canvas/CanvasRenderingContext.idl \
350     html/canvas/CanvasRenderingContext2D.idl \
351     html/canvas/WebGLActiveInfo.idl \
352     html/canvas/WebGLBuffer.idl \
353     html/canvas/WebGLContextAttributes.idl \
354     html/canvas/WebGLFramebuffer.idl \
355     html/canvas/WebGLProgram.idl \
356     html/canvas/WebGLRenderbuffer.idl \
357     html/canvas/WebGLRenderingContext.idl \
358     html/canvas/WebGLShader.idl \
359     html/canvas/Int16Array.idl \
360     html/canvas/WebGLTexture.idl \
361     html/canvas/WebGLUniformLocation.idl \
362     html/canvas/Uint8Array.idl \
363     html/canvas/Uint32Array.idl \
364     html/canvas/Uint16Array.idl \
365     html/DataGridColumn.idl \
366     html/DataGridColumnList.idl \
367     html/DOMFormData.idl \
368     html/File.idl \
369     html/FileError.idl \
370     html/FileList.idl \
371     html/FileReader.idl \
372     html/HTMLAllCollection.idl \
373     html/HTMLAudioElement.idl \
374     html/HTMLAnchorElement.idl \
375     html/HTMLAppletElement.idl \
376     html/HTMLAreaElement.idl \
377     html/HTMLBaseElement.idl \
378     html/HTMLBaseFontElement.idl \
379     html/HTMLBlockquoteElement.idl \
380     html/HTMLBodyElement.idl \
381     html/HTMLBRElement.idl \
382     html/HTMLButtonElement.idl \
383     html/HTMLCanvasElement.idl \
384     html/HTMLCollection.idl \
385     html/HTMLDataGridElement.idl \
386     html/HTMLDataGridCellElement.idl \
387     html/HTMLDataGridColElement.idl \
388     html/HTMLDataGridRowElement.idl \
389     html/HTMLDataListElement.idl \
390     html/HTMLDirectoryElement.idl \
391     html/HTMLDivElement.idl \
392     html/HTMLDListElement.idl \
393     html/HTMLDocument.idl \
394     html/HTMLElement.idl \
395     html/HTMLEmbedElement.idl \
396     html/HTMLFieldSetElement.idl \
397     html/HTMLFontElement.idl \
398     html/HTMLFormElement.idl \
399     html/HTMLFrameElement.idl \
400     html/HTMLFrameSetElement.idl \
401     html/HTMLHeadElement.idl \
402     html/HTMLHeadingElement.idl \
403     html/HTMLHRElement.idl \
404     html/HTMLHtmlElement.idl \
405     html/HTMLIFrameElement.idl \
406     html/HTMLImageElement.idl \
407     html/HTMLInputElement.idl \
408     html/HTMLIsIndexElement.idl \
409     html/HTMLLabelElement.idl \
410     html/HTMLLegendElement.idl \
411     html/HTMLLIElement.idl \
412     html/HTMLLinkElement.idl \
413     html/HTMLMapElement.idl \
414     html/HTMLMarqueeElement.idl \
415     html/HTMLMediaElement.idl \
416     html/HTMLMenuElement.idl \
417     html/HTMLMetaElement.idl \
418     html/HTMLMeterElement.idl \
419     html/HTMLModElement.idl \
420     html/HTMLObjectElement.idl \
421     html/HTMLOListElement.idl \
422     html/HTMLOptGroupElement.idl \
423     html/HTMLOptionElement.idl \
424     html/HTMLOptionsCollection.idl \
425     html/HTMLParagraphElement.idl \
426     html/HTMLParamElement.idl \
427     html/HTMLPreElement.idl \
428     html/HTMLProgressElement.idl \
429     html/HTMLQuoteElement.idl \
430     html/HTMLScriptElement.idl \
431     html/HTMLSelectElement.idl \
432     html/HTMLSourceElement.idl \
433     html/HTMLStyleElement.idl \
434     html/HTMLTableCaptionElement.idl \
435     html/HTMLTableCellElement.idl \
436     html/HTMLTableColElement.idl \
437     html/HTMLTableElement.idl \
438     html/HTMLTableRowElement.idl \
439     html/HTMLTableSectionElement.idl \
440     html/HTMLTextAreaElement.idl \
441     html/HTMLTitleElement.idl \
442     html/HTMLUListElement.idl \
443     html/HTMLVideoElement.idl \
444     html/ImageData.idl \
445     html/MediaError.idl \
446     html/TextMetrics.idl \
447     html/TimeRanges.idl \
448     html/ValidityState.idl \
449     html/VoidCallback.idl \
450     inspector/InjectedScriptHost.idl \
451     inspector/InspectorBackend.idl \
452     inspector/InspectorFrontendHost.idl \
453     inspector/JavaScriptCallFrame.idl \
454     inspector/ScriptProfile.idl \
455     inspector/ScriptProfileNode.idl \
456     loader/appcache/DOMApplicationCache.idl \
457     notifications/Notification.idl \
458     notifications/NotificationCenter.idl \
459     page/BarInfo.idl \
460     page/Console.idl \
461     page/Coordinates.idl \
462     page/DOMSelection.idl \
463     page/DOMWindow.idl \
464     page/EventSource.idl \
465     page/Geolocation.idl \
466     page/Geoposition.idl \
467     page/History.idl \
468     page/Location.idl \
469     page/MemoryInfo.idl \
470     page/Navigation.idl \
471     page/Navigator.idl \
472     page/Performance.idl \
473     page/PositionError.idl \
474     page/Screen.idl \
475     page/Timing.idl \
476     page/WebKitPoint.idl \
477     page/WorkerNavigator.idl \
478     plugins/DOMPlugin.idl \
479     plugins/DOMMimeType.idl \
480     plugins/DOMPluginArray.idl \
481     plugins/DOMMimeTypeArray.idl \
482     storage/Database.idl \
483     storage/DatabaseCallback.idl \
484     storage/DatabaseSync.idl \
485     storage/IDBAny.idl \
486     storage/IDBDatabaseError.idl \
487     storage/IDBDatabaseException.idl \
488     storage/IDBDatabaseRequest.idl \
489     storage/IDBErrorEvent.idl \
490     storage/IDBEvent.idl \
491     storage/IDBIndexRequest.idl \
492     storage/IDBKey.idl \
493     storage/IDBKeyRange.idl \
494     storage/IDBObjectStoreRequest.idl \
495     storage/IDBRequest.idl \
496     storage/IDBSuccessEvent.idl \
497     storage/IndexedDatabaseRequest.idl \
498     storage/Storage.idl \
499     storage/StorageEvent.idl \
500     storage/SQLError.idl \
501     storage/SQLException.idl \
502     storage/SQLResultSet.idl \
503     storage/SQLResultSetRowList.idl \
504     storage/SQLStatementCallback.idl \
505     storage/SQLStatementErrorCallback.idl \
506     storage/SQLTransaction.idl \
507     storage/SQLTransactionCallback.idl \
508     storage/SQLTransactionErrorCallback.idl \
509     storage/SQLTransactionSync.idl \
510     storage/SQLTransactionSyncCallback.idl \
511     svg/SVGZoomEvent.idl \
512     svg/SVGAElement.idl \
513     svg/SVGAltGlyphElement.idl \
514     svg/SVGAngle.idl \
515     svg/SVGAnimateColorElement.idl \
516     svg/SVGAnimatedAngle.idl \
517     svg/SVGAnimatedBoolean.idl \
518     svg/SVGAnimatedEnumeration.idl \
519     svg/SVGAnimatedInteger.idl \
520     svg/SVGAnimatedLength.idl \
521     svg/SVGAnimatedLengthList.idl \
522     svg/SVGAnimatedNumber.idl \
523     svg/SVGAnimatedNumberList.idl \
524     svg/SVGAnimatedPreserveAspectRatio.idl \
525     svg/SVGAnimatedRect.idl \
526     svg/SVGAnimatedString.idl \
527     svg/SVGAnimatedTransformList.idl \
528     svg/SVGAnimateElement.idl \
529     svg/SVGAnimateTransformElement.idl \
530     svg/SVGAnimationElement.idl \
531     svg/SVGCircleElement.idl \
532     svg/SVGClipPathElement.idl \
533     svg/SVGColor.idl \
534     svg/SVGComponentTransferFunctionElement.idl \
535     svg/SVGCursorElement.idl \
536     svg/SVGDefsElement.idl \
537     svg/SVGDescElement.idl \
538     svg/SVGDocument.idl \
539     svg/SVGElement.idl \
540     svg/SVGElementInstance.idl \
541     svg/SVGElementInstanceList.idl \
542     svg/SVGEllipseElement.idl \
543     svg/SVGException.idl \
544     svg/SVGFEBlendElement.idl \
545     svg/SVGFEColorMatrixElement.idl \
546     svg/SVGFEComponentTransferElement.idl \
547     svg/SVGFECompositeElement.idl \
548     svg/SVGFEConvolveMatrixElement.idl \
549     svg/SVGFEDiffuseLightingElement.idl \
550     svg/SVGFEDisplacementMapElement.idl \
551     svg/SVGFEDistantLightElement.idl \
552     svg/SVGFEFloodElement.idl \
553     svg/SVGFEFuncAElement.idl \
554     svg/SVGFEFuncBElement.idl \
555     svg/SVGFEFuncGElement.idl \
556     svg/SVGFEFuncRElement.idl \
557     svg/SVGFEGaussianBlurElement.idl \
558     svg/SVGFEImageElement.idl \
559     svg/SVGFEMergeElement.idl \
560     svg/SVGFEMergeNodeElement.idl \
561     svg/SVGFEMorphologyElement.idl \
562     svg/SVGFEOffsetElement.idl \
563     svg/SVGFEPointLightElement.idl \
564     svg/SVGFESpecularLightingElement.idl \
565     svg/SVGFESpotLightElement.idl \
566     svg/SVGFETileElement.idl \
567     svg/SVGFETurbulenceElement.idl \
568     svg/SVGFilterElement.idl \
569     svg/SVGFontElement.idl \
570     svg/SVGFontFaceElement.idl \
571     svg/SVGFontFaceFormatElement.idl \
572     svg/SVGFontFaceNameElement.idl \
573     svg/SVGFontFaceSrcElement.idl \
574     svg/SVGFontFaceUriElement.idl \
575     svg/SVGForeignObjectElement.idl \
576     svg/SVGGElement.idl \
577     svg/SVGGlyphElement.idl \
578     svg/SVGGradientElement.idl \
579     svg/SVGHKernElement.idl \
580     svg/SVGImageElement.idl \
581     svg/SVGLength.idl \
582     svg/SVGLengthList.idl \
583     svg/SVGLinearGradientElement.idl \
584     svg/SVGLineElement.idl \
585     svg/SVGMarkerElement.idl \
586     svg/SVGMaskElement.idl \
587     svg/SVGMatrix.idl \
588     svg/SVGMetadataElement.idl \
589     svg/SVGMissingGlyphElement.idl \
590     svg/SVGNumber.idl \
591     svg/SVGNumberList.idl \
592     svg/SVGPaint.idl \
593     svg/SVGPathElement.idl \
594     svg/SVGPathSegArcAbs.idl \
595     svg/SVGPathSegArcRel.idl \
596     svg/SVGPathSegClosePath.idl \
597     svg/SVGPathSegCurvetoCubicAbs.idl \
598     svg/SVGPathSegCurvetoCubicRel.idl \
599     svg/SVGPathSegCurvetoCubicSmoothAbs.idl \
600     svg/SVGPathSegCurvetoCubicSmoothRel.idl \
601     svg/SVGPathSegCurvetoQuadraticAbs.idl \
602     svg/SVGPathSegCurvetoQuadraticRel.idl \
603     svg/SVGPathSegCurvetoQuadraticSmoothAbs.idl \
604     svg/SVGPathSegCurvetoQuadraticSmoothRel.idl \
605     svg/SVGPathSeg.idl \
606     svg/SVGPathSegLinetoAbs.idl \
607     svg/SVGPathSegLinetoHorizontalAbs.idl \
608     svg/SVGPathSegLinetoHorizontalRel.idl \
609     svg/SVGPathSegLinetoRel.idl \
610     svg/SVGPathSegLinetoVerticalAbs.idl \
611     svg/SVGPathSegLinetoVerticalRel.idl \
612     svg/SVGPathSegList.idl \
613     svg/SVGPathSegMovetoAbs.idl \
614     svg/SVGPathSegMovetoRel.idl \
615     svg/SVGPatternElement.idl \
616     svg/SVGPoint.idl \
617     svg/SVGPointList.idl \
618     svg/SVGPolygonElement.idl \
619     svg/SVGPolylineElement.idl \
620     svg/SVGPreserveAspectRatio.idl \
621     svg/SVGRadialGradientElement.idl \
622     svg/SVGRectElement.idl \
623     svg/SVGRect.idl \
624     svg/SVGRenderingIntent.idl \
625     svg/SVGScriptElement.idl \
626     svg/SVGSetElement.idl \
627     svg/SVGStopElement.idl \
628     svg/SVGStringList.idl \
629     svg/SVGStyleElement.idl \
630     svg/SVGSVGElement.idl \
631     svg/SVGSwitchElement.idl \
632     svg/SVGSymbolElement.idl \
633     svg/SVGTextContentElement.idl \
634     svg/SVGTextElement.idl \
635     svg/SVGTextPathElement.idl \
636     svg/SVGTextPositioningElement.idl \
637     svg/SVGTitleElement.idl \
638     svg/SVGTransform.idl \
639     svg/SVGTransformList.idl \
640     svg/SVGTRefElement.idl \
641     svg/SVGTSpanElement.idl \
642     svg/SVGUnitTypes.idl \
643     svg/SVGUseElement.idl \
644     svg/SVGViewElement.idl \
645     svg/SVGVKernElement.idl \
646     websockets/WebSocket.idl \
647     workers/AbstractWorker.idl \
648     workers/DedicatedWorkerContext.idl \
649     workers/SharedWorker.idl \
650     workers/SharedWorkerContext.idl \
651     workers/Worker.idl \
652     workers/WorkerContext.idl \
653     workers/WorkerLocation.idl \
654     xml/DOMParser.idl \
655     xml/XMLHttpRequest.idl \
656     xml/XMLHttpRequestException.idl \
657     xml/XMLHttpRequestProgressEvent.idl \
658     xml/XMLHttpRequestUpload.idl \
659     xml/XMLSerializer.idl \
660     xml/XPathNSResolver.idl \
661     xml/XPathException.idl \
662     xml/XPathExpression.idl \
663     xml/XPathResult.idl \
664     xml/XPathEvaluator.idl \
665     xml/XSLTProcessor.idl
666
667 INSPECTOR_INTERFACES = inspector/Inspector.idl
668
669 mathmlnames.output = $${WC_GENERATED_SOURCES_DIR}/MathMLNames.cpp
670 mathmlnames.input = MATHML_NAMES
671 mathmlnames.wkScript = $$PWD/dom/make_names.pl
672 mathmlnames.commands = perl -I$$PWD/bindings/scripts $$mathmlnames.wkScript --tags $$PWD/mathml/mathtags.in --attrs $$PWD/mathml/mathattrs.in --extraDefines \"$${DEFINES}\" --preprocessor \"$${QMAKE_MOC} -E\" --factory --wrapperFactory --outputDir $$WC_GENERATED_SOURCES_DIR
673 mathmlnames.wkExtraSources = $${WC_GENERATED_SOURCES_DIR}/MathMLElementFactory.cpp 
674 addExtraCompiler(mathmlnames)
675
676 contains(DEFINES, ENABLE_WML=1) {
677     wmlnames.output = $${WC_GENERATED_SOURCES_DIR}/WMLNames.cpp
678     wmlnames.input = WML_NAMES
679     wmlnames.wkScript = $$PWD/dom/make_names.pl
680     wmlnames.commands = perl -I$$PWD/bindings/scripts $$wmlnames.wkScript --tags $$PWD/wml/WMLTagNames.in --attrs $$PWD/wml/WMLAttributeNames.in --extraDefines \"$${DEFINES}\" --preprocessor \"$${QMAKE_MOC} -E\" --factory --wrapperFactory --outputDir $$WC_GENERATED_SOURCES_DIR
681     wmlnames.wkExtraSources = $${WC_GENERATED_SOURCES_DIR}/WMLElementFactory.cpp
682     addExtraCompiler(wmlnames)
683 }
684
685 # GENERATOR 5-C:
686 svgnames.output = $${WC_GENERATED_SOURCES_DIR}/SVGNames.cpp
687 svgnames.input = SVG_NAMES
688 svgnames.depends = $$PWD/svg/svgattrs.in
689 svgnames.wkScript = $$PWD/dom/make_names.pl
690 svgnames.commands = perl -I$$PWD/bindings/scripts $$svgnames.wkScript --tags $$PWD/svg/svgtags.in --attrs $$PWD/svg/svgattrs.in --extraDefines \"$${DEFINES}\" --preprocessor \"$${QMAKE_MOC} -E\" --factory --wrapperFactory --outputDir $$WC_GENERATED_SOURCES_DIR
691 svgnames.wkExtraSources = $${WC_GENERATED_SOURCES_DIR}/SVGElementFactory.cpp $${WC_GENERATED_SOURCES_DIR}/JSSVGElementWrapperFactory.cpp
692 addExtraCompiler(svgnames)
693
694 # GENERATOR 5-D:
695 xlinknames.output = $${WC_GENERATED_SOURCES_DIR}/XLinkNames.cpp
696 xlinknames.wkScript = $$PWD/dom/make_names.pl
697 xlinknames.commands = perl -I$$PWD/bindings/scripts $$xlinknames.wkScript --attrs $$PWD/svg/xlinkattrs.in --preprocessor \"$${QMAKE_MOC} -E\" --outputDir $$WC_GENERATED_SOURCES_DIR
698 xlinknames.input = XLINK_NAMES
699 addExtraCompiler(xlinknames)
700
701 # GENERATOR 6-A:
702 cssprops.wkScript = $$PWD/css/makeprop.pl
703 cssprops.output = $${WC_GENERATED_SOURCES_DIR}/CSSPropertyNames.cpp
704 cssprops.input = WALDOCSSPROPS
705 cssprops.commands = perl -ne \"print lc\" ${QMAKE_FILE_NAME} $${DASHBOARDSUPPORTCSSPROPERTIES} $${EXTRACSSPROPERTIES} > $${WC_GENERATED_SOURCES_DIR}/${QMAKE_FILE_BASE}.in && cd $$WC_GENERATED_SOURCES_DIR && perl $$cssprops.wkScript && $(DEL_FILE) ${QMAKE_FILE_BASE}.in ${QMAKE_FILE_BASE}.gperf
706 cssprops.depends = ${QMAKE_FILE_NAME} $${DASHBOARDSUPPORTCSSPROPERTIES} $${EXTRACSSPROPERTIES}
707 addExtraCompiler(cssprops)
708
709 # GENERATOR 6-B:
710 cssvalues.wkScript = $$PWD/css/makevalues.pl
711 cssvalues.output = $${WC_GENERATED_SOURCES_DIR}/CSSValueKeywords.cpp
712 cssvalues.input = WALDOCSSVALUES
713 cssvalues.commands = perl -ne \"print lc\" ${QMAKE_FILE_NAME} $$EXTRACSSVALUES > $${WC_GENERATED_SOURCES_DIR}/${QMAKE_FILE_BASE}.in && cd $$WC_GENERATED_SOURCES_DIR && perl $$cssvalues.wkScript && $(DEL_FILE) ${QMAKE_FILE_BASE}.in ${QMAKE_FILE_BASE}.gperf
714 cssvalues.depends = ${QMAKE_FILE_NAME} $${EXTRACSSVALUES}
715 cssvalues.clean = ${QMAKE_FILE_OUT} ${QMAKE_VAR_WC_GENERATED_SOURCES_DIR}/${QMAKE_FILE_BASE}.h
716 addExtraCompiler(cssvalues)
717
718 # GENERATOR 1: IDL compiler
719 idl.output = $${WC_GENERATED_SOURCES_DIR}/JS${QMAKE_FILE_BASE}.cpp
720 idl.input = IDL_BINDINGS
721 idl.wkScript = $$PWD/bindings/scripts/generate-bindings.pl
722 idl.commands = perl -I$$PWD/bindings/scripts $$idl.wkScript --defines \"$${FEATURE_DEFINES_JAVASCRIPT}\" --generator JS --include $$PWD/dom --include $$PWD/html --include $$PWD/xml --include $$PWD/svg --outputDir $$WC_GENERATED_SOURCES_DIR --preprocessor \"$${QMAKE_MOC} -E\" ${QMAKE_FILE_NAME}
723 idl.depends = $$PWD/bindings/scripts/CodeGenerator.pm \
724               $$PWD/bindings/scripts/CodeGeneratorJS.pm \
725               $$PWD/bindings/scripts/IDLParser.pm \
726               $$PWD/bindings/scripts/IDLStructure.pm \
727               $$PWD/bindings/scripts/InFilesParser.pm
728 addExtraCompiler(idl)
729
730 # GENERATOR 2: inspector idl compiler
731 inspectorIDL.output = $${WC_GENERATED_SOURCES_DIR}/Remote${QMAKE_FILE_BASE}Frontend.cpp
732 inspectorIDL.input = INSPECTOR_INTERFACES
733 inspectorIDL.wkScript = $$PWD/bindings/scripts/generate-bindings.pl
734 inspectorIDL.commands = perl -I$$PWD/bindings/scripts -I$$PWD/inspector $$inspectorIDL.wkScript --defines \"$${FEATURE_DEFINES_JAVASCRIPT}\" --generator Inspector --outputDir $$WC_GENERATED_SOURCES_DIR --preprocessor \"$${QMAKE_MOC} -E\" ${QMAKE_FILE_NAME}
735 inspectorIDL.depends = $$PWD/bindings/scripts/CodeGenerator.pm \
736               $$PWD/inspector/CodeGeneratorInspector.pm \
737               $$PWD/bindings/scripts/IDLParser.pm \
738               $$PWD/bindings/scripts/IDLStructure.pm \
739               $$PWD/bindings/scripts/InFilesParser.pm
740 addExtraCompiler(inspectorIDL)
741
742 # GENERATOR 3: tokenizer (flex)
743 tokenizer.output = $${WC_GENERATED_SOURCES_DIR}/${QMAKE_FILE_BASE}.cpp
744 tokenizer.input = TOKENIZER
745 tokenizer.wkScript = $$PWD/css/maketokenizer
746 tokenizer.commands = flex -t < ${QMAKE_FILE_NAME} | perl $$tokenizer.wkScript > ${QMAKE_FILE_OUT}
747 addExtraCompiler(tokenizer)
748
749 # GENERATOR 4: CSS grammar
750 cssbison.output = $${WC_GENERATED_SOURCES_DIR}/${QMAKE_FILE_BASE}.cpp
751 cssbison.input = CSSBISON
752 cssbison.wkScript = $$PWD/css/makegrammar.pl
753 cssbison.commands = perl $$cssbison.wkScript ${QMAKE_FILE_NAME} $${WC_GENERATED_SOURCES_DIR}/${QMAKE_FILE_BASE}
754 cssbison.depends = ${QMAKE_FILE_NAME}
755 addExtraCompiler(cssbison)
756
757 # GENERATOR 5-A:
758 htmlnames.output = $${WC_GENERATED_SOURCES_DIR}/HTMLNames.cpp
759 htmlnames.input = HTML_NAMES
760 htmlnames.wkScript = $$PWD/dom/make_names.pl
761 htmlnames.commands = perl -I$$PWD/bindings/scripts $$htmlnames.wkScript --tags $$PWD/html/HTMLTagNames.in --attrs $$PWD/html/HTMLAttributeNames.in --extraDefines \"$${DEFINES}\" --preprocessor \"$${QMAKE_MOC} -E\"  --factory --wrapperFactory --outputDir $$WC_GENERATED_SOURCES_DIR
762 htmlnames.depends = $$PWD/html/HTMLAttributeNames.in
763 htmlnames.wkExtraSources = $${WC_GENERATED_SOURCES_DIR}/HTMLElementFactory.cpp $${WC_GENERATED_SOURCES_DIR}/JSHTMLElementWrapperFactory.cpp
764 addExtraCompiler(htmlnames)
765
766 # GENERATOR 5-B:
767 xmlnsnames.output = $${WC_GENERATED_SOURCES_DIR}/XMLNSNames.cpp
768 xmlnsnames.input = XMLNS_NAMES
769 xmlnsnames.wkScript = $$PWD/dom/make_names.pl
770 xmlnsnames.commands = perl -I$$PWD/bindings/scripts $$xmlnsnames.wkScript --attrs $$PWD/xml/xmlnsattrs.in --preprocessor \"$${QMAKE_MOC} -E\" --outputDir $$WC_GENERATED_SOURCES_DIR
771 addExtraCompiler(xmlnsnames)
772
773 # GENERATOR 5-C:
774 xmlnames.output = $${WC_GENERATED_SOURCES_DIR}/XMLNames.cpp
775 xmlnames.input = XML_NAMES
776 xmlnames.wkScript = $$PWD/dom/make_names.pl
777 xmlnames.commands = perl -I$$PWD/bindings/scripts $$xmlnames.wkScript --attrs $$PWD/xml/xmlattrs.in --preprocessor \"$${QMAKE_MOC} -E\" --outputDir $$WC_GENERATED_SOURCES_DIR
778 addExtraCompiler(xmlnames)
779
780 # GENERATOR 8-A:
781 entities.output = $${WC_GENERATED_SOURCES_DIR}/HTMLEntityNames.cpp
782 entities.input = ENTITIES_GPERF
783 entities.wkScript = $$PWD/make-hash-tools.pl
784 entities.commands = perl $$entities.wkScript $${WC_GENERATED_SOURCES_DIR} $$ENTITIES_GPERF
785 entities.clean = ${QMAKE_FILE_OUT}
786 entities.depends = $$PWD/make-hash-tools.pl
787 addExtraCompiler(entities)
788
789 # GENERATOR 8-B:
790 doctypestrings.output = $${WC_GENERATED_SOURCES_DIR}/DocTypeStrings.cpp
791 doctypestrings.input = DOCTYPESTRINGS_GPERF
792 doctypestrings.wkScript = $$PWD/make-hash-tools.pl
793 doctypestrings.commands = perl $$doctypestrings.wkScript $${WC_GENERATED_SOURCES_DIR} $$DOCTYPESTRINGS_GPERF
794 doctypestrings.clean = ${QMAKE_FILE_OUT}
795 doctypestrings.depends = $$PWD/make-hash-tools.pl
796 addExtraCompiler(doctypestrings)
797
798 # GENERATOR 8-C:
799 colordata.output = $${WC_GENERATED_SOURCES_DIR}/ColorData.cpp
800 colordata.input = COLORDATA_GPERF
801 colordata.wkScript = $$PWD/make-hash-tools.pl
802 colordata.commands = perl $$colordata.wkScript $${WC_GENERATED_SOURCES_DIR} $$COLORDATA_GPERF
803 colordata.clean = ${QMAKE_FILE_OUT}
804 colordata.depends = $$PWD/make-hash-tools.pl
805 addExtraCompiler(colordata)
806
807 # GENERATOR 9:
808 stylesheets.wkScript = $$PWD/css/make-css-file-arrays.pl
809 stylesheets.output = $${WC_GENERATED_SOURCES_DIR}/UserAgentStyleSheetsData.cpp
810 stylesheets.input = stylesheets.wkScript
811 stylesheets.commands = perl $$stylesheets.wkScript $${WC_GENERATED_SOURCES_DIR}/UserAgentStyleSheets.h ${QMAKE_FILE_OUT} $$STYLESHEETS_EMBED
812 stylesheets.depends = $$STYLESHEETS_EMBED
813 stylesheets.clean = ${QMAKE_FILE_OUT} ${QMAKE_VAR_WC_GENERATED_SOURCES_DIR}/UserAgentStyleSheets.h
814 addExtraCompiler(stylesheets, $${WC_GENERATED_SOURCES_DIR}/UserAgentStyleSheets.h)
815
816 # GENERATOR 10: XPATH grammar
817 xpathbison.output = $${WC_GENERATED_SOURCES_DIR}/${QMAKE_FILE_BASE}.cpp
818 xpathbison.input = XPATHBISON
819 xpathbison.commands = bison -d -p xpathyy ${QMAKE_FILE_NAME} -o $${WC_GENERATED_SOURCES_DIR}/${QMAKE_FILE_BASE}.tab.c && $(MOVE) $${WC_GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.tab.c $${WC_GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.cpp && $(MOVE) $${WC_GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.tab.h $${WC_GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.h
820 xpathbison.depends = ${QMAKE_FILE_NAME}
821 addExtraCompiler(xpathbison)
822
823 # GENERATOR 11: WebKit Version
824 # The appropriate Apple-maintained Version.xcconfig file for WebKit version information is in WebKit/mac/Configurations/.
825 webkitversion.wkScript = $$PWD/../WebKit/scripts/generate-webkitversion.pl
826 webkitversion.output = $${WC_GENERATED_SOURCES_DIR}/WebKitVersion.h
827 webkitversion.input = webkitversion.wkScript
828 webkitversion.commands = perl $$webkitversion.wkScript --config $$PWD/../WebKit/mac/Configurations/Version.xcconfig --outputDir $${WC_GENERATED_SOURCES_DIR}/
829 webkitversion.clean = ${QMAKE_VAR_WC_GENERATED_SOURCES_DIR}/WebKitVersion.h
830 webkitversion.wkAddOutputToSources = false
831 addExtraCompiler(webkitversion)
832