2010-02-11 Antonio Gomes <tonikitoo@webkit.org>
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.59)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [1])
5 m4_define([webkit_micro_version], [21])
6
7 # This is the version we'll be using as part of our User-Agent string
8 # e.g., AppleWebKit/$(webkit_user_agent_version) ...
9 #
10 # Sourced from WebCore/Configurations/Version.xcconfig
11 m4_define([webkit_user_agent_major_version], [531])
12 m4_define([webkit_user_agent_minor_version], [2])
13
14 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
15
16 AC_CONFIG_MACRO_DIR([autotools])
17 AC_CONFIG_AUX_DIR([autotools])
18 AC_SUBST(ACLOCAL_AMFLAGS, "-I autotools")
19
20 AC_CONFIG_HEADERS([autotoolsconfig.h])
21 AC_CANONICAL_HOST
22
23 WEBKIT_MAJOR_VERSION=webkit_major_version
24 WEBKIT_MINOR_VERSION=webkit_minor_version
25 WEBKIT_MICRO_VERSION=webkit_micro_version
26 WEBKIT_USER_AGENT_MAJOR_VERSION=webkit_user_agent_major_version
27 WEBKIT_USER_AGENT_MINOR_VERSION=webkit_user_agent_minor_version
28 AC_SUBST(WEBKIT_MAJOR_VERSION)
29 AC_SUBST(WEBKIT_MINOR_VERSION)
30 AC_SUBST(WEBKIT_MICRO_VERSION)
31 AC_SUBST(WEBKIT_USER_AGENT_MAJOR_VERSION)
32 AC_SUBST(WEBKIT_USER_AGENT_MINOR_VERSION)
33
34 AC_CONFIG_SRCDIR([WebCore/config.h])
35
36 dnl # Libtool library version, not to confuse with API version
37 dnl # see http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html#Libtool-versioning
38 LIBWEBKITGTK_VERSION=17:1:15
39 AC_SUBST([LIBWEBKITGTK_VERSION])
40
41 AM_INIT_AUTOMAKE([foreign subdir-objects tar-ustar])
42
43 # Use AM_SILENT_RULES if present
44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
45
46 # host checking - inspired by the GTK+ configure.in
47 # TODO: move these to webkit.m4?
48 AC_MSG_CHECKING([for native Win32])
49 case "$host" in
50      *-*-mingw*)
51        os_win32=yes
52        ;;
53      *)
54        os_win32=no
55        ;;
56 esac
57 AC_MSG_RESULT([$os_win32])
58
59 case "$host" in
60      *-*-linux*)
61        os_linux=yes
62        ;;
63      *-*-freebsd*)
64        os_freebsd=yes
65        ;;
66      *-*-darwin*)
67        os_darwin=yes
68        ;;
69 esac
70
71 case "$host_os" in
72      gnu* | linux* | k*bsd*-gnu)
73        os_gnu=yes
74        ;;
75      *)
76        os_gnu=no
77        ;;
78 esac
79
80 # initialize webkit options
81 WEBKIT_INIT
82 AC_DISABLE_STATIC
83 AC_LIBTOOL_WIN32_DLL
84 AC_PROG_LIBTOOL
85 # use dolt to speedup the build
86 DOLT
87
88 AC_PATH_PROG(FLEX, flex)
89 if test -z "$FLEX"; then
90    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
91 else
92    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
93    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
94       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
95 fi
96
97 AC_PATH_PROG(GPERF, gperf)
98 if test -z "$GPERF"; then
99    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
100 fi
101
102 # pthread (not needed on Windows)
103 if test "$os_win32" = "no"; then
104 AC_CHECK_HEADERS([pthread.h],
105                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
106                  AC_MSG_ERROR([pthread support is required to build WebKit]))
107 fi
108
109 # check for libjpeg the way Gtk does it.
110 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
111                    jpeg_ok=yes, jpeg_ok=no
112                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
113 if test "$jpeg_ok" = yes; then
114    AC_MSG_CHECKING([for jpeglib])
115    AC_TRY_CPP(
116 [#include <stdio.h>
117 #undef PACKAGE
118 #undef VERSION
119 #undef HAVE_STDLIB_H
120 #include <jpeglib.h>],
121          jpeg_ok=yes,
122          jpeg_ok=no)
123    AC_MSG_RESULT($jpeg_ok)
124    if test "$jpeg_ok" = yes; then
125       JPEG_LIBS="-ljpeg"
126       # should we check for progressive JPEG like GTK+ as well?
127    else
128       AC_MSG_ERROR([JPEG library (libjpeg) not found])
129    fi
130 fi
131 AC_SUBST([JPEG_LIBS])
132
133 # Check for libpng the way Gtk+ does it
134 AC_MSG_CHECKING(for libpng12)
135 if $PKG_CONFIG --exists libpng12 ; then
136     AC_MSG_RESULT(yes)
137     PNG_LIBS=`$PKG_CONFIG --libs libpng12`
138 else
139   AC_MSG_RESULT(no)
140   AC_CHECK_LIB(png, png_read_info,
141     [AC_CHECK_HEADER(png.h,
142       png_ok=yes,
143       png_ok=no)],
144     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
145   if test "$png_ok" = yes; then
146     AC_MSG_CHECKING([for png_structp in png.h])
147     AC_TRY_COMPILE([#include <png.h>],
148       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
149       png_ok=yes,
150       png_ok=no)
151     AC_MSG_RESULT($png_ok)
152     if test "$png_ok" = yes; then
153       PNG_LIBS='-lpng -lz'
154     else
155       AC_MSG_ERROR([PNG library (libpng) not found])
156     fi
157   else
158    AC_MSG_ERROR([PNG library (libpng) not found])
159   fi
160 fi
161 AC_SUBST([PNG_LIBS])
162
163 # determine the GDK/GTK+ target
164 AC_MSG_CHECKING([the target windowing system])
165 AC_ARG_WITH(target,
166             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
167                            [Select webkit target [default=x11]]),
168             [],[with_target="x11"])
169
170 case "$with_target" in
171      x11|win32|quartz|directfb) ;;
172      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
173 esac
174
175 AC_MSG_RESULT([$with_target])
176
177 AC_MSG_CHECKING([for Hildon UI extensions])
178 AC_ARG_WITH(hildon,
179             AC_HELP_STRING([--with-hildon],
180                            [Use Hildon UI extensions [default=no]]),
181             [],[with_hildon="no"])
182 AC_MSG_RESULT([$with_hildon])
183
184 if test "$with_hildon" = "yes"; then
185     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
186     PKG_CHECK_MODULES([HILDON], [hildon-1])
187     AC_SUBST([HILDON_CPPFLAGS])
188     AC_SUBST([HILDON_CFLAGS])
189     AC_SUBST([HILDON_LIBS])
190 fi
191
192 # minimum base dependencies
193 LIBSOUP_REQUIRED_VERSION=2.28.2
194 CAIRO_REQUIRED_VERSION=1.6
195 FONTCONFIG_REQUIRED_VERSION=2.4
196 FREETYPE2_REQUIRED_VERSION=9.0
197 LIBXML_REQUIRED_VERSION=2.6
198
199 # minimum GTK+ base dependencies
200 PANGO_REQUIRED_VERSION=1.12
201 GTK_REQUIRED_VERSION=2.10
202
203 # optional modules
204 LIBXSLT_REQUIRED_VERSION=1.1.7
205 SQLITE_REQUIRED_VERSION=3.0
206 GSTREAMER_REQUIRED_VERSION=0.10
207 ENCHANT_REQUIRED_VERSION=0.22
208 GAIL_REQUIRED_VERSION=1.8
209
210 # Available modules
211 #
212 # glib - glib and includes gthread
213 # unicode - check and identify which unicode backend to use
214 #
215 # todo: webcore gtk
216 WEBKIT_CHECK_DEPENDENCIES([glib unicode])
217
218 GETTEXT_PACKAGE=$PACKAGE
219 AC_SUBST(GETTEXT_PACKAGE)
220 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
221                    [The gettext catalog name])
222
223 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
224 AC_SUBST(LIBXML_CFLAGS)
225 AC_SUBST(LIBXML_LIBS)
226
227 PKG_CHECK_MODULES(PANGO, 
228                   [pango >= $PANGO_REQUIRED_VERSION
229                    pangoft2])
230 AC_SUBST(PANGO_CFLAGS)
231 AC_SUBST(PANGO_LIBS)
232
233 PKG_CHECK_MODULES(ENCHANT, enchant >= $ENCHANT_REQUIRED_VERSION)
234 AC_SUBST(ENCHANT_CFLAGS)
235 AC_SUBST(ENCHANT_LIBS)
236
237 PKG_CHECK_MODULES(GAIL, gail >= $GAIL_REQUIRED_VERSION)
238 AC_SUBST(GAIL_CFLAGS)
239 AC_SUBST(GAIL_LIBS)
240
241 # check for target-specific dependencies
242 if test "$with_target" = "directfb"; then
243    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
244    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
245    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
246 else
247    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
248    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED_VERSION)
249
250    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
251       # check for XT
252       PKG_CHECK_MODULES([XT],
253                         [xt],
254                         [xt_has_pkg_config=yes],
255                         [xt_has_pkg_config=no])
256       # some old versions of Xt do not provide xt.pc, so try to link against Xt
257       # and if it's installed fall back to just adding -lXt
258       if test "$xt_has_pkg_config" = "no"; then
259          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
260          # we don't care about the XtOpenDisplay symbol but only about the
261          # existence of libXt
262          AC_CHECK_LIB([Xt], [XtOpenDisplay],
263                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
264                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
265       fi
266       AC_SUBST([XT_CFLAGS])
267       AC_SUBST([XT_LIBS])
268       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
269    fi
270 fi
271 AC_SUBST(GTK_CFLAGS)
272 AC_SUBST(GTK_LIBS)
273 AC_SUBST(CAIRO_CFLAGS)
274 AC_SUBST(CAIRO_LIBS)
275
276 # check whether to build with debugging enabled
277 AC_MSG_CHECKING([whether to do a debug build])
278 AC_ARG_ENABLE(debug,
279               AC_HELP_STRING([--enable-debug],
280                              [turn on debugging [default=no]]),
281               [],[enable_debug="no"])
282 AC_MSG_RESULT([$enable_debug])
283
284 # check whether to enable optimized builds
285 AC_MSG_CHECKING([whether to enable optimized builds])
286 AC_ARG_ENABLE(optimizations,
287               AC_HELP_STRING([--enable-optimizations],
288                              [turn on optimize builds (GCC only)
289                              [default=yes]]),
290               [enable_optimizations=$enableval],
291               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
292 AC_MSG_RESULT([$enable_optimizations])
293
294 # check whether to enable 3D transforms support
295 AC_MSG_CHECKING([whether to enable support for 3D Transforms])
296 AC_ARG_ENABLE(3D_transforms,
297               AC_HELP_STRING([--enable-3D-transforms],
298                              [enable support for 3D transforms [default=no]]),
299               [],[enable_3D_transforms="no"])
300 AC_MSG_RESULT([$enable_3D_transforms])
301
302 # check whether to enable channel messaging support
303 AC_MSG_CHECKING([whether to enable HTML5 Channel Messaging support])
304 AC_ARG_ENABLE(channel_messaging,
305               AC_HELP_STRING([--enable-channel-messaging],
306                              [enable HTML5 channel messaging support [default=yes]]),
307               [],[enable_channel_messaging="yes"])
308 AC_MSG_RESULT([$enable_channel_messaging])
309
310 # check whether to enable JavaScript debugger/profiler support
311 AC_MSG_CHECKING([whether to enable JavaScript debugger/profiler support])
312 AC_ARG_ENABLE(javascript_debugger,
313               AC_HELP_STRING([--enable-javascript-debugger],
314                              [enable JavaScript debugger/profiler support [default=yes]]),
315               [],[enable_javascript_debugger="yes"])
316 AC_MSG_RESULT([$enable_javascript_debugger])
317
318 # check whether to enable HTML5 Offline Web Applications support
319 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
320 AC_ARG_ENABLE(offline_web_applications,
321               AC_HELP_STRING([--enable-offline-web-applications],
322                              [enable HTML5 offline web applications support [default=yes]]),
323               [],[enable_offline_web_applications="yes"])
324 AC_MSG_RESULT([$enable_offline_web_applications])
325
326 # check whether to enable HTML5 client-side session and persitent storage support
327 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
328 AC_ARG_ENABLE(dom_storage,
329               AC_HELP_STRING([--enable-dom-storage],
330                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
331               [],[enable_dom_storage="yes"])
332 AC_MSG_RESULT([$enable_dom_storage])
333
334 # check whether to enable the indexed database API
335 AC_MSG_CHECKING([whether to enable the indexed database API])
336 AC_ARG_ENABLE(indexed_database,
337               AC_HELP_STRING([--enable-indexeddb],
338                              [enable the indexed database API [default=no]]),
339               [],[enable_indexed_database="no"])
340 AC_MSG_RESULT([$enable_indexed_database])
341
342 # check whether to build with database support
343 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
344 AC_ARG_ENABLE(database,
345               AC_HELP_STRING([--enable-database],
346                              [enable HTML5 client-side database storage support [default=yes]]),
347               [],[enable_database="yes"])
348 AC_MSG_RESULT([$enable_database])
349
350 # check whether to build with server-sent events support
351 AC_MSG_CHECKING([whether to enable HTML5 server-sent events support])
352 AC_ARG_ENABLE(eventsource,
353               AC_HELP_STRING([--enable-eventsource],
354                              [enable HTML5 server-sent events support [default=yes]]),
355               [],[enable_eventsource="yes"])
356 AC_MSG_RESULT([$enable_eventsource])
357
358 # check whether to build with icon database support
359 AC_MSG_CHECKING([whether to enable icon database support])
360 AC_ARG_ENABLE(icon_database,
361               AC_HELP_STRING([--enable-icon-database],
362                              [enable icon database [default=yes]]),
363               [],[enable_icon_database="yes"])
364 AC_MSG_RESULT([$enable_icon_database])
365
366 # check whether to enable HTML5 datalist support
367 AC_MSG_CHECKING([whether to enable HTML5 datalist support])
368 AC_ARG_ENABLE(datalist,
369               AC_HELP_STRING([--enable-datalist],
370                              [enable HTML5 datalist support [default=yes]]),
371               [],[enable_datalist="yes"])
372 AC_MSG_RESULT([$enable_datalist])
373
374 # check whether to enable HTML5 ruby support
375 AC_MSG_CHECKING([whether to enable HTML5 ruby support])
376 AC_ARG_ENABLE(ruby,
377               AC_HELP_STRING([--enable-ruby],
378                              [enable HTML5 ruby support [default=yes]]),
379               [],[enable_ruby="yes"])
380 AC_MSG_RESULT([$enable_ruby])
381
382 # check whether to enable HTML5 ruby support
383 AC_MSG_CHECKING([whether to enable HTML5 ruby support])
384 AC_ARG_ENABLE(ruby,
385               AC_HELP_STRING([--enable-ruby],
386                              [enable HTML5 ruby support [default=yes]]),
387               [],[enable_ruby="yes"])
388 AC_MSG_RESULT([$enable_ruby])
389
390 # check whether to enable HTML5 audio/video support
391 AC_MSG_CHECKING([whether to enable HTML5 video support])
392 AC_ARG_ENABLE(video,
393               AC_HELP_STRING([--enable-video],
394                              [enable HTML5 video support [default=yes]]),
395               [],[enable_video="yes"])
396 AC_MSG_RESULT([$enable_video])
397
398 # check whether to enable XHTML-MP support
399 AC_MSG_CHECKING([whether to enable XHTML-MP support])
400 AC_ARG_ENABLE(xhtmlmp,
401               AC_HELP_STRING([--enable-xhtmlmp],
402                              [enable support for XHTML-MP [default=no]]),
403               [],[enable_xhtmlmp="no"])
404 AC_MSG_RESULT([$enable_xhtmlmp])
405
406 # check whether to enable XPath support
407 AC_MSG_CHECKING([whether to enable XPath support])
408 AC_ARG_ENABLE(xpath,
409               AC_HELP_STRING([--enable-xpath],
410                              [enable support for XPath [default=yes]]),
411               [],[enable_xpath="yes"])
412 AC_MSG_RESULT([$enable_xpath])
413
414 # check whether to enable XSLT support
415 AC_MSG_CHECKING([whether to enable XSLT support])
416 AC_ARG_ENABLE(xslt,
417               AC_HELP_STRING([--enable-xslt],
418                              [enable support for XSLT [default=yes]]),
419               [],[enable_xslt="yes"])
420 AC_MSG_RESULT([$enable_xslt])
421
422 # check whether to enable geolocation support
423 AC_MSG_CHECKING([whether to enable geolocation support])
424 AC_ARG_ENABLE(geolocation,
425               AC_HELP_STRING([--enable-geolocation],
426                              [enable support for geolocation [default=no]]),
427               [],[enable_geolocation="no"])
428 AC_MSG_RESULT([$enable_geolocation])
429
430 # check whether to enable MathML support
431 AC_MSG_CHECKING([whether to enable MathML support])
432 AC_ARG_ENABLE(mathml,
433               AC_HELP_STRING([--enable-mathml],
434                              [enable support for MathML [default=no]]),
435               [],[enable_mathml="no"])
436 AC_MSG_RESULT([$enable_mathml])
437
438 # check whether to enable SVG support
439 AC_MSG_CHECKING([whether to enable SVG support])
440 AC_ARG_ENABLE(svg,
441               AC_HELP_STRING([--enable-svg],
442                              [enable support for SVG [default=yes]]),
443               [],[enable_svg="yes"])
444 AC_MSG_RESULT([$enable_svg])
445
446 # check whether to enable WML support
447 AC_MSG_CHECKING([whether to enable WML support])
448 AC_ARG_ENABLE(wml,
449               AC_HELP_STRING([--enable-wml],
450                              [enable support for WML [default=no]]),
451               [],[enable_wml="no"])
452 AC_MSG_RESULT([$enable_wml])
453
454 # check whether to enable SharedWorkers support
455 AC_MSG_CHECKING([whether to enable SharedWorkers support])
456 AC_ARG_ENABLE(shared_workers,
457               AC_HELP_STRING([--enable-shared-workers],
458                              [enable support for SharedWorkers [default=no]]),
459               [],[enable_shared_workers="no"])
460 AC_MSG_RESULT([$enable_shared_workers])
461
462 # check whether to enable Web Workers support
463 AC_MSG_CHECKING([whether to enable Web Workers support])
464 AC_ARG_ENABLE(workers,
465               AC_HELP_STRING([--enable-workers],
466                              [enable support for Web Workers [default=yes]]),
467               [],[enable_workers="yes"])
468 AC_MSG_RESULT([$enable_workers])
469
470 # turn off svg features if --disable-svg is requested
471 if test "$enable_svg" = "no"; then
472    enable_svg_animation=no
473    enable_svg_fonts=no
474    enable_svg_foreign_object=no
475    enable_svg_as_image=no
476    enable_svg_use=no
477 fi
478
479 # check whether to enable support for SVG animation
480 AC_MSG_CHECKING([whether to enable support for SVG animation])
481 AC_ARG_ENABLE(svg_animation,
482               AC_HELP_STRING([--enable-svg-animation],
483                              [enable support for SVG animation (experimental) [default=yes]]),
484               [],[enable_svg_animation="yes"])
485 AC_MSG_RESULT([$enable_svg_animation])
486
487 # check whether to enable support for filters
488 AC_MSG_CHECKING([whether to enable support for filters])
489 AC_ARG_ENABLE(filters,
490               AC_HELP_STRING([--enable-filters],
491                              [enable support for filters (experimental) [default=yes]]),
492               [],[enable_filters="yes"])
493 AC_MSG_RESULT([$enable_filters])
494
495 # check whether to enable support for SVG fonts
496 AC_MSG_CHECKING([whether to enable support for SVG fonts])
497 AC_ARG_ENABLE(svg_fonts,
498               AC_HELP_STRING([--enable-svg-fonts],
499                              [enable support for SVG fonts (experimental) [default=yes]]),
500               [],[enable_svg_fonts="yes"])
501 AC_MSG_RESULT([$enable_svg_fonts])
502
503 # check whether to enable foreign objects support for SVG
504 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
505 AC_ARG_ENABLE(svg_foreign_object,
506               AC_HELP_STRING([--enable-svg-foreign-object],
507                              [enable support for SVG foreign objects (experimental) [default=yes]]),
508               [],[enable_svg_foreign_object="yes"])
509 AC_MSG_RESULT([$enable_svg_foreign_object])
510
511 # check whether to enable SVG As Image support
512 AC_MSG_CHECKING([whether to enable SVG as Image support])
513 AC_ARG_ENABLE(svg_as_image,
514               AC_HELP_STRING([--enable-svg-as-image],
515                              [enable SVG as Image support (experimental) [default=yes]]),
516               [],[enable_svg_as_image="yes"])
517 AC_MSG_RESULT([$enable_svg_as_image])
518
519 # check whether to enable SVG USE element support
520 AC_MSG_CHECKING([whether to enable support for SVG use element])
521 AC_ARG_ENABLE(svg_use,
522               AC_HELP_STRING([--enable-svg-use],
523                              [enable SVG use element support (experimental) [default=yes]]),
524               [],[enable_svg_use="yes"])
525 AC_MSG_RESULT([$enable_svg_use])
526
527 # check for SVG features, enabling SVG if necessary
528 if test "$enable_svg_animation" = "yes" || \
529    test "$enable_svg_fonts" = "yes" || \
530    test "$enable_svg_foreign_object" = "yes" || \
531    test "$enable_svg_as_image" = "yes" || \
532    test "$enable_svg_use" = "yes"; then
533    svg_flags=yes
534    if test "$enable_svg" = "no"; then
535        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
536        enable_svg=yes
537    fi
538 fi
539
540 # check whether to enable Web Socket support
541 AC_MSG_CHECKING([whether to enable Web Sockets support])
542 AC_ARG_ENABLE(web_sockets,
543               AC_HELP_STRING([--enable-web-sockets],
544                              [enable support for Web Sockets [default=no]]),
545               [],[enable_web_sockets="no"])
546 AC_MSG_RESULT([$enable_web_sockets])
547
548 # check whether to enable code coverage
549 AC_MSG_CHECKING([whether to enable code coverage support])
550 AC_ARG_ENABLE(coverage,
551               AC_HELP_STRING([--enable-coverage],
552                              [enable code coverage support [default=no]]),
553               [],[enable_coverage="no"])
554 AC_MSG_RESULT([$enable_coverage])
555
556 # check whether to enable FastMalloc
557 AC_MSG_CHECKING([whether to enable optimized memory allocator])
558 AC_ARG_ENABLE(fast_malloc,
559               AC_HELP_STRING([--enable-fast-malloc],
560                              [enable optimized memory allocator default=yes, default=no for debug builds]),
561               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
562 AC_MSG_RESULT([$enable_fast_malloc])
563
564 AC_MSG_CHECKING([whether to enable JIT compilation])
565 AC_ARG_ENABLE([jit],
566               AC_HELP_STRING([--enable-jit],
567                              [Enable JIT compilation default=yes]),
568               [],[enable_jit="yes"])
569 if test "$enable_jit" = "yes"; then
570     case "$host_cpu" in
571         i*86|x86_64)
572             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
573             AC_DEFINE([ENABLE_YARR], [1], [Define to enable YARR])
574             AC_DEFINE([ENABLE_YARR_JIT], [1], [Define to enable YARR JIT])
575             AC_DEFINE([ENABLE_JIT_OPTIMIZE_CALL], [1], [Define to enable optimizing calls])
576             AC_DEFINE([ENABLE_JIT_OPTIMIZE_PROPERTY_ACCESS], [1], [Define to enable optimized property access])
577             AC_DEFINE([ENABLE_JIT_OPTIMIZE_ARITHMETIC], [1], [Define to enable optimized arithmetic])
578             case "$host_cpu" in
579                 i*86)
580                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_VA_LIST], [1], [Use stub va_list])
581                 ;;
582                 x86_64)
583                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_REGISTER], [1], [Use stub register])
584                     AC_DEFINE([WTF_USE_ALTERNATE_JSIMMEDIATE], [1], [Use alternate JSImmediate])
585                 ;;
586             esac
587         ;;
588         *)
589             enable_jit="no (CPU '$host_cpu' not supported)"
590         ;;
591     esac
592 fi
593 AC_MSG_RESULT([$enable_jit])
594
595 # GObject Introspection
596 AC_MSG_CHECKING([whether to enable GObject introspection support])
597 AC_ARG_ENABLE([introspection],
598   [AS_HELP_STRING([--enable-introspection],[Enable GObject introspection (default: disabled)])],
599   [],[enable_introspection=no])
600 AC_MSG_RESULT([$enable_introspection])
601
602 G_IR_SCANNER=
603 G_IR_COMPILER=
604 G_IR_GENERATE=
605 GIRDIR=
606 GIRTYPELIBDIR=
607
608 if test "$enable_introspection" = "yes"; then
609   GOBJECT_INTROSPECTION_REQUIRED=0.6.2
610   PKG_CHECK_MODULES([INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
611   
612   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
613   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
614   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
615   GIRDIR="$($PKG_CONFIG --define-variable=prefix=$prefix --variable=girdir gobject-introspection-1.0)"
616   GIRTYPELIBDIR="$($PKG_CONFIG --define-variable=prefix=$prefix --variable=typelibdir gobject-introspection-1.0)"
617
618   AC_DEFINE([ENABLE_INTROSPECTION],[1],[Define to enable GObject introspection support])
619 fi
620
621 AC_SUBST([G_IR_SCANNER])
622 AC_SUBST([G_IR_COMPILER])
623 AC_SUBST([G_IR_GENERATE])
624 AC_SUBST([GIRDIR])
625 AC_SUBST([GIRTYPELIBDIR])
626
627 # determine the font backend
628 AC_MSG_CHECKING([the font backend to use])
629 AC_ARG_WITH(font_backend,
630             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
631                            [Select font backend [default=freetype]]),
632             [],[with_font_backend="freetype"])
633
634 case "$with_font_backend" in
635      freetype|pango) ;;
636      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
637 esac
638 AC_MSG_RESULT([$with_font_backend])
639
640 # Add '-g' flag to gcc if it's debug build
641 if test "$enable_debug" = "yes"; then
642    CXXFLAGS="$CXXFLAGS -g"
643    CFLAGS="$CFLAGS -g"
644 else
645    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
646 fi
647
648 # Add the appropriate 'O' level for optimized builds
649 if test "$enable_optimizations" = "yes"; then
650    CXXFLAGS="$CXXFLAGS -O2"
651    CFLAGS="$CFLAGS -O2"
652 else
653    CXXFLAGS="$CXXFLAGS -O0"
654    CFLAGS="$CFLAGS -O0"
655 fi
656
657 PKG_CHECK_MODULES([LIBSOUP],
658                   [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
659 AC_SUBST([LIBSOUP_CFLAGS])
660 AC_SUBST([LIBSOUP_LIBS])
661
662 # check if we can use libSoup 2.29.90 features
663 PKG_CHECK_MODULES([LIBSOUP_2_29_90],
664                   [libsoup-2.4 >= 2.29.90],
665                   [have_libsoup_2_29_90=yes],
666                   [have_libsoup_2_29_90=no])
667 if test "$have_libsoup_2_29_90" = "yes"; then
668    AC_DEFINE([HAVE_LIBSOUP_2_29_90], 1, [Whether libSoup 2.29.90 features are available])
669 fi
670
671 # check if FreeType/FontConfig are available
672 if test "$with_font_backend" = "freetype"; then
673    if test "$with_target" = "directfb"; then
674    PKG_CHECK_MODULES([FREETYPE],
675                      [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
676                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
677    else
678    PKG_CHECK_MODULES([FREETYPE],
679                      [cairo-ft
680                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
681                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
682    fi
683    AC_SUBST([FREETYPE_CFLAGS])
684    AC_SUBST([FREETYPE_LIBS])
685 fi
686
687 # check if sqlite 3 is available
688 if test "$enable_icon_database" = "yes" || \
689    test "$enable_database" = "yes" || \
690    test "$enable_offline_web_applications" = "yes" || \
691    test "$enable_dom_storage" = "yes"; then
692    PKG_CHECK_MODULES([SQLITE3],
693                      [sqlite3 >= $SQLITE_REQUIRED_VERSION],
694                      [sqlite3_has_pkg_config=yes],
695                      [sqlite3_has_pkg_config=no])
696    if test "$sqlite3_has_pkg_config" = "no"; then
697       AC_SEARCH_LIBS([sqlite3_open16], [sqlite3],
698                      [SQLITE3_LIBS="$LIBS";SQLITE3_CFLAGS="-I $srcdir/WebKitLibraries/WebCoreSQLite3"],
699                      [AC_MSG_ERROR([SQLite3 is required to enable Database support])])
700    fi
701    AC_SUBST([SQLITE3_CFLAGS])
702    AC_SUBST([SQLITE3_LIBS])
703 fi
704
705 # check if libxslt is available
706 if test "$enable_xslt" = "yes"; then
707    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
708    AC_SUBST([LIBXSLT_CFLAGS])
709    AC_SUBST([LIBXSLT_LIBS])
710 fi
711
712 # check if geoclue is available
713 if test "$enable_geolocation" = "yes"; then
714     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
715     AC_SUBST([GEOCLUE_CFLAGS])
716     AC_SUBST([GEOCLUE_LIBS])
717 fi
718
719 # check if gstreamer is available
720 if test "$enable_video" = "yes"; then
721    PKG_CHECK_MODULES([GSTREAMER],
722                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
723                      gstreamer-app-0.10
724                      gstreamer-base-0.10
725                      gstreamer-pbutils-0.10
726                      gstreamer-plugins-base-0.10.23
727                      gstreamer-video-0.10])
728    AC_SUBST([GSTREAMER_CFLAGS])
729    AC_SUBST([GSTREAMER_LIBS])
730 fi
731
732 # check for code coverage support
733 if test "$enable_coverage" = "yes"; then
734    COVERAGE_CFLAGS="-MD"
735    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
736    AC_SUBST([COVERAGE_CFLAGS])
737    AC_SUBST([COVERAGE_LDFLAGS])
738 fi
739
740 # check for HTML features
741 if test "$enable_video" = "yes"; then
742     html_flags=yes
743 fi
744
745 GTK_DOC_CHECK([1.10])
746
747 # OS conditionals
748 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
749 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
750 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
751 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
752 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
753
754 # target conditionals
755 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
756 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
757 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
758 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
759
760 # Unicode backend conditionals
761 AM_CONDITIONAL([USE_ICU_UNICODE], [test "$with_unicode_backend" = "icu"])
762 AM_CONDITIONAL([USE_GLIB_UNICODE], [test "$with_unicode_backend" = "glib"])
763
764 # Font backend conditionals
765 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
766 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
767
768 # WebKit feature conditionals
769 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
770 AM_CONDITIONAL([ENABLE_3D_TRANSFORMS],[test "$enable_3D_transforms" = "yes"])
771 AM_CONDITIONAL([ENABLE_CHANNEL_MESSAGING],[test "$enable_channel_messaging" = "yes"])
772 AM_CONDITIONAL([ENABLE_JAVASCRIPT_DEBUGGER],[test "$enable_javascript_debugger" = "yes"])
773 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
774 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
775 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
776 AM_CONDITIONAL([ENABLE_DATALIST],[test "$enable_datalist" = "yes"])
777 AM_CONDITIONAL([ENABLE_EVENTSOURCE],[test "$enable_eventsource" = "yes"])
778 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
779 AM_CONDITIONAL([ENABLE_INDEXED_DATABASE],[test "$enable_indexed_database" = "yes"])
780 AM_CONDITIONAL([ENABLE_XHTMLMP],[test "$enable_xhtmlmp" = "yes"])
781 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
782 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
783 AM_CONDITIONAL([ENABLE_FILTERS],[test "$enable_filters" = "yes"])
784 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
785 AM_CONDITIONAL([ENABLE_MATHML], [test "$enable_mathml" = "yes"])
786 AM_CONDITIONAL([ENABLE_RUBY],[test "$enable_ruby" = "yes"])
787 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
788 AM_CONDITIONAL([ENABLE_NOTIFICATIONS],[test "$enable_notifications" = "yes"])
789 AM_CONDITIONAL([ENABLE_ORIENTATION_EVENTS],[test "$enable_orientation_events" = "yes"])
790 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
791 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
792 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
793 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
794 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
795 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use" = "yes"])
796 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
797 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
798 AM_CONDITIONAL([ENABLE_WML],[test "$enable_wml" = "yes"])
799 AM_CONDITIONAL([ENABLE_WORKERS],[test "$enable_workers" = "yes"])
800 AM_CONDITIONAL([ENABLE_SHARED_WORKERS],[test "$enable_shared_workers" = "yes"])
801 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
802 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
803 AM_CONDITIONAL([ENABLE_WEB_SOCKETS],[test "$enable_web_sockets" = "yes"])
804
805 # Gtk conditionals
806 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
807
808
809 AC_CONFIG_FILES([
810 GNUmakefile
811 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
812 WebKit/gtk/webkit/webkitversion.h
813 WebKit/gtk/docs/GNUmakefile
814 WebKit/gtk/docs/version.xml
815 ]
816 )
817
818 AC_OUTPUT
819
820 echo "
821 WebKit was configured with the following options:
822
823 Build configuration:
824  Enable debugging (slow)                                  : $enable_debug
825  Enable GCC build optimization                            : $enable_optimizations
826  Code coverage support                                    : $enable_coverage
827  Unicode backend                                          : $with_unicode_backend
828  Font backend                                             : $with_font_backend
829  Optimized memory allocator                               : $enable_fast_malloc
830 Features:
831  3D Transforms                                            : $enable_3D_transforms
832  JIT compilation                                          : $enable_jit
833  Filters support                                          : $enable_filters
834  Geolocation support                                      : $enable_geolocation
835  JavaScript debugger/profiler support                     : $enable_javascript_debugger
836  MathML support                                           : $enable_mathml
837  HTML5 offline web applications support                   : $enable_offline_web_applications
838  HTML5 channel messaging support                          : $enable_channel_messaging
839  HTML5 client-side session and persistent storage support : $enable_dom_storage
840  HTML5 client-side database storage support               : $enable_database
841  HTML5 ruby support                                       : $enable_ruby
842  HTML5 server-sent events support                         : $enable_eventsource
843  HTML5 video element support                              : $enable_video
844  Icon database support                                    : $enable_icon_database
845  SharedWorkers support                                    : $enable_shared_workers
846  SVG support                                              : $enable_svg
847  SVG animation support                                    : $enable_svg_animation
848  SVG fonts support                                        : $enable_svg_fonts
849  SVG foreign object support                               : $enable_svg_foreign_object
850  SVG as image support                                     : $enable_svg_as_image
851  SVG use element support                                  : $enable_svg_use
852  WML support                                              : $enable_wml
853  Web Sockets support                                      : $enable_web_sockets
854  Web Workers support                                      : $enable_workers
855  XHTML-MP support                                         : $enable_xhtmlmp
856  XPATH support                                            : $enable_xpath
857  XSLT support                                             : $enable_xslt
858 GTK+ configuration:
859  GDK target                                               : $with_target
860  Hildon UI extensions                                     : $with_hildon
861  Introspection support                                    : $enable_introspection
862 "
863 if test "$with_unicode_backend" = "glib"; then
864    echo "     >> WARNING: the glib-based unicode backend is slow and incomplete <<"
865    echo
866    echo
867 fi