JavaScriptCore/pcre/pcre.pri

   1 # Perl Compatible Regular Expressions - Qt4 build info
   2 VPATH += $$PWD
   3 INCLUDEPATH += $$PWD
   4
   5 SOURCES += \
   6     pcre_get.c \
   7     pcre_printint.c \
   8     pcre_refcount.c \
   9     pcre_ucp_findchar.c \
  10     pcre_compile.c \
  11     pcre_globals.c \
  12     pcre_config.c \
  13     pcre_version.c \
  14     pcre_info.c \
  15     pcre_study.c \
  16     pcre_exec.c \
  17     pcre_xclass.c \
  18     ucp_findchar.c \
  19     pcre_tables.c \
  20     pcre_maketables.c \
  21     pcre_try_flipped.c \
  22     pcre_ord2utf8.c \
  23     pcre_fullinfo.c
  24
  25 CTGENFILE += \
  26     dftables.c
  27
  28
  29 # GENERATOR: "chartables.c": compile and execute the chartables generator (and add it to sources)
  30 ctgen.output = tmp/chartables.c
  31 ctgen.commands = gcc ${QMAKE_FILE_NAME} -DBUILDING_QT__ -I$$PWD/../wtf -o tmp/${QMAKE_FILE_BASE} && ./tmp/${QMAKE_FILE_BASE} ${QMAKE_FILE_OUT}
  32 ctgen.input = CTGENFILE
  33 ctgen.CONFIG += target_predeps no_link
  34 ctgen.variable_out = GENERATED_SOURCES
  35 ctgen.dependency_type = TYPE_C
  36 QMAKE_EXTRA_COMPILERS += ctgen