41a3c212be1fd827c938ca36beea61bc8a2043a6
[WebKit-https.git] / Tools / Scripts / webkitdirs.pm
1 # Copyright (C) 2005-2007, 2010-2015 Apple Inc. All rights reserved.
2 # Copyright (C) 2009 Google Inc. All rights reserved.
3 # Copyright (C) 2011 Research In Motion Limited. All rights reserved.
4 # Copyright (C) 2013 Nokia Corporation and/or its subsidiary(-ies).
5 #
6 # Redistribution and use in source and binary forms, with or without
7 # modification, are permitted provided that the following conditions
8 # are met:
9 #
10 # 1.  Redistributions of source code must retain the above copyright
11 #     notice, this list of conditions and the following disclaimer. 
12 # 2.  Redistributions in binary form must reproduce the above copyright
13 #     notice, this list of conditions and the following disclaimer in the
14 #     documentation and/or other materials provided with the distribution. 
15 # 3.  Neither the name of Apple Inc. ("Apple") nor the names of
16 #     its contributors may be used to endorse or promote products derived
17 #     from this software without specific prior written permission. 
18 #
19 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
20 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
21 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
22 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
23 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
24 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
25 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
26 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29
30 # Module to share code to get to WebKit directories.
31
32 use strict;
33 use version;
34 use warnings;
35 use Config;
36 use Cwd qw(realpath);
37 use Digest::MD5 qw(md5_hex);
38 use FindBin;
39 use File::Basename;
40 use File::Find;
41 use File::Path qw(make_path mkpath rmtree);
42 use File::Spec;
43 use File::stat;
44 use List::Util;
45 use POSIX;
46 use Time::HiRes qw(usleep);
47 use VCSUtils;
48
49 BEGIN {
50    use Exporter   ();
51    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
52    $VERSION     = 1.00;
53    @ISA         = qw(Exporter);
54    @EXPORT      = qw(
55        &XcodeCoverageSupportOptions
56        &XcodeOptionString
57        &XcodeOptionStringNoConfig
58        &XcodeOptions
59        &XcodeStaticAnalyzerOption
60        &appDisplayNameFromBundle
61        &baseProductDir
62        &chdirWebKit
63        &checkFrameworks
64        &cmakeBasedPortArguments
65        &cmakeBasedPortName
66        &currentSVNRevision
67        &debugSafari
68        &executableProductDir
69        &findOrCreateSimulatorForIOSDevice
70        &iosSimulatorDeviceByName
71        &nmPath
72        &passedConfiguration
73        &printHelpAndExitForRunAndDebugWebKitAppIfNeeded
74        &productDir
75        &quitIOSSimulator
76        &relaunchIOSSimulator
77        &runIOSWebKitApp
78        &runMacWebKitApp
79        &safariPath
80        &iosVersion
81        &setConfiguration
82        &setupMacWebKitEnvironment
83        &sharedCommandLineOptions
84        &sharedCommandLineOptionsUsage
85        SIMULATOR_DEVICE_SUFFIX_FOR_WEBKIT_DEVELOPMENT
86        USE_OPEN_COMMAND
87    );
88    %EXPORT_TAGS = ( );
89    @EXPORT_OK   = ();
90 }
91
92 use constant USE_OPEN_COMMAND => 1; # Used in runMacWebKitApp().
93 use constant INCLUDE_OPTIONS_FOR_DEBUGGING => 1;
94 use constant SIMULATOR_DEVICE_STATE_SHUTDOWN => "1";
95 use constant SIMULATOR_DEVICE_STATE_BOOTED => "3";
96 use constant SIMULATOR_DEVICE_SUFFIX_FOR_WEBKIT_DEVELOPMENT  => "For WebKit Development";
97
98 # See table "Certificate types and names" on <https://developer.apple.com/library/ios/documentation/IDEs/Conceptual/AppDistributionGuide/MaintainingCertificates/MaintainingCertificates.html#//apple_ref/doc/uid/TP40012582-CH31-SW41>.
99 use constant IOS_DEVELOPMENT_CERTIFICATE_NAME_PREFIX => "iPhone Developer: ";
100
101 our @EXPORT_OK;
102
103 my $architecture;
104 my $asanIsEnabled;
105 my $numberOfCPUs;
106 my $maxCPULoad;
107 my $baseProductDir;
108 my @baseProductDirOption;
109 my $configuration;
110 my $xcodeSDK;
111 my $configurationForVisualStudio;
112 my $configurationProductDir;
113 my $sourceDir;
114 my $currentSVNRevision;
115 my $debugger;
116 my $didLoadIPhoneSimulatorNotification;
117 my $nmPath;
118 my $osXVersion;
119 my $iosVersion;
120 my $generateDsym;
121 my $isGtk;
122 my $isWinCairo;
123 my $isWin64;
124 my $isEfl;
125 my $isInspectorFrontend;
126 my $shouldTargetWebProcess;
127 my $shouldUseXPCServiceForWebProcess;
128 my $shouldUseGuardMalloc;
129 my $shouldNotUseNinja;
130 my $xcodeVersion;
131
132 # Variables for Win32 support
133 my $programFilesPath;
134 my $vcBuildPath;
135 my $vsInstallDir;
136 my $msBuildInstallDir;
137 my $vsVersion;
138 my $windowsSourceDir;
139 my $winVersion;
140 my $willUseVCExpressWhenBuilding = 0;
141
142 # Defined in VCSUtils.
143 sub exitStatus($);
144
145 sub findMatchingArguments($$);
146 sub hasArgument($$);
147
148 sub determineSourceDir
149 {
150     return if $sourceDir;
151     $sourceDir = $FindBin::Bin;
152     $sourceDir =~ s|/+$||; # Remove trailing '/' as we would die later
153
154     # walks up path checking each directory to see if it is the main WebKit project dir, 
155     # defined by containing Sources, WebCore, and WebKit
156     until ((-d File::Spec->catdir($sourceDir, "Source") && -d File::Spec->catdir($sourceDir, "Source", "WebCore") && -d File::Spec->catdir($sourceDir, "Source", "WebKit")) || (-d File::Spec->catdir($sourceDir, "Internal") && -d File::Spec->catdir($sourceDir, "OpenSource")))
157     {
158         if ($sourceDir !~ s|/[^/]+$||) {
159             die "Could not find top level webkit directory above source directory using FindBin.\n";
160         }
161     }
162
163     $sourceDir = File::Spec->catdir($sourceDir, "OpenSource") if -d File::Spec->catdir($sourceDir, "OpenSource");
164 }
165
166 sub currentPerlPath()
167 {
168     my $thisPerl = $^X;
169     if ($^O ne 'VMS') {
170         $thisPerl .= $Config{_exe} unless $thisPerl =~ m/$Config{_exe}$/i;
171     }
172     return $thisPerl;
173 }
174
175 # used for scripts which are stored in a non-standard location
176 sub setSourceDir($)
177 {
178     ($sourceDir) = @_;
179 }
180
181 sub determineNinjaVersion
182 {
183     chomp(my $ninjaVersion = `ninja --version`);
184     return $ninjaVersion;
185 }
186
187 sub determineXcodeVersion
188 {
189     return if defined $xcodeVersion;
190     my $xcodebuildVersionOutput = `xcodebuild -version`;
191     $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : "3.0";
192 }
193
194 sub readXcodeUserDefault($)
195 {
196     my ($unprefixedKey) = @_;
197
198     determineXcodeVersion();
199
200     my $xcodeDefaultsDomain = (eval "v$xcodeVersion" lt v4) ? "com.apple.Xcode" : "com.apple.dt.Xcode";
201     my $xcodeDefaultsPrefix = (eval "v$xcodeVersion" lt v4) ? "PBX" : "IDE";
202     my $devnull = File::Spec->devnull();
203
204     my $value = `defaults read $xcodeDefaultsDomain ${xcodeDefaultsPrefix}${unprefixedKey} 2> ${devnull}`;
205     return if $?;
206
207     chomp $value;
208     return $value;
209 }
210
211 sub determineBaseProductDir
212 {
213     return if defined $baseProductDir;
214     determineSourceDir();
215
216     my $setSharedPrecompsDir;
217     $baseProductDir = $ENV{"WEBKIT_OUTPUTDIR"};
218
219     if (!defined($baseProductDir) and isAppleMacWebKit()) {
220         # Silently remove ~/Library/Preferences/xcodebuild.plist which can
221         # cause build failure. The presence of
222         # ~/Library/Preferences/xcodebuild.plist can prevent xcodebuild from
223         # respecting global settings such as a custom build products directory
224         # (<rdar://problem/5585899>).
225         my $personalPlistFile = $ENV{HOME} . "/Library/Preferences/xcodebuild.plist";
226         if (-e $personalPlistFile) {
227             unlink($personalPlistFile) || die "Could not delete $personalPlistFile: $!";
228         }
229
230         determineXcodeVersion();
231
232         if (eval "v$xcodeVersion" ge v4) {
233             my $buildLocationStyle = join '', readXcodeUserDefault("BuildLocationStyle");
234             if ($buildLocationStyle eq "Custom") {
235                 my $buildLocationType = join '', readXcodeUserDefault("CustomBuildLocationType");
236                 # FIXME: Read CustomBuildIntermediatesPath and set OBJROOT accordingly.
237                 $baseProductDir = readXcodeUserDefault("CustomBuildProductsPath") if $buildLocationType eq "Absolute";
238             }
239
240             # DeterminedByTargets corresponds to a setting of "Legacy" in Xcode.
241             # It is the only build location style for which SHARED_PRECOMPS_DIR is not
242             # overridden when building from within Xcode.
243             $setSharedPrecompsDir = 1 if $buildLocationStyle ne "DeterminedByTargets";
244         }
245
246         if (!defined($baseProductDir)) {
247             $baseProductDir = join '', readXcodeUserDefault("ApplicationwideBuildSettings");
248             $baseProductDir = $1 if $baseProductDir =~ /SYMROOT\s*=\s*\"(.*?)\";/s;
249         }
250
251         undef $baseProductDir unless $baseProductDir =~ /^\//;
252     }
253
254     if (!defined($baseProductDir)) { # Port-specific checks failed, use default
255         $baseProductDir = "$sourceDir/WebKitBuild";
256     }
257
258     if (isGit() && isGitBranchBuild()) {
259         my $branch = gitBranch();
260         $baseProductDir = "$baseProductDir/$branch";
261     }
262
263     if (isAppleMacWebKit()) {
264         $baseProductDir =~ s|^\Q$(SRCROOT)/..\E$|$sourceDir|;
265         $baseProductDir =~ s|^\Q$(SRCROOT)/../|$sourceDir/|;
266         $baseProductDir =~ s|^~/|$ENV{HOME}/|;
267         die "Can't handle Xcode product directory with a ~ in it.\n" if $baseProductDir =~ /~/;
268         die "Can't handle Xcode product directory with a variable in it.\n" if $baseProductDir =~ /\$/;
269         @baseProductDirOption = ("SYMROOT=$baseProductDir", "OBJROOT=$baseProductDir");
270         push(@baseProductDirOption, "SHARED_PRECOMPS_DIR=${baseProductDir}/PrecompiledHeaders") if $setSharedPrecompsDir;
271     }
272
273     if (isCygwin()) {
274         my $dosBuildPath = `cygpath --windows \"$baseProductDir\"`;
275         chomp $dosBuildPath;
276         $ENV{"WEBKIT_OUTPUTDIR"} = $dosBuildPath;
277         my $unixBuildPath = `cygpath --unix \"$baseProductDir\"`;
278         chomp $unixBuildPath;
279         $baseProductDir = $unixBuildPath;
280     }
281 }
282
283 sub setBaseProductDir($)
284 {
285     ($baseProductDir) = @_;
286 }
287
288 sub determineConfiguration
289 {
290     return if defined $configuration;
291     determineBaseProductDir();
292     if (open CONFIGURATION, "$baseProductDir/Configuration") {
293         $configuration = <CONFIGURATION>;
294         close CONFIGURATION;
295     }
296     if ($configuration) {
297         chomp $configuration;
298         # compatibility for people who have old Configuration files
299         $configuration = "Release" if $configuration eq "Deployment";
300         $configuration = "Debug" if $configuration eq "Development";
301     } else {
302         $configuration = "Release";
303     }
304 }
305
306 sub determineArchitecture
307 {
308     return if defined $architecture;
309     # make sure $architecture is defined in all cases
310     $architecture = "";
311
312     determineBaseProductDir();
313     determineXcodeSDK();
314
315     if (isAppleMacWebKit()) {
316         if (open ARCHITECTURE, "$baseProductDir/Architecture") {
317             $architecture = <ARCHITECTURE>;
318             close ARCHITECTURE;
319         }
320         if ($architecture) {
321             chomp $architecture;
322         } else {
323             if (not defined $xcodeSDK or $xcodeSDK =~ /^(\/$|macosx)/) {
324                 my $supports64Bit = `sysctl -n hw.optional.x86_64`;
325                 chomp $supports64Bit;
326                 $architecture = 'x86_64' if $supports64Bit;
327             } elsif ($xcodeSDK =~ /^iphonesimulator/) {
328                 $architecture = 'x86_64';
329             } elsif ($xcodeSDK =~ /^iphoneos/) {
330                 $architecture = 'armv7';
331             }
332         }
333     } elsif (isEfl() || isGtk()) {
334         my $host_processor = "";
335         $host_processor = `cmake --system-information | grep CMAKE_SYSTEM_PROCESSOR`;
336         if ($host_processor =~ m/^CMAKE_SYSTEM_PROCESSOR \"([^"]+)\"/) {
337             # We have a configured build tree; use it.
338             $architecture = $1;
339             $architecture = 'x86_64' if $architecture eq 'amd64';
340         }
341     }
342
343     if (!$architecture && (isGtk() || isAppleMacWebKit() || isEfl())) {
344         # Fall back to output of `arch', if it is present.
345         $architecture = `arch`;
346         chomp $architecture;
347     }
348
349     if (!$architecture && (isGtk() || isAppleMacWebKit() || isEfl())) {
350         # Fall back to output of `uname -m', if it is present.
351         $architecture = `uname -m`;
352         chomp $architecture;
353     }
354
355     $architecture = 'x86_64' if ($architecture =~ /amd64/ && isBSD());
356 }
357
358 sub determineASanIsEnabled
359 {
360     return if defined $asanIsEnabled;
361     determineBaseProductDir();
362
363     $asanIsEnabled = 0;
364     my $asanConfigurationValue;
365
366     if (open ASAN, "$baseProductDir/ASan") {
367         $asanConfigurationValue = <ASAN>;
368         close ASAN;
369         chomp $asanConfigurationValue;
370         $asanIsEnabled = 1 if $asanConfigurationValue eq "YES";
371     }
372 }
373
374 sub determineNumberOfCPUs
375 {
376     return if defined $numberOfCPUs;
377     if (defined($ENV{NUMBER_OF_PROCESSORS})) {
378         $numberOfCPUs = $ENV{NUMBER_OF_PROCESSORS};
379     } elsif (isLinux()) {
380         # First try the nproc utility, if it exists. If we get no
381         # results fall back to just interpretting /proc directly.
382         chomp($numberOfCPUs = `nproc --all 2> /dev/null`);
383         if ($numberOfCPUs eq "") {
384             $numberOfCPUs = (grep /processor/, `cat /proc/cpuinfo`);
385         }
386     } elsif (isWindows() || isCygwin()) {
387         # Assumes cygwin
388         $numberOfCPUs = `ls /proc/registry/HKEY_LOCAL_MACHINE/HARDWARE/DESCRIPTION/System/CentralProcessor | wc -w`;
389     } elsif (isDarwin() || isBSD()) {
390         chomp($numberOfCPUs = `sysctl -n hw.ncpu`);
391     }
392 }
393
394 sub determineMaxCPULoad
395 {
396     return if defined $maxCPULoad;
397     if (defined($ENV{MAX_CPU_LOAD})) {
398         $maxCPULoad = $ENV{MAX_CPU_LOAD};
399     }
400 }
401
402 sub jscPath($)
403 {
404     my ($productDir) = @_;
405     my $jscName = "jsc";
406     $jscName .= "_debug"  if configuration() eq "Debug_All";
407     $jscName .= ".exe" if (isWindows() || isCygwin());
408     return "$productDir/$jscName" if -e "$productDir/$jscName";
409     return "$productDir/JavaScriptCore.framework/Resources/$jscName";
410 }
411
412 sub argumentsForConfiguration()
413 {
414     determineConfiguration();
415     determineArchitecture();
416     determineXcodeSDK();
417
418     my @args = ();
419     # FIXME: Is it necessary to pass --debug, --release, --32-bit or --64-bit?
420     # These are determined automatically from stored configuration.
421     push(@args, '--debug') if ($configuration =~ "^Debug");
422     push(@args, '--release') if ($configuration =~ "^Release");
423     push(@args, '--device') if (defined $xcodeSDK && $xcodeSDK =~ /^iphoneos/);
424     push(@args, '--ios-simulator') if (defined $xcodeSDK && $xcodeSDK =~ /^iphonesimulator/);
425     push(@args, '--32-bit') if ($architecture ne "x86_64" and !isWin64());
426     push(@args, '--64-bit') if (isWin64());
427     push(@args, '--gtk') if isGtk();
428     push(@args, '--efl') if isEfl();
429     push(@args, '--wincairo') if isWinCairo();
430     push(@args, '--inspector-frontend') if isInspectorFrontend();
431     return @args;
432 }
433
434 sub determineXcodeSDK
435 {
436     return if defined $xcodeSDK;
437     my $sdk;
438     if (checkForArgumentAndRemoveFromARGVGettingValue("--sdk", \$sdk)) {
439         $xcodeSDK = $sdk;
440     }
441     if (checkForArgumentAndRemoveFromARGV("--device")) {
442         my $hasInternalSDK = exitStatus(system("xcrun --sdk iphoneos.internal --show-sdk-version > /dev/null 2>&1")) == 0;
443         $xcodeSDK ||= $hasInternalSDK ? "iphoneos.internal" : "iphoneos";
444     }
445     if (checkForArgumentAndRemoveFromARGV("--ios-simulator")) {
446         $xcodeSDK ||= 'iphonesimulator';
447     }
448 }
449
450 sub xcodeSDK
451 {
452     determineXcodeSDK();
453     return $xcodeSDK;
454 }
455
456 sub setXcodeSDK($)
457 {
458     ($xcodeSDK) = @_;
459 }
460
461
462 sub xcodeSDKPlatformName()
463 {
464     determineXcodeSDK();
465     return "" if !defined $xcodeSDK;
466     return "iphoneos" if $xcodeSDK =~ /iphoneos/i;
467     return "iphonesimulator" if $xcodeSDK =~ /iphonesimulator/i;
468     return "macosx" if $xcodeSDK =~ /macosx/i;
469     die "Couldn't determine platform name from Xcode SDK";
470 }
471
472 sub XcodeSDKPath
473 {
474     determineXcodeSDK();
475
476     die "Can't find the SDK path because no Xcode SDK was specified" if not $xcodeSDK;
477
478     my $sdkPath = `xcrun --sdk $xcodeSDK --show-sdk-path` if $xcodeSDK;
479     die 'Failed to get SDK path from xcrun' if $?;
480     chomp $sdkPath;
481
482     return $sdkPath;
483 }
484
485 sub xcodeSDKVersion
486 {
487     determineXcodeSDK();
488
489     die "Can't find the SDK version because no Xcode SDK was specified" if !$xcodeSDK;
490
491     chomp(my $sdkVersion = `xcrun --sdk $xcodeSDK --show-sdk-version`);
492     die "Failed to get SDK version from xcrun" if exitStatus($?);
493
494     return $sdkVersion;
495 }
496
497 sub programFilesPath
498 {
499     return $programFilesPath if defined $programFilesPath;
500
501     $programFilesPath = $ENV{'PROGRAMFILES(X86)'} || $ENV{'PROGRAMFILES'} || "C:\\Program Files";
502
503     return $programFilesPath;
504 }
505
506 sub visualStudioInstallDir
507 {
508     return $vsInstallDir if defined $vsInstallDir;
509
510     if ($ENV{'VSINSTALLDIR'}) {
511         $vsInstallDir = $ENV{'VSINSTALLDIR'};
512         $vsInstallDir =~ s|[\\/]$||;
513     } else {
514         $vsInstallDir = File::Spec->catdir(programFilesPath(), "Microsoft Visual Studio 14.0");
515     }
516     chomp($vsInstallDir = `cygpath "$vsInstallDir"`) if isCygwin();
517
518     print "Using Visual Studio: $vsInstallDir\n";
519     return $vsInstallDir;
520 }
521
522 sub msBuildInstallDir
523 {
524     return $msBuildInstallDir if defined $msBuildInstallDir;
525
526     $msBuildInstallDir = File::Spec->catdir(programFilesPath(), "MSBuild", "14.0", "Bin");
527    
528     chomp($msBuildInstallDir = `cygpath "$msBuildInstallDir"`) if isCygwin();
529
530     print "Using MSBuild: $msBuildInstallDir\n";
531     return $msBuildInstallDir;
532 }
533
534 sub visualStudioVersion
535 {
536     return $vsVersion if defined $vsVersion;
537
538     my $installDir = visualStudioInstallDir();
539
540     $vsVersion = ($installDir =~ /Microsoft Visual Studio ([0-9]+\.[0-9]*)/) ? $1 : "14";
541
542     print "Using Visual Studio $vsVersion\n";
543     return $vsVersion;
544 }
545
546 sub determineConfigurationForVisualStudio
547 {
548     return if defined $configurationForVisualStudio;
549     determineConfiguration();
550     # FIXME: We should detect when Debug_All or Production has been chosen.
551     $configurationForVisualStudio = "/p:Configuration=" . $configuration;
552 }
553
554 sub usesPerConfigurationBuildDirectory
555 {
556     # [Gtk] We don't have Release/Debug configurations in straight
557     # autotool builds (non build-webkit). In this case and if
558     # WEBKIT_OUTPUTDIR exist, use that as our configuration dir. This will
559     # allows us to run run-webkit-tests without using build-webkit.
560     return ($ENV{"WEBKIT_OUTPUTDIR"} && isGtk()) || isAppleWinWebKit();
561 }
562
563 sub determineConfigurationProductDir
564 {
565     return if defined $configurationProductDir;
566     determineBaseProductDir();
567     determineConfiguration();
568     if (isAppleWinWebKit() || isWinCairo()) {
569         $configurationProductDir = File::Spec->catdir($baseProductDir, $configuration);
570     } else {
571         if (usesPerConfigurationBuildDirectory()) {
572             $configurationProductDir = "$baseProductDir";
573         } else {
574             $configurationProductDir = "$baseProductDir/$configuration";
575             $configurationProductDir .= "-" . xcodeSDKPlatformName() if isIOSWebKit();
576         }
577     }
578 }
579
580 sub setConfigurationProductDir($)
581 {
582     ($configurationProductDir) = @_;
583 }
584
585 sub determineCurrentSVNRevision
586 {
587     # We always update the current SVN revision here, and leave the caching
588     # to currentSVNRevision(), so that changes to the SVN revision while the
589     # script is running can be picked up by calling this function again.
590     determineSourceDir();
591     $currentSVNRevision = svnRevisionForDirectory($sourceDir);
592     return $currentSVNRevision;
593 }
594
595
596 sub chdirWebKit
597 {
598     determineSourceDir();
599     chdir $sourceDir or die;
600 }
601
602 sub baseProductDir
603 {
604     determineBaseProductDir();
605     return $baseProductDir;
606 }
607
608 sub sourceDir
609 {
610     determineSourceDir();
611     return $sourceDir;
612 }
613
614 sub productDir
615 {
616     determineConfigurationProductDir();
617     return $configurationProductDir;
618 }
619
620 sub executableProductDir
621 {
622     my $productDirectory = productDir();
623
624     my $binaryDirectory;
625     if (isEfl() || isGtk()) {
626         $binaryDirectory = "bin";
627     } elsif (isAnyWindows()) {
628         $binaryDirectory = isWin64() ? "bin64" : "bin32";
629     } else {
630         return $productDirectory;
631     }
632
633     return File::Spec->catdir($productDirectory, $binaryDirectory);
634 }
635
636 sub jscProductDir
637 {
638     return executableProductDir();
639 }
640
641 sub configuration()
642 {
643     determineConfiguration();
644     return $configuration;
645 }
646
647 sub asanIsEnabled()
648 {
649     determineASanIsEnabled();
650     return $asanIsEnabled;
651 }
652
653 sub configurationForVisualStudio()
654 {
655     determineConfigurationForVisualStudio();
656     return $configurationForVisualStudio;
657 }
658
659 sub currentSVNRevision
660 {
661     determineCurrentSVNRevision() if not defined $currentSVNRevision;
662     return $currentSVNRevision;
663 }
664
665 sub generateDsym()
666 {
667     determineGenerateDsym();
668     return $generateDsym;
669 }
670
671 sub determineGenerateDsym()
672 {
673     return if defined($generateDsym);
674     $generateDsym = checkForArgumentAndRemoveFromARGV("--dsym");
675 }
676
677 sub hasIOSDevelopmentCertificate()
678 {
679     return !exitStatus(system("security find-identity -p codesigning | grep '" . IOS_DEVELOPMENT_CERTIFICATE_NAME_PREFIX . "' > /dev/null 2>&1"));
680 }
681
682 sub argumentsForXcode()
683 {
684     my @args = ();
685     push @args, "DEBUG_INFORMATION_FORMAT=dwarf-with-dsym" if generateDsym();
686     return @args;
687 }
688
689 sub XcodeOptions
690 {
691     determineBaseProductDir();
692     determineConfiguration();
693     determineArchitecture();
694     determineASanIsEnabled();
695     determineXcodeSDK();
696
697     my @options;
698     push @options, "-UseSanitizedBuildSystemEnvironment=YES";
699     push @options, ("-configuration", $configuration);
700     push @options, ("-xcconfig", sourceDir() . "/Tools/asan/asan.xcconfig", "ASAN_IGNORE=" . sourceDir() . "/Tools/asan/webkit-asan-ignore.txt") if $asanIsEnabled;
701     push @options, @baseProductDirOption;
702     push @options, "ARCHS=$architecture" if $architecture;
703     push @options, "SDKROOT=$xcodeSDK" if $xcodeSDK;
704     if (willUseIOSDeviceSDKWhenBuilding()) {
705         push @options, "ENABLE_BITCODE=NO";
706         if (hasIOSDevelopmentCertificate()) {
707             # FIXME: May match more than one installed development certificate.
708             push @options, "CODE_SIGN_IDENTITY=" . IOS_DEVELOPMENT_CERTIFICATE_NAME_PREFIX;
709         } else {
710             push @options, "CODE_SIGN_IDENTITY="; # No identity
711             push @options, "CODE_SIGNING_REQUIRED=NO";
712         }
713     }
714     push @options, argumentsForXcode();
715     return @options;
716 }
717
718 sub XcodeOptionString
719 {
720     return join " ", XcodeOptions();
721 }
722
723 sub XcodeOptionStringNoConfig
724 {
725     return join " ", @baseProductDirOption;
726 }
727
728 sub XcodeCoverageSupportOptions()
729 {
730     my @coverageSupportOptions = ();
731     push @coverageSupportOptions, "GCC_GENERATE_TEST_COVERAGE_FILES=YES";
732     push @coverageSupportOptions, "GCC_INSTRUMENT_PROGRAM_FLOW_ARCS=YES";
733     return @coverageSupportOptions;
734 }
735
736 sub XcodeStaticAnalyzerOption()
737 {
738     return "RUN_CLANG_STATIC_ANALYZER=YES";
739 }
740
741 my $passedConfiguration;
742 my $searchedForPassedConfiguration;
743 sub determinePassedConfiguration
744 {
745     return if $searchedForPassedConfiguration;
746     $searchedForPassedConfiguration = 1;
747     $passedConfiguration = undef;
748
749     if (checkForArgumentAndRemoveFromARGV("--debug")) {
750         $passedConfiguration = "Debug";
751     } elsif(checkForArgumentAndRemoveFromARGV("--release")) {
752         $passedConfiguration = "Release";
753     } elsif (checkForArgumentAndRemoveFromARGV("--profile") || checkForArgumentAndRemoveFromARGV("--profiling")) {
754         $passedConfiguration = "Profiling";
755     }
756 }
757
758 sub passedConfiguration
759 {
760     determinePassedConfiguration();
761     return $passedConfiguration;
762 }
763
764 sub setConfiguration
765 {
766     setArchitecture();
767
768     if (my $config = shift @_) {
769         $configuration = $config;
770         return;
771     }
772
773     determinePassedConfiguration();
774     $configuration = $passedConfiguration if $passedConfiguration;
775 }
776
777
778 my $passedArchitecture;
779 my $searchedForPassedArchitecture;
780 sub determinePassedArchitecture
781 {
782     return if $searchedForPassedArchitecture;
783     $searchedForPassedArchitecture = 1;
784
785     $passedArchitecture = undef;
786     if (checkForArgumentAndRemoveFromARGV("--32-bit")) {
787         if (isAppleMacWebKit()) {
788             # PLATFORM_IOS: Don't run `arch` command inside Simulator environment
789             local %ENV = %ENV;
790             delete $ENV{DYLD_ROOT_PATH};
791             delete $ENV{DYLD_FRAMEWORK_PATH};
792
793             $passedArchitecture = `arch`;
794             chomp $passedArchitecture;
795         }
796     }
797 }
798
799 sub passedArchitecture
800 {
801     determinePassedArchitecture();
802     return $passedArchitecture;
803 }
804
805 sub architecture()
806 {
807     determineArchitecture();
808     return $architecture;
809 }
810
811 sub numberOfCPUs()
812 {
813     determineNumberOfCPUs();
814     return $numberOfCPUs;
815 }
816
817 sub maxCPULoad()
818 {
819     determineMaxCPULoad();
820     return $maxCPULoad;
821 }
822
823 sub setArchitecture
824 {
825     if (my $arch = shift @_) {
826         $architecture = $arch;
827         return;
828     }
829
830     determinePassedArchitecture();
831     $architecture = $passedArchitecture if $passedArchitecture;
832 }
833
834 sub skipSafariExecutableEntitlementChecks
835 {
836     return `defaults read /Library/Preferences/org.webkit.BuildConfiguration SkipSafariExecutableEntitlementChecks 2>/dev/null` eq "1\n";
837 }
838
839 sub executableHasEntitlements
840 {
841     my $executablePath = shift;
842     return (`codesign -d --entitlements - $executablePath 2>&1` =~ /<key>/);
843 }
844
845 sub safariPathFromSafariBundle
846 {
847     my ($safariBundle) = @_;
848
849     die "Safari path is only relevant on Apple Mac platform\n" unless isAppleMacWebKit();
850
851     my $safariPath = "$safariBundle/Contents/MacOS/Safari";
852     return $safariPath if skipSafariExecutableEntitlementChecks();
853
854     my $safariForWebKitDevelopmentPath = "$safariBundle/Contents/MacOS/SafariForWebKitDevelopment";
855     return $safariForWebKitDevelopmentPath if -f $safariForWebKitDevelopmentPath && executableHasEntitlements($safariPath);
856
857     return $safariPath;
858 }
859
860 sub installedSafariPath
861 {
862     return safariPathFromSafariBundle("/Applications/Safari.app");
863 }
864
865 # Locate Safari.
866 sub safariPath
867 {
868     die "Safari path is only relevant on Apple Mac platform\n" unless isAppleMacWebKit();
869
870     # Use WEBKIT_SAFARI environment variable if present.
871     my $safariBundle = $ENV{WEBKIT_SAFARI};
872     if (!$safariBundle) {
873         determineConfigurationProductDir();
874         # Use Safari.app in product directory if present (good for Safari development team).
875         if (-d "$configurationProductDir/Safari.app") {
876             $safariBundle = "$configurationProductDir/Safari.app";
877         }
878         if (!$safariBundle) {
879             return installedSafariPath();
880         }
881     }
882     my $safariPath = safariPathFromSafariBundle($safariBundle);
883     die "Can't find executable at $safariPath.\n" if !-x $safariPath;
884     return $safariPath;
885 }
886
887 sub builtDylibPathForName
888 {
889     my $libraryName = shift;
890     determineConfigurationProductDir();
891
892     if (isGtk()) {
893         my $extension = isDarwin() ? ".dylib" : ".so";
894         return "$configurationProductDir/lib/libwebkit2gtk-4.0" . $extension;
895     }
896     if (isEfl()) {
897         return "$configurationProductDir/lib/libewebkit2.so";
898     }
899     if (isIOSWebKit()) {
900         return "$configurationProductDir/$libraryName.framework/$libraryName";
901     }
902     if (isAppleMacWebKit()) {
903         return "$configurationProductDir/$libraryName.framework/Versions/A/$libraryName";
904     }
905     if (isAppleWinWebKit()) {
906         if ($libraryName eq "JavaScriptCore") {
907             return "$baseProductDir/lib/$libraryName.lib";
908         } else {
909             return "$baseProductDir/$libraryName.intermediate/$configuration/$libraryName.intermediate/$libraryName.lib";
910         }
911     }
912
913     die "Unsupported platform, can't determine built library locations.\nTry `build-webkit --help` for more information.\n";
914 }
915
916 # Check to see that all the frameworks are built.
917 sub checkFrameworks # FIXME: This is a poor name since only the Mac calls built WebCore a Framework.
918 {
919     return if isCygwin() || isWindows();
920     my @frameworks = ("JavaScriptCore", "WebCore");
921     push(@frameworks, "WebKit") if isAppleMacWebKit(); # FIXME: This seems wrong, all ports should have a WebKit these days.
922     for my $framework (@frameworks) {
923         my $path = builtDylibPathForName($framework);
924         die "Can't find built framework at \"$path\".\n" unless -e $path;
925     }
926 }
927
928 sub isInspectorFrontend()
929 {
930     determineIsInspectorFrontend();
931     return $isInspectorFrontend;
932 }
933
934 sub determineIsInspectorFrontend()
935 {
936     return if defined($isInspectorFrontend);
937     $isInspectorFrontend = checkForArgumentAndRemoveFromARGV("--inspector-frontend");
938 }
939
940 sub commandExists($)
941 {
942     my $command = shift;
943     my $devnull = File::Spec->devnull();
944
945     if (isAnyWindows()) {
946         return exitStatus(system("where /q $command >$devnull 2>&1")) == 0;
947     }
948     return exitStatus(system("which $command >$devnull 2>&1")) == 0;
949 }
950
951 sub checkForArgumentAndRemoveFromARGV($)
952 {
953     my $argToCheck = shift;
954     return checkForArgumentAndRemoveFromArrayRef($argToCheck, \@ARGV);
955 }
956
957 sub checkForArgumentAndRemoveFromArrayRefGettingValue($$$)
958 {
959     my ($argToCheck, $valueRef, $arrayRef) = @_;
960     my $argumentStartRegEx = qr#^$argToCheck(?:=\S|$)#;
961     my $i = 0;
962     for (; $i < @$arrayRef; ++$i) {
963         last if $arrayRef->[$i] =~ $argumentStartRegEx;
964     }
965     if ($i >= @$arrayRef) {
966         return $$valueRef = undef;
967     }
968     my ($key, $value) = split("=", $arrayRef->[$i]);
969     splice(@$arrayRef, $i, 1);
970     if (defined($value)) {
971         # e.g. --sdk=iphonesimulator
972         return $$valueRef = $value;
973     }
974     return $$valueRef = splice(@$arrayRef, $i, 1); # e.g. --sdk iphonesimulator
975 }
976
977 sub checkForArgumentAndRemoveFromARGVGettingValue($$)
978 {
979     my ($argToCheck, $valueRef) = @_;
980     return checkForArgumentAndRemoveFromArrayRefGettingValue($argToCheck, $valueRef, \@ARGV);
981 }
982
983 sub findMatchingArguments($$)
984 {
985     my ($argToCheck, $arrayRef) = @_;
986     my @matchingIndices;
987     foreach my $index (0 .. $#$arrayRef) {
988         my $opt = $$arrayRef[$index];
989         if ($opt =~ /^$argToCheck$/i ) {
990             push(@matchingIndices, $index);
991         }
992     }
993     return @matchingIndices; 
994 }
995
996 sub hasArgument($$)
997 {
998     my ($argToCheck, $arrayRef) = @_;
999     my @matchingIndices = findMatchingArguments($argToCheck, $arrayRef);
1000     return scalar @matchingIndices > 0;
1001 }
1002
1003 sub checkForArgumentAndRemoveFromArrayRef
1004 {
1005     my ($argToCheck, $arrayRef) = @_;
1006     my @indicesToRemove = findMatchingArguments($argToCheck, $arrayRef);
1007     my $removeOffset = 0;
1008     foreach my $index (@indicesToRemove) {
1009         splice(@$arrayRef, $index - $removeOffset++, 1);
1010     }
1011     return scalar @indicesToRemove > 0;
1012 }
1013
1014 sub determineIsEfl()
1015 {
1016     return if defined($isEfl);
1017     $isEfl = checkForArgumentAndRemoveFromARGV("--efl");
1018 }
1019
1020 sub isEfl()
1021 {
1022     determineIsEfl();
1023     return $isEfl;
1024 }
1025
1026 sub determineIsGtk()
1027 {
1028     return if defined($isGtk);
1029     $isGtk = checkForArgumentAndRemoveFromARGV("--gtk");
1030 }
1031
1032 sub isGtk()
1033 {
1034     determineIsGtk();
1035     return $isGtk;
1036 }
1037
1038 # Determine if this is debian, ubuntu, linspire, or something similar.
1039 sub isDebianBased()
1040 {
1041     return -e "/etc/debian_version";
1042 }
1043
1044 sub isFedoraBased()
1045 {
1046     return -e "/etc/fedora-release";
1047 }
1048
1049 sub isWinCairo()
1050 {
1051     determineIsWinCairo();
1052     return $isWinCairo;
1053 }
1054
1055 sub determineIsWinCairo()
1056 {
1057     return if defined($isWinCairo);
1058     $isWinCairo = checkForArgumentAndRemoveFromARGV("--wincairo");
1059 }
1060
1061 sub isWin64()
1062 {
1063     determineIsWin64();
1064     return $isWin64;
1065 }
1066
1067 sub determineIsWin64()
1068 {
1069     return if defined($isWin64);
1070     $isWin64 = checkForArgumentAndRemoveFromARGV("--64-bit");
1071 }
1072
1073 sub determineIsWin64FromArchitecture($)
1074 {
1075     my $arch = shift;
1076     $isWin64 = ($arch eq "x86_64");
1077     return $isWin64;
1078 }
1079
1080 sub isCygwin()
1081 {
1082     return ($^O eq "cygwin") || 0;
1083 }
1084
1085 sub isAnyWindows()
1086 {
1087     return isWindows() || isCygwin();
1088 }
1089
1090 sub determineWinVersion()
1091 {
1092     return if $winVersion;
1093
1094     if (!isAnyWindows()) {
1095         $winVersion = -1;
1096         return;
1097     }
1098
1099     my $versionString = `cmd /c ver`;
1100     $versionString =~ /(\d)\.(\d)\.(\d+)/;
1101
1102     $winVersion = {
1103         major => $1,
1104         minor => $2,
1105         build => $3,
1106     };
1107 }
1108
1109 sub winVersion()
1110 {
1111     determineWinVersion();
1112     return $winVersion;
1113 }
1114
1115 sub isWindows7SP0()
1116 {
1117     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 1 && winVersion()->{build} == 7600;
1118 }
1119
1120 sub isWindowsVista()
1121 {
1122     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 0;
1123 }
1124
1125 sub isWindowsXP()
1126 {
1127     return isAnyWindows() && winVersion()->{major} == 5 && winVersion()->{minor} == 1;
1128 }
1129
1130 sub isDarwin()
1131 {
1132     return ($^O eq "darwin") || 0;
1133 }
1134
1135 sub isWindows()
1136 {
1137     return ($^O eq "MSWin32") || 0;
1138 }
1139
1140 sub isLinux()
1141 {
1142     return ($^O eq "linux") || 0;
1143 }
1144
1145 sub isBSD()
1146 {
1147     return ($^O eq "freebsd") || ($^O eq "openbsd") || ($^O eq "netbsd") || 0;
1148 }
1149
1150 sub isARM()
1151 {
1152     return ($Config{archname} =~ /^arm[v\-]/) || ($Config{archname} =~ /^aarch64[v\-]/);
1153 }
1154
1155 sub isCrossCompilation()
1156 {
1157   my $compiler = "";
1158   $compiler = $ENV{'CC'} if (defined($ENV{'CC'}));
1159   if ($compiler =~ /gcc/) {
1160       my $compiler_options = `$compiler -v 2>&1`;
1161       my @host = $compiler_options =~ m/--host=(.*?)\s/;
1162       my @target = $compiler_options =~ m/--target=(.*?)\s/;
1163
1164       return ($host[0] ne "" && $target[0] ne "" && $host[0] ne $target[0]);
1165   }
1166   return 0;
1167 }
1168
1169 sub isAppleWebKit()
1170 {
1171     return isAppleMacWebKit() || isAppleWinWebKit();
1172 }
1173
1174 sub isAppleMacWebKit()
1175 {
1176     return isDarwin() && !isGtk();
1177 }
1178
1179 sub isAppleWinWebKit()
1180 {
1181     return (isCygwin() || isWindows()) && !isWinCairo() && !isGtk();
1182 }
1183
1184 sub iOSSimulatorDevicesPath
1185 {
1186     return "$ENV{HOME}/Library/Developer/CoreSimulator/Devices";
1187 }
1188
1189 sub iOSSimulatorDevices
1190 {
1191     eval "require Foundation";
1192     my $devicesPath = iOSSimulatorDevicesPath();
1193     opendir(DEVICES, $devicesPath);
1194     my @udids = grep {
1195         $_ =~ m/[0-9A-F]{8}-([0-9A-F]{4}-){3}[0-9A-F]{12}/;
1196     } readdir(DEVICES);
1197     close(DEVICES);
1198
1199     # FIXME: We should parse the device.plist file ourself and map the dictionary keys in it to known
1200     #        dictionary keys so as to decouple our representation of the plist from the actual structure
1201     #        of the plist, which may change.
1202     my @devices = map {
1203         Foundation::perlRefFromObjectRef(NSDictionary->dictionaryWithContentsOfFile_("$devicesPath/$_/device.plist"));
1204     } @udids;
1205
1206     return @devices;
1207 }
1208
1209 sub createiOSSimulatorDevice
1210 {
1211     my $name = shift;
1212     my $deviceTypeId = shift;
1213     my $runtimeId = shift;
1214
1215     my $created = system("xcrun", "--sdk", "iphonesimulator", "simctl", "create", $name, $deviceTypeId, $runtimeId) == 0;
1216     die "Couldn't create simulator device: $name $deviceTypeId $runtimeId" if not $created;
1217
1218     system("xcrun", "--sdk", "iphonesimulator", "simctl", "list");
1219
1220     print "Waiting for device to be created ...\n";
1221     sleep 5;
1222     for (my $tries = 0; $tries < 5; $tries++){
1223         my @devices = iOSSimulatorDevices();
1224         foreach my $device (@devices) {
1225             return $device if $device->{name} eq $name and $device->{deviceType} eq $deviceTypeId and $device->{runtime} eq $runtimeId;
1226         }
1227         sleep 5;
1228     }
1229     die "Device $name $deviceTypeId $runtimeId wasn't found in " . iOSSimulatorDevicesPath();
1230 }
1231
1232 sub willUseIOSDeviceSDKWhenBuilding()
1233 {
1234     return xcodeSDKPlatformName() eq "iphoneos";
1235 }
1236
1237 sub willUseIOSSimulatorSDKWhenBuilding()
1238 {
1239     return xcodeSDKPlatformName() eq "iphonesimulator";
1240 }
1241
1242 sub isIOSWebKit()
1243 {
1244     determineXcodeSDK();
1245     return isAppleMacWebKit() && (willUseIOSDeviceSDKWhenBuilding() || willUseIOSSimulatorSDKWhenBuilding());
1246 }
1247
1248 sub determineNmPath()
1249 {
1250     return if $nmPath;
1251
1252     if (isAppleMacWebKit()) {
1253         $nmPath = `xcrun -find nm`;
1254         chomp $nmPath;
1255     }
1256     $nmPath = "nm" if !$nmPath;
1257 }
1258
1259 sub nmPath()
1260 {
1261     determineNmPath();
1262     return $nmPath;
1263 }
1264
1265 sub splitVersionString
1266 {
1267     my $versionString = shift;
1268     my @splitVersion = split(/\./, $versionString);
1269     @splitVersion >= 2 or die "Invalid version $versionString";
1270     $osXVersion = {
1271             "major" => $splitVersion[0],
1272             "minor" => $splitVersion[1],
1273             "subminor" => (defined($splitVersion[2]) ? $splitVersion[2] : 0),
1274     };
1275 }
1276
1277 sub determineOSXVersion()
1278 {
1279     return if $osXVersion;
1280
1281     if (!isDarwin()) {
1282         $osXVersion = -1;
1283         return;
1284     }
1285
1286     my $versionString = `sw_vers -productVersion`;
1287     $osXVersion = splitVersionString($versionString);
1288 }
1289
1290 sub osXVersion()
1291 {
1292     determineOSXVersion();
1293     return $osXVersion;
1294 }
1295
1296 sub determineIOSVersion()
1297 {
1298     return if $iosVersion;
1299
1300     if (!isIOSWebKit()) {
1301         $iosVersion = -1;
1302         return;
1303     }
1304
1305     my $versionString = xcodeSDKVersion();
1306     $iosVersion = splitVersionString($versionString);
1307 }
1308
1309 sub iosVersion()
1310 {
1311     determineIOSVersion();
1312     return $iosVersion;
1313 }
1314
1315 sub isWindowsNT()
1316 {
1317     return $ENV{'OS'} eq 'Windows_NT';
1318 }
1319
1320 sub shouldTargetWebProcess
1321 {
1322     determineShouldTargetWebProcess();
1323     return $shouldTargetWebProcess;
1324 }
1325
1326 sub determineShouldTargetWebProcess
1327 {
1328     return if defined($shouldTargetWebProcess);
1329     $shouldTargetWebProcess = checkForArgumentAndRemoveFromARGV("--target-web-process");
1330 }
1331
1332 sub shouldUseXPCServiceForWebProcess
1333 {
1334     determineShouldUseXPCServiceForWebProcess();
1335     return $shouldUseXPCServiceForWebProcess;
1336 }
1337
1338 sub determineShouldUseXPCServiceForWebProcess
1339 {
1340     return if defined($shouldUseXPCServiceForWebProcess);
1341     $shouldUseXPCServiceForWebProcess = checkForArgumentAndRemoveFromARGV("--use-web-process-xpc-service");
1342 }
1343
1344 sub debugger
1345 {
1346     determineDebugger();
1347     return $debugger;
1348 }
1349
1350 sub determineDebugger
1351 {
1352     return if defined($debugger);
1353
1354     determineXcodeVersion();
1355     if (eval "v$xcodeVersion" ge v4.5) {
1356         $debugger = "lldb";
1357     } else {
1358         $debugger = "gdb";
1359     }
1360
1361     if (checkForArgumentAndRemoveFromARGV("--use-lldb")) {
1362         $debugger = "lldb";
1363     }
1364
1365     if (checkForArgumentAndRemoveFromARGV("--use-gdb")) {
1366         $debugger = "gdb";
1367     }
1368 }
1369
1370 sub appendToEnvironmentVariableList
1371 {
1372     my ($environmentVariableName, $value) = @_;
1373
1374     if (defined($ENV{$environmentVariableName})) {
1375         $ENV{$environmentVariableName} .= ":" . $value;
1376     } else {
1377         $ENV{$environmentVariableName} = $value;
1378     }
1379 }
1380
1381 sub sharedCommandLineOptions()
1382 {
1383     return (
1384         "g|guard-malloc" => \$shouldUseGuardMalloc,
1385     );
1386 }
1387
1388 sub sharedCommandLineOptionsUsage
1389 {
1390     my %opts = @_;
1391
1392     my %switches = (
1393         '-g|--guard-malloc' => 'Use guardmalloc when running executable',
1394     );
1395
1396     my $indent = " " x ($opts{indent} || 2);
1397     my $switchWidth = List::Util::max(int($opts{switchWidth}), List::Util::max(map { length($_) } keys %switches) + ($opts{brackets} ? 2 : 0));
1398
1399     my $result = "Common switches:\n";
1400
1401     for my $switch (keys %switches) {
1402         my $switchName = $opts{brackets} ? "[" . $switch . "]" : $switch;
1403         $result .= sprintf("%s%-" . $switchWidth . "s %s\n", $indent, $switchName, $switches{$switch});
1404     }
1405
1406     return $result;
1407 }
1408
1409 sub setUpGuardMallocIfNeeded
1410 {
1411     if (!isDarwin()) {
1412         return;
1413     }
1414
1415     if (!defined($shouldUseGuardMalloc)) {
1416         $shouldUseGuardMalloc = checkForArgumentAndRemoveFromARGV("-g") || checkForArgumentAndRemoveFromARGV("--guard-malloc");
1417     }
1418
1419     if ($shouldUseGuardMalloc) {
1420         appendToEnvironmentVariableList("DYLD_INSERT_LIBRARIES", "/usr/lib/libgmalloc.dylib");
1421     }
1422 }
1423
1424 sub relativeScriptsDir()
1425 {
1426     my $scriptDir = File::Spec->catpath("", File::Spec->abs2rel($FindBin::Bin, getcwd()), "");
1427     if ($scriptDir eq "") {
1428         $scriptDir = ".";
1429     }
1430     return $scriptDir;
1431 }
1432
1433 sub launcherPath()
1434 {
1435     my $relativeScriptsPath = relativeScriptsDir();
1436     if (isGtk() || isEfl()) {
1437         return "$relativeScriptsPath/run-minibrowser";
1438     } elsif (isAppleWebKit()) {
1439         return "$relativeScriptsPath/run-safari";
1440     }
1441 }
1442
1443 sub launcherName()
1444 {
1445     if (isGtk() || isEfl()) {
1446         return "MiniBrowser";
1447     } elsif (isAppleMacWebKit()) {
1448         return "Safari";
1449     } elsif (isAppleWinWebKit()) {
1450         return "MiniBrowser";
1451     }
1452 }
1453
1454 sub checkRequiredSystemConfig
1455 {
1456     if (isDarwin()) {
1457         chomp(my $productVersion = `sw_vers -productVersion`);
1458         if (eval "v$productVersion" lt v10.7.5) {
1459             print "*************************************************************\n";
1460             print "Mac OS X Version 10.7.5 or later is required to build WebKit.\n";
1461             print "You have " . $productVersion . ", thus the build will most likely fail.\n";
1462             print "*************************************************************\n";
1463         }
1464         my $xcodebuildVersionOutput = `xcodebuild -version`;
1465         my $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : undef;
1466         if (!$xcodeVersion || $xcodeVersion && eval "v$xcodeVersion" lt v4.6) {
1467             print "*************************************************************\n";
1468             print "Xcode Version 4.6 or later is required to build WebKit.\n";
1469             print "You have an earlier version of Xcode, thus the build will\n";
1470             print "most likely fail. The latest Xcode is available from the App Store.\n";
1471             print "*************************************************************\n";
1472         }
1473     } elsif (isGtk() or isEfl() or isWindows() or isCygwin()) {
1474         my @cmds = qw(bison gperf flex);
1475         my @missing = ();
1476         my $oldPath = $ENV{PATH};
1477         foreach my $cmd (@cmds) {
1478             push @missing, $cmd if not commandExists($cmd);
1479         }
1480
1481         if (@missing) {
1482             my $list = join ", ", @missing;
1483             die "ERROR: $list missing but required to build WebKit.\n";
1484         }
1485     }
1486     # Win32 and other platforms may want to check for minimum config
1487 }
1488
1489 sub determineWindowsSourceDir()
1490 {
1491     return if $windowsSourceDir;
1492     $windowsSourceDir = sourceDir();
1493     chomp($windowsSourceDir = `cygpath -w '$windowsSourceDir'`) if isCygwin();
1494 }
1495
1496 sub windowsSourceDir()
1497 {
1498     determineWindowsSourceDir();
1499     return $windowsSourceDir;
1500 }
1501
1502 sub windowsSourceSourceDir()
1503 {
1504     return File::Spec->catdir(windowsSourceDir(), "Source");
1505 }
1506
1507 sub windowsLibrariesDir()
1508 {
1509     return File::Spec->catdir(windowsSourceDir(), "WebKitLibraries", "win");
1510 }
1511
1512 sub windowsOutputDir()
1513 {
1514     return File::Spec->catdir(windowsSourceDir(), "WebKitBuild");
1515 }
1516
1517 sub fontExists($)
1518 {
1519     my $font = shift;
1520     my $cmd = "reg query \"HKLM\\SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\Fonts\\" . $font ."\" 2>&1";
1521     my $val = `$cmd`;
1522     return $? == 0;
1523 }
1524
1525 sub checkInstalledTools()
1526 {
1527     # environment variables. Avoid until this is corrected.
1528     my $pythonVer = `python --version 2>&1`;
1529     die "You must have Python installed to build WebKit.\n" if ($?);
1530
1531     # cURL 7.34.0 has a bug that prevents authentication with opensource.apple.com (and other things using SSL3).
1532     my $curlVer = `curl --version 2> NUL`;
1533     if (!$? and $curlVer =~ "(.*curl.*)") {
1534         $curlVer = $1;
1535         if ($curlVer =~ /libcurl\/7\.34\.0/) {
1536             print "cURL version 7.34.0 has a bug that prevents authentication with SSL v2 or v3.\n";
1537             print "cURL 7.33.0 is known to work. The cURL projects is preparing an update to\n";
1538             print "correct this problem.\n\n";
1539             die "Please install a working cURL and try again.\n";
1540         }
1541     }
1542
1543     # MathML requires fonts that do not ship with Windows (at least through Windows 8). Warn the user if they are missing
1544     my @fonts = qw(STIXGeneral-Regular MathJax_Main-Regular);
1545     my @missing = ();
1546     foreach my $font (@fonts) {
1547         push @missing, $font if not fontExists($font);
1548     }
1549
1550     if (scalar @missing > 0) {
1551         print "*************************************************************\n";
1552         print "Mathematical fonts, such as STIX and MathJax, are needed to\n";
1553         print "use the MathML feature.  You do not appear to have these fonts\n";
1554         print "on your system.\n\n";
1555         print "You can download a suitable set of fonts from the following URL:\n";
1556         print "https://developer.mozilla.org/Mozilla/MathML_Projects/Fonts\n";
1557         print "*************************************************************\n";
1558     }
1559
1560     print "Installed tools are correct for the WebKit build.\n";
1561 }
1562
1563 sub setupAppleWinEnv()
1564 {
1565     return unless isAppleWinWebKit();
1566
1567     checkInstalledTools();
1568
1569     if (isWindowsNT()) {
1570         my $restartNeeded = 0;
1571         my %variablesToSet = ();
1572
1573         # FIXME: We should remove this explicit version check for cygwin once we stop supporting Cygwin 1.7.9 or older versions. 
1574         # https://bugs.webkit.org/show_bug.cgi?id=85791
1575         my $uname_version = (POSIX::uname())[2];
1576         $uname_version =~ s/\(.*\)//;  # Remove the trailing cygwin version, if any.
1577         $uname_version =~ s/\-.*$//; # Remove trailing dash-version content, if any
1578         if (version->parse($uname_version) < version->parse("1.7.10")) {
1579             # Setting the environment variable 'CYGWIN' to 'tty' makes cygwin enable extra support (i.e., termios)
1580             # for UNIX-like ttys in the Windows console
1581             $variablesToSet{CYGWIN} = "tty" unless $ENV{CYGWIN};
1582         }
1583         
1584         # Those environment variables must be set to be able to build inside Visual Studio.
1585         $variablesToSet{WEBKIT_LIBRARIES} = windowsLibrariesDir() unless $ENV{WEBKIT_LIBRARIES};
1586         $variablesToSet{WEBKIT_OUTPUTDIR} = windowsOutputDir() unless $ENV{WEBKIT_OUTPUTDIR};
1587         $variablesToSet{MSBUILDDISABLENODEREUSE} = "1" unless $ENV{MSBUILDDISABLENODEREUSE};
1588         $variablesToSet{_IsNativeEnvironment} = "true" unless $ENV{_IsNativeEnvironment};
1589         $variablesToSet{PreferredToolArchitecture} = "x64" unless $ENV{PreferredToolArchitecture};
1590
1591         foreach my $variable (keys %variablesToSet) {
1592             print "Setting the Environment Variable '" . $variable . "' to '" . $variablesToSet{$variable} . "'\n\n";
1593             my $ret = system "setx", $variable, $variablesToSet{$variable};
1594             if ($ret != 0) {
1595                 system qw(regtool -s set), '\\HKEY_CURRENT_USER\\Environment\\' . $variable, $variablesToSet{$variable};
1596             }
1597             $restartNeeded ||=  $variable eq "WEBKIT_LIBRARIES" || $variable eq "WEBKIT_OUTPUTDIR";
1598         }
1599
1600         if ($restartNeeded) {
1601             print "Please restart your computer before attempting to build inside Visual Studio.\n\n";
1602         }
1603     } else {
1604         if (!defined $ENV{'WEBKIT_LIBRARIES'} || !$ENV{'WEBKIT_LIBRARIES'}) {
1605             print "Warning: You must set the 'WebKit_Libraries' environment variable\n";
1606             print "         to be able build WebKit from within Visual Studio 2013 and newer.\n";
1607             print "         Make sure that 'WebKit_Libraries' points to the\n";
1608             print "         'WebKitLibraries/win' directory, not the 'WebKitLibraries/' directory.\n\n";
1609         }
1610         if (!defined $ENV{'WEBKIT_OUTPUTDIR'} || !$ENV{'WEBKIT_OUTPUTDIR'}) {
1611             print "Warning: You must set the 'WebKit_OutputDir' environment variable\n";
1612             print "         to be able build WebKit from within Visual Studio 2013 and newer.\n\n";
1613         }
1614         if (!defined $ENV{'MSBUILDDISABLENODEREUSE'} || !$ENV{'MSBUILDDISABLENODEREUSE'}) {
1615             print "Warning: You should set the 'MSBUILDDISABLENODEREUSE' environment variable to '1'\n";
1616             print "         to avoid periodic locked log files when building.\n\n";
1617         }
1618     }
1619     # FIXME (125180): Remove the following temporary 64-bit support once official support is available.
1620     if (isWin64() and !$ENV{'WEBKIT_64_SUPPORT'}) {
1621         print "Warning: You must set the 'WEBKIT_64_SUPPORT' environment variable\n";
1622         print "         to be able run WebKit or JavaScriptCore tests.\n\n";
1623     }
1624 }
1625
1626 sub setupCygwinEnv()
1627 {
1628     return if !isCygwin() && !isWindows();
1629     return if $vcBuildPath;
1630
1631     my $programFilesPath = programFilesPath();
1632     my $visualStudioPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.com));
1633     if (-e $visualStudioPath) {
1634         # Visual Studio is installed;
1635         if (visualStudioVersion() eq "12") {
1636             $visualStudioPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.exe));
1637         }
1638     } else {
1639         # Visual Studio not found, try VC++ Express
1640         $visualStudioPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE WDExpress.exe));
1641         if (! -e $visualStudioPath) {
1642             print "*************************************************************\n";
1643             print "Cannot find '$visualStudioPath'\n";
1644             print "Please execute the file 'vcvars32.bat' from\n";
1645             print "'$programFilesPath\\Microsoft Visual Studio 14.0\\VC\\bin\\'\n";
1646             print "to setup the necessary environment variables.\n";
1647             print "*************************************************************\n";
1648             die;
1649         }
1650         $willUseVCExpressWhenBuilding = 1;
1651     }
1652
1653     print "Building results into: ", baseProductDir(), "\n";
1654     print "WEBKIT_OUTPUTDIR is set to: ", $ENV{"WEBKIT_OUTPUTDIR"}, "\n";
1655     print "WEBKIT_LIBRARIES is set to: ", $ENV{"WEBKIT_LIBRARIES"}, "\n";
1656     # FIXME (125180): Remove the following temporary 64-bit support once official support is available.
1657     print "WEBKIT_64_SUPPORT is set to: ", $ENV{"WEBKIT_64_SUPPORT"}, "\n" if isWin64();
1658
1659     # We will actually use MSBuild to build WebKit, but we need to find the Visual Studio install (above) to make
1660     # sure we use the right options.
1661     $vcBuildPath = File::Spec->catfile(msBuildInstallDir(), qw(MSBuild.exe));
1662     if (! -e $vcBuildPath) {
1663         print "*************************************************************\n";
1664         print "Cannot find '$vcBuildPath'\n";
1665         print "Please make sure execute that the Microsoft .NET Framework SDK\n";
1666         print "is installed on this machine.\n";
1667         print "*************************************************************\n";
1668         die;
1669     }
1670 }
1671
1672 sub dieIfWindowsPlatformSDKNotInstalled
1673 {
1674     my $registry32Path = "/proc/registry/";
1675     my $registry64Path = "/proc/registry64/";
1676     my @windowsPlatformSDKRegistryEntries = (
1677         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0A",
1678         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0",
1679         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.1A",
1680         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.0A",
1681         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/MicrosoftSDK/InstalledSDKs/D2FF9F89-8AA2-4373-8A31-C838BF4DBBE1",
1682     );
1683
1684     # FIXME: It would be better to detect whether we are using 32- or 64-bit Windows
1685     # and only check the appropriate entry. But for now we just blindly check both.
1686     my $recommendedPlatformSDK = $windowsPlatformSDKRegistryEntries[0];
1687
1688     while (@windowsPlatformSDKRegistryEntries) {
1689         my $windowsPlatformSDKRegistryEntry = shift @windowsPlatformSDKRegistryEntries;
1690         return if (-e $registry32Path . $windowsPlatformSDKRegistryEntry) || (-e $registry64Path . $windowsPlatformSDKRegistryEntry);
1691     }
1692
1693     print "*************************************************************\n";
1694     print "Cannot find registry entry '$recommendedPlatformSDK'.\n";
1695     print "Please download and install the Microsoft Windows SDK\n";
1696     print "from <http://www.microsoft.com/en-us/download/details.aspx?id=8279>.\n\n";
1697     print "Then follow step 2 in the Windows section of the \"Installing Developer\n";
1698     print "Tools\" instructions at <http://www.webkit.org/building/tools.html>.\n";
1699     print "*************************************************************\n";
1700     die;
1701 }
1702
1703 sub buildXCodeProject($$@)
1704 {
1705     my ($project, $clean, @extraOptions) = @_;
1706
1707     if ($clean) {
1708         push(@extraOptions, "-alltargets");
1709         push(@extraOptions, "clean");
1710     }
1711
1712     push(@extraOptions, ("-sdk", xcodeSDK())) if isIOSWebKit();
1713
1714     chomp($ENV{DSYMUTIL_NUM_THREADS} = `sysctl -n hw.activecpu`);
1715     return system "xcodebuild", "-project", "$project.xcodeproj", @extraOptions;
1716 }
1717
1718 sub usingVisualStudioExpress()
1719 {
1720     setupCygwinEnv();
1721     return $willUseVCExpressWhenBuilding;
1722 }
1723
1724 sub buildVisualStudioProject
1725 {
1726     my ($project, $clean) = @_;
1727     setupCygwinEnv();
1728
1729     my $config = configurationForVisualStudio();
1730
1731     dieIfWindowsPlatformSDKNotInstalled() if $willUseVCExpressWhenBuilding;
1732
1733     chomp($project = `cygpath -w "$project"`) if isCygwin();
1734
1735     my $action = "/t:build";
1736     if ($clean) {
1737         $action = "/t:clean";
1738     }
1739
1740     my $platform = "/p:Platform=" . (isWin64() ? "x64" : "Win32");
1741     my $logPath = File::Spec->catdir($baseProductDir, $configuration);
1742     make_path($logPath) unless -d $logPath or $logPath eq ".";
1743
1744     my $errorLogFile = File::Spec->catfile($logPath, "webkit_errors.log");
1745     chomp($errorLogFile = `cygpath -w "$errorLogFile"`) if isCygwin();
1746     my $errorLogging = "/flp:LogFile=" . $errorLogFile . ";ErrorsOnly";
1747
1748     my $warningLogFile = File::Spec->catfile($logPath, "webkit_warnings.log");
1749     chomp($warningLogFile = `cygpath -w "$warningLogFile"`) if isCygwin();
1750     my $warningLogging = "/flp1:LogFile=" . $warningLogFile . ";WarningsOnly";
1751
1752     my @command = ($vcBuildPath, "/verbosity:minimal", $project, $action, $config, $platform, "/fl", $errorLogging, "/fl1", $warningLogging);
1753     print join(" ", @command), "\n";
1754     return system @command;
1755 }
1756
1757 sub getJhbuildPath()
1758 {
1759     my @jhbuildPath = File::Spec->splitdir(baseProductDir());
1760     if (isGit() && isGitBranchBuild() && gitBranch()) {
1761         pop(@jhbuildPath);
1762     }
1763     if (isEfl()) {
1764         push(@jhbuildPath, "DependenciesEFL");
1765     } elsif (isGtk()) {
1766         push(@jhbuildPath, "DependenciesGTK");
1767     } else {
1768         die "Cannot get JHBuild path for platform that isn't GTK+ or EFL.\n";
1769     }
1770     return File::Spec->catdir(@jhbuildPath);
1771 }
1772
1773 sub isCachedArgumentfileOutOfDate($@)
1774 {
1775     my ($filename, $currentContents) = @_;
1776
1777     if (! -e $filename) {
1778         return 1;
1779     }
1780
1781     open(CONTENTS_FILE, $filename);
1782     chomp(my $previousContents = <CONTENTS_FILE>);
1783     close(CONTENTS_FILE);
1784
1785     if ($previousContents ne $currentContents) {
1786         print "Contents for file $filename have changed.\n";
1787         print "Previous contents were: $previousContents\n\n";
1788         print "New contents are: $currentContents\n";
1789         return 1;
1790     }
1791
1792     return 0;
1793 }
1794
1795 sub jhbuildWrapperPrefixIfNeeded()
1796 {
1797     if (isWindows() || isCygwin()) {
1798         return ();
1799     }
1800     if (-e getJhbuildPath()) {
1801         my @prefix = (File::Spec->catfile(sourceDir(), "Tools", "jhbuild", "jhbuild-wrapper"));
1802         if (isEfl()) {
1803             push(@prefix, "--efl");
1804         } elsif (isGtk()) {
1805             push(@prefix, "--gtk");
1806         }
1807         push(@prefix, "run");
1808
1809         return @prefix;
1810     }
1811
1812     return ();
1813 }
1814
1815 sub cmakeCachePath()
1816 {
1817     return File::Spec->catdir(baseProductDir(), configuration(), "CMakeCache.txt");
1818 }
1819
1820 sub shouldRemoveCMakeCache(@)
1821 {
1822     my ($cacheFilePath, @buildArgs) = @_;
1823
1824     # We check this first, because we always want to create this file for a fresh build.
1825     my $productDir = File::Spec->catdir(baseProductDir(), configuration());
1826     my $optionsCache = File::Spec->catdir($productDir, "build-webkit-options.txt");
1827     my $joinedBuildArgs = join(" ", @buildArgs);
1828     if (isCachedArgumentfileOutOfDate($optionsCache, $joinedBuildArgs)) {
1829         File::Path::mkpath($productDir) unless -d $productDir;
1830         open(CACHED_ARGUMENTS, ">", $optionsCache);
1831         print CACHED_ARGUMENTS $joinedBuildArgs;
1832         close(CACHED_ARGUMENTS);
1833
1834         return 1;
1835     }
1836
1837     my $cmakeCache = cmakeCachePath();
1838     unless (-e $cmakeCache) {
1839         return 0;
1840     }
1841
1842     my $cacheFileModifiedTime = stat($cmakeCache)->mtime;
1843     my $platformConfiguration = File::Spec->catdir(sourceDir(), "Source", "cmake", "Options" . cmakeBasedPortName() . ".cmake");
1844     if ($cacheFileModifiedTime < stat($platformConfiguration)->mtime) {
1845         return 1;
1846     }
1847
1848     my $globalConfiguration = File::Spec->catdir(sourceDir(), "Source", "cmake", "OptionsCommon.cmake");
1849     if ($cacheFileModifiedTime < stat($globalConfiguration)->mtime) {
1850         return 1;
1851     }
1852
1853     my $inspectorUserInterfaceDircetory = File::Spec->catdir(sourceDir(), "Source", "WebInspectorUI", "UserInterface");
1854     if ($cacheFileModifiedTime < stat($inspectorUserInterfaceDircetory)->mtime) {
1855         return 1;
1856     }
1857
1858     return 0;
1859 }
1860
1861 sub removeCMakeCache(@)
1862 {
1863     my (@buildArgs) = @_;
1864     if (shouldRemoveCMakeCache(@buildArgs)) {
1865         my $cmakeCache = cmakeCachePath();
1866         unlink($cmakeCache) if -e $cmakeCache;
1867     }
1868 }
1869
1870 sub canUseNinja(@)
1871 {
1872     if (!defined($shouldNotUseNinja)) {
1873         $shouldNotUseNinja = checkForArgumentAndRemoveFromARGV("--no-ninja");
1874     }
1875
1876     if ($shouldNotUseNinja) {
1877         return 0;
1878     }
1879
1880     # Test both ninja and ninja-build. Fedora uses ninja-build and has patched CMake to also call ninja-build.
1881     return commandExists("ninja") || commandExists("ninja-build");
1882 }
1883
1884 sub canUseEclipse(@)
1885 {
1886     return commandExists("eclipse");
1887 }
1888
1889 sub cmakeGeneratedBuildfile(@)
1890 {
1891     my ($willUseNinja) = @_;
1892     if ($willUseNinja) {
1893         return File::Spec->catfile(baseProductDir(), configuration(), "build.ninja")
1894     } elsif (isWindows() || isCygwin()) {
1895         return File::Spec->catfile(baseProductDir(), configuration(), "WebKit.sln")
1896     } else {
1897         return File::Spec->catfile(baseProductDir(), configuration(), "Makefile")
1898     }
1899 }
1900
1901 sub generateBuildSystemFromCMakeProject
1902 {
1903     my ($port, $prefixPath, @cmakeArgs, $additionalCMakeArgs) = @_;
1904     my $config = configuration();
1905     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
1906     File::Path::mkpath($buildPath) unless -d $buildPath;
1907     my $originalWorkingDirectory = getcwd();
1908     chdir($buildPath) or die;
1909
1910     # We try to be smart about when to rerun cmake, so that we can have faster incremental builds.
1911     my $willUseNinja = canUseNinja();
1912     if (-e cmakeCachePath() && -e cmakeGeneratedBuildfile($willUseNinja)) {
1913         return 0;
1914     }
1915
1916     my @args;
1917     push @args, "-DPORT=\"$port\"";
1918     push @args, "-DCMAKE_INSTALL_PREFIX=\"$prefixPath\"" if $prefixPath;
1919     push @args, "-DCMAKE_EXPORT_COMPILE_COMMANDS=ON" if isGtk();
1920     if ($config =~ /release/i) {
1921         push @args, "-DCMAKE_BUILD_TYPE=Release";
1922     } elsif ($config =~ /debug/i) {
1923         push @args, "-DCMAKE_BUILD_TYPE=Debug";
1924     }
1925
1926     if ($willUseNinja) {
1927         push @args, "-G";
1928         if (canUseEclipse()) {
1929             push @args, "'Eclipse CDT4 - Ninja'";
1930         } else {
1931             push @args, "Ninja";
1932         }
1933     } elsif (isAnyWindows() && isWin64()) {
1934         push @args, '-G "Visual Studio 14 2015 Win64"';
1935     }
1936
1937     # GTK+ has a production mode, but build-webkit should always use developer mode.
1938     push @args, "-DDEVELOPER_MODE=ON" if isEfl() || isGtk();
1939
1940     # Don't warn variables which aren't used by cmake ports.
1941     push @args, "--no-warn-unused-cli";
1942     push @args, @cmakeArgs if @cmakeArgs;
1943     push @args, $additionalCMakeArgs if $additionalCMakeArgs;
1944
1945     my $cmakeSourceDir = isCygwin() ? windowsSourceDir() : sourceDir();
1946     push @args, '"' . $cmakeSourceDir . '"';
1947
1948     # Compiler options to keep floating point values consistent
1949     # between 32-bit and 64-bit architectures.
1950     determineArchitecture();
1951     if ($architecture ne "x86_64" && !isARM() && !isCrossCompilation() && !isWindows() && !isCygwin()) {
1952         $ENV{'CXXFLAGS'} = "-march=pentium4 -msse2 -mfpmath=sse " . ($ENV{'CXXFLAGS'} || "");
1953     }
1954
1955     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
1956     # parsed for shell metacharacters.
1957     my $wrapper = join(" ", jhbuildWrapperPrefixIfNeeded()) . " ";
1958     my $returnCode = system($wrapper . "cmake @args");
1959
1960     chdir($originalWorkingDirectory);
1961     return $returnCode;
1962 }
1963
1964 sub buildCMakeGeneratedProject($)
1965 {
1966     my ($makeArgs) = @_;
1967     my $config = configuration();
1968     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
1969     if (! -d $buildPath) {
1970         die "Must call generateBuildSystemFromCMakeProject() before building CMake project.";
1971     }
1972
1973     my $command = "cmake";
1974     my @args = ("--build", $buildPath, "--config", $config);
1975     push @args, ("--", $makeArgs) if $makeArgs;
1976
1977     # GTK can use a build script to preserve colors and pretty-printing.
1978     if (isGtk() && -e "$buildPath/build.sh") {
1979         chdir "$buildPath" or die;
1980         $command = "$buildPath/build.sh";
1981         @args = ($makeArgs);
1982     }
1983
1984     if ($ENV{VERBOSE} && canUseNinja()) {
1985         push @args, "-v";
1986         push @args, "-d keeprsp" if (version->parse(determineNinjaVersion()) >= version->parse("1.4.0"));
1987     }
1988
1989     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
1990     # parsed for shell metacharacters. In particular, $makeArgs may contain such metacharacters.
1991     my $wrapper = join(" ", jhbuildWrapperPrefixIfNeeded()) . " ";
1992     return system($wrapper . "$command @args");
1993
1994 }
1995
1996 sub cleanCMakeGeneratedProject()
1997 {
1998     my $config = configuration();
1999     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
2000     if (-d $buildPath) {
2001         return system("cmake", "--build", $buildPath, "--config", $config, "--target", "clean");
2002     }
2003     return 0;
2004 }
2005
2006 sub buildCMakeProjectOrExit($$$$@)
2007 {
2008     my ($clean, $port, $prefixPath, $makeArgs, @cmakeArgs) = @_;
2009     my $returnCode;
2010
2011     exit(exitStatus(cleanCMakeGeneratedProject())) if $clean;
2012
2013     if (isEfl() && checkForArgumentAndRemoveFromARGV("--update-efl")) {
2014         system("perl", "$sourceDir/Tools/Scripts/update-webkitefl-libs") == 0 or die $!;
2015     }
2016
2017     if (isGtk() && checkForArgumentAndRemoveFromARGV("--update-gtk")) {
2018         system("perl", "$sourceDir/Tools/Scripts/update-webkitgtk-libs") == 0 or die $!;
2019     }
2020
2021     $returnCode = exitStatus(generateBuildSystemFromCMakeProject($port, $prefixPath, @cmakeArgs));
2022     exit($returnCode) if $returnCode;
2023
2024     $returnCode = exitStatus(buildCMakeGeneratedProject($makeArgs));
2025     exit($returnCode) if $returnCode;
2026     return 0;
2027 }
2028
2029 sub cmakeBasedPortArguments()
2030 {
2031     return ();
2032 }
2033
2034 sub cmakeBasedPortName()
2035 {
2036     return "Efl" if isEfl();
2037     return "GTK" if isGtk();
2038     return "";
2039 }
2040
2041 sub isCMakeBuild()
2042 {
2043     return isEfl() || isGtk();
2044 }
2045
2046 sub promptUser
2047 {
2048     my ($prompt, $default) = @_;
2049     my $defaultValue = $default ? "[$default]" : "";
2050     print "$prompt $defaultValue: ";
2051     chomp(my $input = <STDIN>);
2052     return $input ? $input : $default;
2053 }
2054
2055 sub appleApplicationSupportPath
2056 {
2057     open INSTALL_DIR, "</proc/registry/HKEY_LOCAL_MACHINE/SOFTWARE/Apple\ Inc./Apple\ Application\ Support/InstallDir";
2058     my $path = <INSTALL_DIR>;
2059     $path =~ s/[\r\n\x00].*//;
2060     close INSTALL_DIR;
2061
2062     my $unixPath = `cygpath -u '$path'`;
2063     chomp $unixPath;
2064     return $unixPath;
2065 }
2066
2067 sub setPathForRunningWebKitApp
2068 {
2069     my ($env) = @_;
2070
2071     if (isAnyWindows()) {
2072         my $productBinaryDir = executableProductDir();
2073         if (isAppleWinWebKit()) {
2074             $env->{PATH} = join(':', $productBinaryDir, appleApplicationSupportPath(), $env->{PATH} || "");
2075         } elsif (isWinCairo()) {
2076             my $winCairoBin = sourceDir() . "/WebKitLibraries/win/" . (isWin64() ? "bin64/" : "bin32/");
2077             my $gstreamerBin = isWin64() ? $ENV{"GSTREAMER_1_0_ROOT_X86_64"} . "bin" : $ENV{"GSTREAMER_1_0_ROOT_X86"} . "bin";
2078             $env->{PATH} = join(':', $productBinaryDir, $winCairoBin, $gstreamerBin, $env->{PATH} || "");
2079         }
2080     }
2081 }
2082
2083 sub printHelpAndExitForRunAndDebugWebKitAppIfNeeded
2084 {
2085     return unless checkForArgumentAndRemoveFromARGV("--help");
2086
2087     my ($includeOptionsForDebugging) = @_;
2088
2089     print STDERR <<EOF;
2090 Usage: @{[basename($0)]} [options] [args ...]
2091   --help                            Show this help message
2092   --no-saved-state                  Launch the application without state restoration (OS X 10.7 and later)
2093   -g|--guard-malloc                 Enable Guard Malloc (OS X only)
2094   --use-web-process-xpc-service     Launch the Web Process as an XPC Service (OS X only)
2095 EOF
2096
2097     if ($includeOptionsForDebugging) {
2098         print STDERR <<EOF;
2099   --target-web-process              Debug the web process
2100   --use-gdb                         Use GDB (this is the default when using Xcode 4.4 or earlier)
2101   --use-lldb                        Use LLDB (this is the default when using Xcode 4.5 or later)
2102 EOF
2103     }
2104
2105     exit(1);
2106 }
2107
2108 sub argumentsForRunAndDebugMacWebKitApp()
2109 {
2110     my @args = ();
2111     if (checkForArgumentAndRemoveFromARGV("--no-saved-state")) {
2112         push @args, ("-ApplePersistenceIgnoreStateQuietly", "YES");
2113         # FIXME: Don't set ApplePersistenceIgnoreState once all supported OS versions respect ApplePersistenceIgnoreStateQuietly (rdar://15032886).
2114         push @args, ("-ApplePersistenceIgnoreState", "YES");
2115     }
2116     push @args, ("-WebKit2UseXPCServiceForWebProcess", "YES") if shouldUseXPCServiceForWebProcess();
2117     unshift @args, @ARGV;
2118
2119     return @args;
2120 }
2121
2122 sub setupMacWebKitEnvironment($)
2123 {
2124     my ($dyldFrameworkPath) = @_;
2125
2126     $dyldFrameworkPath = File::Spec->rel2abs($dyldFrameworkPath);
2127
2128     $ENV{DYLD_FRAMEWORK_PATH} = $ENV{DYLD_FRAMEWORK_PATH} ? join(":", $dyldFrameworkPath, $ENV{DYLD_FRAMEWORK_PATH}) : $dyldFrameworkPath;
2129     $ENV{__XPC_DYLD_FRAMEWORK_PATH} = $dyldFrameworkPath;
2130     $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
2131
2132     setUpGuardMallocIfNeeded();
2133 }
2134
2135 sub setupIOSWebKitEnvironment($)
2136 {
2137     my ($dyldFrameworkPath) = @_;
2138     $dyldFrameworkPath = File::Spec->rel2abs($dyldFrameworkPath);
2139
2140     $ENV{DYLD_FRAMEWORK_PATH} = $dyldFrameworkPath;
2141     $ENV{DYLD_LIBRARY_PATH} = $dyldFrameworkPath;
2142
2143     setUpGuardMallocIfNeeded();
2144 }
2145
2146 sub iosSimulatorApplicationsPath()
2147 {
2148     return File::Spec->catdir(XcodeSDKPath(), "Applications");
2149 }
2150
2151 sub installedMobileSafariBundle()
2152 {
2153     return File::Spec->catfile(iosSimulatorApplicationsPath(), "MobileSafari.app");
2154 }
2155
2156 sub mobileSafariBundle()
2157 {
2158     determineConfigurationProductDir();
2159
2160     # Use MobileSafari.app in product directory if present.
2161     if (isAppleMacWebKit() && -d "$configurationProductDir/MobileSafari.app") {
2162         return "$configurationProductDir/MobileSafari.app";
2163     }
2164     return installedMobileSafariBundle();
2165 }
2166
2167 sub plistPathFromBundle($)
2168 {
2169     my ($appBundle) = @_;
2170     return "$appBundle/Info.plist" if -f "$appBundle/Info.plist"; # iOS app bundle
2171     return "$appBundle/Contents/Info.plist" if -f "$appBundle/Contents/Info.plist"; # Mac app bundle
2172     return "";
2173 }
2174
2175 sub appIdentifierFromBundle($)
2176 {
2177     my ($appBundle) = @_;
2178     my $plistPath = File::Spec->rel2abs(plistPathFromBundle($appBundle)); # defaults(1) will complain if the specified path is not absolute.
2179     chomp(my $bundleIdentifier = `defaults read '$plistPath' CFBundleIdentifier 2> /dev/null`);
2180     return $bundleIdentifier;
2181 }
2182
2183 sub appDisplayNameFromBundle($)
2184 {
2185     my ($appBundle) = @_;
2186     my $plistPath = File::Spec->rel2abs(plistPathFromBundle($appBundle)); # defaults(1) will complain if the specified path is not absolute.
2187     chomp(my $bundleDisplayName = `defaults read '$plistPath' CFBundleDisplayName 2> /dev/null`);
2188     return $bundleDisplayName;
2189 }
2190
2191 sub waitUntilIOSSimulatorDeviceIsInState($$)
2192 {
2193     my ($deviceUDID, $waitUntilState) = @_;
2194     my $device = iosSimulatorDeviceByUDID($deviceUDID);
2195     while ($device->{state} ne $waitUntilState) {
2196         usleep(500 * 1000); # Waiting 500ms between file system polls does not make script run-safari feel sluggish.
2197         $device = iosSimulatorDeviceByUDID($deviceUDID);
2198     }
2199 }
2200
2201 sub relaunchIOSSimulator($)
2202 {
2203     my ($simulatedDevice) = @_;
2204     quitIOSSimulator($simulatedDevice->{UDID});
2205
2206     # FIXME: <rdar://problem/20916140> Switch to using CoreSimulator.framework for launching and quitting iOS Simulator
2207     my $iosSimulatorBundleID = "com.apple.iphonesimulator";
2208     system("open", "-b", $iosSimulatorBundleID, "--args", "-CurrentDeviceUDID", $simulatedDevice->{UDID}) == 0 or die "Failed to open $iosSimulatorBundleID: $!";
2209
2210     waitUntilIOSSimulatorDeviceIsInState($simulatedDevice->{UDID}, SIMULATOR_DEVICE_STATE_BOOTED);
2211 }
2212
2213 sub quitIOSSimulator(;$)
2214 {
2215     my ($waitForShutdownOfSimulatedDeviceUDID) = @_;
2216     # FIXME: <rdar://problem/20916140> Switch to using CoreSimulator.framework for launching and quitting iOS Simulator
2217     exitStatus(system {"osascript"} "osascript", "-e", 'tell application id "com.apple.iphonesimulator" to quit') == 0 or die "Failed to quit iOS Simulator: $!";
2218     if (!defined($waitForShutdownOfSimulatedDeviceUDID)) {
2219         return;
2220     }
2221     # FIXME: We assume that $waitForShutdownOfSimulatedDeviceUDID was not booted using the simctl command line tool.
2222     #        Otherwise we will spin indefinitely since quiting the iOS Simulator will not shutdown this device. We
2223     #        should add a maximum time limit to wait for a device to shutdown and either return an error or die()
2224     #        on expiration of the time limit.
2225     waitUntilIOSSimulatorDeviceIsInState($waitForShutdownOfSimulatedDeviceUDID, SIMULATOR_DEVICE_STATE_SHUTDOWN);
2226 }
2227
2228 sub iosSimulatorDeviceByName($)
2229 {
2230     my ($simulatorName) = @_;
2231     my $simulatorRuntime = iosSimulatorRuntime();
2232     my @devices = iOSSimulatorDevices();
2233     for my $device (@devices) {
2234         if ($device->{name} eq $simulatorName && $device->{runtime} eq $simulatorRuntime) {
2235             return $device;
2236         }
2237     }
2238     return undef;
2239 }
2240
2241 sub iosSimulatorDeviceByUDID($)
2242 {
2243     my ($simulatedDeviceUDID) = @_;
2244     my $devicePlistPath = File::Spec->catfile(iOSSimulatorDevicesPath(), $simulatedDeviceUDID, "device.plist");
2245     if (!-f $devicePlistPath) {
2246         return;
2247     }
2248     # FIXME: We should parse the device.plist file ourself and map the dictionary keys in it to known
2249     #        dictionary keys so as to decouple our representation of the plist from the actual structure
2250     #        of the plist, which may change.
2251     eval "require Foundation";
2252     return Foundation::perlRefFromObjectRef(NSDictionary->dictionaryWithContentsOfFile_($devicePlistPath));
2253 }
2254
2255 sub iosSimulatorRuntime()
2256 {
2257     my $xcodeSDKVersion = xcodeSDKVersion();
2258     $xcodeSDKVersion =~ s/\./-/;
2259     return "com.apple.CoreSimulator.SimRuntime.iOS-$xcodeSDKVersion";
2260 }
2261
2262 sub findOrCreateSimulatorForIOSDevice($)
2263 {
2264     my ($simulatorNameSuffix) = @_;
2265     my $simulatorName;
2266     my $simulatorDeviceType;
2267     if (architecture() eq "x86_64") {
2268         $simulatorName = "iPhone 5s " . $simulatorNameSuffix;
2269         $simulatorDeviceType = "com.apple.CoreSimulator.SimDeviceType.iPhone-5s";
2270     } else {
2271         $simulatorName = "iPhone 5 " . $simulatorNameSuffix;
2272         $simulatorDeviceType = "com.apple.CoreSimulator.SimDeviceType.iPhone-5";
2273     }
2274     my $simulatedDevice = iosSimulatorDeviceByName($simulatorName);
2275     return $simulatedDevice if $simulatedDevice;
2276     return createiOSSimulatorDevice($simulatorName, $simulatorDeviceType, iosSimulatorRuntime());
2277 }
2278
2279 sub isIOSSimulatorSystemInstalledApp($)
2280 {
2281     my ($appBundle) = @_;
2282     my $simulatorApplicationsPath = realpath(iosSimulatorApplicationsPath());
2283     return substr(realpath($appBundle), 0, length($simulatorApplicationsPath)) eq $simulatorApplicationsPath;
2284 }
2285
2286 sub hasUserInstalledAppInSimulatorDevice($$)
2287 {
2288     my ($appIdentifier, $simulatedDeviceUDID) = @_;
2289     my $userInstalledAppPath = File::Spec->catfile($ENV{HOME}, "Library", "Developer", "CoreSimulator", "Devices", $simulatedDeviceUDID, "data", "Containers", "Bundle", "Application");
2290     if (!-d $userInstalledAppPath) {
2291         return 0; # No user installed apps.
2292     }
2293     local @::userInstalledAppBundles;
2294     my $wantedFunction = sub {
2295         my $file = $_;
2296
2297         # Ignore hidden files and directories.
2298         if ($file =~ /^\../) {
2299             $File::Find::prune = 1;
2300             return;
2301         }
2302
2303         return if !-d $file || $file !~ /\.app$/;
2304         push @::userInstalledAppBundles, $File::Find::name;
2305         $File::Find::prune = 1; # Do not traverse contents of app bundle.
2306     };
2307     find($wantedFunction, $userInstalledAppPath);
2308     for my $userInstalledAppBundle (@::userInstalledAppBundles) {
2309         if (appIdentifierFromBundle($userInstalledAppBundle) eq $appIdentifier) {
2310             return 1; # Has user installed app.
2311         }
2312     }
2313     return 0; # Does not have user installed app.
2314 }
2315
2316 sub isSimulatorDeviceBooted($)
2317 {
2318     my ($simulatedDeviceUDID) = @_;
2319     my $device = iosSimulatorDeviceByUDID($simulatedDeviceUDID);
2320     return $device && $device->{state} eq SIMULATOR_DEVICE_STATE_BOOTED;
2321 }
2322
2323 sub runIOSWebKitAppInSimulator($;$)
2324 {
2325     my ($appBundle, $simulatorOptions) = @_;
2326     my $productDir = productDir();
2327     my $appDisplayName = appDisplayNameFromBundle($appBundle);
2328     my $appIdentifier = appIdentifierFromBundle($appBundle);
2329     my $simulatedDevice = findOrCreateSimulatorForIOSDevice(SIMULATOR_DEVICE_SUFFIX_FOR_WEBKIT_DEVELOPMENT);
2330     my $simulatedDeviceUDID = $simulatedDevice->{UDID};
2331
2332     my $willUseSystemInstalledApp = isIOSSimulatorSystemInstalledApp($appBundle);
2333     if ($willUseSystemInstalledApp) {
2334         if (hasUserInstalledAppInSimulatorDevice($appIdentifier, $simulatedDeviceUDID)) {
2335             # Restore the system-installed app in the simulator device corresponding to $appBundle as it
2336             # was previously overwritten with a custom built version of the app.
2337             # FIXME: Only restore the system-installed version of the app instead of erasing all contents and settings.
2338             print "Quitting iOS Simulator...\n";
2339             quitIOSSimulator($simulatedDeviceUDID);
2340             print "Erasing contents and settings for simulator device \"$simulatedDevice->{name}\".\n";
2341             exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "erase", $simulatedDeviceUDID)) == 0 or die;
2342         }
2343         # FIXME: We assume that if $simulatedDeviceUDID is not booted then iOS Simulator is not open. However
2344         #        $simulatedDeviceUDID may have been booted using the simctl command line tool. If $simulatedDeviceUDID
2345         #        was booted using simctl then we should shutdown the device and launch iOS Simulator to boot it again.
2346         if (!isSimulatorDeviceBooted($simulatedDeviceUDID)) {
2347             print "Launching iOS Simulator...\n";
2348             relaunchIOSSimulator($simulatedDevice);
2349         }
2350     } else {
2351         # FIXME: We should killall(1) any running instances of $appBundle before installing it to ensure
2352         #        that simctl launch opens the latest installed version of the app. For now we quit and
2353         #        launch the iOS Simulator again to ensure there are no running instances of $appBundle.
2354         print "Quitting and launching iOS Simulator...\n";
2355         relaunchIOSSimulator($simulatedDevice);
2356
2357         print "Installing $appBundle.\n";
2358         # Install custom built app, overwriting an app with the same app identifier if one exists.
2359         exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "install", $simulatedDeviceUDID, $appBundle)) == 0 or die;
2360
2361     }
2362
2363     $simulatorOptions = {} unless $simulatorOptions;
2364
2365     my %simulatorENV;
2366     %simulatorENV = %{$simulatorOptions->{applicationEnvironment}} if $simulatorOptions->{applicationEnvironment};
2367     {
2368         local %ENV; # Shadow global-scope %ENV so that changes to it will not be seen outside of this scope.
2369         setupIOSWebKitEnvironment($productDir);
2370         %simulatorENV = %ENV;
2371     }
2372     my $applicationArguments = \@ARGV;
2373     $applicationArguments = $simulatorOptions->{applicationArguments} if $simulatorOptions && $simulatorOptions->{applicationArguments};
2374
2375     # Prefix the environment variables with SIMCTL_CHILD_ per `xcrun simctl help launch`.
2376     foreach my $key (keys %simulatorENV) {
2377         $ENV{"SIMCTL_CHILD_$key"} = $simulatorENV{$key};
2378     }
2379
2380     print "Starting $appDisplayName with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2381     return exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "launch", $simulatedDeviceUDID, $appIdentifier, @$applicationArguments));
2382 }
2383
2384 sub runIOSWebKitApp($)
2385 {
2386     my ($appBundle) = @_;
2387     if (willUseIOSDeviceSDKWhenBuilding()) {
2388         die "Only running Safari in iOS Simulator is supported now.";
2389     }
2390     if (willUseIOSSimulatorSDKWhenBuilding()) {
2391         return runIOSWebKitAppInSimulator($appBundle);
2392     }
2393     die "Not using an iOS SDK."
2394 }
2395
2396 sub runMacWebKitApp($;$)
2397 {
2398     my ($appPath, $useOpenCommand) = @_;
2399     my $productDir = productDir();
2400     print "Starting @{[basename($appPath)]} with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2401
2402     local %ENV = %ENV;
2403     setupMacWebKitEnvironment($productDir);
2404
2405     if (defined($useOpenCommand) && $useOpenCommand == USE_OPEN_COMMAND) {
2406         return system("open", "-W", "-a", $appPath, "--args", argumentsForRunAndDebugMacWebKitApp());
2407     }
2408     if (architecture()) {
2409         return system "arch", "-" . architecture(), $appPath, argumentsForRunAndDebugMacWebKitApp();
2410     }
2411     return system { $appPath } $appPath, argumentsForRunAndDebugMacWebKitApp();
2412 }
2413
2414 sub execMacWebKitAppForDebugging($)
2415 {
2416     my ($appPath) = @_;
2417     my $architectureSwitch;
2418     my $argumentsSeparator;
2419
2420     if (debugger() eq "lldb") {
2421         $architectureSwitch = "--arch";
2422         $argumentsSeparator = "--";
2423     } elsif (debugger() eq "gdb") {
2424         $architectureSwitch = "-arch";
2425         $argumentsSeparator = "--args";
2426     } else {
2427         die "Unknown debugger $debugger.\n";
2428     }
2429
2430     my $debuggerPath = `xcrun -find $debugger`;
2431     chomp $debuggerPath;
2432     die "Can't find the $debugger executable.\n" unless -x $debuggerPath;
2433
2434     my $productDir = productDir();
2435     setupMacWebKitEnvironment($productDir);
2436
2437     my @architectureFlags = ($architectureSwitch, architecture());
2438     if (!shouldTargetWebProcess()) {
2439         print "Starting @{[basename($appPath)]} under $debugger with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2440         exec { $debuggerPath } $debuggerPath, @architectureFlags, $argumentsSeparator, $appPath, argumentsForRunAndDebugMacWebKitApp() or die;
2441     } else {
2442         if (shouldUseXPCServiceForWebProcess()) {
2443             die "Targeting the Web Process is not compatible with using an XPC Service for the Web Process at this time.";
2444         }
2445         
2446         my $webProcessShimPath = File::Spec->catfile($productDir, "SecItemShim.dylib");
2447         my $webProcessPath = File::Spec->catdir($productDir, "WebProcess.app");
2448         my $webKit2ExecutablePath = File::Spec->catfile($productDir, "WebKit2.framework", "WebKit2");
2449
2450         appendToEnvironmentVariableList("DYLD_INSERT_LIBRARIES", $webProcessShimPath);
2451
2452         print "Starting WebProcess under $debugger with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2453         exec { $debuggerPath } $debuggerPath, @architectureFlags, $argumentsSeparator, $webProcessPath, $webKit2ExecutablePath, "-type", "webprocess", "-client-executable", $appPath or die;
2454     }
2455 }
2456
2457 sub debugSafari
2458 {
2459     if (isAppleMacWebKit()) {
2460         checkFrameworks();
2461         execMacWebKitAppForDebugging(safariPath());
2462     }
2463
2464     return 1; # Unsupported platform; can't debug Safari on this platform.
2465 }
2466
2467 sub runSafari
2468 {
2469     if (isIOSWebKit()) {
2470         return runIOSWebKitApp(mobileSafariBundle());
2471     }
2472
2473     if (isAppleMacWebKit()) {
2474         return runMacWebKitApp(safariPath());
2475     }
2476
2477     if (isAppleWinWebKit()) {
2478         my $result;
2479         my $webKitLauncherPath = File::Spec->catfile(executableProductDir(), "MiniBrowser.exe");
2480         return system { $webKitLauncherPath } $webKitLauncherPath, @ARGV;
2481     }
2482
2483     return 1; # Unsupported platform; can't run Safari on this platform.
2484 }
2485
2486 sub runMiniBrowser
2487 {
2488     if (isAppleMacWebKit()) {
2489         return runMacWebKitApp(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2490     } elsif (isAppleWinWebKit()) {
2491         my $result;
2492         my $webKitLauncherPath = File::Spec->catfile(executableProductDir(), "MiniBrowser.exe");
2493         return system { $webKitLauncherPath } $webKitLauncherPath, @ARGV;
2494     }
2495
2496     return 1;
2497 }
2498
2499 sub debugMiniBrowser
2500 {
2501     if (isAppleMacWebKit()) {
2502         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2503     }
2504     
2505     return 1;
2506 }
2507
2508 sub runWebKitTestRunner
2509 {
2510     if (isAppleMacWebKit()) {
2511         return runMacWebKitApp(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2512     }
2513
2514     return 1;
2515 }
2516
2517 sub debugWebKitTestRunner
2518 {
2519     if (isAppleMacWebKit()) {
2520         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2521     }
2522
2523     return 1;
2524 }
2525
2526 sub readRegistryString
2527 {
2528     my ($valueName) = @_;
2529     chomp(my $string = `regtool --wow32 get "$valueName"`);
2530     return $string;
2531 }
2532
2533 sub writeRegistryString
2534 {
2535     my ($valueName, $string) = @_;
2536
2537     my $error = system "regtool", "--wow32", "set", "-s", $valueName, $string;
2538
2539     # On Windows Vista/7 with UAC enabled, regtool will fail to modify the registry, but will still
2540     # return a successful exit code. So we double-check here that the value we tried to write to the
2541     # registry was really written.
2542     return !$error && readRegistryString($valueName) eq $string;
2543 }
2544
2545 sub formatBuildTime($)
2546 {
2547     my ($buildTime) = @_;
2548
2549     my $buildHours = int($buildTime / 3600);
2550     my $buildMins = int(($buildTime - $buildHours * 3600) / 60);
2551     my $buildSecs = $buildTime - $buildHours * 3600 - $buildMins * 60;
2552
2553     if ($buildHours) {
2554         return sprintf("%dh:%02dm:%02ds", $buildHours, $buildMins, $buildSecs);
2555     }
2556     return sprintf("%02dm:%02ds", $buildMins, $buildSecs);
2557 }
2558
2559 sub runSvnUpdateAndResolveChangeLogs(@)
2560 {
2561     my @svnOptions = @_;
2562     my $openCommand = "svn update " . join(" ", @svnOptions);
2563     open my $update, "$openCommand |" or die "cannot execute command $openCommand";
2564     my @conflictedChangeLogs;
2565     while (my $line = <$update>) {
2566         print $line;
2567         $line =~ m/^C\s+(.+?)[\r\n]*$/;
2568         if ($1) {
2569           my $filename = normalizePath($1);
2570           push @conflictedChangeLogs, $filename if basename($filename) eq "ChangeLog";
2571         }
2572     }
2573     close $update or die;
2574
2575     if (@conflictedChangeLogs) {
2576         print "Attempting to merge conflicted ChangeLogs.\n";
2577         my $resolveChangeLogsPath = File::Spec->catfile(sourceDir(), "Tools", "Scripts", "resolve-ChangeLogs");
2578         (system($resolveChangeLogsPath, "--no-warnings", @conflictedChangeLogs) == 0)
2579             or die "Could not open resolve-ChangeLogs script: $!.\n";
2580     }
2581 }
2582
2583 sub runGitUpdate()
2584 {
2585     # Doing a git fetch first allows setups with svn-remote.svn.fetch = trunk:refs/remotes/origin/master
2586     # to perform the rebase much much faster.
2587     system("git", "fetch");
2588     if (isGitSVNDirectory(".")) {
2589         system("git", "svn", "rebase") == 0 or die;
2590     } else {
2591         # This will die if branch.$BRANCHNAME.merge isn't set, which is
2592         # almost certainly what we want.
2593         system("git", "pull") == 0 or die;
2594     }
2595 }
2596
2597 1;