ecda56c808ae7626e98673ea2ad12ae921eaaa45
[WebKit-https.git] / JavaScriptCore / kjs / grammar.y
1 %{
2
3 /*
4  *  This file is part of the KDE libraries
5  *  Copyright (C) 1999-2000 Harri Porten (porten@kde.org)
6  *  Copyright (C) 2006, 2007 Apple Inc. All rights reserved.
7  *
8  *  This library is free software; you can redistribute it and/or
9  *  modify it under the terms of the GNU Lesser General Public
10  *  License as published by the Free Software Foundation; either
11  *  version 2 of the License, or (at your option) any later version.
12  *
13  *  This library is distributed in the hope that it will be useful,
14  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
15  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16  *  Lesser General Public License for more details.
17  *
18  *  You should have received a copy of the GNU Lesser General Public
19  *  License along with this library; if not, write to the Free Software
20  *  Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
21  *
22  */
23
24 #include "config.h"
25
26 #include <string.h>
27 #include <stdlib.h>
28 #include "value.h"
29 #include "object.h"
30 #include "types.h"
31 #include "interpreter.h"
32 #include "nodes.h"
33 #include "lexer.h"
34 #include "internal.h"
35 #include "CommonIdentifiers.h"
36 #include <wtf/MathExtras.h>
37
38 // Not sure why, but yacc doesn't add this define along with the others.
39 #define yylloc kjsyylloc
40
41 #define YYMAXDEPTH 10000
42 #define YYENABLE_NLS 0
43
44 /* default values for bison */
45 #define YYDEBUG 0
46 #if !PLATFORM(DARWIN)
47     // avoid triggering warnings in older bison
48 #define YYERROR_VERBOSE
49 #endif
50
51 extern int kjsyylex();
52 int kjsyyerror(const char *);
53 static bool allowAutomaticSemicolon();
54
55 #define AUTO_SEMICOLON do { if (!allowAutomaticSemicolon()) YYABORT; } while (0)
56 #define DBG(l, s, e) (l)->setLoc((s).first_line, (e).last_line)
57
58 using namespace KJS;
59
60 static Node* makeAssignNode(Node* loc, Operator, Node* expr);
61 static Node* makePrefixNode(Node* expr, Operator);
62 static Node* makePostfixNode(Node* expr, Operator);
63 static bool makeGetterOrSetterPropertyNode(PropertyNode*& result, Identifier &getOrSet, Identifier& name, ParameterNode *params, FunctionBodyNode *body);
64 static Node *makeFunctionCallNode(Node *func, ArgumentsNode *args);
65 static Node *makeTypeOfNode(Node *expr);
66 static Node *makeDeleteNode(Node *expr);
67 static Node *makeNegateNode(Node *expr);
68
69 #if COMPILER(MSVC)
70
71 #pragma warning(disable: 4065)
72 #pragma warning(disable: 4244)
73 #pragma warning(disable: 4702)
74
75 // At least some of the time, the declarations of malloc and free that bison
76 // generates are causing warnings. A way to avoid this is to explicitly define
77 // the macros so that bison doesn't try to declare malloc and free.
78 #define YYMALLOC malloc
79 #define YYFREE free
80
81 #endif
82
83 %}
84
85 %union {
86   int                 ival;
87   double              dval;
88   UString             *ustr;
89   Identifier          *ident;
90   Node                *node;
91   StatementNode       *stat;
92   ParameterNode       *param;
93   FunctionBodyNode    *body;
94   FuncDeclNode        *func;
95   FuncExprNode        *funcExpr;
96   ProgramNode         *prog;
97   AssignExprNode      *init;
98   SourceElementsNode  *srcs;
99   ArgumentsNode       *args;
100   ArgumentListNode    *alist;
101   VarDeclNode         *decl;
102   VarDeclListNode     *vlist;
103   CaseBlockNode       *cblk;
104   ClauseListNode      *clist;
105   CaseClauseNode      *ccl;
106   ElementNode         *elm;
107   Operator            op;
108   PropertyListNode   *plist;
109   PropertyNode       *pnode;
110   PropertyNameNode   *pname;
111 }
112
113 %start Program
114
115 /* literals */
116 %token NULLTOKEN TRUETOKEN FALSETOKEN
117
118 /* keywords */
119 %token BREAK CASE DEFAULT FOR NEW VAR CONSTTOKEN CONTINUE
120 %token FUNCTION RETURN VOIDTOKEN DELETETOKEN
121 %token IF THISTOKEN DO WHILE INTOKEN INSTANCEOF TYPEOF
122 %token SWITCH WITH RESERVED
123 %token THROW TRY CATCH FINALLY
124 %token DEBUGGER
125
126 /* give an if without an else higher precedence than an else to resolve the ambiguity */
127 %nonassoc IF_WITHOUT_ELSE
128 %nonassoc ELSE
129
130 /* punctuators */
131 %token EQEQ NE                     /* == and != */
132 %token STREQ STRNEQ                /* === and !== */
133 %token LE GE                       /* < and > */
134 %token OR AND                      /* || and && */
135 %token PLUSPLUS MINUSMINUS         /* ++ and --  */
136 %token LSHIFT                      /* << */
137 %token RSHIFT URSHIFT              /* >> and >>> */
138 %token PLUSEQUAL MINUSEQUAL        /* += and -= */
139 %token MULTEQUAL DIVEQUAL          /* *= and /= */
140 %token LSHIFTEQUAL                 /* <<= */
141 %token RSHIFTEQUAL URSHIFTEQUAL    /* >>= and >>>= */
142 %token ANDEQUAL MODEQUAL           /* &= and %= */
143 %token XOREQUAL OREQUAL            /* ^= and |= */
144
145 /* terminal types */
146 %token <dval> NUMBER
147 %token <ustr> STRING
148 %token <ident> IDENT
149
150 /* automatically inserted semicolon */
151 %token AUTOPLUSPLUS AUTOMINUSMINUS
152
153 /* non-terminal types */
154 %type <node>  Literal ArrayLiteral
155
156 %type <node>  PrimaryExpr PrimaryExprNoBrace
157 %type <node>  MemberExpr MemberExprNoBF /* BF => brace or function */
158 %type <node>  NewExpr NewExprNoBF
159 %type <node>  CallExpr CallExprNoBF
160 %type <node>  LeftHandSideExpr LeftHandSideExprNoBF
161 %type <node>  PostfixExpr PostfixExprNoBF
162 %type <node>  UnaryExpr UnaryExprNoBF UnaryExprCommon
163 %type <node>  MultiplicativeExpr MultiplicativeExprNoBF
164 %type <node>  AdditiveExpr AdditiveExprNoBF
165 %type <node>  ShiftExpr ShiftExprNoBF
166 %type <node>  RelationalExpr RelationalExprNoIn RelationalExprNoBF
167 %type <node>  EqualityExpr EqualityExprNoIn EqualityExprNoBF
168 %type <node>  BitwiseANDExpr BitwiseANDExprNoIn BitwiseANDExprNoBF
169 %type <node>  BitwiseXORExpr BitwiseXORExprNoIn BitwiseXORExprNoBF
170 %type <node>  BitwiseORExpr BitwiseORExprNoIn BitwiseORExprNoBF
171 %type <node>  LogicalANDExpr LogicalANDExprNoIn LogicalANDExprNoBF
172 %type <node>  LogicalORExpr LogicalORExprNoIn LogicalORExprNoBF
173 %type <node>  ConditionalExpr ConditionalExprNoIn ConditionalExprNoBF
174 %type <node>  AssignmentExpr AssignmentExprNoIn AssignmentExprNoBF
175 %type <node>  Expr ExprNoIn ExprNoBF
176
177 %type <node>  ExprOpt ExprNoInOpt
178
179 %type <stat>  Statement Block
180 %type <stat>  VariableStatement ConstStatement EmptyStatement ExprStatement
181 %type <stat>  IfStatement IterationStatement ContinueStatement
182 %type <stat>  BreakStatement ReturnStatement WithStatement
183 %type <stat>  SwitchStatement LabelledStatement
184 %type <stat>  ThrowStatement TryStatement
185 %type <stat>  DebuggerStatement
186 %type <stat>  SourceElement
187
188 %type <init>  Initializer InitializerNoIn
189 %type <func>  FunctionDeclaration
190 %type <funcExpr>  FunctionExpr
191 %type <body>  FunctionBody
192 %type <srcs>  SourceElements
193 %type <param> FormalParameterList
194 %type <op>    AssignmentOperator
195 %type <args>  Arguments
196 %type <alist> ArgumentList
197 %type <vlist> VariableDeclarationList VariableDeclarationListNoIn ConstDeclarationList
198 %type <decl>  VariableDeclaration VariableDeclarationNoIn ConstDeclaration
199 %type <cblk>  CaseBlock
200 %type <ccl>   CaseClause DefaultClause
201 %type <clist> CaseClauses  CaseClausesOpt
202 %type <ival>  Elision ElisionOpt
203 %type <elm>   ElementList
204 %type <pname> PropertyName
205 %type <pnode> Property
206 %type <plist> PropertyList
207 %%
208
209 Literal:
210     NULLTOKEN                           { $$ = new NullNode(); }
211   | TRUETOKEN                           { $$ = new BooleanNode(true); }
212   | FALSETOKEN                          { $$ = new BooleanNode(false); }
213   | NUMBER                              { $$ = new NumberNode($1); }
214   | STRING                              { $$ = new StringNode($1); }
215   | '/' /* regexp */                    {
216                                             Lexer *l = Lexer::curr();
217                                             if (!l->scanRegExp()) YYABORT;
218                                             $$ = new RegExpNode(l->pattern, l->flags);
219                                         }
220   | DIVEQUAL /* regexp with /= */       {
221                                             Lexer *l = Lexer::curr();
222                                             if (!l->scanRegExp()) YYABORT;
223                                             $$ = new RegExpNode("=" + l->pattern, l->flags);
224                                         }
225 ;
226
227 PropertyName:
228     IDENT                               { $$ = new PropertyNameNode(*$1); }
229   | STRING                              { $$ = new PropertyNameNode(Identifier(*$1)); }
230   | NUMBER                              { $$ = new PropertyNameNode($1); }
231 ;
232
233 Property:
234     PropertyName ':' AssignmentExpr     { $$ = new PropertyNode($1, $3, PropertyNode::Constant); }
235   | IDENT IDENT '(' ')' FunctionBody    { if (!makeGetterOrSetterPropertyNode($$, *$1, *$2, 0, $5)) YYABORT; }
236   | IDENT IDENT '(' FormalParameterList ')' FunctionBody
237                                         { if (!makeGetterOrSetterPropertyNode($$, *$1, *$2, $4, $6)) YYABORT; }
238 ;
239
240 PropertyList:
241     Property                            { $$ = new PropertyListNode($1); }
242   | PropertyList ',' Property           { $$ = new PropertyListNode($3, $1); }
243 ;
244
245 PrimaryExpr:
246     PrimaryExprNoBrace
247   | '{' '}'                             { $$ = new ObjectLiteralNode(); }
248   | '{' PropertyList '}'                { $$ = new ObjectLiteralNode($2); }
249   /* allow extra comma, see http://bugs.webkit.org/show_bug.cgi?id=5939 */
250   | '{' PropertyList ',' '}'            { $$ = new ObjectLiteralNode($2); }
251 ;
252
253 PrimaryExprNoBrace:
254     THISTOKEN                           { $$ = new ThisNode(); }
255   | Literal
256   | ArrayLiteral
257   | IDENT                               { $$ = new ResolveNode(*$1); }
258   | '(' Expr ')'                        { $$ = ($2->isResolveNode() || $2->isGroupNode()) ?
259                                             $2 : new GroupNode($2); }
260 ;
261
262 ArrayLiteral:
263     '[' ElisionOpt ']'                  { $$ = new ArrayNode($2); }
264   | '[' ElementList ']'                 { $$ = new ArrayNode($2); }
265   | '[' ElementList ',' ElisionOpt ']'  { $$ = new ArrayNode($4, $2); }
266 ;
267
268 ElementList:
269     ElisionOpt AssignmentExpr           { $$ = new ElementNode($1, $2); }
270   | ElementList ',' ElisionOpt AssignmentExpr
271                                         { $$ = new ElementNode($1, $3, $4); }
272 ;
273
274 ElisionOpt:
275     /* nothing */                       { $$ = 0; }
276   | Elision
277 ;
278
279 Elision:
280     ','                                 { $$ = 1; }
281   | Elision ','                         { $$ = $1 + 1; }
282 ;
283
284 MemberExpr:
285     PrimaryExpr
286   | FunctionExpr                        { $$ = $1; }
287   | MemberExpr '[' Expr ']'             { $$ = new BracketAccessorNode($1, $3); }
288   | MemberExpr '.' IDENT                { $$ = new DotAccessorNode($1, *$3); }
289   | NEW MemberExpr Arguments            { $$ = new NewExprNode($2, $3); }
290 ;
291
292 MemberExprNoBF:
293     PrimaryExprNoBrace
294   | MemberExprNoBF '[' Expr ']'         { $$ = new BracketAccessorNode($1, $3); }
295   | MemberExprNoBF '.' IDENT            { $$ = new DotAccessorNode($1, *$3); }
296   | NEW MemberExpr Arguments            { $$ = new NewExprNode($2, $3); }
297 ;
298
299 NewExpr:
300     MemberExpr
301   | NEW NewExpr                         { $$ = new NewExprNode($2); }
302 ;
303
304 NewExprNoBF:
305     MemberExprNoBF
306   | NEW NewExpr                         { $$ = new NewExprNode($2); }
307 ;
308
309 CallExpr:
310     MemberExpr Arguments                { $$ = makeFunctionCallNode($1, $2); }
311   | CallExpr Arguments                  { $$ = makeFunctionCallNode($1, $2); }
312   | CallExpr '[' Expr ']'               { $$ = new BracketAccessorNode($1, $3); }
313   | CallExpr '.' IDENT                  { $$ = new DotAccessorNode($1, *$3); }
314 ;
315
316 CallExprNoBF:
317     MemberExprNoBF Arguments            { $$ = makeFunctionCallNode($1, $2); }
318   | CallExprNoBF Arguments              { $$ = makeFunctionCallNode($1, $2); }
319   | CallExprNoBF '[' Expr ']'           { $$ = new BracketAccessorNode($1, $3); }
320   | CallExprNoBF '.' IDENT              { $$ = new DotAccessorNode($1, *$3); }
321 ;
322
323 Arguments:
324     '(' ')'                             { $$ = new ArgumentsNode(); }
325   | '(' ArgumentList ')'                { $$ = new ArgumentsNode($2); }
326 ;
327
328 ArgumentList:
329     AssignmentExpr                      { $$ = new ArgumentListNode($1); }
330   | ArgumentList ',' AssignmentExpr     { $$ = new ArgumentListNode($1, $3); }
331 ;
332
333 LeftHandSideExpr:
334     NewExpr
335   | CallExpr
336 ;
337
338 LeftHandSideExprNoBF:
339     NewExprNoBF
340   | CallExprNoBF
341 ;
342
343 PostfixExpr:
344     LeftHandSideExpr
345   | LeftHandSideExpr PLUSPLUS           { $$ = makePostfixNode($1, OpPlusPlus); }
346   | LeftHandSideExpr MINUSMINUS         { $$ = makePostfixNode($1, OpMinusMinus); }
347 ;
348
349 PostfixExprNoBF:
350     LeftHandSideExprNoBF
351   | LeftHandSideExprNoBF PLUSPLUS       { $$ = makePostfixNode($1, OpPlusPlus); }
352   | LeftHandSideExprNoBF MINUSMINUS     { $$ = makePostfixNode($1, OpMinusMinus); }
353 ;
354
355 UnaryExprCommon:
356     DELETETOKEN UnaryExpr               { $$ = makeDeleteNode($2); }
357   | VOIDTOKEN UnaryExpr                 { $$ = new VoidNode($2); }
358   | TYPEOF UnaryExpr                    { $$ = makeTypeOfNode($2); }
359   | PLUSPLUS UnaryExpr                  { $$ = makePrefixNode($2, OpPlusPlus); }
360   | AUTOPLUSPLUS UnaryExpr              { $$ = makePrefixNode($2, OpPlusPlus); }
361   | MINUSMINUS UnaryExpr                { $$ = makePrefixNode($2, OpMinusMinus); }
362   | AUTOMINUSMINUS UnaryExpr            { $$ = makePrefixNode($2, OpMinusMinus); }
363   | '+' UnaryExpr                       { $$ = new UnaryPlusNode($2); }
364   | '-' UnaryExpr                       { $$ = makeNegateNode($2); }
365   | '~' UnaryExpr                       { $$ = new BitwiseNotNode($2); }
366   | '!' UnaryExpr                       { $$ = new LogicalNotNode($2); }
367
368 UnaryExpr:
369     PostfixExpr
370   | UnaryExprCommon
371 ;
372
373 UnaryExprNoBF:
374     PostfixExprNoBF
375   | UnaryExprCommon
376 ;
377
378 MultiplicativeExpr:
379     UnaryExpr
380   | MultiplicativeExpr '*' UnaryExpr    { $$ = new MultNode($1, $3, '*'); }
381   | MultiplicativeExpr '/' UnaryExpr    { $$ = new MultNode($1, $3, '/'); }
382   | MultiplicativeExpr '%' UnaryExpr    { $$ = new MultNode($1, $3,'%'); }
383 ;
384
385 MultiplicativeExprNoBF:
386     UnaryExprNoBF
387   | MultiplicativeExprNoBF '*' UnaryExpr
388                                         { $$ = new MultNode($1, $3, '*'); }
389   | MultiplicativeExprNoBF '/' UnaryExpr
390                                         { $$ = new MultNode($1, $3, '/'); }
391   | MultiplicativeExprNoBF '%' UnaryExpr
392                                         { $$ = new MultNode($1, $3,'%'); }
393 ;
394
395 AdditiveExpr:
396     MultiplicativeExpr
397   | AdditiveExpr '+' MultiplicativeExpr { $$ = new AddNode($1, $3, '+'); }
398   | AdditiveExpr '-' MultiplicativeExpr { $$ = new AddNode($1, $3, '-'); }
399 ;
400
401 AdditiveExprNoBF:
402     MultiplicativeExprNoBF
403   | AdditiveExprNoBF '+' MultiplicativeExpr
404                                         { $$ = new AddNode($1, $3, '+'); }
405   | AdditiveExprNoBF '-' MultiplicativeExpr
406                                         { $$ = new AddNode($1, $3, '-'); }
407 ;
408
409 ShiftExpr:
410     AdditiveExpr
411   | ShiftExpr LSHIFT AdditiveExpr       { $$ = new ShiftNode($1, OpLShift, $3); }
412   | ShiftExpr RSHIFT AdditiveExpr       { $$ = new ShiftNode($1, OpRShift, $3); }
413   | ShiftExpr URSHIFT AdditiveExpr      { $$ = new ShiftNode($1, OpURShift, $3); }
414 ;
415
416 ShiftExprNoBF:
417     AdditiveExprNoBF
418   | ShiftExprNoBF LSHIFT AdditiveExpr   { $$ = new ShiftNode($1, OpLShift, $3); }
419   | ShiftExprNoBF RSHIFT AdditiveExpr   { $$ = new ShiftNode($1, OpRShift, $3); }
420   | ShiftExprNoBF URSHIFT AdditiveExpr  { $$ = new ShiftNode($1, OpURShift, $3); }
421 ;
422
423 RelationalExpr:
424     ShiftExpr
425   | RelationalExpr '<' ShiftExpr        { $$ = new RelationalNode($1, OpLess, $3); }
426   | RelationalExpr '>' ShiftExpr        { $$ = new RelationalNode($1, OpGreater, $3); }
427   | RelationalExpr LE ShiftExpr         { $$ = new RelationalNode($1, OpLessEq, $3); }
428   | RelationalExpr GE ShiftExpr         { $$ = new RelationalNode($1, OpGreaterEq, $3); }
429   | RelationalExpr INSTANCEOF ShiftExpr { $$ = new RelationalNode($1, OpInstanceOf, $3); }
430   | RelationalExpr INTOKEN ShiftExpr    { $$ = new RelationalNode($1, OpIn, $3); }
431 ;
432
433 RelationalExprNoIn:
434     ShiftExpr
435   | RelationalExprNoIn '<' ShiftExpr    { $$ = new RelationalNode($1, OpLess, $3); }
436   | RelationalExprNoIn '>' ShiftExpr    { $$ = new RelationalNode($1, OpGreater, $3); }
437   | RelationalExprNoIn LE ShiftExpr     { $$ = new RelationalNode($1, OpLessEq, $3); }
438   | RelationalExprNoIn GE ShiftExpr     { $$ = new RelationalNode($1, OpGreaterEq, $3); }
439   | RelationalExprNoIn INSTANCEOF ShiftExpr
440                                         { $$ = new RelationalNode($1, OpInstanceOf, $3); }
441 ;
442
443 RelationalExprNoBF:
444     ShiftExprNoBF
445   | RelationalExprNoBF '<' ShiftExpr    { $$ = new RelationalNode($1, OpLess, $3); }
446   | RelationalExprNoBF '>' ShiftExpr    { $$ = new RelationalNode($1, OpGreater, $3); }
447   | RelationalExprNoBF LE ShiftExpr     { $$ = new RelationalNode($1, OpLessEq, $3); }
448   | RelationalExprNoBF GE ShiftExpr     { $$ = new RelationalNode($1, OpGreaterEq, $3); }
449   | RelationalExprNoBF INSTANCEOF ShiftExpr
450                                         { $$ = new RelationalNode($1, OpInstanceOf, $3); }
451   | RelationalExprNoBF INTOKEN ShiftExpr     { $$ = new RelationalNode($1, OpIn, $3); }
452 ;
453
454 EqualityExpr:
455     RelationalExpr
456   | EqualityExpr EQEQ RelationalExpr    { $$ = new EqualNode($1, OpEqEq, $3); }
457   | EqualityExpr NE RelationalExpr      { $$ = new EqualNode($1, OpNotEq, $3); }
458   | EqualityExpr STREQ RelationalExpr   { $$ = new EqualNode($1, OpStrEq, $3); }
459   | EqualityExpr STRNEQ RelationalExpr  { $$ = new EqualNode($1, OpStrNEq, $3);}
460 ;
461
462 EqualityExprNoIn:
463     RelationalExprNoIn
464   | EqualityExprNoIn EQEQ RelationalExprNoIn
465                                         { $$ = new EqualNode($1, OpEqEq, $3); }
466   | EqualityExprNoIn NE RelationalExprNoIn
467                                         { $$ = new EqualNode($1, OpNotEq, $3); }
468   | EqualityExprNoIn STREQ RelationalExprNoIn
469                                         { $$ = new EqualNode($1, OpStrEq, $3); }
470   | EqualityExprNoIn STRNEQ RelationalExprNoIn
471                                         { $$ = new EqualNode($1, OpStrNEq, $3);}
472 ;
473
474 EqualityExprNoBF:
475     RelationalExprNoBF
476   | EqualityExprNoBF EQEQ RelationalExpr
477                                         { $$ = new EqualNode($1, OpEqEq, $3); }
478   | EqualityExprNoBF NE RelationalExpr  { $$ = new EqualNode($1, OpNotEq, $3); }
479   | EqualityExprNoBF STREQ RelationalExpr
480                                         { $$ = new EqualNode($1, OpStrEq, $3); }
481   | EqualityExprNoBF STRNEQ RelationalExpr
482                                         { $$ = new EqualNode($1, OpStrNEq, $3);}
483 ;
484
485 BitwiseANDExpr:
486     EqualityExpr
487   | BitwiseANDExpr '&' EqualityExpr     { $$ = new BitOperNode($1, OpBitAnd, $3); }
488 ;
489
490 BitwiseANDExprNoIn:
491     EqualityExprNoIn
492   | BitwiseANDExprNoIn '&' EqualityExprNoIn
493                                         { $$ = new BitOperNode($1, OpBitAnd, $3); }
494 ;
495
496 BitwiseANDExprNoBF:
497     EqualityExprNoBF
498   | BitwiseANDExprNoBF '&' EqualityExpr { $$ = new BitOperNode($1, OpBitAnd, $3); }
499 ;
500
501 BitwiseXORExpr:
502     BitwiseANDExpr
503   | BitwiseXORExpr '^' BitwiseANDExpr   { $$ = new BitOperNode($1, OpBitXOr, $3); }
504 ;
505
506 BitwiseXORExprNoIn:
507     BitwiseANDExprNoIn
508   | BitwiseXORExprNoIn '^' BitwiseANDExprNoIn
509                                         { $$ = new BitOperNode($1, OpBitXOr, $3); }
510 ;
511
512 BitwiseXORExprNoBF:
513     BitwiseANDExprNoBF
514   | BitwiseXORExprNoBF '^' BitwiseANDExpr
515                                         { $$ = new BitOperNode($1, OpBitXOr, $3); }
516 ;
517
518 BitwiseORExpr:
519     BitwiseXORExpr
520   | BitwiseORExpr '|' BitwiseXORExpr    { $$ = new BitOperNode($1, OpBitOr, $3); }
521 ;
522
523 BitwiseORExprNoIn:
524     BitwiseXORExprNoIn
525   | BitwiseORExprNoIn '|' BitwiseXORExprNoIn
526                                         { $$ = new BitOperNode($1, OpBitOr, $3); }
527 ;
528
529 BitwiseORExprNoBF:
530     BitwiseXORExprNoBF
531   | BitwiseORExprNoBF '|' BitwiseXORExpr
532                                         { $$ = new BitOperNode($1, OpBitOr, $3); }
533 ;
534
535 LogicalANDExpr:
536     BitwiseORExpr
537   | LogicalANDExpr AND BitwiseORExpr    { $$ = new BinaryLogicalNode($1, OpAnd, $3); }
538 ;
539
540 LogicalANDExprNoIn:
541     BitwiseORExprNoIn
542   | LogicalANDExprNoIn AND BitwiseORExprNoIn
543                                         { $$ = new BinaryLogicalNode($1, OpAnd, $3); }
544 ;
545
546 LogicalANDExprNoBF:
547     BitwiseORExprNoBF
548   | LogicalANDExprNoBF AND BitwiseORExpr
549                                         { $$ = new BinaryLogicalNode($1, OpAnd, $3); }
550 ;
551
552 LogicalORExpr:
553     LogicalANDExpr
554   | LogicalORExpr OR LogicalANDExpr     { $$ = new BinaryLogicalNode($1, OpOr, $3); }
555 ;
556
557 LogicalORExprNoIn:
558     LogicalANDExprNoIn
559   | LogicalORExprNoIn OR LogicalANDExprNoIn
560                                         { $$ = new BinaryLogicalNode($1, OpOr, $3); }
561 ;
562
563 LogicalORExprNoBF:
564     LogicalANDExprNoBF
565   | LogicalORExprNoBF OR LogicalANDExpr { $$ = new BinaryLogicalNode($1, OpOr, $3); }
566 ;
567
568 ConditionalExpr:
569     LogicalORExpr
570   | LogicalORExpr '?' AssignmentExpr ':' AssignmentExpr
571                                         { $$ = new ConditionalNode($1, $3, $5); }
572 ;
573
574 ConditionalExprNoIn:
575     LogicalORExprNoIn
576   | LogicalORExprNoIn '?' AssignmentExprNoIn ':' AssignmentExprNoIn
577                                         { $$ = new ConditionalNode($1, $3, $5); }
578 ;
579
580 ConditionalExprNoBF:
581     LogicalORExprNoBF
582   | LogicalORExprNoBF '?' AssignmentExpr ':' AssignmentExpr
583                                         { $$ = new ConditionalNode($1, $3, $5); }
584 ;
585
586 AssignmentExpr:
587     ConditionalExpr
588   | LeftHandSideExpr AssignmentOperator AssignmentExpr
589                                         { $$ = makeAssignNode($1, $2, $3); }
590 ;
591
592 AssignmentExprNoIn:
593     ConditionalExprNoIn
594   | LeftHandSideExpr AssignmentOperator AssignmentExprNoIn
595                                         { $$ = makeAssignNode($1, $2, $3); }
596 ;
597
598 AssignmentExprNoBF:
599     ConditionalExprNoBF
600   | LeftHandSideExprNoBF AssignmentOperator AssignmentExpr
601                                         { $$ = makeAssignNode($1, $2, $3); }
602 ;
603
604 AssignmentOperator:
605     '='                                 { $$ = OpEqual; }
606   | PLUSEQUAL                           { $$ = OpPlusEq; }
607   | MINUSEQUAL                          { $$ = OpMinusEq; }
608   | MULTEQUAL                           { $$ = OpMultEq; }
609   | DIVEQUAL                            { $$ = OpDivEq; }
610   | LSHIFTEQUAL                         { $$ = OpLShift; }
611   | RSHIFTEQUAL                         { $$ = OpRShift; }
612   | URSHIFTEQUAL                        { $$ = OpURShift; }
613   | ANDEQUAL                            { $$ = OpAndEq; }
614   | XOREQUAL                            { $$ = OpXOrEq; }
615   | OREQUAL                             { $$ = OpOrEq; }
616   | MODEQUAL                            { $$ = OpModEq; }
617 ;
618
619 Expr:
620     AssignmentExpr
621   | Expr ',' AssignmentExpr             { $$ = new CommaNode($1, $3); }
622 ;
623
624 ExprNoIn:
625     AssignmentExprNoIn
626   | ExprNoIn ',' AssignmentExprNoIn     { $$ = new CommaNode($1, $3); }
627 ;
628
629 ExprNoBF:
630     AssignmentExprNoBF
631   | ExprNoBF ',' AssignmentExpr         { $$ = new CommaNode($1, $3); }
632 ;
633
634 Statement:
635     Block
636   | VariableStatement
637   | ConstStatement
638   | EmptyStatement
639   | ExprStatement
640   | IfStatement
641   | IterationStatement
642   | ContinueStatement
643   | BreakStatement
644   | ReturnStatement
645   | WithStatement
646   | SwitchStatement
647   | LabelledStatement
648   | ThrowStatement
649   | TryStatement
650   | DebuggerStatement
651 ;
652
653 Block:
654     '{' '}'                             { $$ = new BlockNode(0); DBG($$, @2, @2); }
655   | '{' SourceElements '}'              { $$ = new BlockNode($2); DBG($$, @3, @3); }
656 ;
657
658 VariableStatement:
659     VAR VariableDeclarationList ';'     { $$ = new VarStatementNode($2); DBG($$, @1, @3); }
660   | VAR VariableDeclarationList error   { $$ = new VarStatementNode($2); DBG($$, @1, @2); AUTO_SEMICOLON; }
661 ;
662
663 VariableDeclarationList:
664     VariableDeclaration                 { $$ = new VarDeclListNode($1); }
665   | VariableDeclarationList ',' VariableDeclaration
666                                         { $$ = new VarDeclListNode($1, $3); }
667 ;
668
669 VariableDeclarationListNoIn:
670     VariableDeclarationNoIn             { $$ = new VarDeclListNode($1); }
671   | VariableDeclarationListNoIn ',' VariableDeclarationNoIn
672                                         { $$ = new VarDeclListNode($1, $3); }
673 ;
674
675 VariableDeclaration:
676     IDENT                               { $$ = new VarDeclNode(*$1, 0, VarDeclNode::Variable); }
677   | IDENT Initializer                   { $$ = new VarDeclNode(*$1, $2, VarDeclNode::Variable); }
678 ;
679
680 VariableDeclarationNoIn:
681     IDENT                               { $$ = new VarDeclNode(*$1, 0, VarDeclNode::Variable); }
682   | IDENT InitializerNoIn               { $$ = new VarDeclNode(*$1, $2, VarDeclNode::Variable); }
683 ;
684
685 ConstStatement:
686     CONSTTOKEN ConstDeclarationList ';' { $$ = new VarStatementNode($2); DBG($$, @1, @3); }
687   | CONSTTOKEN ConstDeclarationList error
688                                         { $$ = new VarStatementNode($2); DBG($$, @1, @2); AUTO_SEMICOLON; }
689 ;
690
691 ConstDeclarationList:
692     ConstDeclaration                    { $$ = new VarDeclListNode($1); }
693   | ConstDeclarationList ',' ConstDeclaration
694                                         { $$ = new VarDeclListNode($1, $3); }
695 ;
696
697 ConstDeclaration:
698     IDENT                               { $$ = new VarDeclNode(*$1, 0, VarDeclNode::Constant); }
699   | IDENT Initializer                   { $$ = new VarDeclNode(*$1, $2, VarDeclNode::Constant); }
700 ;
701
702 Initializer:
703     '=' AssignmentExpr                  { $$ = new AssignExprNode($2); }
704 ;
705
706 InitializerNoIn:
707     '=' AssignmentExprNoIn              { $$ = new AssignExprNode($2); }
708 ;
709
710 EmptyStatement:
711     ';'                                 { $$ = new EmptyStatementNode(); }
712 ;
713
714 ExprStatement:
715     ExprNoBF ';'                        { $$ = new ExprStatementNode($1); DBG($$, @1, @2); }
716   | ExprNoBF error                      { $$ = new ExprStatementNode($1); DBG($$, @1, @1); AUTO_SEMICOLON; }
717 ;
718
719 IfStatement:
720     IF '(' Expr ')' Statement %prec IF_WITHOUT_ELSE
721                                         { $$ = new IfNode($3, $5, 0); DBG($$, @1, @4); }
722   | IF '(' Expr ')' Statement ELSE Statement
723                                         { $$ = new IfNode($3, $5, $7); DBG($$, @1, @4); }
724 ;
725
726 IterationStatement:
727     DO Statement WHILE '(' Expr ')' ';'    { $$ = new DoWhileNode($2, $5); DBG($$, @1, @3);}
728   | DO Statement WHILE '(' Expr ')'     { $$ = new DoWhileNode($2, $5); DBG($$, @1, @3);}
729   | WHILE '(' Expr ')' Statement        { $$ = new WhileNode($3, $5); DBG($$, @1, @4); }
730   | FOR '(' ExprNoInOpt ';' ExprOpt ';' ExprOpt ')' Statement
731                                         { $$ = new ForNode($3, $5, $7, $9); DBG($$, @1, @8); }
732   | FOR '(' VAR VariableDeclarationListNoIn ';' ExprOpt ';' ExprOpt ')' Statement
733                                         { $$ = new ForNode($4, $6, $8, $10); DBG($$, @1, @9); }
734   | FOR '(' LeftHandSideExpr INTOKEN Expr ')' Statement
735                                         {
736                                             Node *n = $3->nodeInsideAllParens();
737                                             if (!n->isLocation())
738                                                 YYABORT;
739                                             $$ = new ForInNode(n, $5, $7);
740                                             DBG($$, @1, @6);
741                                         }
742   | FOR '(' VAR IDENT INTOKEN Expr ')' Statement
743                                         { $$ = new ForInNode(*$4, 0, $6, $8); DBG($$, @1, @7); }
744   | FOR '(' VAR IDENT InitializerNoIn INTOKEN Expr ')' Statement
745                                         { $$ = new ForInNode(*$4, $5, $7, $9); DBG($$, @1, @8); }
746 ;
747
748 ExprOpt:
749     /* nothing */                       { $$ = 0; }
750   | Expr
751 ;
752
753 ExprNoInOpt:
754     /* nothing */                       { $$ = 0; }
755   | ExprNoIn
756 ;
757
758 ContinueStatement:
759     CONTINUE ';'                        { $$ = new ContinueNode(); DBG($$, @1, @2); }
760   | CONTINUE error                      { $$ = new ContinueNode(); DBG($$, @1, @1); AUTO_SEMICOLON; }
761   | CONTINUE IDENT ';'                  { $$ = new ContinueNode(*$2); DBG($$, @1, @3); }
762   | CONTINUE IDENT error                { $$ = new ContinueNode(*$2); DBG($$, @1, @2); AUTO_SEMICOLON; }
763 ;
764
765 BreakStatement:
766     BREAK ';'                           { $$ = new BreakNode(); DBG($$, @1, @2); }
767   | BREAK error                         { $$ = new BreakNode(); DBG($$, @1, @1); AUTO_SEMICOLON; }
768   | BREAK IDENT ';'                     { $$ = new BreakNode(*$2); DBG($$, @1, @3); }
769   | BREAK IDENT error                   { $$ = new BreakNode(*$2); DBG($$, @1, @2); AUTO_SEMICOLON; }
770 ;
771
772 ReturnStatement:
773     RETURN ';'                          { $$ = new ReturnNode(0); DBG($$, @1, @2); }
774   | RETURN error                        { $$ = new ReturnNode(0); DBG($$, @1, @1); AUTO_SEMICOLON; }
775   | RETURN Expr ';'                     { $$ = new ReturnNode($2); DBG($$, @1, @3); }
776   | RETURN Expr error                   { $$ = new ReturnNode($2); DBG($$, @1, @2); AUTO_SEMICOLON; }
777 ;
778
779 WithStatement:
780     WITH '(' Expr ')' Statement         { $$ = new WithNode($3, $5); DBG($$, @1, @4); }
781 ;
782
783 SwitchStatement:
784     SWITCH '(' Expr ')' CaseBlock       { $$ = new SwitchNode($3, $5); DBG($$, @1, @4); }
785 ;
786
787 CaseBlock:
788     '{' CaseClausesOpt '}'              { $$ = new CaseBlockNode($2, 0, 0); }
789   | '{' CaseClausesOpt DefaultClause CaseClausesOpt '}'
790                                         { $$ = new CaseBlockNode($2, $3, $4); }
791 ;
792
793 CaseClausesOpt:
794     /* nothing */                       { $$ = 0; }
795   | CaseClauses
796 ;
797
798 CaseClauses:
799     CaseClause                          { $$ = new ClauseListNode($1); }
800   | CaseClauses CaseClause              { $$ = new ClauseListNode($1, $2); }
801 ;
802
803 CaseClause:
804     CASE Expr ':'                       { $$ = new CaseClauseNode($2); }
805   | CASE Expr ':' SourceElements        { $$ = new CaseClauseNode($2, $4); }
806 ;
807
808 DefaultClause:
809     DEFAULT ':'                         { $$ = new CaseClauseNode(0); }
810   | DEFAULT ':' SourceElements          { $$ = new CaseClauseNode(0, $3); }
811 ;
812
813 LabelledStatement:
814     IDENT ':' Statement                 { $3->pushLabel(*$1); $$ = new LabelNode(*$1, $3); }
815 ;
816
817 ThrowStatement:
818     THROW Expr ';'                      { $$ = new ThrowNode($2); DBG($$, @1, @3); }
819   | THROW Expr error                    { $$ = new ThrowNode($2); DBG($$, @1, @2); AUTO_SEMICOLON; }
820 ;
821
822 TryStatement:
823     TRY Block FINALLY Block             { $$ = new TryNode($2, CommonIdentifiers::shared()->nullIdentifier, 0, $4); DBG($$, @1, @2); }
824   | TRY Block CATCH '(' IDENT ')' Block { $$ = new TryNode($2, *$5, $7, 0); DBG($$, @1, @2); }
825   | TRY Block CATCH '(' IDENT ')' Block FINALLY Block
826                                         { $$ = new TryNode($2, *$5, $7, $9); DBG($$, @1, @2); }
827 ;
828
829 DebuggerStatement:
830     DEBUGGER ';'                        { $$ = new EmptyStatementNode(); DBG($$, @1, @2); }
831   | DEBUGGER error                      { $$ = new EmptyStatementNode(); DBG($$, @1, @1); AUTO_SEMICOLON; }
832 ;
833
834 FunctionDeclaration:
835     FUNCTION IDENT '(' ')' FunctionBody { $$ = new FuncDeclNode(*$2, $5); }
836   | FUNCTION IDENT '(' FormalParameterList ')' FunctionBody
837                                         { $$ = new FuncDeclNode(*$2, $4, $6); }
838 ;
839
840 FunctionExpr:
841     FUNCTION '(' ')' FunctionBody       { $$ = new FuncExprNode(CommonIdentifiers::shared()->nullIdentifier, $4); }
842   | FUNCTION '(' FormalParameterList ')' FunctionBody
843                                         { $$ = new FuncExprNode(CommonIdentifiers::shared()->nullIdentifier, $5, $3); }
844   | FUNCTION IDENT '(' ')' FunctionBody { $$ = new FuncExprNode(*$2, $5); }
845   | FUNCTION IDENT '(' FormalParameterList ')' FunctionBody
846                                         { $$ = new FuncExprNode(*$2, $6, $4); }
847 ;
848
849 FormalParameterList:
850     IDENT                               { $$ = new ParameterNode(*$1); }
851   | FormalParameterList ',' IDENT       { $$ = new ParameterNode($1, *$3); }
852 ;
853
854 FunctionBody:
855     '{' '}' /* not in spec */           { $$ = new FunctionBodyNode(0); DBG($$, @1, @2); }
856   | '{' SourceElements '}'              { $$ = new FunctionBodyNode($2); DBG($$, @1, @3); }
857 ;
858
859 Program:
860     /* not in spec */                   { Parser::accept(new ProgramNode(0)); }
861     | SourceElements                    { Parser::accept(new ProgramNode($1)); }
862 ;
863
864 SourceElements:
865     SourceElement                       { $$ = new SourceElementsNode($1); }
866   | SourceElements SourceElement        { $$ = new SourceElementsNode($1, $2); }
867 ;
868
869 SourceElement:
870     FunctionDeclaration                 { $$ = $1; }
871   | Statement                           { $$ = $1; }
872 ;
873  
874 %%
875
876 static Node* makeAssignNode(Node* loc, Operator op, Node* expr)
877
878     Node *n = loc->nodeInsideAllParens();
879
880     if (!n->isLocation())
881         return new AssignErrorNode(loc, op, expr);
882
883     if (n->isResolveNode()) {
884         ResolveNode *resolve = static_cast<ResolveNode *>(n);
885         return new AssignResolveNode(resolve->identifier(), op, expr);
886     }
887     if (n->isBracketAccessorNode()) {
888         BracketAccessorNode *bracket = static_cast<BracketAccessorNode *>(n);
889         return new AssignBracketNode(bracket->base(), bracket->subscript(), op, expr);
890     }
891     ASSERT(n->isDotAccessorNode());
892     DotAccessorNode *dot = static_cast<DotAccessorNode *>(n);
893     return new AssignDotNode(dot->base(), dot->identifier(), op, expr);
894 }
895
896 static Node* makePrefixNode(Node *expr, Operator op)
897
898     Node *n = expr->nodeInsideAllParens();
899
900     if (!n->isLocation())
901         return new PrefixErrorNode(expr, op);
902     
903     if (n->isResolveNode()) {
904         ResolveNode *resolve = static_cast<ResolveNode *>(n);
905         return new PrefixResolveNode(resolve->identifier(), op);
906     }
907     if (n->isBracketAccessorNode()) {
908         BracketAccessorNode *bracket = static_cast<BracketAccessorNode *>(n);
909         return new PrefixBracketNode(bracket->base(), bracket->subscript(), op);
910     }
911     ASSERT(n->isDotAccessorNode());
912     DotAccessorNode *dot = static_cast<DotAccessorNode *>(n);
913     return new PrefixDotNode(dot->base(), dot->identifier(), op);
914 }
915
916 static Node* makePostfixNode(Node* expr, Operator op)
917
918     Node *n = expr->nodeInsideAllParens();
919
920     if (!n->isLocation())
921         return new PostfixErrorNode(expr, op);
922     
923     if (n->isResolveNode()) {
924         ResolveNode *resolve = static_cast<ResolveNode *>(n);
925         return new PostfixResolveNode(resolve->identifier(), op);
926     }
927     if (n->isBracketAccessorNode()) {
928         BracketAccessorNode *bracket = static_cast<BracketAccessorNode *>(n);
929         return new PostfixBracketNode(bracket->base(), bracket->subscript(), op);
930     }
931     ASSERT(n->isDotAccessorNode());
932     DotAccessorNode *dot = static_cast<DotAccessorNode *>(n);
933     return new PostfixDotNode(dot->base(), dot->identifier(), op);
934 }
935
936 static Node *makeFunctionCallNode(Node *func, ArgumentsNode *args)
937 {
938     Node *n = func->nodeInsideAllParens();
939     
940     if (!n->isLocation())
941         return new FunctionCallValueNode(func, args);
942     else if (n->isResolveNode()) {
943         ResolveNode *resolve = static_cast<ResolveNode *>(n);
944         return new FunctionCallResolveNode(resolve->identifier(), args);
945     } else if (n->isBracketAccessorNode()) {
946         BracketAccessorNode *bracket = static_cast<BracketAccessorNode *>(n);
947         if (n != func)
948             return new FunctionCallParenBracketNode(bracket->base(), bracket->subscript(), args);
949         else
950             return new FunctionCallBracketNode(bracket->base(), bracket->subscript(), args);
951     } else {
952         ASSERT(n->isDotAccessorNode());
953         DotAccessorNode *dot = static_cast<DotAccessorNode *>(n);
954         if (n != func)
955             return new FunctionCallParenDotNode(dot->base(), dot->identifier(), args);
956         else
957             return new FunctionCallDotNode(dot->base(), dot->identifier(), args);
958     }
959 }
960
961 static Node *makeTypeOfNode(Node *expr)
962 {
963     Node *n = expr->nodeInsideAllParens();
964
965     if (n->isResolveNode()) {
966         ResolveNode *resolve = static_cast<ResolveNode *>(n);
967         return new TypeOfResolveNode(resolve->identifier());
968     } else
969         return new TypeOfValueNode(expr);
970 }
971
972 static Node *makeDeleteNode(Node *expr)
973 {
974     Node *n = expr->nodeInsideAllParens();
975     
976     if (!n->isLocation())
977         return new DeleteValueNode(expr);
978     else if (n->isResolveNode()) {
979         ResolveNode *resolve = static_cast<ResolveNode *>(n);
980         return new DeleteResolveNode(resolve->identifier());
981     } else if (n->isBracketAccessorNode()) {
982         BracketAccessorNode *bracket = static_cast<BracketAccessorNode *>(n);
983         return new DeleteBracketNode(bracket->base(), bracket->subscript());
984     } else {
985         ASSERT(n->isDotAccessorNode());
986         DotAccessorNode *dot = static_cast<DotAccessorNode *>(n);
987         return new DeleteDotNode(dot->base(), dot->identifier());
988     }
989 }
990
991 static bool makeGetterOrSetterPropertyNode(PropertyNode*& result, Identifier& getOrSet, Identifier& name, ParameterNode *params, FunctionBodyNode *body)
992 {
993     PropertyNode::Type type;
994     
995     if (getOrSet == "get")
996         type = PropertyNode::Getter;
997     else if (getOrSet == "set")
998         type = PropertyNode::Setter;
999     else
1000         return false;
1001     
1002     result = new PropertyNode(new PropertyNameNode(name), 
1003                               new FuncExprNode(CommonIdentifiers::shared()->nullIdentifier, body, params), type);
1004
1005     return true;
1006 }
1007
1008 static Node* makeNegateNode(Node *n)
1009 {
1010     if (n->isNumber()) {
1011         NumberNode* number = static_cast<NumberNode*>(n);
1012
1013         if (number->value() > 0.0) {
1014             number->setValue(-number->value());
1015             return number;
1016         }
1017     }
1018
1019     return new NegateNode(n);
1020 }
1021
1022 /* called by yyparse on error */
1023 int yyerror(const char *)
1024 {
1025     return 1;
1026 }
1027
1028 /* may we automatically insert a semicolon ? */
1029 static bool allowAutomaticSemicolon()
1030 {
1031     return yychar == '}' || yychar == 0 || Lexer::curr()->prevTerminator();
1032 }