8b27cae5d0c3e9ce6a169a8bdf9c46467f33568d
[WebKit-https.git] / Source / QtWebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file for QtWebKit
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = subdirs
8 CONFIG += ordered
9
10 api.file = api.pri
11 SUBDIRS += api
12
13 !no_webkit2 {
14     webprocess.file = WebKit2/WebProcess.pro
15     SUBDIRS += webprocess
16 }
17
18 include(WebKit/qt/docs/docs.pri)
19
20 declarative.file = WebKit/qt/declarative/declarative.pro
21 declarative.makefile = Makefile.declarative
22 SUBDIRS += declarative
23
24 tests.file = tests.pri
25 SUBDIRS += tests
26
27 examples.file = WebKit/qt/examples/examples.pro
28 examples.CONFIG += no_default_target
29 examples.makefile = Makefile
30 SUBDIRS += examples
31
32 haveQt(4):!build_pass {
33     # Use our own copy of syncqt from Qt 4.8 to generate forwarding headers
34     syncqt = $$toSystemPath($${ROOT_WEBKIT_DIR}/Tools/qmake/syncqt-4.8)
35     command = $$syncqt
36     win32-msvc*: command = $$command -windows
37
38     outdir = $$toSystemPath($${ROOT_BUILD_DIR})
39
40     # The module root has to be the same as directory of the pro-file that generates
41     # the install rules (api.pri), otherwise the relative paths in the generated
42     # headers.pri will be incorrect.
43     module_rootdir = $$toSystemPath($${_PRO_FILE_PWD_})
44
45     module = $${TARGET}$${DIRLIST_SEPARATOR}$${module_rootdir}$${DIRLIST_SEPARATOR}$$toSystemPath(WebKit/qt/Api)
46     fwheader_generator.commands = perl $${command} -outdir $${outdir} -separate-module $${module}
47     fwheader_generator.depends = $${syncqt}
48
49     variables = $$computeSubdirVariables(api)
50
51     api_qmake.target = $$eval($${variables}.target)-qmake_all
52     api_qmake.depends = fwheader_generator
53
54     api_makefile.target = $$eval($${variables}.makefile)
55     api_makefile.depends = fwheader_generator
56
57     QMAKE_EXTRA_TARGETS += fwheader_generator api_qmake api_makefile
58 }