[Qt] Build fix of the private QML module with --no-webkit2.
[WebKit-https.git] / Source / QtWebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file for QtWebKit
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = subdirs
8 CONFIG += ordered
9
10 api.file = api.pri
11 SUBDIRS += api
12
13 !no_webkit2 {
14     webprocess.file = WebKit2/WebProcess.pro
15     SUBDIRS += webprocess
16 }
17
18 include(WebKit/qt/docs/docs.pri)
19
20 SUBDIRS += WebKit/qt/declarative
21 haveQt(5) {
22     !no_webkit2 {
23         SUBDIRS += WebKit/qt/declarative/private
24     }
25 }
26
27 tests.file = tests.pri
28 SUBDIRS += tests
29
30 examples.file = WebKit/qt/examples/examples.pro
31 examples.CONFIG += no_default_target
32 examples.makefile = Makefile
33 SUBDIRS += examples
34
35 haveQt(4):!build_pass {
36     # Use our own copy of syncqt from Qt 4.8 to generate forwarding headers
37     syncqt = $$toSystemPath($${ROOT_WEBKIT_DIR}/Tools/qmake/syncqt-4.8)
38     command = $$syncqt
39     win32-msvc*: command = $$command -windows
40
41     outdir = $$toSystemPath($${ROOT_BUILD_DIR})
42
43     # The module root has to be the same as directory of the pro-file that generates
44     # the install rules (api.pri), otherwise the relative paths in the generated
45     # headers.pri will be incorrect.
46     module_rootdir = $$toSystemPath($${_PRO_FILE_PWD_})
47
48     module = $${TARGET}$${DIRLIST_SEPARATOR}$${module_rootdir}$${DIRLIST_SEPARATOR}$$toSystemPath(WebKit/qt/Api)
49     fwheader_generator.commands = perl $${command} -outdir $${outdir} -separate-module $${module}
50     fwheader_generator.depends = $${syncqt}
51
52     variables = $$computeSubdirVariables(api)
53
54     api_qmake.target = $$eval($${variables}.target)-qmake_all
55     api_qmake.depends = fwheader_generator
56
57     api_makefile.target = $$eval($${variables}.makefile)
58     api_makefile.depends = fwheader_generator
59
60     QMAKE_EXTRA_TARGETS += fwheader_generator api_qmake api_makefile
61 }