CMake is too slow to make it the default build for us. This
[WebKit-https.git] / JavaScriptCore / JavaScriptCore.pro
1 # JavaScriptCore - Qt4 build info
2 VPATH += $$PWD
3 TEMPLATE = lib
4 TARGET = JavaScriptCore
5 DESTDIR = ../lib
6 OBJECTS_DIR = tmp
7 INCLUDEPATH += tmp
8 INCLUDEPATH += $$PWD $$PWD/kjs $$PWD/bindings $$PWD/bindings/c $$PWD/wtf
9 DEFINES -= KJS_IDENTIFIER_HIDE_GLOBALS 
10 DEFINES += BUILDING_QT__
11 QT -= gui
12
13 isEmpty(OUTPUT_DIR):OUTPUT_DIR=$$PWD
14 include($$OUTPUT_DIR/config.pri)
15
16 include(pcre/pcre.pri)
17
18 LUT_FILES += \
19     kjs/date_object.cpp \
20     kjs/number_object.cpp \
21     kjs/string_object.cpp \
22     kjs/array_object.cpp \
23     kjs/math_object.cpp \
24     kjs/regexp_object.cpp
25
26 KEYWORDLUT_FILES += \
27     kjs/keywords.table
28
29 KJSBISON += \
30     kjs/grammar.y
31
32 SOURCES += \
33     wtf/TCSystemAlloc.cpp \
34     wtf/Assertions.cpp \
35     wtf/HashTable.cpp \
36     wtf/FastMalloc.cpp \
37     bindings/NP_jsobject.cpp \
38     bindings/npruntime.cpp \
39     bindings/runtime_array.cpp \
40     bindings/runtime.cpp \
41     bindings/runtime_method.cpp \
42     bindings/runtime_object.cpp \
43     bindings/runtime_root.cpp \
44     bindings/c/c_class.cpp \
45     bindings/c/c_instance.cpp \
46     bindings/c/c_runtime.cpp \
47     bindings/c/c_utility.cpp \
48     kjs/DateMath.cpp \
49     kjs/JSWrapperObject.cpp \
50     kjs/PropertyNameArray.cpp \
51     kjs/array_object.cpp \
52     kjs/bool_object.cpp \
53     kjs/collector.cpp \
54     kjs/Context.cpp \
55     kjs/date_object.cpp \
56     kjs/debugger.cpp \
57     kjs/dtoa.cpp \
58     kjs/error_object.cpp \
59     kjs/ExecState.cpp \
60     kjs/fpconst.cpp \
61     kjs/function.cpp \
62     kjs/function_object.cpp \
63     kjs/identifier.cpp \
64     kjs/internal.cpp \
65     kjs/interpreter.cpp \
66     kjs/JSImmediate.cpp \
67     kjs/JSLock.cpp \
68     kjs/lexer.cpp \
69     kjs/list.cpp \
70     kjs/lookup.cpp \
71     kjs/math_object.cpp \
72     kjs/nodes.cpp \
73     kjs/nodes2string.cpp \
74     kjs/number_object.cpp \
75     kjs/object.cpp \
76     kjs/object_object.cpp \
77     kjs/operations.cpp \
78     kjs/Parser.cpp \
79     kjs/property_map.cpp \
80     kjs/property_slot.cpp \
81     kjs/regexp.cpp \
82     kjs/regexp_object.cpp \
83     kjs/scope_chain.cpp \
84     kjs/string_object.cpp \
85     kjs/ustring.cpp \
86     kjs/value.cpp
87
88
89 # GENERATOR 1-A: LUT creator
90 lut.output = tmp/${QMAKE_FILE_BASE}.lut.h
91 lut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
92 lut.depend = ${QMAKE_FILE_NAME}
93 lut.input = LUT_FILES
94 lut.CONFIG += no_link
95 QMAKE_EXTRA_COMPILERS += lut
96
97 # GENERATOR 1-B: particular LUT creator (for 1 file only)
98 keywordlut.output = tmp/lexer.lut.h
99 keywordlut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
100 keywordlut.depend = ${QMAKE_FILE_NAME}
101 keywordlut.input = KEYWORDLUT_FILES
102 keywordlut.CONFIG += no_link
103 QMAKE_EXTRA_COMPILERS += keywordlut
104
105 # GENERATOR 2: bison grammar
106 kjsbison.output = tmp/${QMAKE_FILE_BASE}.cpp
107 macx:kjsbison.commands = bison -d -p kjsyy ${QMAKE_FILE_NAME} && mv kjs/${QMAKE_FILE_BASE}.tab.c ${QMAKE_FILE_OUT} && mv kjs/${QMAKE_FILE_BASE}.tab.h tmp/${QMAKE_FILE_BASE}.h
108 !macx:kjsbison.commands = bison -d -p kjsyy ${QMAKE_FILE_NAME} && mv ${QMAKE_FILE_BASE}.tab.c ${QMAKE_FILE_OUT} && mv ${QMAKE_FILE_BASE}.tab.h tmp/${QMAKE_FILE_BASE}.h
109 kjsbison.depend = ${QMAKE_FILE_NAME}
110 kjsbison.input = KJSBISON
111 kjsbison.variable_out = GENERATED_SOURCES
112 kjsbison.dependency_type = TYPE_C
113 kjsbison.CONFIG = target_predeps
114 QMAKE_EXTRA_COMPILERS += kjsbison