Source/WTF/WTF.pri

   1 # -------------------------------------------------------------------
   2 # This file contains shared rules used both when building WTF itself
   3 # and for targets that depend in some way on WTF.
   4 #
   5 # See 'Tools/qmake/README' for an overview of the build system
   6 # -------------------------------------------------------------------
   7
   8 load(features)
   9
  10 SOURCE_DIR = $${ROOT_WEBKIT_DIR}/Source/WTF
  11 OLD_SOURCE_DIR = $${ROOT_WEBKIT_DIR}/Source/JavaScriptCore/wtf
  12
  13 INCLUDEPATH += \
  14     $$OLD_SOURCE_DIR/.. \
  15     $$OLD_SOURCE_DIR \
  16     $$OLD_SOURCE_DIR/gobject \
  17     $$OLD_SOURCE_DIR/qt \
  18     $$OLD_SOURCE_DIR/unicode
  19
  20 haveQt(5) {
  21     mac {
  22         # Mac OS does ship libicu but not the associated header files.
  23         # Therefore WebKit provides adequate header files.
  24         INCLUDEPATH += $${ROOT_WEBKIT_DIR}/Source/WTF/icu
  25         LIBS += -licucore
  26     } else {
  27         contains(QT_CONFIG,icu) {
  28             LIBS += -licui18n -licuuc -licudata
  29         } else {
  30             error("To build QtWebKit with Qt 5 you need ICU")
  31         }
  32     }
  33 }
  34
  35 v8 {
  36     !haveQt(5): error("To build QtWebKit+V8 you need to use Qt 5")
  37     DEFINES *= WTF_USE_V8=1
  38     INCLUDEPATH += $${ROOT_WEBKIT_DIR}/Source/WebKit/qt/v8/ForwardingHeaders
  39     QT += v8-private declarative
  40 }
  41
  42 linux-*:!contains(DEFINES, USE_QTMULTIMEDIA=1) {
  43     !contains(QT_CONFIG, no-pkg-config):system(pkg-config --exists glib-2.0 gio-2.0 gstreamer-0.10): {
  44         DEFINES += ENABLE_GLIB_SUPPORT=1
  45         PKGCONFIG += glib-2.0 gio-2.0
  46     }
  47 }
  48
  49 win32-* {
  50     LIBS += -lwinmm
  51     LIBS += -lgdi32
  52 }