[Qt] Add a way to have experimental features in WebKit2
[WebKit-https.git] / Source / QtWebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file for QtWebKit
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = subdirs
8 CONFIG += ordered
9
10 api.file = api.pri
11 SUBDIRS += api
12
13 !no_webkit2 {
14     webprocess.file = WebKit2/WebProcess.pro
15     SUBDIRS += webprocess
16 }
17
18 include(WebKit/qt/docs/docs.pri)
19
20 SUBDIRS += WebKit/qt/declarative
21 haveQt(5) {
22     SUBDIRS += WebKit/qt/declarative/private
23 }
24
25 tests.file = tests.pri
26 SUBDIRS += tests
27
28 examples.file = WebKit/qt/examples/examples.pro
29 examples.CONFIG += no_default_target
30 examples.makefile = Makefile
31 SUBDIRS += examples
32
33 haveQt(4):!build_pass {
34     # Use our own copy of syncqt from Qt 4.8 to generate forwarding headers
35     syncqt = $$toSystemPath($${ROOT_WEBKIT_DIR}/Tools/qmake/syncqt-4.8)
36     command = $$syncqt
37     win32-msvc*: command = $$command -windows
38
39     outdir = $$toSystemPath($${ROOT_BUILD_DIR})
40
41     # The module root has to be the same as directory of the pro-file that generates
42     # the install rules (api.pri), otherwise the relative paths in the generated
43     # headers.pri will be incorrect.
44     module_rootdir = $$toSystemPath($${_PRO_FILE_PWD_})
45
46     module = $${TARGET}$${DIRLIST_SEPARATOR}$${module_rootdir}$${DIRLIST_SEPARATOR}$$toSystemPath(WebKit/qt/Api)
47     fwheader_generator.commands = perl $${command} -outdir $${outdir} -separate-module $${module}
48     fwheader_generator.depends = $${syncqt}
49
50     variables = $$computeSubdirVariables(api)
51
52     api_qmake.target = $$eval($${variables}.target)-qmake_all
53     api_qmake.depends = fwheader_generator
54
55     api_makefile.target = $$eval($${variables}.makefile)
56     api_makefile.depends = fwheader_generator
57
58     QMAKE_EXTRA_TARGETS += fwheader_generator api_qmake api_makefile
59 }