Make the directory of where to put the generated sources configurable through the...
[WebKit-https.git] / JavaScriptCore / pcre / pcre.pri
1 # Perl Compatible Regular Expressions - Qt4 build info
2 VPATH += $$PWD
3 INCLUDEPATH += $$PWD $$OUTPUT_DIR/JavaScriptCore/kjs/tmp
4 DEPENDPATH += $$PWD
5
6 isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
7
8 SOURCES += \
9     pcre_compile.cpp \
10     pcre_exec.cpp \
11     pcre_ord2utf8.cpp \
12     pcre_tables.cpp \
13     pcre_ucp_searchfuncs.cpp \
14     pcre_xclass.cpp
15
16 CTGENFILE += \
17     dftables.cpp
18
19 !CONFIG(QTDIR_build) {
20     defineTest(addExtraCompiler) {
21         QMAKE_EXTRA_COMPILERS += $$1
22         generated_files.depends += compiler_$${1}_make_all
23         export(QMAKE_EXTRA_COMPILERS)
24         export(generated_files.depends)
25         return(true)
26     }
27 }
28
29 # GENERATOR: "chartables.c": compile and execute the chartables generator (and add it to sources)
30 ctgen.output = $$GENERATED_SOURCES_DIR/chartables.c
31 ctgen.commands = $$OUTPUT_DIR/JavaScriptCore/pcre/tmp/dftables ${QMAKE_FILE_OUT}
32 ctgen.input = CTGENFILE
33 ctgen.CONFIG += target_predeps no_link
34 ctgen.variable_out = GENERATED_SOURCES
35 ctgen.dependency_type = TYPE_C
36 ctgen.clean = ${QMAKE_FILE_OUT} ${QMAKE_VAR_OBJECTS_DIR_WTR}${QMAKE_FILE_BASE}
37 addExtraCompiler(ctgen)