Gdk build fixes using the Qt build's qmake tool from Holger Freyther, reviewed by...
[WebKit-https.git] / JavaScriptCore / pcre / pcre.pri
1 # Perl Compatible Regular Expressions - Qt4 build info
2 VPATH += $$PWD
3 INCLUDEPATH += $$PWD $$OUTPUT_DIR/JavaScriptCore/kjs/tmp
4
5 SOURCES += \
6     pcre_get.c \
7     pcre_refcount.c \
8     pcre_ucp_findchar.c \
9     pcre_compile.c \
10     pcre_globals.c \
11     pcre_config.c \
12     pcre_version.c \
13     pcre_info.c \
14     pcre_study.c \
15     pcre_exec.c \
16     pcre_xclass.c \
17     pcre_tables.c \
18     pcre_maketables.c \
19     pcre_try_flipped.c \
20     pcre_ord2utf8.c \
21     pcre_fullinfo.c
22
23 CTGENFILE += \
24     dftables.c
25
26
27 # GENERATOR: "chartables.c": compile and execute the chartables generator (and add it to sources)
28 ctgen.output = tmp/chartables.c
29 ctgen.commands = gcc ${QMAKE_FILE_NAME} -I$$PWD/../wtf -o tmp/${QMAKE_FILE_BASE} && ./tmp/${QMAKE_FILE_BASE} ${QMAKE_FILE_OUT}
30 qt-port:ctgen.commands = gcc ${QMAKE_FILE_NAME} -DBUILDING_QT__ -I$$PWD/../wtf -o tmp/${QMAKE_FILE_BASE} && ./tmp/${QMAKE_FILE_BASE} ${QMAKE_FILE_OUT}
31 gdk-port:ctgen.commands = gcc ${QMAKE_FILE_NAME} -DBUILDING_GDK__ -DBUILDING_CAIRO__ -I$$PWD/../wtf -o tmp/${QMAKE_FILE_BASE} && ./tmp/${QMAKE_FILE_BASE} ${QMAKE_FILE_OUT}
32 ctgen.input = CTGENFILE
33 ctgen.CONFIG += target_predeps no_link
34 ctgen.variable_out = GENERATED_SOURCES
35 ctgen.dependency_type = TYPE_C
36 ctgen.clean = ${QMAKE_FILE_OUT} tmp/${QMAKE_FILE_BASE}
37 QMAKE_EXTRA_COMPILERS += ctgen