670f9d1a766519c57d48f6b17d633493b6b484d6
[WebKit-https.git] / JavaScriptCore / JavaScriptCore.pri
1 # JavaScriptCore - Qt4 build info
2 VPATH += $$PWD
3
4 INCLUDEPATH += tmp
5 INCLUDEPATH += $$PWD $$PWD/kjs $$PWD/bindings $$PWD/bindings/c $$PWD/bindings/qt $$PWD/wtf
6 DEFINES -= KJS_IDENTIFIER_HIDE_GLOBALS 
7 DEFINES += BUILDING_QT__
8
9 include(pcre/pcre.pri)
10
11 LUT_FILES += \
12     kjs/date_object.cpp \
13     kjs/number_object.cpp \
14     kjs/string_object.cpp \
15     kjs/array_object.cpp \
16     kjs/math_object.cpp \
17     kjs/regexp_object.cpp
18
19 KEYWORDLUT_FILES += \
20     kjs/keywords.table
21
22 KJSBISON += \
23     kjs/grammar.y
24
25 SOURCES += \
26     wtf/TCSystemAlloc.cpp \
27     wtf/Assertions.cpp \
28     wtf/HashTable.cpp \
29     wtf/FastMalloc.cpp \
30     bindings/NP_jsobject.cpp \
31     bindings/npruntime.cpp \
32     bindings/runtime_array.cpp \
33     bindings/runtime.cpp \
34     bindings/runtime_method.cpp \
35     bindings/runtime_object.cpp \
36     bindings/runtime_root.cpp \
37     bindings/c/c_class.cpp \
38     bindings/c/c_instance.cpp \
39     bindings/c/c_runtime.cpp \
40     bindings/c/c_utility.cpp \
41     bindings/qt/qt_class.cpp \
42     bindings/qt/qt_instance.cpp \
43     bindings/qt/qt_runtime.cpp \
44     kjs/DateMath.cpp \
45     kjs/JSWrapperObject.cpp \
46     kjs/PropertyNameArray.cpp \
47     kjs/array_object.cpp \
48     kjs/bool_object.cpp \
49     kjs/collector.cpp \
50     kjs/CommonIdentifiers.cpp \
51     kjs/Context.cpp \
52     kjs/date_object.cpp \
53     kjs/debugger.cpp \
54     kjs/dtoa.cpp \
55     kjs/error_object.cpp \
56     kjs/ExecState.cpp \
57     kjs/fpconst.cpp \
58     kjs/function.cpp \
59     kjs/function_object.cpp \
60     kjs/identifier.cpp \
61     kjs/internal.cpp \
62     kjs/interpreter.cpp \
63     kjs/JSImmediate.cpp \
64     kjs/JSLock.cpp \
65     kjs/lexer.cpp \
66     kjs/list.cpp \
67     kjs/lookup.cpp \
68     kjs/math_object.cpp \
69     kjs/nodes.cpp \
70     kjs/nodes2string.cpp \
71     kjs/number_object.cpp \
72     kjs/object.cpp \
73     kjs/object_object.cpp \
74     kjs/operations.cpp \
75     kjs/Parser.cpp \
76     kjs/property_map.cpp \
77     kjs/property_slot.cpp \
78     kjs/regexp.cpp \
79     kjs/regexp_object.cpp \
80     kjs/scope_chain.cpp \
81     kjs/string_object.cpp \
82     kjs/ustring.cpp \
83     kjs/value.cpp
84
85
86 # GENERATOR 1-A: LUT creator
87 lut.output = tmp/${QMAKE_FILE_BASE}.lut.h
88 lut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
89 lut.depend = ${QMAKE_FILE_NAME}
90 lut.input = LUT_FILES
91 lut.CONFIG += no_link
92 QMAKE_EXTRA_COMPILERS += lut
93
94 # GENERATOR 1-B: particular LUT creator (for 1 file only)
95 keywordlut.output = tmp/lexer.lut.h
96 keywordlut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
97 keywordlut.depend = ${QMAKE_FILE_NAME}
98 keywordlut.input = KEYWORDLUT_FILES
99 keywordlut.CONFIG += no_link
100 QMAKE_EXTRA_COMPILERS += keywordlut
101
102 # GENERATOR 2: bison grammar
103 kjsbison.output = tmp/${QMAKE_FILE_BASE}.cpp
104 kjsbison.commands = bison -d -p kjsyy ${QMAKE_FILE_NAME} -o ${QMAKE_FILE_BASE}.tab.c && mv ${QMAKE_FILE_BASE}.tab.c ${QMAKE_FILE_OUT} && mv ${QMAKE_FILE_BASE}.tab.h tmp/${QMAKE_FILE_BASE}.h
105 kjsbison.depend = ${QMAKE_FILE_NAME}
106 kjsbison.input = KJSBISON
107 kjsbison.variable_out = GENERATED_SOURCES
108 kjsbison.dependency_type = TYPE_C
109 kjsbison.CONFIG = target_predeps
110 kjsbison.clean = ${QMAKE_FILE_OUT} tmp/${QMAKE_FILE_BASE}.h
111 QMAKE_EXTRA_COMPILERS += kjsbison