[Autotools] Rework the build target selection
[WebKit-https.git] / Source / autotools / FindDependencies.m4
1 PKG_PROG_PKG_CONFIG
2
3 # Check for libjpeg the way Gtk does it.
4 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress, jpeg_ok=yes, jpeg_ok=no AC_MSG_ERROR([JPEG library (libjpeg) not found]))
5 if test "$jpeg_ok" = yes; then
6     AC_MSG_CHECKING([for jpeglib])
7     AC_TRY_CPP([
8 #include <stdio.h>
9 #undef PACKAGE
10 #undef VERSION
11 #undef HAVE_STDLIB_H
12 #include <jpeglib.h>
13 ], jpeg_ok=yes, jpeg_ok=no)
14     AC_MSG_RESULT($jpeg_ok)
15     if test "$jpeg_ok" = yes; then
16         JPEG_LIBS="-ljpeg"
17         # Should we check for progressive JPEG like GTK+ as well?
18     else
19         AC_MSG_ERROR([JPEG library (libjpeg) not found])
20     fi
21 fi
22 AC_SUBST([JPEG_LIBS])
23
24 # Check for libpng the way Gtk+ does it.
25 for l in libpng libpng14 libpng12; do
26     AC_MSG_CHECKING(for $l)
27     if $PKG_CONFIG --exists $l ; then
28         AC_MSG_RESULT(yes)
29         PNG_LIBS=`$PKG_CONFIG --libs $l`
30         png_ok=yes
31         break
32     else
33         AC_MSG_RESULT(no)
34         png_ok=no
35     fi
36 done
37 if test "$png_ok" != yes; then
38     AC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=no)],
39         AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
40    if test "$png_ok" = yes; then
41         AC_MSG_CHECKING([for png_structp in png.h])
42         AC_TRY_COMPILE([
43 #include <png.h>
44 ], [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;], png_ok=yes, png_ok=no)
45         AC_MSG_RESULT($png_ok)
46         if test "$png_ok" = yes; then
47             PNG_LIBS='-lpng -lz'
48         else
49             AC_MSG_ERROR([PNG library (libpng) not found])
50         fi
51     else
52         AC_MSG_ERROR([PNG library (libpng) not found])
53     fi
54 fi
55 AC_SUBST([PNG_LIBS])
56
57 # Check for WebP Image support.
58 AC_CHECK_HEADERS([webp/decode.h], [WEBP_LIBS='-lwebp'], [AC_MSG_ERROR([WebP library (libwebp) not found])])
59 AC_SUBST([WEBP_LIBS])
60
61 if test "$os_win32" = "yes"; then
62     WINMM_LIBS=-lwinmm
63     SHLWAPI_LIBS=-lshlwapi
64     OLE32_LIBS=-lole32
65 fi
66 AC_SUBST([WINMM_LIBS])
67 AC_SUBST([SHLWAPI_LIBS])
68 AC_SUBST([OLE32_LIBS])
69
70 case "$with_gtk" in
71     2.0) GTK_REQUIRED_VERSION=gtk2_required_version
72         GTK_API_VERSION=2.0
73         WEBKITGTK_API_MAJOR_VERSION=1
74         WEBKITGTK_API_MINOR_VERSION=0
75         WEBKITGTK_API_VERSION=1.0
76         WEBKITGTK_PC_NAME=webkit
77         ;;
78     3.0) GTK_REQUIRED_VERSION=gtk3_required_version
79         GTK_API_VERSION=3.0
80         WEBKITGTK_API_MAJOR_VERSION=3
81         WEBKITGTK_API_MINOR_VERSION=0
82         WEBKITGTK_API_VERSION=3.0
83         WEBKITGTK_PC_NAME=webkitgtk
84         ;;
85 esac
86 AC_SUBST([WEBKITGTK_API_MAJOR_VERSION])
87 AC_SUBST([WEBKITGTK_API_MINOR_VERSION])
88 AC_SUBST([WEBKITGTK_API_VERSION])
89 AC_SUBST([WEBKITGTK_PC_NAME])
90 AC_SUBST([GTK_API_VERSION])
91
92
93 # Check for glib and required utilities. This macro is named as if it interacts
94 # with automake, but it doesn't. Thus it doesn't need to be in the automake section.
95 AM_PATH_GLIB_2_0(glib_required_version, :, :, gmodule gobject gthread gio)
96 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
97     AC_MSG_ERROR([You need the GLib dev tools in your path])
98 fi
99
100 # GResources
101 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG --variable glib_compile_resources gio-2.0`
102 AC_SUBST(GLIB_COMPILE_RESOURCES)
103 GLIB_GSETTINGS
104
105 # TODO: use pkg-config (after CFLAGS in their .pc files are cleaned up).
106 case "$host" in
107     *-*-darwin*)
108         UNICODE_CFLAGS="-I$srcdir/Source/JavaScriptCore/icu -I$srcdir/Source/WebCore/icu"
109         UNICODE_LIBS="-licucore"
110         ;;
111     *-*-mingw*)
112         UNICODE_CFLAGS=""
113         UNICODE_LIBS="-licui18n -licuuc"
114         AC_CHECK_HEADERS([unicode/uchar.h], [], [AC_MSG_ERROR([Could not find ICU headers.])])
115         ;;
116     *)
117         AC_PATH_PROG(icu_config, icu-config, no)
118         if test "$icu_config" = "no"; then
119             AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
120         fi
121
122         # We don't use --cflags as this gives us a lot of things that we don't necessarily want,
123         # like debugging and optimization flags. See man (1) icu-config for more info.
124         UNICODE_CFLAGS=`$icu_config --cppflags-searchpath`
125         UNICODE_LIBS=`$icu_config --ldflags-libsonly`
126         ;;
127 esac
128
129 AC_SUBST([UNICODE_CFLAGS])
130 AC_SUBST([UNICODE_LIBS])
131
132 PKG_CHECK_MODULES([ZLIB], [zlib])
133 AC_SUBST([ZLIB_CFLAGS])
134 AC_SUBST([ZLIB_LIBS])
135
136 GETTEXT_PACKAGE=WebKitGTK-$GTK_API_VERSION
137 AC_SUBST(GETTEXT_PACKAGE)
138
139 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= libxml_required_version)
140 AC_SUBST(LIBXML_CFLAGS)
141 AC_SUBST(LIBXML_LIBS)
142
143 PKG_CHECK_MODULES(PANGO, [pango >= pango_required_version pangoft2])
144 AC_SUBST(PANGO_CFLAGS)
145 AC_SUBST(PANGO_LIBS)
146
147 if test "$enable_spellcheck" = "yes"; then
148     PKG_CHECK_MODULES(ENCHANT, enchant >= enchant_required_version, [], [enable_spellcheck="no"])
149     AC_SUBST(ENCHANT_CFLAGS)
150     AC_SUBST(ENCHANT_LIBS)
151 fi
152
153 PKG_CHECK_MODULES(CAIRO, cairo >= cairo_required_version)
154 PKG_CHECK_MODULES(GTK, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED_VERSION)
155 GTK_ACTUAL_VERSION=`pkg-config --modversion gtk+-$GTK_API_VERSION`
156
157 if test "$enable_directfb_target" = "yes"; then
158     PKG_CHECK_MODULES(CAIRO_DIRECTFB, cairo-directfb >= cairo_required_version)
159     CAIRO_CFLAGS="$CAIRO_CFLAGS $CAIRO_DIRECTFB_CFLAGS"
160     CAIRO_LIBS="$CAIRO_LIBS $CAIRO_DIRECTFB_LIBS"
161
162     PKG_CHECK_MODULES(GTK_DIRECTFB, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
163     GTK_CFLAGS="$GTK_CFLAGS $GTK_DIRECTFB_CFLAGS"
164     GTK_LIBS="$GTK_LIBS $GTK_DIRECTFB_LIBS"
165 fi
166
167 AC_SUBST(GTK_CFLAGS)
168 AC_SUBST(GTK_LIBS)
169 AC_SUBST(CAIRO_CFLAGS)
170 AC_SUBST(CAIRO_LIBS)
171
172 if test "$enable_x11_target" = "yes"; then
173     # The GTK+ X11 target dependency should match the version of the master GTK+ dependency.
174     PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$GTK_API_VERSION = $GTK_ACTUAL_VERSION)
175
176     if test "$os_win32" = "no"; then
177         PKG_CHECK_MODULES([XT], [xt], [xt_has_pkg_config=yes], [xt_has_pkg_config=no])
178
179         # Some old versions of Xt do not provide xt.pc, so try to link against Xt
180         # and if it's installed fall back to just adding -lXt.
181         if test "$xt_has_pkg_config" = "no"; then
182             # Using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as we don't care
183             # about the XtOpenDisplay symbol but only about the existence of libXt.
184             AC_CHECK_LIB([Xt], [XtOpenDisplay], [XT_CFLAGS=""; XT_LIBS="-lXt"],
185                 [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
186         fi
187
188         AC_SUBST([XT_CFLAGS])
189         AC_SUBST([XT_LIBS])
190     fi
191
192     # Check for XRender under Linux/Unix. Some linkers require explicit linkage (like GNU Gold),
193     # so we cannot rely on GTK+ pulling XRender.
194     if test "$enable_x11_target" = "yes"; then
195         PKG_CHECK_MODULES([XRENDER], [xrender])
196         AC_SUBST([XRENDER_CFLAGS])
197         AC_SUBST([XRENDER_LIBS])
198     fi
199 elif test "enable_glx" != "no"; then
200     AC_MSG_WARN([X11 target support not enabled, disabling GLX support.])
201     enable_glx=no
202 fi
203
204 if test "$enable_wayland_target" = "yes"; then
205     # The GTK+ Wayland target dependency should match the version of the master GTK+ dependency.
206     PKG_CHECK_MODULES(GTK_WAYLAND, gtk+-wayland-$GTK_API_VERSION = $GTK_ACTUAL_VERSION)
207 fi
208
209 AC_CHECK_HEADERS([GL/glx.h], [have_glx="yes"], [have_glx="no"])
210 AC_MSG_CHECKING([whether to enable GLX support])
211 if test "$enable_glx" != "no"; then
212     if test "$have_glx" = "no"; then
213         if test "$enable_glx" = "yes"; then
214             AC_MSG_ERROR([--enable-glx specified, but not available])
215         else
216             enable_glx=no
217         fi
218     elif test "$enable_gles2" != "yes"; then
219         enable_glx=yes
220     fi
221 fi
222 AC_MSG_RESULT([$enable_glx])
223
224 AC_CHECK_HEADERS([EGL/egl.h], [have_egl="yes"], [have_egl="no"])
225 AC_MSG_CHECKING([whether to enable EGL support])
226 if test "$enable_egl" != "no"; then
227     if test "$have_egl" = "no"; then
228         if test "$enable_egl" = "yes"; then
229             AC_MSG_ERROR([--enable-egl specified, but not available])
230         else
231             enable_egl=no
232         fi
233     else
234         enable_egl=yes
235     fi
236 fi
237 AC_MSG_RESULT([$enable_egl])
238
239 AC_CHECK_HEADERS([GLES2/gl2.h], [have_gles2="yes"], [have_gles2="no"])
240 AC_MSG_CHECKING([whether to use OpenGL ES 2 support])
241 if test "$enable_glx" = "yes"; then
242     if test "$enable_gles2" = "yes"; then
243         AC_MSG_ERROR([Cannot enable OpenGL ES 2 support with GLX enabled.])
244     else
245         enable_gles2=no
246     fi
247 fi
248 if test "$enable_egl" = "no"; then
249     if test "$enable_gles2" = "yes"; then
250         AC_MSG_ERROR([Cannot enable OpenGL ES 2 support without EGL enabled.])
251     else
252         enable_gles2=no
253     fi
254 fi
255 if test "$enable_gles2" != "no"; then
256     if test "$have_gles2" = "no"; then
257         if test "$enable_gles2" = "yes"; then
258             AC_MSG_ERROR([--enable-gles2 specified, but not available.])
259         else
260             enable_gles2=no
261         fi
262     else
263         enable_gles2=yes
264     fi
265 fi
266 AC_MSG_RESULT([$enable_gles2])
267
268 found_opengl=no
269 if test "$enable_gles2" = "yes"; then
270     found_opengl=yes
271 else
272     AC_CHECK_HEADERS([GL/gl.h], [found_opengl="yes"], [])
273 fi
274
275 if test "$enable_x11_target" = "yes" && test "$found_opengl" = "yes"; then
276     PKG_CHECK_MODULES([XCOMPOSITE], [xcomposite])
277     PKG_CHECK_MODULES([XDAMAGE], [xdamage])
278     AC_SUBST(XCOMPOSITE_CFLAGS)
279     AC_SUBST(XCOMPOSITE_LIBS)
280     AC_SUBST(XDAMAGE_CFLAGS)
281     AC_SUBST(XDAMAGE_LIBS)
282 fi
283
284 if test "$enable_webgl" != "no"; then
285     if test "$found_opengl" = "yes"; then
286         enable_webgl=yes
287     else
288         if test "$enable_webgl" = "yes"; then
289             AC_MSG_ERROR([OpenGL support must be present to enable WebGL.])
290         fi
291         enable_webgl=no
292     fi
293 fi
294
295 if test "$enable_x11_target" != "yes" && test "$enable_wayland_target" = "yes" && test "enable_accelerated_compositing" != "no"; then
296     AC_MSG_WARN([Accelerated compositing for Wayland is not yet implemented, disabling due to the Wayland-only target.])
297     enable_accelerated_compositing=no
298 fi
299
300 if test "$enable_accelerated_compositing" != "no"; then
301     if test "$found_opengl" = "yes"; then
302         enable_accelerated_compositing=yes
303     else
304         if test "$enable_accelerated_compositing" = "yes"; then
305             AC_MSG_ERROR([OpenGL support must be present to enable accelerated compositing.])
306         fi
307         enable_accelerated_compositing=no
308     fi
309 fi
310
311 if test "$enable_gamepad" = "yes" && test "$os_linux" = no; then
312     AC_MSG_WARN([Gamepad support is only available on Linux. Disabling Gamepad support.])
313     enable_gamepad=no;
314 fi
315
316 # Turn off svg features if --disable-svg is requested.
317 if test "$enable_svg" = "no"; then
318    enable_svg_fonts=no
319 fi
320
321 # Check for SVG features, enabling SVG if necessary.
322 if test "$enable_svg_fonts" = "yes" && test "$enable_svg" = "no"; then
323     AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
324     enable_svg=yes
325 fi
326
327 if test "$enable_opcode_stats" = "yes"; then
328     if test "$enable_jit" = "yes"; then
329         AC_MSG_ERROR([JIT must be disabled for Opcode stats to work.])
330     fi
331 fi
332
333 # Enable CSS Filters and Shaders if accelerated_compositing is turned on.
334 enable_css_filters=no;
335 enable_css_shaders=no;
336 AC_MSG_CHECKING([whether to enable CSS Filters and Shaders])
337 if test "$enable_accelerated_compositing" = "yes" && test "$found_opengl" = "yes"; then
338     enable_css_filters=yes;
339     enable_css_shaders=yes;
340 fi
341 AC_MSG_RESULT([$enable_css_filters])
342
343 G_IR_SCANNER=
344 G_IR_COMPILER=
345 G_IR_GENERATE=
346 GIRDIR=
347 GIRTYPELIBDIR=
348
349 if test "$enable_introspection" = "yes"; then
350     PKG_CHECK_MODULES([INTROSPECTION],[gobject-introspection-1.0 >= gobject_introspection_required_version])
351
352     G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
353     G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
354     G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
355 fi
356
357 AC_SUBST([G_IR_SCANNER])
358 AC_SUBST([G_IR_COMPILER])
359 AC_SUBST([G_IR_GENERATE])
360
361 PKG_CHECK_MODULES([LIBSOUP], [libsoup-2.4 >= libsoup_required_version])
362 AC_SUBST([LIBSOUP_CFLAGS])
363 AC_SUBST([LIBSOUP_LIBS])
364
365 if test "$enable_credential_storage" = "yes"; then
366     PKG_CHECK_MODULES([LIBSECRET], [libsecret-1])
367     AC_SUBST([LIBSECRET_CFLAGS])
368     AC_SUBST([LIBSECRET_LIBS])
369 fi
370
371 # Check if FreeType/FontConfig are available.
372 if test "$enable_directfb_target" = "yes"; then
373     PKG_CHECK_MODULES([FREETYPE],
374         [fontconfig >= fontconfig_required_version freetype2 >= freetype2_required_version harfbuzz >= harfbuzz_required_version])
375 else
376     PKG_CHECK_MODULES([FREETYPE],
377         [cairo-ft fontconfig >= fontconfig_required_version freetype2 >= freetype2_required_version harfbuzz >= harfbuzz_required_version])
378 fi
379 # HarfBuzz 0.9.18 splits harbuzz-icu into a separate library.
380 # Since we support earlier HarfBuzz versions we keep this conditional for now.
381 if $PKG_CONFIG --atleast-version 0.9.18 harfbuzz; then
382     PKG_CHECK_MODULES([HARFBUZZ_ICU], [harfbuzz-icu >= harfbuzz_required_version])
383     FREETYPE_CFLAGS="$FREETYPE_CFLAGS $HARFBUZZ_ICU_CFLAGS"
384     FREETYPE_LIBS="$FREETYPE_LIBS $HARFBUZZ_ICU_LIBS"
385 fi
386 AC_SUBST([FREETYPE_CFLAGS])
387 AC_SUBST([FREETYPE_LIBS])
388
389 # Check if SQLite3 is available. Error out only if one of the features hard-depending
390 # on it is enabled while SQLite3 is unavailable.
391 PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= sqlite_required_version], [sqlite3_has_pkg_config=yes], [sqlite3_has_pkg_config=no])
392 if test "$sqlite3_has_pkg_config" = "no"; then
393     AC_SEARCH_LIBS([sqlite3_open16], [sqlite3],
394         [sqlite3_found=yes; SQLITE3_LIBS="$LIBS"; SQLITE3_CFLAGS="-I $srcdir/WebKitLibraries/WebCoreSQLite3"], [sqlite3_found=no])
395 fi
396 AC_SUBST([SQLITE3_CFLAGS])
397 AC_SUBST([SQLITE3_LIBS])
398
399 if (test "$sqlite3_found" = "no"); then
400     AC_MSG_ERROR([SQLite3 is required for the Database related features])
401 fi
402
403 PKG_CHECK_MODULES([LIBXSLT],[libxslt >= libxslt_required_version])
404 AC_SUBST([LIBXSLT_CFLAGS])
405 AC_SUBST([LIBXSLT_LIBS])
406
407 # Check if geoclue is available.
408 if test "$enable_geolocation" = "yes"; then
409     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
410     AC_SUBST([GEOCLUE_CFLAGS])
411     AC_SUBST([GEOCLUE_LIBS])
412 fi
413
414 if test "$enable_video" = "yes" || test "$enable_web_audio" = "yes"; then
415     PKG_CHECK_MODULES([GSTREAMER], [
416         gstreamer-1.0 >= gstreamer_required_version
417         gstreamer-plugins-base-1.0 >= gstreamer_plugins_base_required_version
418         gstreamer-app-1.0
419         gstreamer-audio-1.0,
420         gstreamer-fft-1.0,
421         gstreamer-base-1.0,
422         gstreamer-pbutils-1.0,
423         gstreamer-video-1.0])
424     AC_SUBST([GSTREAMER_CFLAGS])
425     AC_SUBST([GSTREAMER_LIBS])
426 fi
427
428 acceleration_description=
429 if test "$found_opengl" = "yes"; then
430     acceleration_description="OpenGL"
431     if test "$enable_gles2" = "yes"; then
432         acceleration_description="$acceleration_description (gles2"
433         OPENGL_LIBS="-lGLESv2"
434     else
435         acceleration_description="$acceleration_description (gl"
436         OPENGL_LIBS="-lGL"
437     fi
438     if test "$enable_egl" = "yes"; then
439         acceleration_description="$acceleration_description, egl"
440         OPENGL_LIBS="$OPENGL_LIBS -lEGL"
441     fi
442     if test "$enable_glx" = "yes"; then
443         acceleration_description="$acceleration_description, glx"
444     fi
445
446     # Check whether dlopen() is in the core libc like on FreeBSD, or in a separate
447     # libdl like on GNU/Linux (in which case we want to link to libdl).
448     AC_CHECK_FUNC([dlopen], [], [AC_CHECK_LIB([dl], [dlopen], [OPENGL_LIBS="$OPENGL_LIBS -ldl"])])
449
450     acceleration_description="$acceleration_description)"
451 fi
452 AC_SUBST([OPENGL_LIBS])
453
454 enable_accelerated_canvas=no
455 if test "$enable_accelerated_compositing" = "yes" && test "$found_opengl" = "yes"; then
456     CAIRO_GL_LIBS="cairo-gl"
457     if test "$enable_glx" = "yes"; then
458         CAIRO_GL_LIBS="$CAIRO_GL_LIBS cairo-glx"
459     fi
460     if test "$enable_egl" = "yes"; then
461         CAIRO_GL_LIBS="$CAIRO_GL_LIBS cairo-egl"
462     fi
463
464     # At the moment CairoGL does not add any extra cflags and libraries, so we can
465     # safely ignore CAIRO_GL_LIBS and CAIRO_GL_CFLAGS for the moment.
466     PKG_CHECK_MODULES(CAIRO_GL, $CAIRO_GL_LIBS, [enable_accelerated_canvas=yes], [enable_accelerated_canvas=no])
467 fi
468
469 if test "$enable_gamepad" = "yes"; then
470     PKG_CHECK_MODULES([GAMEPAD], [gio-unix-2.0 gudev-1.0])
471
472     AC_SUBST(GAMEPAD_CFLAGS)
473     AC_SUBST(GAMEPAD_LIBS)
474 fi
475
476 if test "$enable_battery_status" = "yes"; then
477     PKG_CHECK_MODULES([UPOWER_GLIB], [upower-glib])
478
479     AC_SUBST(UPOWER_GLIB_CFLAGS)
480     AC_SUBST(UPOWER_GLIB_LIBS)
481 fi
482
483 # Check whether to enable code coverage support.
484 if test "$enable_coverage" = "yes"; then
485     COVERAGE_CFLAGS="-MD"
486     COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
487     AC_SUBST([COVERAGE_CFLAGS])
488     AC_SUBST([COVERAGE_LDFLAGS])
489 fi
490
491 if test "$enable_webkit2" = "yes"; then
492     if test "$GTK_API_VERSION" = "2.0"; then
493         AC_MSG_ERROR([WebKit2 requires GTK+ 3.x, use --with-gtk=3.0])
494     fi
495
496     # Make sure we have GTK+ 2.x to build the plugin process.
497     PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= gtk2_required_version)
498     AC_SUBST(GTK2_CFLAGS)
499     AC_SUBST(GTK2_LIBS)
500
501     # Check Unix printing
502     PKG_CHECK_MODULES(GTK_UNIX_PRINTING, gtk+-unix-print-3.0, [have_gtk_unix_printing=yes], [have_gtk_unix_printing=no])
503     AC_SUBST(GTK_UNIX_PRINTING_CFLAGS)
504     AC_SUBST(GTK_UNIX_PRINTING_LIBS)
505
506     # On some Linux/Unix platforms, shm_* may only be available if linking against librt
507     if test "$os_win32" = "no"; then
508         AC_SEARCH_LIBS([shm_open], [rt], [SHM_LIBS="-lrt"])
509         AC_SUBST(SHM_LIBS)
510     fi
511 fi
512
513 # We need atspi2 for Webkit2 unit tests.
514 if test "$enable_webkit2" = "yes"; then
515    PKG_CHECK_MODULES([ATSPI2], [atspi-2 >= atspi2_required_version], [have_atspi2=yes], [have_atspi2=no])
516    AC_SUBST([ATSPI2_CFLAGS])
517    AC_SUBST([ATSPI2_LIBS])
518 fi
519
520 if test "$enable_jit" = "no"; then
521     AC_MSG_NOTICE([JIT compilation is disabled, also disabling FTL JIT support.])
522     enable_ftl_jit=no
523 fi
524
525 if test "$enable_ftl_jit" != no && test "$cxx_compiler" != "clang++"; then
526     if test "$enable_ftl_jit" = "yes"; then
527         AC_MSG_ERROR([Clang C++ compiler is required for FTL JIT support.])
528     else
529         AC_MSG_WARN([Clang C++ compiler is not used, disabling FTL JIT support.])
530         enable_ftl_jit=no
531     fi
532 fi
533
534 if test "$enable_ftl_jit" != "no"; then
535     AC_PATH_PROG(llvm_config, llvm-config, no)
536     if test "$llvm_config" = "no"; then
537         if test "$enable_ftl_jit" = "yes"; then
538             AC_MSG_ERROR([Cannot find llvm-config. LLVM >= 3.4 is needed for FTL JIT support.])
539         else
540             AC_MSG_WARN([Cannot find llvm-config. LLVM >= 3.4 is not present, disabling FTL JIT support.])
541             enable_ftl_jit=no
542         fi
543     else
544         LLVM_VERSION=`$llvm_config --version`
545         AX_COMPARE_VERSION([$LLVM_VERSION], [ge], [3.4], [have_llvm=yes], [have_llvm=no])
546         if test "$have_llvm" = "no"; then
547             if test "$enable_ftl_jit" = "yes"; then
548                 AC_MSG_ERROR([LLVM >= 3.4 is needed for FTL JIT support.])
549             else
550                 AC_MSG_WARN([LLVM >= 3.4 is not present, disabling FTL JIT support.])
551                 enable_ftl_jit=no
552             fi
553         else
554             LLVM_CFLAGS=`$llvm_config --cppflags`
555             LLVM_LIBS="`$llvm_config --ldflags` `$llvm_config --libs`"
556             AC_SUBST([LLVM_CFLAGS])
557             AC_SUBST([LLVM_LIBS])
558         fi
559     fi
560 fi
561
562 m4_ifdef([GTK_DOC_CHECK], [
563 GTK_DOC_CHECK([1.10])
564 ],[
565 AM_CONDITIONAL([ENABLE_GTK_DOC], false)
566 ])