Source/WTF/WTF.pri

   1 # -------------------------------------------------------------------
   2 # This file contains shared rules used both when building WTF itself
   3 # and for targets that depend in some way on WTF.
   4 #
   5 # See 'Tools/qmake/README' for an overview of the build system
   6 # -------------------------------------------------------------------
   7
   8 load(features)
   9
  10 SOURCE_DIR = $${ROOT_WEBKIT_DIR}/Source/WTF
  11 OLD_SOURCE_DIR = $${ROOT_WEBKIT_DIR}/Source/JavaScriptCore/wtf
  12
  13 INCLUDEPATH += \
  14     $$OLD_SOURCE_DIR/.. \
  15     $$OLD_SOURCE_DIR \
  16     $$OLD_SOURCE_DIR/gobject \
  17     $$OLD_SOURCE_DIR/qt \
  18     $$OLD_SOURCE_DIR/unicode
  19
  20 contains(CONFIG, use_system_icu) {
  21     DEFINES += WTF_USE_ICU_UNICODE=1
  22     DEFINES -= WTF_USE_QT4_UNICODE
  23     LIBS += -licuuc -licui18n
  24 } else {
  25     DEFINES += WTF_USE_QT4_UNICODE=1
  26     DEFINES -= WTF_USE_ICU_UNICODE
  27 }
  28
  29 v8 {
  30     !haveQt(5): error("To build QtWebKit+V8 you need to use Qt 5")
  31     DEFINES *= WTF_USE_V8=1
  32     INCLUDEPATH += $${ROOT_WEBKIT_DIR}/Source/WebKit/qt/v8/ForwardingHeaders
  33     QT += v8-private declarative
  34 }
  35
  36 linux-*:!contains(DEFINES, USE_QTMULTIMEDIA=1) {
  37     !contains(QT_CONFIG, no-pkg-config):system(pkg-config --exists glib-2.0 gio-2.0 gstreamer-0.10): {
  38         DEFINES += ENABLE_GLIB_SUPPORT=1
  39         PKGCONFIG += glib-2.0 gio-2.0
  40     }
  41 }
  42
  43 win32-* {
  44     LIBS += -lwinmm
  45     LIBS += -lgdi32
  46 }