[iOS] Support TestWebKitAPI in the iOS Simulator
[WebKit-https.git] / Tools / Scripts / webkitdirs.pm
1 # Copyright (C) 2005, 2006, 2007, 2010, 2011, 2012, 2013 Apple Inc. All rights reserved.
2 # Copyright (C) 2009 Google Inc. All rights reserved.
3 # Copyright (C) 2011 Research In Motion Limited. All rights reserved.
4 # Copyright (C) 2013 Nokia Corporation and/or its subsidiary(-ies).
5 #
6 # Redistribution and use in source and binary forms, with or without
7 # modification, are permitted provided that the following conditions
8 # are met:
9 #
10 # 1.  Redistributions of source code must retain the above copyright
11 #     notice, this list of conditions and the following disclaimer. 
12 # 2.  Redistributions in binary form must reproduce the above copyright
13 #     notice, this list of conditions and the following disclaimer in the
14 #     documentation and/or other materials provided with the distribution. 
15 # 3.  Neither the name of Apple Inc. ("Apple") nor the names of
16 #     its contributors may be used to endorse or promote products derived
17 #     from this software without specific prior written permission. 
18 #
19 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
20 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
21 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
22 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
23 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
24 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
25 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
26 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29
30 # Module to share code to get to WebKit directories.
31
32 use strict;
33 use version;
34 use warnings;
35 use Config;
36 use Digest::MD5 qw(md5_hex);
37 use FindBin;
38 use File::Basename;
39 use File::Path qw(mkpath rmtree);
40 use File::Spec;
41 use File::stat;
42 use POSIX;
43 use VCSUtils;
44
45 BEGIN {
46    use Exporter   ();
47    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
48    $VERSION     = 1.00;
49    @ISA         = qw(Exporter);
50    @EXPORT      = qw(
51        &XcodeOptionString
52        &XcodeOptionStringNoConfig
53        &XcodeOptions
54        &baseProductDir
55        &chdirWebKit
56        &checkFrameworks
57        &cmakeBasedPortArguments
58        &cmakeBasedPortName
59        &currentSVNRevision
60        &debugSafari
61        &nmPath
62        &passedConfiguration
63        &printHelpAndExitForRunAndDebugWebKitAppIfNeeded
64        &productDir
65        &runMacWebKitApp
66        &safariPath
67        &setConfiguration
68        USE_OPEN_COMMAND
69    );
70    %EXPORT_TAGS = ( );
71    @EXPORT_OK   = ();
72 }
73
74 use constant USE_OPEN_COMMAND => 1; # Used in runMacWebKitApp().
75 use constant INCLUDE_OPTIONS_FOR_DEBUGGING => 1;
76
77 our @EXPORT_OK;
78
79 my $architecture;
80 my $numberOfCPUs;
81 my $maxCPULoad;
82 my $baseProductDir;
83 my @baseProductDirOption;
84 my $configuration;
85 my $xcodeSDK;
86 my $configurationForVisualStudio;
87 my $configurationProductDir;
88 my $sourceDir;
89 my $currentSVNRevision;
90 my $debugger;
91 my $iPhoneSimulatorVersion;
92 my $nmPath;
93 my $osXVersion;
94 my $generateDsym;
95 my $isGtk;
96 my $isWinCE;
97 my $isWinCairo;
98 my $isWin64;
99 my $isEfl;
100 my $isInspectorFrontend;
101 my $isWK2;
102 my $shouldTargetWebProcess;
103 my $shouldUseXPCServiceForWebProcess;
104 my $shouldUseGuardMalloc;
105 my $xcodeVersion;
106
107 # Variables for Win32 support
108 my $programFilesPath;
109 my $vcBuildPath;
110 my $vsInstallDir;
111 my $vsVersion;
112 my $windowsSourceDir;
113 my $winVersion;
114 my $willUseVCExpressWhenBuilding = 0;
115
116 # Defined in VCSUtils.
117 sub exitStatus($);
118
119 sub findMatchingArguments($$);
120 sub hasArgument($$);
121
122 sub determineSourceDir
123 {
124     return if $sourceDir;
125     $sourceDir = $FindBin::Bin;
126     $sourceDir =~ s|/+$||; # Remove trailing '/' as we would die later
127
128     # walks up path checking each directory to see if it is the main WebKit project dir, 
129     # defined by containing Sources, WebCore, and WebKit
130     until ((-d "$sourceDir/Source" && -d "$sourceDir/Source/WebCore" && -d "$sourceDir/Source/WebKit") || (-d "$sourceDir/Internal" && -d "$sourceDir/OpenSource"))
131     {
132         if ($sourceDir !~ s|/[^/]+$||) {
133             die "Could not find top level webkit directory above source directory using FindBin.\n";
134         }
135     }
136
137     $sourceDir = "$sourceDir/OpenSource" if -d "$sourceDir/OpenSource";
138 }
139
140 sub currentPerlPath()
141 {
142     my $thisPerl = $^X;
143     if ($^O ne 'VMS') {
144         $thisPerl .= $Config{_exe} unless $thisPerl =~ m/$Config{_exe}$/i;
145     }
146     return $thisPerl;
147 }
148
149 # used for scripts which are stored in a non-standard location
150 sub setSourceDir($)
151 {
152     ($sourceDir) = @_;
153 }
154
155 sub determineXcodeVersion
156 {
157     return if defined $xcodeVersion;
158     my $xcodebuildVersionOutput = `xcodebuild -version`;
159     $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : "3.0";
160 }
161
162 sub readXcodeUserDefault($)
163 {
164     my ($unprefixedKey) = @_;
165
166     determineXcodeVersion();
167
168     my $xcodeDefaultsDomain = (eval "v$xcodeVersion" lt v4) ? "com.apple.Xcode" : "com.apple.dt.Xcode";
169     my $xcodeDefaultsPrefix = (eval "v$xcodeVersion" lt v4) ? "PBX" : "IDE";
170     my $devnull = File::Spec->devnull();
171
172     my $value = `defaults read $xcodeDefaultsDomain ${xcodeDefaultsPrefix}${unprefixedKey} 2> ${devnull}`;
173     return if $?;
174
175     chomp $value;
176     return $value;
177 }
178
179 sub determineBaseProductDir
180 {
181     return if defined $baseProductDir;
182     determineSourceDir();
183
184     my $setSharedPrecompsDir;
185     $baseProductDir = $ENV{"WEBKIT_OUTPUTDIR"};
186
187     if (!defined($baseProductDir) and isAppleMacWebKit()) {
188         # Silently remove ~/Library/Preferences/xcodebuild.plist which can
189         # cause build failure. The presence of
190         # ~/Library/Preferences/xcodebuild.plist can prevent xcodebuild from
191         # respecting global settings such as a custom build products directory
192         # (<rdar://problem/5585899>).
193         my $personalPlistFile = $ENV{HOME} . "/Library/Preferences/xcodebuild.plist";
194         if (-e $personalPlistFile) {
195             unlink($personalPlistFile) || die "Could not delete $personalPlistFile: $!";
196         }
197
198         determineXcodeVersion();
199
200         if (eval "v$xcodeVersion" ge v4) {
201             my $buildLocationStyle = join '', readXcodeUserDefault("BuildLocationStyle");
202             if ($buildLocationStyle eq "Custom") {
203                 my $buildLocationType = join '', readXcodeUserDefault("CustomBuildLocationType");
204                 # FIXME: Read CustomBuildIntermediatesPath and set OBJROOT accordingly.
205                 $baseProductDir = readXcodeUserDefault("CustomBuildProductsPath") if $buildLocationType eq "Absolute";
206             }
207
208             # DeterminedByTargets corresponds to a setting of "Legacy" in Xcode.
209             # It is the only build location style for which SHARED_PRECOMPS_DIR is not
210             # overridden when building from within Xcode.
211             $setSharedPrecompsDir = 1 if $buildLocationStyle ne "DeterminedByTargets";
212         }
213
214         if (!defined($baseProductDir)) {
215             $baseProductDir = join '', readXcodeUserDefault("ApplicationwideBuildSettings");
216             $baseProductDir = $1 if $baseProductDir =~ /SYMROOT\s*=\s*\"(.*?)\";/s;
217         }
218
219         undef $baseProductDir unless $baseProductDir =~ /^\//;
220     }
221
222     if (!defined($baseProductDir)) { # Port-specific checks failed, use default
223         $baseProductDir = "$sourceDir/WebKitBuild";
224     }
225
226     if (isGit() && isGitBranchBuild()) {
227         my $branch = gitBranch();
228         $baseProductDir = "$baseProductDir/$branch";
229     }
230
231     if (isAppleMacWebKit()) {
232         $baseProductDir =~ s|^\Q$(SRCROOT)/..\E$|$sourceDir|;
233         $baseProductDir =~ s|^\Q$(SRCROOT)/../|$sourceDir/|;
234         $baseProductDir =~ s|^~/|$ENV{HOME}/|;
235         die "Can't handle Xcode product directory with a ~ in it.\n" if $baseProductDir =~ /~/;
236         die "Can't handle Xcode product directory with a variable in it.\n" if $baseProductDir =~ /\$/;
237         @baseProductDirOption = ("SYMROOT=$baseProductDir", "OBJROOT=$baseProductDir");
238         push(@baseProductDirOption, "SHARED_PRECOMPS_DIR=${baseProductDir}/PrecompiledHeaders") if $setSharedPrecompsDir;
239     }
240
241     if (isCygwin()) {
242         my $dosBuildPath = `cygpath --windows \"$baseProductDir\"`;
243         chomp $dosBuildPath;
244         $ENV{"WEBKIT_OUTPUTDIR"} = $dosBuildPath;
245         my $unixBuildPath = `cygpath --unix \"$baseProductDir\"`;
246         chomp $unixBuildPath;
247         $baseProductDir = $unixBuildPath;
248     }
249 }
250
251 sub setBaseProductDir($)
252 {
253     ($baseProductDir) = @_;
254 }
255
256 sub determineConfiguration
257 {
258     return if defined $configuration;
259     determineBaseProductDir();
260     if (open CONFIGURATION, "$baseProductDir/Configuration") {
261         $configuration = <CONFIGURATION>;
262         close CONFIGURATION;
263     }
264     if ($configuration) {
265         chomp $configuration;
266         # compatibility for people who have old Configuration files
267         $configuration = "Release" if $configuration eq "Deployment";
268         $configuration = "Debug" if $configuration eq "Development";
269     } else {
270         $configuration = "Release";
271     }
272
273     if ($configuration && isWinCairo()) {
274         unless ($configuration =~ /_WinCairo$/) {
275             $configuration .= "_WinCairo";
276         }
277     }
278 }
279
280 sub determineArchitecture
281 {
282     return if defined $architecture;
283     # make sure $architecture is defined in all cases
284     $architecture = "";
285
286     determineBaseProductDir();
287     determineXcodeSDK();
288
289     if (isAppleMacWebKit()) {
290         if (open ARCHITECTURE, "$baseProductDir/Architecture") {
291             $architecture = <ARCHITECTURE>;
292             close ARCHITECTURE;
293         }
294         if ($architecture) {
295             chomp $architecture;
296         } else {
297             if (not defined $xcodeSDK or $xcodeSDK =~ /^(\/$|macosx)/) {
298                 my $supports64Bit = `sysctl -n hw.optional.x86_64`;
299                 chomp $supports64Bit;
300                 $architecture = 'x86_64' if $supports64Bit;
301             } elsif ($xcodeSDK =~ /^iphonesimulator/) {
302                 $architecture = 'x86_64';
303             } elsif ($xcodeSDK =~ /^iphoneos/) {
304                 $architecture = 'armv7';
305             }
306         }
307     } elsif (isEfl() || isGtk()) {
308         my $host_processor = "";
309         $host_processor = `cmake --system-information | grep CMAKE_SYSTEM_PROCESSOR`;
310         if ($host_processor =~ m/^CMAKE_SYSTEM_PROCESSOR \"([^"]+)\"/) {
311             # We have a configured build tree; use it.
312             $architecture = $1;
313             $architecture = 'x86_64' if $architecture eq 'amd64';
314         }
315     }
316
317     if (!$architecture && (isGtk() || isAppleMacWebKit() || isEfl())) {
318         # Fall back to output of `arch', if it is present.
319         $architecture = `arch`;
320         chomp $architecture;
321     }
322
323     if (!$architecture && (isGtk() || isAppleMacWebKit() || isEfl())) {
324         # Fall back to output of `uname -m', if it is present.
325         $architecture = `uname -m`;
326         chomp $architecture;
327     }
328
329     $architecture = 'x86_64' if ($architecture =~ /amd64/ && isBSD());
330 }
331
332 sub determineNumberOfCPUs
333 {
334     return if defined $numberOfCPUs;
335     if (defined($ENV{NUMBER_OF_PROCESSORS})) {
336         $numberOfCPUs = $ENV{NUMBER_OF_PROCESSORS};
337     } elsif (isLinux()) {
338         # First try the nproc utility, if it exists. If we get no
339         # results fall back to just interpretting /proc directly.
340         chomp($numberOfCPUs = `nproc --all 2> /dev/null`);
341         if ($numberOfCPUs eq "") {
342             $numberOfCPUs = (grep /processor/, `cat /proc/cpuinfo`);
343         }
344     } elsif (isWindows() || isCygwin()) {
345         # Assumes cygwin
346         $numberOfCPUs = `ls /proc/registry/HKEY_LOCAL_MACHINE/HARDWARE/DESCRIPTION/System/CentralProcessor | wc -w`;
347     } elsif (isDarwin() || isBSD()) {
348         chomp($numberOfCPUs = `sysctl -n hw.ncpu`);
349     }
350 }
351
352 sub determineMaxCPULoad
353 {
354     return if defined $maxCPULoad;
355     if (defined($ENV{MAX_CPU_LOAD})) {
356         $maxCPULoad = $ENV{MAX_CPU_LOAD};
357     }
358 }
359
360 sub jscPath($)
361 {
362     my ($productDir) = @_;
363     my $jscName = "jsc";
364     $jscName .= "_debug"  if configuration() eq "Debug_All";
365     $jscName .= ".exe" if (isWindows() || isCygwin());
366     return "$productDir/$jscName" if -e "$productDir/$jscName";
367     return "$productDir/JavaScriptCore.framework/Resources/$jscName";
368 }
369
370 sub argumentsForConfiguration()
371 {
372     determineConfiguration();
373     determineArchitecture();
374     determineXcodeSDK();
375
376     my @args = ();
377     push(@args, '--debug') if ($configuration =~ "^Debug");
378     push(@args, '--release') if ($configuration =~ "^Release");
379     push(@args, '--device') if ($xcodeSDK =~ /^iphoneos/);
380     push(@args, '--sim') if ($xcodeSDK =~ /^iphonesimulator/);
381     push(@args, '--32-bit') if ($architecture ne "x86_64" and !isWin64());
382     push(@args, '--64-bit') if (isWin64());
383     push(@args, '--gtk') if isGtk();
384     push(@args, '--efl') if isEfl();
385     push(@args, '--wincairo') if isWinCairo();
386     push(@args, '--wince') if isWinCE();
387     push(@args, '--inspector-frontend') if isInspectorFrontend();
388     return @args;
389 }
390
391 sub determineXcodeSDK
392 {
393     return if defined $xcodeSDK;
394     my $sdk;
395     if (checkForArgumentAndRemoveFromARGVGettingValue("--sdk", \$sdk)) {
396         $xcodeSDK = $sdk;
397     } elsif (checkForArgumentAndRemoveFromARGV("--device")) {
398         $xcodeSDK = 'iphoneos.internal';
399     } elsif (checkForArgumentAndRemoveFromARGV("--sim") ||
400         checkForArgumentAndRemoveFromARGV("--simulator")) {
401         $xcodeSDK = 'iphonesimulator';
402     }
403 }
404
405 sub xcodeSDK
406 {
407     determineXcodeSDK();
408     return $xcodeSDK;
409 }
410
411 sub xcodeSDKPlatformName()
412 {
413     determineXcodeSDK();
414     return "" if !defined $xcodeSDK;
415     return "iphoneos" if $xcodeSDK =~ /iphoneos/i;
416     return "iphonesimulator" if $xcodeSDK =~ /iphonesimulator/i;
417     return "macosx" if $xcodeSDK =~ /macosx/i;
418     die "Couldn't determine platform name from Xcode SDK";
419 }
420
421 sub XcodeSDKPath
422 {
423     determineXcodeSDK();
424
425     die "Can't find the SDK path because no Xcode SDK was specified" if not $xcodeSDK;
426
427     my $sdkPath = `xcrun --sdk $xcodeSDK --show-sdk-path` if $xcodeSDK;
428     die 'Failed to get SDK path from xcrun' if $?;
429     chomp $sdkPath;
430
431     return $sdkPath;
432 }
433
434
435 sub programFilesPath
436 {
437     return $programFilesPath if defined $programFilesPath;
438
439     $programFilesPath = $ENV{'PROGRAMFILES(X86)'} || $ENV{'PROGRAMFILES'} || "C:\\Program Files";
440
441     return $programFilesPath;
442 }
443
444 sub visualStudioInstallDir
445 {
446     return $vsInstallDir if defined $vsInstallDir;
447
448     if ($ENV{'VSINSTALLDIR'}) {
449         $vsInstallDir = $ENV{'VSINSTALLDIR'};
450         $vsInstallDir =~ s|[\\/]$||;
451     } else {
452         $vsInstallDir = File::Spec->catdir(programFilesPath(), "Microsoft Visual Studio 12.0");
453     }
454     chomp($vsInstallDir = `cygpath "$vsInstallDir"`) if isCygwin();
455
456     return $vsInstallDir;
457 }
458
459 sub visualStudioVersion
460 {
461     return $vsVersion if defined $vsVersion;
462
463     my $installDir = visualStudioInstallDir();
464
465     $vsVersion = ($installDir =~ /Microsoft Visual Studio ([0-9]+\.[0-9]*)/) ? $1 : "12";
466
467     return $vsVersion;
468 }
469
470 sub determineConfigurationForVisualStudio
471 {
472     return if defined $configurationForVisualStudio;
473     determineConfiguration();
474     # FIXME: We should detect when Debug_All or Production has been chosen.
475     $configurationForVisualStudio = $configuration . (isWin64() ? "|x64" : "|Win32");
476 }
477
478 sub usesPerConfigurationBuildDirectory
479 {
480     # [Gtk] We don't have Release/Debug configurations in straight
481     # autotool builds (non build-webkit). In this case and if
482     # WEBKIT_OUTPUTDIR exist, use that as our configuration dir. This will
483     # allows us to run run-webkit-tests without using build-webkit.
484     return ($ENV{"WEBKIT_OUTPUTDIR"} && isGtk()) || isAppleWinWebKit();
485 }
486
487 sub determineConfigurationProductDir
488 {
489     return if defined $configurationProductDir;
490     determineBaseProductDir();
491     determineConfiguration();
492     if (isAppleWinWebKit() || isWinCairo()) {
493         my $binDir = isWin64() ? "bin64" : "bin32";
494         $configurationProductDir = File::Spec->catdir($baseProductDir, $configuration, $binDir);
495     } else {
496         if (usesPerConfigurationBuildDirectory()) {
497             $configurationProductDir = "$baseProductDir";
498         } else {
499             $configurationProductDir = "$baseProductDir/$configuration";
500             $configurationProductDir .= "-" . xcodeSDKPlatformName() if isIOSWebKit();
501         }
502     }
503 }
504
505 sub setConfigurationProductDir($)
506 {
507     ($configurationProductDir) = @_;
508 }
509
510 sub determineCurrentSVNRevision
511 {
512     # We always update the current SVN revision here, and leave the caching
513     # to currentSVNRevision(), so that changes to the SVN revision while the
514     # script is running can be picked up by calling this function again.
515     determineSourceDir();
516     $currentSVNRevision = svnRevisionForDirectory($sourceDir);
517     return $currentSVNRevision;
518 }
519
520
521 sub chdirWebKit
522 {
523     determineSourceDir();
524     chdir $sourceDir or die;
525 }
526
527 sub baseProductDir
528 {
529     determineBaseProductDir();
530     return $baseProductDir;
531 }
532
533 sub sourceDir
534 {
535     determineSourceDir();
536     return $sourceDir;
537 }
538
539 sub productDir
540 {
541     determineConfigurationProductDir();
542     return $configurationProductDir;
543 }
544
545 sub jscProductDir
546 {
547     my $productDir = productDir();
548     $productDir .= "/bin" if (isEfl() || isGtk());
549
550     return $productDir;
551 }
552
553 sub configuration()
554 {
555     determineConfiguration();
556     return $configuration;
557 }
558
559 sub configurationForVisualStudio()
560 {
561     determineConfigurationForVisualStudio();
562     return $configurationForVisualStudio;
563 }
564
565 sub currentSVNRevision
566 {
567     determineCurrentSVNRevision() if not defined $currentSVNRevision;
568     return $currentSVNRevision;
569 }
570
571 sub generateDsym()
572 {
573     determineGenerateDsym();
574     return $generateDsym;
575 }
576
577 sub determineGenerateDsym()
578 {
579     return if defined($generateDsym);
580     $generateDsym = checkForArgumentAndRemoveFromARGV("--dsym");
581 }
582
583 sub argumentsForXcode()
584 {
585     my @args = ();
586     push @args, "DEBUG_INFORMATION_FORMAT=dwarf-with-dsym" if generateDsym();
587     return @args;
588 }
589
590 sub XcodeOptions
591 {
592     determineBaseProductDir();
593     determineConfiguration();
594     determineArchitecture();
595     determineXcodeSDK();
596
597     my @sdkOption = ($xcodeSDK ? "SDKROOT=$xcodeSDK" : ());
598     my @architectureOption = ($architecture ? "ARCHS=$architecture" : ());
599
600     return (@baseProductDirOption, "-configuration", $configuration, @architectureOption, @sdkOption, argumentsForXcode());
601 }
602
603 sub XcodeOptionString
604 {
605     return join " ", XcodeOptions();
606 }
607
608 sub XcodeOptionStringNoConfig
609 {
610     return join " ", @baseProductDirOption;
611 }
612
613 sub XcodeCoverageSupportOptions()
614 {
615     my @coverageSupportOptions = ();
616     push @coverageSupportOptions, "GCC_GENERATE_TEST_COVERAGE_FILES=YES";
617     push @coverageSupportOptions, "GCC_INSTRUMENT_PROGRAM_FLOW_ARCS=YES";
618     return @coverageSupportOptions;
619 }
620
621 my $passedConfiguration;
622 my $searchedForPassedConfiguration;
623 sub determinePassedConfiguration
624 {
625     return if $searchedForPassedConfiguration;
626     $searchedForPassedConfiguration = 1;
627     $passedConfiguration = undef;
628
629     if (checkForArgumentAndRemoveFromARGV("--debug")) {
630         $passedConfiguration = "Debug";
631     } elsif(checkForArgumentAndRemoveFromARGV("--release")) {
632         $passedConfiguration = "Release";
633     } elsif (checkForArgumentAndRemoveFromARGV("--profile") || checkForArgumentAndRemoveFromARGV("--profiling")) {
634         $passedConfiguration = "Profiling";
635     }
636
637     $passedConfiguration .= "_WinCairo" if (defined($passedConfiguration) && isWinCairo() && isCygwin());
638 }
639
640 sub passedConfiguration
641 {
642     determinePassedConfiguration();
643     return $passedConfiguration;
644 }
645
646 sub setConfiguration
647 {
648     setArchitecture();
649
650     if (my $config = shift @_) {
651         $configuration = $config;
652         return;
653     }
654
655     determinePassedConfiguration();
656     $configuration = $passedConfiguration if $passedConfiguration;
657 }
658
659
660 my $passedArchitecture;
661 my $searchedForPassedArchitecture;
662 sub determinePassedArchitecture
663 {
664     return if $searchedForPassedArchitecture;
665     $searchedForPassedArchitecture = 1;
666
667     $passedArchitecture = undef;
668     if (checkForArgumentAndRemoveFromARGV("--32-bit")) {
669         if (isAppleMacWebKit()) {
670             # PLATFORM_IOS: Don't run `arch` command inside Simulator environment
671             local %ENV = %ENV;
672             delete $ENV{DYLD_ROOT_PATH};
673             delete $ENV{DYLD_FRAMEWORK_PATH};
674
675             $passedArchitecture = `arch`;
676             chomp $passedArchitecture;
677         }
678     }
679 }
680
681 sub passedArchitecture
682 {
683     determinePassedArchitecture();
684     return $passedArchitecture;
685 }
686
687 sub architecture()
688 {
689     determineArchitecture();
690     return $architecture;
691 }
692
693 sub numberOfCPUs()
694 {
695     determineNumberOfCPUs();
696     return $numberOfCPUs;
697 }
698
699 sub maxCPULoad()
700 {
701     determineMaxCPULoad();
702     return $maxCPULoad;
703 }
704
705 sub setArchitecture
706 {
707     if (my $arch = shift @_) {
708         $architecture = $arch;
709         return;
710     }
711
712     determinePassedArchitecture();
713     $architecture = $passedArchitecture if $passedArchitecture;
714 }
715
716 sub skipSafariExecutableEntitlementChecks
717 {
718     return `defaults read /Library/Preferences/org.webkit.BuildConfiguration SkipSafariExecutableEntitlementChecks 2>/dev/null` eq "1\n";
719 }
720
721 sub executableHasEntitlements
722 {
723     my $executablePath = shift;
724     return (`codesign -d --entitlements - $executablePath 2>&1` =~ /<key>/);
725 }
726
727 sub safariPathFromSafariBundle
728 {
729     my ($safariBundle) = @_;
730
731     if (isAppleMacWebKit()) {
732         my $safariPath = "$safariBundle/Contents/MacOS/Safari";
733         return $safariPath if skipSafariExecutableEntitlementChecks();
734
735         my $safariForWebKitDevelopmentPath = "$safariBundle/Contents/MacOS/SafariForWebKitDevelopment";
736         return $safariForWebKitDevelopmentPath if -f $safariForWebKitDevelopmentPath && executableHasEntitlements($safariPath);
737
738         return $safariPath;
739     }
740     return $safariBundle if isAppleWinWebKit();
741 }
742
743 sub installedSafariPath
744 {
745     my $safariBundle;
746
747     if (isAppleMacWebKit()) {
748         $safariBundle = "/Applications/Safari.app";
749     } elsif (isAppleWinWebKit()) {
750         $safariBundle = readRegistryString("/HKLM/SOFTWARE/Apple Inc./Safari/InstallDir");
751         $safariBundle =~ s/[\r\n]+$//;
752         $safariBundle = `cygpath -u '$safariBundle'` if isCygwin();
753         $safariBundle =~ s/[\r\n]+$//;
754         $safariBundle .= "Safari.exe";
755     }
756
757     return safariPathFromSafariBundle($safariBundle);
758 }
759
760 # Locate Safari.
761 sub safariPath
762 {
763     # Use WEBKIT_SAFARI environment variable if present.
764     my $safariBundle = $ENV{WEBKIT_SAFARI};
765     if (!$safariBundle) {
766         determineConfigurationProductDir();
767         # Use Safari.app in product directory if present (good for Safari development team).
768         if (isAppleMacWebKit() && -d "$configurationProductDir/Safari.app") {
769             $safariBundle = "$configurationProductDir/Safari.app";
770         } elsif (isAppleWinWebKit()) {
771             my $path = "$configurationProductDir/Safari.exe";
772             my $debugPath = "$configurationProductDir/Safari_debug.exe";
773
774             if (configuration() eq "Debug_All" && -x $debugPath) {
775                 $safariBundle = $debugPath;
776             } elsif (-x $path) {
777                 $safariBundle = $path;
778             }
779         }
780         if (!$safariBundle) {
781             return installedSafariPath();
782         }
783     }
784     my $safariPath = safariPathFromSafariBundle($safariBundle);
785     die "Can't find executable at $safariPath.\n" if isAppleMacWebKit() && !-x $safariPath;
786     return $safariPath;
787 }
788
789 sub builtDylibPathForName
790 {
791     my $libraryName = shift;
792     determineConfigurationProductDir();
793
794     if (isGtk()) {
795         # WebKitGTK+ for GTK2, WebKitGTK+ for GTK3, and WebKit2 respectively.
796         my @libraries = ("libwebkitgtk-1.0", "libwebkitgtk-3.0", "libwebkit2gtk-3.0");
797         my $extension = isDarwin() ? ".dylib" : ".so";
798         my $builtLibraryPath = "$configurationProductDir/lib/";
799
800         foreach $libraryName (@libraries) {
801             my $libraryPath = "$builtLibraryPath" . $libraryName . $extension;
802             return $libraryPath if -e $libraryPath;
803         }
804         return "NotFound";
805     }
806     if (isEfl()) {
807         if (isWK2()) {
808             return "$configurationProductDir/lib/libewebkit2.so";
809         }
810         return "$configurationProductDir/lib/libewebkit.so";
811     }
812     if (isWinCE()) {
813         return "$configurationProductDir/$libraryName";
814     }
815     if (isIOSWebKit()) {
816         return "$configurationProductDir/$libraryName.framework/$libraryName";
817     }
818     if (isAppleMacWebKit()) {
819         return "$configurationProductDir/$libraryName.framework/Versions/A/$libraryName";
820     }
821     if (isAppleWinWebKit()) {
822         if ($libraryName eq "JavaScriptCore") {
823             return "$baseProductDir/lib/$libraryName.lib";
824         } else {
825             return "$baseProductDir/$libraryName.intermediate/$configuration/$libraryName.intermediate/$libraryName.lib";
826         }
827     }
828
829     die "Unsupported platform, can't determine built library locations.\nTry `build-webkit --help` for more information.\n";
830 }
831
832 # Check to see that all the frameworks are built.
833 sub checkFrameworks # FIXME: This is a poor name since only the Mac calls built WebCore a Framework.
834 {
835     return if isCygwin() || isWindows();
836     my @frameworks = ("JavaScriptCore", "WebCore");
837     push(@frameworks, "WebKit") if isAppleMacWebKit(); # FIXME: This seems wrong, all ports should have a WebKit these days.
838     for my $framework (@frameworks) {
839         my $path = builtDylibPathForName($framework);
840         die "Can't find built framework at \"$path\".\n" unless -e $path;
841     }
842 }
843
844 sub isInspectorFrontend()
845 {
846     determineIsInspectorFrontend();
847     return $isInspectorFrontend;
848 }
849
850 sub determineIsInspectorFrontend()
851 {
852     return if defined($isInspectorFrontend);
853     $isInspectorFrontend = checkForArgumentAndRemoveFromARGV("--inspector-frontend");
854 }
855
856 sub commandExists($)
857 {
858     my $command = shift;
859     my $devnull = File::Spec->devnull();
860     return `$command --version 2> $devnull`;
861 }
862
863 sub checkForArgumentAndRemoveFromARGV($)
864 {
865     my $argToCheck = shift;
866     return checkForArgumentAndRemoveFromArrayRef($argToCheck, \@ARGV);
867 }
868
869 sub checkForArgumentAndRemoveFromArrayRefGettingValue($$$)
870 {
871     my ($argToCheck, $valueRef, $arrayRef) = @_;
872     my $argumentStartRegEx = qr#^$argToCheck(?:=\S|$)#;
873     my $i = 0;
874     for (; $i < @$arrayRef; ++$i) {
875         last if $arrayRef->[$i] =~ $argumentStartRegEx;
876     }
877     if ($i >= @$arrayRef) {
878         return $$valueRef = undef;
879     }
880     my ($key, $value) = split("=", $arrayRef->[$i]);
881     splice(@$arrayRef, $i, 1);
882     if (defined($value)) {
883         # e.g. --sdk=iphonesimulator
884         return $$valueRef = $value;
885     }
886     return $$valueRef = splice(@$arrayRef, $i, 1); # e.g. --sdk iphonesimulator
887 }
888
889 sub checkForArgumentAndRemoveFromARGVGettingValue($$)
890 {
891     my ($argToCheck, $valueRef) = @_;
892     return checkForArgumentAndRemoveFromArrayRefGettingValue($argToCheck, $valueRef, \@ARGV);
893 }
894
895 sub findMatchingArguments($$)
896 {
897     my ($argToCheck, $arrayRef) = @_;
898     my @matchingIndices;
899     foreach my $index (0 .. $#$arrayRef) {
900         my $opt = $$arrayRef[$index];
901         if ($opt =~ /^$argToCheck$/i ) {
902             push(@matchingIndices, $index);
903         }
904     }
905     return @matchingIndices; 
906 }
907
908 sub hasArgument($$)
909 {
910     my ($argToCheck, $arrayRef) = @_;
911     my @matchingIndices = findMatchingArguments($argToCheck, $arrayRef);
912     return scalar @matchingIndices > 0;
913 }
914
915 sub checkForArgumentAndRemoveFromArrayRef
916 {
917     my ($argToCheck, $arrayRef) = @_;
918     my @indicesToRemove = findMatchingArguments($argToCheck, $arrayRef);
919     my $removeOffset = 0;
920     foreach my $index (@indicesToRemove) {
921         splice(@$arrayRef, $index - $removeOffset++, 1);
922     }
923     return scalar @indicesToRemove > 0;
924 }
925
926 sub isWK2()
927 {
928     if (defined($isWK2)) {
929         return $isWK2;
930     }
931     if (checkForArgumentAndRemoveFromARGV("-2")) {
932         $isWK2 = 1;
933     } else {
934         $isWK2 = 0;
935     }
936     return $isWK2;
937 }
938
939 sub determineIsEfl()
940 {
941     return if defined($isEfl);
942     $isEfl = checkForArgumentAndRemoveFromARGV("--efl");
943 }
944
945 sub isEfl()
946 {
947     determineIsEfl();
948     return $isEfl;
949 }
950
951 sub determineIsGtk()
952 {
953     return if defined($isGtk);
954     $isGtk = checkForArgumentAndRemoveFromARGV("--gtk");
955 }
956
957 sub isGtk()
958 {
959     determineIsGtk();
960     return $isGtk;
961 }
962
963 sub isWinCE()
964 {
965     determineIsWinCE();
966     return $isWinCE;
967 }
968
969 sub determineIsWinCE()
970 {
971     return if defined($isWinCE);
972     $isWinCE = checkForArgumentAndRemoveFromARGV("--wince");
973 }
974
975 # Determine if this is debian, ubuntu, linspire, or something similar.
976 sub isDebianBased()
977 {
978     return -e "/etc/debian_version";
979 }
980
981 sub isFedoraBased()
982 {
983     return -e "/etc/fedora-release";
984 }
985
986 sub isWinCairo()
987 {
988     determineIsWinCairo();
989     return $isWinCairo;
990 }
991
992 sub determineIsWinCairo()
993 {
994     return if defined($isWinCairo);
995     $isWinCairo = checkForArgumentAndRemoveFromARGV("--wincairo");
996 }
997
998 sub isWin64()
999 {
1000     determineIsWin64();
1001     return $isWin64;
1002 }
1003
1004 sub determineIsWin64()
1005 {
1006     return if defined($isWin64);
1007     $isWin64 = checkForArgumentAndRemoveFromARGV("--64-bit");
1008 }
1009
1010 sub isCygwin()
1011 {
1012     return ($^O eq "cygwin") || 0;
1013 }
1014
1015 sub isAnyWindows()
1016 {
1017     return isWindows() || isCygwin();
1018 }
1019
1020 sub determineWinVersion()
1021 {
1022     return if $winVersion;
1023
1024     if (!isAnyWindows()) {
1025         $winVersion = -1;
1026         return;
1027     }
1028
1029     my $versionString = `cmd /c ver`;
1030     $versionString =~ /(\d)\.(\d)\.(\d+)/;
1031
1032     $winVersion = {
1033         major => $1,
1034         minor => $2,
1035         build => $3,
1036     };
1037 }
1038
1039 sub winVersion()
1040 {
1041     determineWinVersion();
1042     return $winVersion;
1043 }
1044
1045 sub isWindows7SP0()
1046 {
1047     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 1 && winVersion()->{build} == 7600;
1048 }
1049
1050 sub isWindowsVista()
1051 {
1052     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 0;
1053 }
1054
1055 sub isWindowsXP()
1056 {
1057     return isAnyWindows() && winVersion()->{major} == 5 && winVersion()->{minor} == 1;
1058 }
1059
1060 sub isDarwin()
1061 {
1062     return ($^O eq "darwin") || 0;
1063 }
1064
1065 sub isWindows()
1066 {
1067     return ($^O eq "MSWin32") || 0;
1068 }
1069
1070 sub isLinux()
1071 {
1072     return ($^O eq "linux") || 0;
1073 }
1074
1075 sub isBSD()
1076 {
1077     return ($^O eq "freebsd") || ($^O eq "openbsd") || ($^O eq "netbsd") || 0;
1078 }
1079
1080 sub isARM()
1081 {
1082     return ($Config{archname} =~ /^arm[v\-]/) || ($Config{archname} =~ /^aarch64[v\-]/);
1083 }
1084
1085 sub isCrossCompilation()
1086 {
1087   my $compiler = "";
1088   $compiler = $ENV{'CC'} if (defined($ENV{'CC'}));
1089   if ($compiler =~ /gcc/) {
1090       my $compiler_options = `$compiler -v 2>&1`;
1091       my @host = $compiler_options =~ m/--host=(.*?)\s/;
1092       my @target = $compiler_options =~ m/--target=(.*?)\s/;
1093
1094       return ($host[0] ne "" && $target[0] ne "" && $host[0] ne $target[0]);
1095   }
1096   return 0;
1097 }
1098
1099 sub isAppleWebKit()
1100 {
1101     return isAppleMacWebKit() || isAppleWinWebKit();
1102 }
1103
1104 sub isAppleMacWebKit()
1105 {
1106     return isDarwin() && !isGtk();
1107 }
1108
1109 sub isAppleWinWebKit()
1110 {
1111     return (isCygwin() || isWindows()) && !isWinCairo() && !isGtk() && !isWinCE();
1112 }
1113
1114 sub willUseIOSDeviceSDKWhenBuilding()
1115 {
1116     return xcodeSDKPlatformName() eq "iphoneos";
1117 }
1118
1119 sub willUseIOSSimulatorSDKWhenBuilding()
1120 {
1121     return xcodeSDKPlatformName() eq "iphonesimulator";
1122 }
1123
1124 sub isIOSWebKit()
1125 {
1126     determineXcodeSDK();
1127     return isAppleMacWebKit() && (willUseIOSDeviceSDKWhenBuilding() || willUseIOSSimulatorSDKWhenBuilding());
1128 }
1129
1130 sub isPerianInstalled()
1131 {
1132     if (!isAppleWebKit()) {
1133         return 0;
1134     }
1135
1136     if (-d "/Library/QuickTime/Perian.component") {
1137         return 1;
1138     }
1139
1140     if (-d "$ENV{HOME}/Library/QuickTime/Perian.component") {
1141         return 1;
1142     }
1143
1144     return 0;
1145 }
1146
1147 sub determineIPhoneSimulatorVersion()
1148 {
1149     return if $iPhoneSimulatorVersion;
1150
1151     if (!isIOSWebKit()) {
1152         $iPhoneSimulatorVersion = -1;
1153         return;
1154     }
1155
1156     my $version = `/usr/local/bin/psw_vers -productVersion`;
1157     my @splitVersion = split(/\./, $version);
1158     @splitVersion >= 2 or die "Invalid version $version";
1159     $iPhoneSimulatorVersion = {
1160             "major" => $splitVersion[0],
1161             "minor" => $splitVersion[1],
1162             "subminor" => defined($splitVersion[2] ? $splitVersion[2] : 0),
1163     };
1164 }
1165
1166 sub iPhoneSimulatorVersion()
1167 {
1168     determineIPhoneSimulatorVersion();
1169     return $iPhoneSimulatorVersion;
1170 }
1171
1172 sub determineNmPath()
1173 {
1174     return if $nmPath;
1175
1176     if (isAppleMacWebKit()) {
1177         $nmPath = `xcrun -find nm`;
1178         chomp $nmPath;
1179     }
1180     $nmPath = "nm" if !$nmPath;
1181 }
1182
1183 sub nmPath()
1184 {
1185     determineNmPath();
1186     return $nmPath;
1187 }
1188
1189 sub determineOSXVersion()
1190 {
1191     return if $osXVersion;
1192
1193     if (!isDarwin()) {
1194         $osXVersion = -1;
1195         return;
1196     }
1197
1198     my $version = `sw_vers -productVersion`;
1199     my @splitVersion = split(/\./, $version);
1200     @splitVersion >= 2 or die "Invalid version $version";
1201     $osXVersion = {
1202             "major" => $splitVersion[0],
1203             "minor" => $splitVersion[1],
1204             "subminor" => (defined($splitVersion[2]) ? $splitVersion[2] : 0),
1205     };
1206 }
1207
1208 sub osXVersion()
1209 {
1210     determineOSXVersion();
1211     return $osXVersion;
1212 }
1213
1214 sub isSnowLeopard()
1215 {
1216     return isDarwin() && osXVersion()->{"minor"} == 6;
1217 }
1218
1219 sub isLion()
1220 {
1221     return isDarwin() && osXVersion()->{"minor"} == 7;
1222 }
1223
1224 sub isWindowsNT()
1225 {
1226     return $ENV{'OS'} eq 'Windows_NT';
1227 }
1228
1229 sub shouldTargetWebProcess
1230 {
1231     determineShouldTargetWebProcess();
1232     return $shouldTargetWebProcess;
1233 }
1234
1235 sub determineShouldTargetWebProcess
1236 {
1237     return if defined($shouldTargetWebProcess);
1238     $shouldTargetWebProcess = checkForArgumentAndRemoveFromARGV("--target-web-process");
1239 }
1240
1241 sub shouldUseXPCServiceForWebProcess
1242 {
1243     determineShouldUseXPCServiceForWebProcess();
1244     return $shouldUseXPCServiceForWebProcess;
1245 }
1246
1247 sub determineShouldUseXPCServiceForWebProcess
1248 {
1249     return if defined($shouldUseXPCServiceForWebProcess);
1250     $shouldUseXPCServiceForWebProcess = checkForArgumentAndRemoveFromARGV("--use-web-process-xpc-service");
1251 }
1252
1253 sub debugger
1254 {
1255     determineDebugger();
1256     return $debugger;
1257 }
1258
1259 sub determineDebugger
1260 {
1261     return if defined($debugger);
1262
1263     determineXcodeVersion();
1264     if (eval "v$xcodeVersion" ge v4.5) {
1265         $debugger = "lldb";
1266     } else {
1267         $debugger = "gdb";
1268     }
1269
1270     if (checkForArgumentAndRemoveFromARGV("--use-lldb")) {
1271         $debugger = "lldb";
1272     }
1273
1274     if (checkForArgumentAndRemoveFromARGV("--use-gdb")) {
1275         $debugger = "gdb";
1276     }
1277 }
1278
1279 sub appendToEnvironmentVariableList
1280 {
1281     my ($environmentVariableName, $value) = @_;
1282
1283     if (defined($ENV{$environmentVariableName})) {
1284         $ENV{$environmentVariableName} .= ":" . $value;
1285     } else {
1286         $ENV{$environmentVariableName} = $value;
1287     }
1288 }
1289
1290 sub setUpGuardMallocIfNeeded
1291 {
1292     if (!isDarwin()) {
1293         return;
1294     }
1295
1296     if (!defined($shouldUseGuardMalloc)) {
1297         $shouldUseGuardMalloc = checkForArgumentAndRemoveFromARGV("--guard-malloc");
1298     }
1299
1300     if ($shouldUseGuardMalloc) {
1301         appendToEnvironmentVariableList("DYLD_INSERT_LIBRARIES", "/usr/lib/libgmalloc.dylib");
1302     }
1303 }
1304
1305 sub relativeScriptsDir()
1306 {
1307     my $scriptDir = File::Spec->catpath("", File::Spec->abs2rel($FindBin::Bin, getcwd()), "");
1308     if ($scriptDir eq "") {
1309         $scriptDir = ".";
1310     }
1311     return $scriptDir;
1312 }
1313
1314 sub launcherPath()
1315 {
1316     my $relativeScriptsPath = relativeScriptsDir();
1317     if (isGtk() || isEfl() || isWinCE()) {
1318         return "$relativeScriptsPath/run-launcher";
1319     } elsif (isAppleWebKit()) {
1320         return "$relativeScriptsPath/run-safari";
1321     }
1322 }
1323
1324 sub launcherName()
1325 {
1326     if (isGtk()) {
1327         return "MiniBrowser";
1328     } elsif (isAppleMacWebKit()) {
1329         return "Safari";
1330     } elsif (isAppleWinWebKit()) {
1331         return "WinLauncher";
1332     } elsif (isEfl()) {
1333         return "EWebLauncher/MiniBrowser";
1334     } elsif (isWinCE()) {
1335         return "WinCELauncher";
1336     }
1337 }
1338
1339 sub checkRequiredSystemConfig
1340 {
1341     if (isDarwin()) {
1342         chomp(my $productVersion = `sw_vers -productVersion`);
1343         if (eval "v$productVersion" lt v10.7.5) {
1344             print "*************************************************************\n";
1345             print "Mac OS X Version 10.7.5 or later is required to build WebKit.\n";
1346             print "You have " . $productVersion . ", thus the build will most likely fail.\n";
1347             print "*************************************************************\n";
1348         }
1349         my $xcodebuildVersionOutput = `xcodebuild -version`;
1350         my $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : undef;
1351         if (!$xcodeVersion || $xcodeVersion && eval "v$xcodeVersion" lt v4.6) {
1352             print "*************************************************************\n";
1353             print "Xcode Version 4.6 or later is required to build WebKit.\n";
1354             print "You have an earlier version of Xcode, thus the build will\n";
1355             print "most likely fail. The latest Xcode is available from the App Store.\n";
1356             print "*************************************************************\n";
1357         }
1358     } elsif (isGtk() or isEfl() or isWindows()) {
1359         my @cmds = qw(bison gperf flex);
1360         my @missing = ();
1361         my $oldPath = $ENV{PATH};
1362         foreach my $cmd (@cmds) {
1363             push @missing, $cmd if not commandExists($cmd);
1364         }
1365
1366         if (@missing) {
1367             my $list = join ", ", @missing;
1368             die "ERROR: $list missing but required to build WebKit.\n";
1369         }
1370     }
1371     # Win32 and other platforms may want to check for minimum config
1372 }
1373
1374 sub determineWindowsSourceDir()
1375 {
1376     return if $windowsSourceDir;
1377     $windowsSourceDir = sourceDir();
1378     chomp($windowsSourceDir = `cygpath -w '$windowsSourceDir'`) if isCygwin();
1379 }
1380
1381 sub windowsSourceDir()
1382 {
1383     determineWindowsSourceDir();
1384     return $windowsSourceDir;
1385 }
1386
1387 sub windowsSourceSourceDir()
1388 {
1389     return windowsSourceDir() . "\\Source";
1390 }
1391
1392 sub windowsLibrariesDir()
1393 {
1394     return windowsSourceDir() . "\\WebKitLibraries\\win";
1395 }
1396
1397 sub windowsOutputDir()
1398 {
1399     return windowsSourceDir() . "\\WebKitBuild";
1400 }
1401
1402 sub fontExists($)
1403 {
1404     my $font = shift;
1405     my $val = system qw(regtool get), '\\HKLM\\SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\Fonts\\' . $font . ' (TrueType)';
1406     return 0 == $val;
1407 }
1408
1409 sub checkInstalledTools()
1410 {
1411     # SVN 1.7.10 is known to be compatible with current servers. SVN 1.8.x seems to be missing some authentication
1412     # protocols we use for svn.webkit.org:
1413     my $svnVersion = `svn --version | grep "\\sversion"`;
1414     chomp($svnVersion);
1415     if (!$? and $svnVersion =~ /1\.8\./) {
1416         print "svn 1.7.10 is known to be compatible with our servers. You are running $svnVersion,\nwhich may not work properly.\n"
1417     }
1418
1419     # environment variables. Avoid until this is corrected.
1420     my $pythonVer = `python --version 2>&1`;
1421     die "You must have Python installed to build WebKit.\n" if ($?);
1422
1423     # cURL 7.34.0 has a bug that prevents authentication with opensource.apple.com (and other things using SSL3).
1424     my $curlVer = `curl --version | grep "curl"`;
1425     chomp($curlVer);
1426     if (!$? and $curlVer =~ /libcurl\/7\.34\.0/) {
1427         print "cURL version 7.34.0 has a bug that prevents authentication with SSL v2 or v3.\n";
1428         print "cURL 7.33.0 is known to work. The cURL projects is preparing an update to\n";
1429         print "correct this problem.\n\n";
1430         die "Please install a working cURL and try again.\n";
1431     }
1432
1433     # MathML requires fonts that do not ship with Windows (at least through Windows 8). Warn the user if they are missing
1434     my @fonts = qw(STIXGeneral-Regular MathJax_Main-Regular);
1435     my @missing = ();
1436     foreach my $font (@fonts) {
1437         push @missing, $font if not fontExists($font);
1438     }
1439
1440     if (scalar @missing > 0) {
1441         print "*************************************************************\n";
1442         print "Mathematical fonts, such as STIX and MathJax, are needed to\n";
1443         print "use the MathML feature.  You do not appear to have these fonts\n";
1444         print "on your system.\n\n";
1445         print "You can download a suitable set of fonts from the following URL:\n";
1446         print "https://developer.mozilla.org/Mozilla/MathML_Projects/Fonts\n";
1447         print "*************************************************************\n";
1448     }
1449
1450     print "Installed tools are correct for the WebKit build.\n";
1451 }
1452
1453 sub setupAppleWinEnv()
1454 {
1455     return unless isAppleWinWebKit();
1456
1457     checkInstalledTools();
1458
1459     if (isWindowsNT()) {
1460         my $restartNeeded = 0;
1461         my %variablesToSet = ();
1462
1463         # FIXME: We should remove this explicit version check for cygwin once we stop supporting Cygwin 1.7.9 or older versions. 
1464         # https://bugs.webkit.org/show_bug.cgi?id=85791
1465         my $uname_version = (POSIX::uname())[2];
1466         $uname_version =~ s/\(.*\)//;  # Remove the trailing cygwin version, if any.
1467         if (version->parse($uname_version) < version->parse("1.7.10")) {
1468             # Setting the environment variable 'CYGWIN' to 'tty' makes cygwin enable extra support (i.e., termios)
1469             # for UNIX-like ttys in the Windows console
1470             $variablesToSet{CYGWIN} = "tty" unless $ENV{CYGWIN};
1471         }
1472         
1473         # Those environment variables must be set to be able to build inside Visual Studio.
1474         $variablesToSet{WEBKIT_LIBRARIES} = windowsLibrariesDir() unless $ENV{WEBKIT_LIBRARIES};
1475         $variablesToSet{WEBKIT_OUTPUTDIR} = windowsOutputDir() unless $ENV{WEBKIT_OUTPUTDIR};
1476         $variablesToSet{MSBUILDDISABLENODEREUSE} = "1" unless $ENV{MSBUILDDISABLENODEREUSE};
1477
1478         foreach my $variable (keys %variablesToSet) {
1479             print "Setting the Environment Variable '" . $variable . "' to '" . $variablesToSet{$variable} . "'\n\n";
1480             system qw(regtool -s set), '\\HKEY_CURRENT_USER\\Environment\\' . $variable, $variablesToSet{$variable};
1481             $restartNeeded ||=  $variable eq "WEBKIT_LIBRARIES" || $variable eq "WEBKIT_OUTPUTDIR";
1482         }
1483
1484         if ($restartNeeded) {
1485             print "Please restart your computer before attempting to build inside Visual Studio.\n\n";
1486         }
1487     } else {
1488         if (!defined $ENV{'WEBKIT_LIBRARIES'} || !$ENV{'WEBKIT_LIBRARIES'}) {
1489             print "Warning: You must set the 'WebKit_Libraries' environment variable\n";
1490             print "         to be able build WebKit from within Visual Studio 2013 and newer.\n";
1491             print "         Make sure that 'WebKit_Libraries' points to the\n";
1492             print "         'WebKitLibraries/win' directory, not the 'WebKitLibraries/' directory.\n\n";
1493         }
1494         if (!defined $ENV{'WEBKIT_OUTPUTDIR'} || !$ENV{'WEBKIT_OUTPUTDIR'}) {
1495             print "Warning: You must set the 'WebKit_OutputDir' environment variable\n";
1496             print "         to be able build WebKit from within Visual Studio 2013 and newer.\n\n";
1497         }
1498         if (!defined $ENV{'MSBUILDDISABLENODEREUSE'} || !$ENV{'MSBUILDDISABLENODEREUSE'}) {
1499             print "Warning: You should set the 'MSBUILDDISABLENODEREUSE' environment variable to '1'\n";
1500             print "         to avoid periodic locked log files when building.\n\n";
1501         }
1502     }
1503     # FIXME (125180): Remove the following temporary 64-bit support once official support is available.
1504     if (isWin64() and !$ENV{'WEBKIT_64_SUPPORT'}) {
1505         print "Warning: You must set the 'WEBKIT_64_SUPPORT' environment variable\n";
1506         print "         to be able run WebKit or JavaScriptCore tests.\n\n";
1507     }
1508 }
1509
1510 sub setupCygwinEnv()
1511 {
1512     return if !isCygwin() && !isWindows();
1513     return if $vcBuildPath;
1514
1515     my $programFilesPath = programFilesPath();
1516     $vcBuildPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.com));
1517     if (-e $vcBuildPath) {
1518         # Visual Studio is installed;
1519         if (visualStudioVersion() eq "12") {
1520             $vcBuildPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.exe));
1521         }
1522     } else {
1523         # Visual Studio not found, try VC++ Express
1524         $vcBuildPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE WDExpress.exe));
1525         if (! -e $vcBuildPath) {
1526             print "*************************************************************\n";
1527             print "Cannot find '$vcBuildPath'\n";
1528             print "Please execute the file 'vcvars32.bat' from\n";
1529             print "'$programFilesPath\\Microsoft Visual Studio 12.0\\VC\\bin\\'\n";
1530             print "to setup the necessary environment variables.\n";
1531             print "*************************************************************\n";
1532             die;
1533         }
1534         $willUseVCExpressWhenBuilding = 1;
1535     }
1536
1537     print "Building results into: ", baseProductDir(), "\n";
1538     print "WEBKIT_OUTPUTDIR is set to: ", $ENV{"WEBKIT_OUTPUTDIR"}, "\n";
1539     print "WEBKIT_LIBRARIES is set to: ", $ENV{"WEBKIT_LIBRARIES"}, "\n";
1540     # FIXME (125180): Remove the following temporary 64-bit support once official support is available.
1541     print "WEBKIT_64_SUPPORT is set to: ", $ENV{"WEBKIT_64_SUPPORT"}, "\n" if isWin64();
1542 }
1543
1544 sub dieIfWindowsPlatformSDKNotInstalled
1545 {
1546     my $registry32Path = "/proc/registry/";
1547     my $registry64Path = "/proc/registry64/";
1548     my @windowsPlatformSDKRegistryEntries = (
1549         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0A",
1550         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0",
1551         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.1A",
1552         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.0A",
1553         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/MicrosoftSDK/InstalledSDKs/D2FF9F89-8AA2-4373-8A31-C838BF4DBBE1",
1554     );
1555
1556     # FIXME: It would be better to detect whether we are using 32- or 64-bit Windows
1557     # and only check the appropriate entry. But for now we just blindly check both.
1558     my $recommendedPlatformSDK = $windowsPlatformSDKRegistryEntries[0];
1559
1560     while (@windowsPlatformSDKRegistryEntries) {
1561         my $windowsPlatformSDKRegistryEntry = shift @windowsPlatformSDKRegistryEntries;
1562         return if (-e $registry32Path . $windowsPlatformSDKRegistryEntry) || (-e $registry64Path . $windowsPlatformSDKRegistryEntry);
1563     }
1564
1565     print "*************************************************************\n";
1566     print "Cannot find registry entry '$recommendedPlatformSDK'.\n";
1567     print "Please download and install the Microsoft Windows SDK\n";
1568     print "from <http://www.microsoft.com/en-us/download/details.aspx?id=8279>.\n\n";
1569     print "Then follow step 2 in the Windows section of the \"Installing Developer\n";
1570     print "Tools\" instructions at <http://www.webkit.org/building/tools.html>.\n";
1571     print "*************************************************************\n";
1572     die;
1573 }
1574
1575 sub copyInspectorFrontendFiles
1576 {
1577     my $productDir = productDir();
1578     my $sourceInspectorPath = sourceDir() . "/Source/WebCore/inspector/front-end/";
1579     my $inspectorResourcesDirPath = $ENV{"WEBKITINSPECTORRESOURCESDIR"};
1580
1581     if (!defined($inspectorResourcesDirPath)) {
1582         $inspectorResourcesDirPath = "";
1583     }
1584
1585     if (isAppleMacWebKit()) {
1586         if (isIOSWebKit()) {
1587             $inspectorResourcesDirPath = $productDir . "/WebCore.framework/inspector";
1588         } else {
1589             $inspectorResourcesDirPath = $productDir . "/WebCore.framework/Resources/inspector";
1590         }
1591     } elsif (isAppleWinWebKit() || isWinCairo()) {
1592         $inspectorResourcesDirPath = $productDir . "/WebKit.resources/inspector";
1593     } elsif (isGtk()) {
1594         my $prefix = $ENV{"WebKitInstallationPrefix"};
1595         $inspectorResourcesDirPath = (defined($prefix) ? $prefix : "/usr/share") . "/webkit-1.0/webinspector";
1596     } elsif (isEfl()) {
1597         my $prefix = $ENV{"WebKitInstallationPrefix"};
1598         $inspectorResourcesDirPath = (defined($prefix) ? $prefix : "/usr/share") . "/ewebkit/webinspector";
1599     }
1600
1601     if (! -d $inspectorResourcesDirPath) {
1602         print "*************************************************************\n";
1603         print "Cannot find '$inspectorResourcesDirPath'.\n" if (defined($inspectorResourcesDirPath));
1604         print "Make sure that you have built WebKit first.\n" if (! -d $productDir || defined($inspectorResourcesDirPath));
1605         print "Optionally, set the environment variable 'WebKitInspectorResourcesDir'\n";
1606         print "to point to the directory that contains the WebKit Inspector front-end\n";
1607         print "files for the built WebCore framework.\n";
1608         print "*************************************************************\n";
1609         die;
1610     }
1611
1612     if (isAppleMacWebKit()) {
1613         my $sourceLocalizedStrings = sourceDir() . "/Source/WebCore/English.lproj/localizedStrings.js";
1614         my $destinationLocalizedStrings;
1615         if (isIOSWebKit()) {
1616             $destinationLocalizedStrings = $productDir . "/WebCore.framework/English.lproj/localizedStrings.js";
1617         } else {
1618             $destinationLocalizedStrings = $productDir . "/WebCore.framework/Resources/English.lproj/localizedStrings.js";
1619         }
1620         system "ditto", $sourceLocalizedStrings, $destinationLocalizedStrings;
1621     }
1622
1623     my $exitStatus = system "rsync", "-aut", "--exclude=/.DS_Store", "--exclude=*.re2js", "--exclude=.svn/", $sourceInspectorPath, $inspectorResourcesDirPath;
1624     return $exitStatus if $exitStatus;
1625
1626     if (isIOSWebKit()) {
1627         chdir($productDir . "/WebCore.framework");
1628         return system "zip", "--quiet", "--exclude=*.qrc", "-r", "inspector-remote.zip", "inspector";
1629     }
1630
1631     return 0; # Success; did copy files.
1632 }
1633
1634 sub buildXCodeProject($$@)
1635 {
1636     my ($project, $clean, @extraOptions) = @_;
1637
1638     if ($clean) {
1639         push(@extraOptions, "-alltargets");
1640         push(@extraOptions, "clean");
1641     }
1642
1643     return system "xcodebuild", "-project", "$project.xcodeproj", @extraOptions;
1644 }
1645
1646 sub usingVisualStudioExpress()
1647 {
1648     setupCygwinEnv();
1649     return $willUseVCExpressWhenBuilding;
1650 }
1651
1652 sub buildVisualStudioProject
1653 {
1654     my ($project, $clean) = @_;
1655     setupCygwinEnv();
1656
1657     my $config = configurationForVisualStudio();
1658
1659     dieIfWindowsPlatformSDKNotInstalled() if $willUseVCExpressWhenBuilding;
1660
1661     chomp($project = `cygpath -w "$project"`) if isCygwin();
1662     
1663     my $action = "/build";
1664     if ($clean) {
1665         $action = "/clean";
1666     }
1667
1668     my @command = ($vcBuildPath, $project, $action, $config);
1669
1670     print join(" ", @command), "\n";
1671     return system @command;
1672 }
1673
1674 sub getJhbuildPath()
1675 {
1676     my @jhbuildPath = File::Spec->splitdir(baseProductDir());
1677     if (isGit() && isGitBranchBuild() && gitBranch()) {
1678         pop(@jhbuildPath);
1679     }
1680     push(@jhbuildPath, "Dependencies");
1681     return File::Spec->catdir(@jhbuildPath);
1682 }
1683
1684 sub isCachedArgumentfileOutOfDate($@)
1685 {
1686     my ($filename, $currentContents) = @_;
1687
1688     if (! -e $filename) {
1689         return 1;
1690     }
1691
1692     open(CONTENTS_FILE, $filename);
1693     chomp(my $previousContents = <CONTENTS_FILE>);
1694     close(CONTENTS_FILE);
1695
1696     if ($previousContents ne $currentContents) {
1697         print "Contents for file $filename have changed.\n";
1698         print "Previous contents were: $previousContents\n\n";
1699         print "New contents are: $currentContents\n";
1700         return 1;
1701     }
1702
1703     return 0;
1704 }
1705
1706 sub jhbuildWrapperPrefixIfNeeded()
1707 {
1708     if (-e getJhbuildPath()) {
1709         my @prefix = (File::Spec->catfile(sourceDir(), "Tools", "jhbuild", "jhbuild-wrapper"));
1710         if (isEfl()) {
1711             push(@prefix, "--efl");
1712         } elsif (isGtk()) {
1713             push(@prefix, "--gtk");
1714         }
1715         push(@prefix, "run");
1716
1717         return @prefix;
1718     }
1719
1720     return ();
1721 }
1722
1723 sub cmakeCachePath()
1724 {
1725     return File::Spec->catdir(baseProductDir(), configuration(), "CMakeCache.txt");
1726 }
1727
1728 sub shouldRemoveCMakeCache(@)
1729 {
1730     my ($cacheFilePath, @buildArgs) = @_;
1731     if (isWinCE()) {
1732         return 0;
1733     }
1734
1735     if (!isGtk()) {
1736         return 1;
1737     }
1738
1739     # We check this first, because we always want to create this file for a fresh build.
1740     my $productDir = File::Spec->catdir(baseProductDir(), configuration());
1741     my $optionsCache = File::Spec->catdir($productDir, "build-webkit-options.txt");
1742     my $joinedBuildArgs = join(" ", @buildArgs);
1743     if (isCachedArgumentfileOutOfDate($optionsCache, $joinedBuildArgs)) {
1744         File::Path::mkpath($productDir) unless -d $productDir;
1745         open(CACHED_ARGUMENTS, ">", $optionsCache);
1746         print CACHED_ARGUMENTS $joinedBuildArgs;
1747         close(CACHED_ARGUMENTS);
1748
1749         return 1;
1750     }
1751
1752     my $cmakeCache = cmakeCachePath();
1753     unless (-e $cmakeCache) {
1754         return 0;
1755     }
1756
1757     my $cacheFileModifiedTime = stat($cmakeCache)->mtime;
1758     my $platformConfiguration = File::Spec->catdir(sourceDir(), "Source", "cmake", "Options" . cmakeBasedPortName() . ".cmake");
1759     if ($cacheFileModifiedTime < stat($platformConfiguration)->mtime) {
1760         return 1;
1761     }
1762
1763     my $globalConfiguration = File::Spec->catdir(sourceDir(), "Source", "cmake", "OptionsCommon.cmake");
1764     if ($cacheFileModifiedTime < stat($globalConfiguration)->mtime) {
1765         return 1;
1766     }
1767
1768     return 0;
1769 }
1770
1771 sub removeCMakeCache(@)
1772 {
1773     my (@buildArgs) = @_;
1774     if (shouldRemoveCMakeCache(@buildArgs)) {
1775         my $cmakeCache = cmakeCachePath();
1776         unlink($cmakeCache) if -e $cmakeCache;
1777     }
1778 }
1779
1780 sub canUseNinja(@)
1781 {
1782     # Test both ninja and ninja-build. Fedora uses ninja-build and has patched CMake to also call ninja-build.
1783     system('which ninja > /dev/null || which ninja-build > /dev/null');
1784     return $? == 0;
1785 }
1786
1787 sub canUseEclipse(@)
1788 {
1789     system('which eclipse > /dev/null');
1790     return $? == 0;
1791 }
1792
1793 sub cmakeGeneratedBuildfile(@)
1794 {
1795     my ($willUseNinja) = @_;
1796     if ($willUseNinja) {
1797         return File::Spec->catfile(baseProductDir(), configuration(), "build.ninja")
1798     } else {
1799         return File::Spec->catfile(baseProductDir(), configuration(), "Makefile")
1800     }
1801 }
1802
1803 sub generateBuildSystemFromCMakeProject
1804 {
1805     my ($port, $prefixPath, @cmakeArgs, $additionalCMakeArgs) = @_;
1806     my $config = configuration();
1807     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
1808     File::Path::mkpath($buildPath) unless -d $buildPath;
1809     my $originalWorkingDirectory = getcwd();
1810     chdir($buildPath) or die;
1811
1812     # For GTK+ we try to be smart about when to rerun cmake, so that we can have faster incremental builds.
1813     my $willUseNinja = isGtk() && canUseNinja();
1814     if (isGtk() && -e cmakeCachePath() && -e cmakeGeneratedBuildfile($willUseNinja)) {
1815         return 0;
1816     }
1817
1818     my @args;
1819     push @args, "-DPORT=\"$port\"";
1820     push @args, "-DCMAKE_INSTALL_PREFIX=\"$prefixPath\"" if $prefixPath;
1821     push @args, "-DCMAKE_EXPORT_COMPILE_COMMANDS=ON" if isGtk();
1822     push @args, "-DSHARED_CORE=ON" if isEfl() && $ENV{"ENABLE_DRT"};
1823     if ($config =~ /release/i) {
1824         push @args, "-DCMAKE_BUILD_TYPE=Release";
1825     } elsif ($config =~ /debug/i) {
1826         push @args, "-DCMAKE_BUILD_TYPE=Debug";
1827     }
1828
1829     if ($willUseNinja) {
1830         push @args, "-G";
1831         if (canUseEclipse()) {
1832             push @args, "'Eclipse CDT4 - Ninja'";
1833         } else {
1834             push @args, "Ninja";
1835         }
1836     }
1837
1838     # GTK+ has a production mode, but build-webkit should always use developer mode.
1839     push @args, "-DDEVELOPER_MODE=ON" if isGtk();
1840
1841     # Don't warn variables which aren't used by cmake ports.
1842     push @args, "--no-warn-unused-cli";
1843     push @args, @cmakeArgs if @cmakeArgs;
1844     push @args, $additionalCMakeArgs if $additionalCMakeArgs;
1845
1846     push @args, '"' . sourceDir() . '"';
1847
1848     # Compiler options to keep floating point values consistent
1849     # between 32-bit and 64-bit architectures.
1850     determineArchitecture();
1851     if ($architecture ne "x86_64" && !isARM() && !isCrossCompilation()) {
1852         $ENV{'CXXFLAGS'} = "-march=pentium4 -msse2 -mfpmath=sse " . ($ENV{'CXXFLAGS'} || "");
1853     }
1854
1855     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
1856     # parsed for shell metacharacters.
1857     my $wrapper = join(" ", jhbuildWrapperPrefixIfNeeded()) . " ";
1858     my $returnCode = system($wrapper . "cmake @args");
1859
1860     chdir($originalWorkingDirectory);
1861     return $returnCode;
1862 }
1863
1864 sub buildCMakeGeneratedProject($)
1865 {
1866     my ($makeArgs) = @_;
1867     my $config = configuration();
1868     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
1869     if (! -d $buildPath) {
1870         die "Must call generateBuildSystemFromCMakeProject() before building CMake project.";
1871     }
1872
1873     my $command = "cmake";
1874     my @args = ("--build", $buildPath, "--config", $config);
1875     push @args, ("--", $makeArgs) if $makeArgs;
1876
1877     # GTK uses a build script to preserve colors and pretty-printing.
1878     if (isGtk()) {
1879         chdir "$buildPath" or die;
1880         $command = "$buildPath/build.sh";
1881         @args = ($makeArgs);
1882     }
1883
1884     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
1885     # parsed for shell metacharacters. In particular, $makeArgs may contain such metacharacters.
1886     my $wrapper = join(" ", jhbuildWrapperPrefixIfNeeded()) . " ";
1887     return system($wrapper . "$command @args");
1888
1889 }
1890
1891 sub cleanCMakeGeneratedProject()
1892 {
1893     my $config = configuration();
1894     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
1895     if (-d $buildPath) {
1896         return system("cmake", "--build", $buildPath, "--config", $config, "--target", "clean");
1897     }
1898     return 0;
1899 }
1900
1901 sub buildCMakeProjectOrExit($$$$@)
1902 {
1903     my ($clean, $port, $prefixPath, $makeArgs, @cmakeArgs) = @_;
1904     my $returnCode;
1905
1906     exit(exitStatus(cleanCMakeGeneratedProject())) if $clean;
1907
1908     if (isEfl() && checkForArgumentAndRemoveFromARGV("--update-efl")) {
1909         system("perl", "$sourceDir/Tools/Scripts/update-webkitefl-libs") == 0 or die $!;
1910     }
1911
1912     if (isGtk() && checkForArgumentAndRemoveFromARGV("--update-gtk")) {
1913         system("perl", "$sourceDir/Tools/Scripts/update-webkitgtk-libs") == 0 or die $!;
1914     }
1915
1916     $returnCode = exitStatus(generateBuildSystemFromCMakeProject($port, $prefixPath, @cmakeArgs));
1917     exit($returnCode) if $returnCode;
1918
1919     $returnCode = exitStatus(buildCMakeGeneratedProject($makeArgs));
1920     exit($returnCode) if $returnCode;
1921     return 0;
1922 }
1923
1924 sub cmakeBasedPortArguments()
1925 {
1926     return ('-G "Visual Studio 8 2005 STANDARDSDK_500 (ARMV4I)"') if isWinCE();
1927     return ();
1928 }
1929
1930 sub cmakeBasedPortName()
1931 {
1932     return "Efl" if isEfl();
1933     return "WinCE" if isWinCE();
1934     return "GTK" if isGtk();
1935     return "";
1936 }
1937
1938 sub isCMakeBuild()
1939 {
1940     return isEfl() || isWinCE() || isGtk();
1941 }
1942
1943 sub promptUser
1944 {
1945     my ($prompt, $default) = @_;
1946     my $defaultValue = $default ? "[$default]" : "";
1947     print "$prompt $defaultValue: ";
1948     chomp(my $input = <STDIN>);
1949     return $input ? $input : $default;
1950 }
1951
1952 sub appleApplicationSupportPath
1953 {
1954     if (isWin64()) {
1955         # FIXME (125180): Remove the following once official 64-bit Windows support is available.
1956         return $ENV{"WEBKIT_64_SUPPORT"}, "\n" if isWin64();
1957     }
1958
1959     open INSTALL_DIR, "</proc/registry/HKEY_LOCAL_MACHINE/SOFTWARE/Apple\ Inc./Apple\ Application\ Support/InstallDir";
1960     my $path = <INSTALL_DIR>;
1961     $path =~ s/[\r\n\x00].*//;
1962     close INSTALL_DIR;
1963
1964     my $unixPath = `cygpath -u '$path'`;
1965     chomp $unixPath;
1966     return $unixPath;
1967 }
1968
1969 sub setPathForRunningWebKitApp
1970 {
1971     my ($env) = @_;
1972
1973     if (isAppleWinWebKit()) {
1974         $env->{PATH} = join(':', productDir(), dirname(installedSafariPath()), appleApplicationSupportPath(), $env->{PATH} || "");
1975     } elsif (isWinCairo()) {
1976         my $winCairoBin = sourceDir() . "/WebKitLibraries/win/" . (isWin64() ? "bin64/" : "bin32/");
1977         my $gstreamerBin = isWin64() ? $ENV{"GSTREAMER_1_0_ROOT_X86_64"} . "bin" : $ENV{"GSTREAMER_1_0_ROOT_X86"} . "bin";
1978         $env->{PATH} = join(':', productDir(), $winCairoBin, $gstreamerBin, $env->{PATH} || "");
1979     }
1980 }
1981
1982 sub printHelpAndExitForRunAndDebugWebKitAppIfNeeded
1983 {
1984     return unless checkForArgumentAndRemoveFromARGV("--help");
1985
1986     my ($includeOptionsForDebugging) = @_;
1987
1988     print STDERR <<EOF;
1989 Usage: @{[basename($0)]} [options] [args ...]
1990   --help                            Show this help message
1991   --no-saved-state                  Launch the application without state restoration (OS X 10.7 and later)
1992   --guard-malloc                    Enable Guard Malloc (OS X only)
1993   --use-web-process-xpc-service     Launch the Web Process as an XPC Service (OS X only)
1994 EOF
1995
1996     if ($includeOptionsForDebugging) {
1997         print STDERR <<EOF;
1998   --target-web-process              Debug the web process
1999   --use-gdb                         Use GDB (this is the default when using Xcode 4.4 or earlier)
2000   --use-lldb                        Use LLDB (this is the default when using Xcode 4.5 or later)
2001 EOF
2002     }
2003
2004     exit(1);
2005 }
2006
2007 sub argumentsForRunAndDebugMacWebKitApp()
2008 {
2009     my @args = ();
2010     if (checkForArgumentAndRemoveFromARGV("--no-saved-state")) {
2011         push @args, ("-ApplePersistenceIgnoreStateQuietly", "YES");
2012         # FIXME: Don't set ApplePersistenceIgnoreState once all supported OS versions respect ApplePersistenceIgnoreStateQuietly (rdar://15032886).
2013         push @args, ("-ApplePersistenceIgnoreState", "YES");
2014     }
2015     push @args, ("-WebKit2UseXPCServiceForWebProcess", "YES") if shouldUseXPCServiceForWebProcess();
2016     unshift @args, @ARGV;
2017
2018     return @args;
2019 }
2020
2021 sub runMacWebKitApp($;$)
2022 {
2023     my ($appPath, $useOpenCommand) = @_;
2024     my $productDir = productDir();
2025     print "Starting @{[basename($appPath)]} with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2026     $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
2027     $ENV{__XPC_DYLD_FRAMEWORK_PATH} = File::Spec->rel2abs($productDir);
2028     $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
2029
2030     setUpGuardMallocIfNeeded();
2031
2032     if (defined($useOpenCommand) && $useOpenCommand == USE_OPEN_COMMAND) {
2033         return system("open", "-W", "-a", $appPath, "--args", argumentsForRunAndDebugMacWebKitApp());
2034     }
2035     if (architecture()) {
2036         return system "arch", "-" . architecture(), $appPath, argumentsForRunAndDebugMacWebKitApp();
2037     }
2038     return system { $appPath } $appPath, argumentsForRunAndDebugMacWebKitApp();
2039 }
2040
2041 sub execMacWebKitAppForDebugging($)
2042 {
2043     my ($appPath) = @_;
2044     my $architectureSwitch;
2045     my $argumentsSeparator;
2046
2047     if (debugger() eq "lldb") {
2048         $architectureSwitch = "--arch";
2049         $argumentsSeparator = "--";
2050     } elsif (debugger() eq "gdb") {
2051         $architectureSwitch = "-arch";
2052         $argumentsSeparator = "--args";
2053     } else {
2054         die "Unknown debugger $debugger.\n";
2055     }
2056
2057     my $debuggerPath = `xcrun -find $debugger`;
2058     chomp $debuggerPath;
2059     die "Can't find the $debugger executable.\n" unless -x $debuggerPath;
2060
2061     my $productDir = productDir();
2062     $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
2063     $ENV{__XPC_DYLD_FRAMEWORK_PATH} = File::Spec->rel2abs($productDir);
2064     $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
2065
2066     setUpGuardMallocIfNeeded();
2067
2068     my @architectureFlags = ($architectureSwitch, architecture());
2069     if (!shouldTargetWebProcess()) {
2070         print "Starting @{[basename($appPath)]} under $debugger with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2071         exec { $debuggerPath } $debuggerPath, @architectureFlags, $argumentsSeparator, $appPath, argumentsForRunAndDebugMacWebKitApp() or die;
2072     } else {
2073         if (shouldUseXPCServiceForWebProcess()) {
2074             die "Targetting the Web Process is not compatible with using an XPC Service for the Web Process at this time.";
2075         }
2076         
2077         my $webProcessShimPath = File::Spec->catfile($productDir, "SecItemShim.dylib");
2078         my $webProcessPath = File::Spec->catdir($productDir, "WebProcess.app");
2079         my $webKit2ExecutablePath = File::Spec->catfile($productDir, "WebKit2.framework", "WebKit2");
2080
2081         appendToEnvironmentVariableList("DYLD_INSERT_LIBRARIES", $webProcessShimPath);
2082
2083         print "Starting WebProcess under $debugger with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2084         exec { $debuggerPath } $debuggerPath, @architectureFlags, $argumentsSeparator, $webProcessPath, $webKit2ExecutablePath, "-type", "webprocess", "-client-executable", $appPath or die;
2085     }
2086 }
2087
2088 sub debugSafari
2089 {
2090     if (isAppleMacWebKit()) {
2091         checkFrameworks();
2092         execMacWebKitAppForDebugging(safariPath());
2093     }
2094
2095     return 1; # Unsupported platform; can't debug Safari on this platform.
2096 }
2097
2098 sub runSafari
2099 {
2100
2101     if (isAppleMacWebKit()) {
2102         return runMacWebKitApp(safariPath());
2103     }
2104
2105     if (isAppleWinWebKit()) {
2106         my $result;
2107         my $productDir = productDir();
2108         my $webKitLauncherPath = File::Spec->catfile(productDir(), "WinLauncher.exe");
2109         return system { $webKitLauncherPath } $webKitLauncherPath, @ARGV;
2110     }
2111
2112     return 1; # Unsupported platform; can't run Safari on this platform.
2113 }
2114
2115 sub runMiniBrowser
2116 {
2117     if (isAppleMacWebKit()) {
2118         return runMacWebKitApp(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2119     }
2120
2121     return 1;
2122 }
2123
2124 sub debugMiniBrowser
2125 {
2126     if (isAppleMacWebKit()) {
2127         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2128     }
2129     
2130     return 1;
2131 }
2132
2133 sub runWebKitTestRunner
2134 {
2135     if (isAppleMacWebKit()) {
2136         return runMacWebKitApp(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2137     }
2138
2139     return 1;
2140 }
2141
2142 sub debugWebKitTestRunner
2143 {
2144     if (isAppleMacWebKit()) {
2145         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2146     }
2147
2148     return 1;
2149 }
2150
2151 sub readRegistryString
2152 {
2153     my ($valueName) = @_;
2154     chomp(my $string = `regtool --wow32 get "$valueName"`);
2155     return $string;
2156 }
2157
2158 sub writeRegistryString
2159 {
2160     my ($valueName, $string) = @_;
2161
2162     my $error = system "regtool", "--wow32", "set", "-s", $valueName, $string;
2163
2164     # On Windows Vista/7 with UAC enabled, regtool will fail to modify the registry, but will still
2165     # return a successful exit code. So we double-check here that the value we tried to write to the
2166     # registry was really written.
2167     return !$error && readRegistryString($valueName) eq $string;
2168 }
2169
2170 1;