176949f754cd850c75459a78bbb2ab1e9bdbbd0a
[WebKit-https.git] / Source / JavaScriptCore / wtf / wtf.pri
1 # -------------------------------------------------------------------
2 # This file contains shared rules used both when building WTF itself
3 # and for targets that depend in some way on WTF.
4 #
5 # See 'Tools/qmake/README' for an overview of the build system
6 # -------------------------------------------------------------------
7
8 load(features)
9
10 SOURCE_DIR = $${ROOT_WEBKIT_DIR}/Source/JavaScriptCore/wtf
11
12 INCLUDEPATH += \
13     $$SOURCE_DIR/.. \
14     $$SOURCE_DIR \
15     $$SOURCE_DIR/gobject \
16     $$SOURCE_DIR/qt \
17     $$SOURCE_DIR/unicode
18
19 contains(CONFIG, use_system_icu) {
20     DEFINES += WTF_USE_ICU_UNICODE=1
21     DEFINES -= WTF_USE_QT4_UNICODE
22     LIBS += -licuuc -licui18n
23 } else {
24     DEFINES += WTF_USE_QT4_UNICODE=1
25     DEFINES -= WTF_USE_ICU_UNICODE
26 }
27
28 v8 {
29     !haveQt(5): error("To build QtWebKit+V8 you need to use Qt 5")
30     DEFINES *= WTF_USE_V8=1
31     INCLUDEPATH += $${ROOT_WEBKIT_DIR}/Source/WebKit/qt/v8/ForwardingHeaders
32     QT += v8-private declarative
33 }
34
35 linux-*:!contains(DEFINES, USE_QTMULTIMEDIA=1) {
36     !contains(QT_CONFIG, no-pkg-config):system(pkg-config --exists glib-2.0 gio-2.0 gstreamer-0.10): {
37         DEFINES += ENABLE_GLIB_SUPPORT=1
38         PKGCONFIG += glib-2.0 gio-2.0
39     }
40 }
41
42 win32-*: LIBS += -lwinmm