ccd206cc331a850e0ad5e80953d7b8a207d7d868
[WebKit-https.git] / Source / api.pri
1 # -------------------------------------------------------------------
2 # Project file for the QtWebKit C++ APIs
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 # Use Qt5's module system
8 load(qt_build_config)
9
10 TEMPLATE = lib
11 TARGET = QtWebKit
12
13 WEBKIT_DESTDIR = $${ROOT_BUILD_DIR}/lib
14
15 WEBKIT += wtf javascriptcore webcore
16
17 build?(webkit1): WEBKIT += webkit1
18 build?(webkit2): WEBKIT += webkit2
19
20 # Ensure that changes to the WebKit1 and WebKit2 API will trigger a qmake of this
21 # file, which in turn runs syncqt to update the forwarding headers.
22 build?(webkit1): {
23     QMAKE_INTERNAL_INCLUDED_FILES *= WebKit/WebKit1.pro
24 }
25 build?(webkit2): QMAKE_INTERNAL_INCLUDED_FILES *= WebKit2/Target.pri
26
27 use?(3D_GRAPHICS): WEBKIT += angle
28
29 MODULE = webkit
30 CONFIG += creating_module
31
32 # This is the canonical list of dependencies for the public API of
33 # the QtWebKit library, and will end up in the library's prl file.
34 QT_API_DEPENDS = core gui network
35
36 # We want the QtWebKit API forwarding includes to live in the root build dir.
37 MODULE_BASE_DIR = $$_PRO_FILE_PWD_
38 MODULE_BASE_OUTDIR = $$ROOT_BUILD_DIR
39
40 QMAKE_DOCS = $$PWD/qtwebkit.qdocconf
41
42 # We load the relevant modules here, so that the effects of each module
43 # on the QT variable can be picked up when we later load(qt_module).
44 load(webkit_modules)
45
46 # Resources have to be included directly in the final binary for MSVC.
47 # The linker won't pick them from a static library since they aren't referenced.
48 win* {
49     RESOURCES += $$PWD/WebCore/WebCore.qrc
50     include_webinspector {
51         # WEBCORE_GENERATED_SOURCES_DIR is defined in WebCore.pri, included by
52         # load(webkit_modules) if WEBKIT contains webcore.
53         RESOURCES += \
54             $$PWD/WebCore/inspector/front-end/WebKit.qrc \
55             $${WEBCORE_GENERATED_SOURCES_DIR}/InspectorBackendCommands.qrc
56     }
57 }
58
59 # ---------------- Custom developer-build handling -------------------
60 #
61 # The assumption for Qt developer builds is that the module file
62 # will be put into qtbase/mkspecs/modules, and the libraries into
63 # qtbase/lib, with rpath/install_name set to the Qt lib dir.
64 #
65 # For WebKit we don't want that behavior for the libraries, as we want
66 # them to be self-contained in the WebKit build dir.
67 #
68 !production_build: CONFIG += force_independent
69
70 BASE_TARGET = $$TARGET
71
72 load(qt_module)
73
74 # Make sure the install_name of the QtWebKit library point to webkit
75 !production_build:force_independent:macx {
76     # We do our own absolute path so that we can trick qmake into
77     # using the webkit build path instead of the Qt install path.
78     CONFIG -= absolute_library_soname
79     QMAKE_LFLAGS_SONAME = $$QMAKE_LFLAGS_SONAME$$WEBKIT_DESTDIR/
80
81     !debug_and_release|build_pass {
82         # We also have to make sure the install_name is correct when
83         # the library is installed.
84         change_install_name.depends = install_target
85
86         # The install rules generated by qmake for frameworks are busted in
87         # that both the debug and the release makefile copy QtWebKit.framework
88         # into the install dir, so whatever changes we did to the release library
89         # will get overwritten when the debug library is installed. We work around
90         # that by running install_name on both, for both configs.
91         change_install_name.commands = framework_dir=\$\$(dirname $(TARGETD)); \
92             for file in \$\$(ls $$[QT_INSTALL_LIBS]/\$\$framework_dir/$$BASE_TARGET*); do \
93                 install_name_tool -id \$\$file \$\$file; \
94             done
95         default_install_target.target = install
96         default_install_target.depends += change_install_name
97
98         QMAKE_EXTRA_TARGETS += change_install_name default_install_target
99     }
100 }
101
102 qnx {
103     # see: https://bugs.webkit.org/show_bug.cgi?id=93460
104     # the gcc 4.4.2 used in the qnx bbndk cannot cope with
105     # the linkage step of libQtWebKit, adding a dummy .cpp
106     # file fixes this though - so do this here
107     dummyfile.target = dummy.cpp
108     dummyfile.commands = touch $$dummyfile.target
109     QMAKE_EXTRA_TARGETS += dummyfile
110     GENERATED_SOURCES += $$dummyfile.target
111 }