JavaScriptCore/JavaScriptCore.pri

   1 # JavaScriptCore - Qt4 build info
   2 VPATH += $$PWD
   3
   4 INCLUDEPATH += tmp
   5 INCLUDEPATH += $$PWD $$PWD/kjs $$PWD/bindings $$PWD/bindings/c $$PWD/wtf
   6 DEPENDPATH += $$PWD $$PWD/kjs $$PWD/bindings $$PWD/bindings/c $$PWD/wtf
   7 DEFINES -= KJS_IDENTIFIER_HIDE_GLOBALS
   8 qt-port:INCLUDEPATH += $$PWD/bindings/qt
   9 qt-port:DEFINES += BUILDING_QT__
  10 gtk-port:DEFINES += BUILDING_GTK__
  11
  12 win32-msvc*: INCLUDEPATH += $$PWD/os-win32
  13
  14 isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
  15
  16 include(pcre/pcre.pri)
  17
  18 LUT_FILES += \
  19     kjs/date_object.cpp \
  20     kjs/number_object.cpp \
  21     kjs/string_object.cpp \
  22     kjs/array_object.cpp \
  23     kjs/math_object.cpp \
  24     kjs/regexp_object.cpp
  25
  26 KEYWORDLUT_FILES += \
  27     kjs/keywords.table
  28
  29 KJSBISON += \
  30     kjs/grammar.y
  31
  32 gtk-port: SOURCES += wtf/TCSystemAlloc.cpp
  33
  34 SOURCES += \
  35     wtf/Assertions.cpp \
  36     wtf/HashTable.cpp \
  37     wtf/FastMalloc.cpp \
  38     wtf/unicode/UTF8.cpp \
  39     bindings/NP_jsobject.cpp \
  40     bindings/npruntime.cpp \
  41     bindings/runtime_array.cpp \
  42     bindings/runtime.cpp \
  43     bindings/runtime_method.cpp \
  44     bindings/runtime_object.cpp \
  45     bindings/runtime_root.cpp \
  46     bindings/c/c_class.cpp \
  47     bindings/c/c_instance.cpp \
  48     bindings/c/c_runtime.cpp \
  49     bindings/c/c_utility.cpp \
  50     API/JSBase.cpp \
  51     API/JSCallbackConstructor.cpp \
  52     API/JSCallbackFunction.cpp \
  53     API/JSCallbackObject.cpp \
  54     API/JSClassRef.cpp \
  55     API/JSContextRef.cpp \
  56     API/JSObjectRef.cpp \
  57     API/JSStringRef.cpp \
  58     API/JSValueRef.cpp \
  59     kjs/DateMath.cpp \
  60     kjs/JSWrapperObject.cpp \
  61     kjs/PropertyNameArray.cpp \
  62     kjs/array_instance.cpp \
  63     kjs/array_object.cpp \
  64     kjs/bool_object.cpp \
  65     kjs/collector.cpp \
  66     kjs/CommonIdentifiers.cpp \
  67     kjs/date_object.cpp \
  68     kjs/debugger.cpp \
  69     kjs/dtoa.cpp \
  70     kjs/error_object.cpp \
  71     kjs/ExecState.cpp \
  72     kjs/fpconst.cpp \
  73     kjs/function.cpp \
  74     kjs/function_object.cpp \
  75     kjs/identifier.cpp \
  76     kjs/internal.cpp \
  77     kjs/interpreter.cpp \
  78     kjs/JSImmediate.cpp \
  79     kjs/JSLock.cpp \
  80     kjs/lexer.cpp \
  81     kjs/list.cpp \
  82     kjs/lookup.cpp \
  83     kjs/math_object.cpp \
  84     kjs/nodes.cpp \
  85     kjs/nodes2string.cpp \
  86     kjs/number_object.cpp \
  87     kjs/object.cpp \
  88     kjs/object_object.cpp \
  89     kjs/operations.cpp \
  90     kjs/Parser.cpp \
  91     kjs/property_map.cpp \
  92     kjs/property_slot.cpp \
  93     kjs/regexp.cpp \
  94     kjs/regexp_object.cpp \
  95     kjs/scope_chain.cpp \
  96     kjs/string_object.cpp \
  97     kjs/ustring.cpp \
  98     kjs/value.cpp
  99
 100 qt-port:SOURCES += \
 101     bindings/qt/qt_class.cpp \
 102     bindings/qt/qt_instance.cpp \
 103     bindings/qt/qt_runtime.cpp
 104
 105 !CONFIG(QTDIR_build) {
 106     defineTest(addExtraCompiler) {
 107         QMAKE_EXTRA_COMPILERS += $$1
 108         generated_files.depends += compiler_$${1}_make_all
 109         export(QMAKE_EXTRA_COMPILERS)
 110         export(generated_files.depends)
 111         return(true)
 112     }
 113 }
 114
 115 # GENERATOR 1-A: LUT creator
 116 lut.output = $$GENERATED_SOURCES_DIR/${QMAKE_FILE_BASE}.lut.h
 117 lut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
 118 lut.depend = ${QMAKE_FILE_NAME}
 119 lut.input = LUT_FILES
 120 lut.CONFIG += no_link
 121 addExtraCompiler(lut)
 122
 123 # GENERATOR 1-B: particular LUT creator (for 1 file only)
 124 keywordlut.output = $$GENERATED_SOURCES_DIR/lexer.lut.h
 125 keywordlut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
 126 keywordlut.depend = ${QMAKE_FILE_NAME}
 127 keywordlut.input = KEYWORDLUT_FILES
 128 keywordlut.CONFIG += no_link
 129 addExtraCompiler(keywordlut)
 130
 131 # GENERATOR 2: bison grammar
 132 kjsbison.output = $$GENERATED_SOURCES_DIR/${QMAKE_FILE_BASE}.cpp
 133 kjsbison.commands = bison -d -p kjsyy ${QMAKE_FILE_NAME} -o ${QMAKE_FILE_BASE}.tab.c && $(MOVE) ${QMAKE_FILE_BASE}.tab.c ${QMAKE_FILE_OUT} && $(MOVE) ${QMAKE_FILE_BASE}.tab.h $$GENERATED_SOURCES_DIR/${QMAKE_FILE_BASE}.h
 134 kjsbison.depend = ${QMAKE_FILE_NAME}
 135 kjsbison.input = KJSBISON
 136 kjsbison.variable_out = GENERATED_SOURCES
 137 kjsbison.dependency_type = TYPE_C
 138 kjsbison.CONFIG = target_predeps
 139 kjsbison.clean = ${QMAKE_FILE_OUT} ${QMAKE_VAR_OBJECTS_DIR_WTR}${QMAKE_FILE_BASE}.h
 140 addExtraCompiler(kjsbison)