[GTK] configure.ac requires a cleanup
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.60)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [11])
5 m4_define([webkit_micro_version], [5])
6
7 # This is the version we'll be using as part of our User-Agent string,
8 # e.g., AppleWebKit/$(webkit_user_agent_version) ...
9 #
10 # Sourced from Source/WebCore/Configurations/Version.xcconfig
11 m4_define([webkit_user_agent_major_version], [537])
12 m4_define([webkit_user_agent_minor_version], [30])
13
14 AC_INIT([WebKitGTK],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
15
16 AC_CONFIG_MACRO_DIR([Source/autotools])
17 AC_CONFIG_AUX_DIR([Source/autotools])
18 AC_SUBST(ACLOCAL_AMFLAGS, "-I Source/autotools")
19
20 AC_CONFIG_HEADERS([autotoolsconfig.h])
21 AC_CANONICAL_HOST
22
23 WEBKIT_MAJOR_VERSION=webkit_major_version
24 WEBKIT_MINOR_VERSION=webkit_minor_version
25 WEBKIT_MICRO_VERSION=webkit_micro_version
26 WEBKIT_USER_AGENT_MAJOR_VERSION=webkit_user_agent_major_version
27 WEBKIT_USER_AGENT_MINOR_VERSION=webkit_user_agent_minor_version
28 AC_SUBST(WEBKIT_MAJOR_VERSION)
29 AC_SUBST(WEBKIT_MINOR_VERSION)
30 AC_SUBST(WEBKIT_MICRO_VERSION)
31 AC_SUBST(WEBKIT_USER_AGENT_MAJOR_VERSION)
32 AC_SUBST(WEBKIT_USER_AGENT_MINOR_VERSION)
33
34 AC_CONFIG_SRCDIR([Source/WebCore/config.h])
35
36 # Libtool library version, not to confuse with API version.
37 # See http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
38 LIBWEBKITGTK_VERSION=18:1:18
39 AC_SUBST([LIBWEBKITGTK_VERSION])
40
41 LIBJAVASCRIPTCOREGTK_VERSION=13:8:13
42 AC_SUBST([LIBJAVASCRIPTCOREGTK_VERSION])
43
44 LIBWEBKIT2GTK_VERSION=21:0:21
45 AC_SUBST([LIBWEBKIT2GTK_VERSION])
46
47 AM_INIT_AUTOMAKE([foreign subdir-objects dist-xz no-dist-gzip tar-ustar])
48
49 # Use AM_SILENT_RULES if present.
50 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
51
52 # Host checking - inspired by the GTK+ configure.in
53 # TODO: move these to webkit.m4?
54 AC_MSG_CHECKING([for native Win32])
55 case "$host" in
56     *-*-mingw*)
57         os_win32=yes
58         ;;
59     *)
60         os_win32=no
61         ;;
62 esac
63 AC_MSG_RESULT([$os_win32])
64 case "$host" in
65     *-*-linux*)
66         os_linux=yes
67         ;;
68     *-*-freebsd*)
69         os_freebsd=yes
70         ;;
71     *-*-darwin*)
72         os_darwin=yes
73         ;;
74 esac
75
76 case "$host_os" in
77     gnu* | linux* | k*bsd*-gnu)
78         os_gnu=yes
79         ;;
80     *)
81         os_gnu=no
82         ;;
83 esac
84
85 # If CFLAGS and CXXFLAGS are unset, default to empty.
86 # This is to tell automake not to include '-g' if C{XX,}FLAGS is not set.
87 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
88 if test -z "$CXXFLAGS"; then
89     CXXFLAGS=""
90 fi
91 if test -z "$CFLAGS"; then
92     CFLAGS=""
93 fi
94
95 PKG_PROG_PKG_CONFIG
96
97 AC_PATH_PROG(PERL, perl)
98 if test -z "$PERL"; then
99     AC_MSG_ERROR([You need 'perl' to compile WebKit])
100 fi
101
102 AC_PATH_PROG(PYTHON, python)
103 if test -z "$PYTHON"; then
104     AC_MSG_ERROR([You need 'python' to compile WebKit])
105 fi
106
107 AC_PATH_PROG(RUBY, ruby)
108 if test -z "$RUBY"; then
109     AC_MSG_ERROR([You need 'ruby' to compile WebKit])
110 fi
111
112 AC_PATH_PROG(BISON, bison)
113 if test -z "$BISON"; then
114     AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
115 fi
116
117 AC_PATH_PROG(MV, mv)
118 if test -z "$MV"; then
119     AC_MSG_ERROR([You need 'mv' to compile WebKit])
120 fi
121
122 AC_PROG_CC
123 AC_PROG_CXX
124 AM_PROG_CC_C_O
125 AC_PROG_INSTALL
126 AC_SYS_LARGEFILE
127
128 if test -z "$AR_FLAGS"; then
129     AR_FLAGS="cruT"
130 fi
131
132 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it doesn't exist).
133 AC_LANG_PUSH([C++])
134 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
135 AC_LANG_POP([C++])
136
137 # C/C++ Language Features
138 AC_C_CONST
139 AC_C_INLINE
140 AC_C_VOLATILE
141
142 # C/C++ Headers
143 AC_HEADER_STDC
144 AC_HEADER_STDBOOL
145
146 # Linker
147 AC_DISABLE_STATIC
148 AC_LIBTOOL_WIN32_DLL
149 AC_PROG_LIBTOOL
150
151 # Use dolt to speedup the build.
152 DOLT
153
154 AC_PATH_PROG(FLEX, flex)
155 if test -z "$FLEX"; then
156     AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
157 else
158     FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
159     AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
160         AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
161 fi
162
163 AC_PATH_PROG(GPERF, gperf)
164 if test -z "$GPERF"; then
165     AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
166 fi
167
168 # Check for -fvisibility=hidden compiler support (GCC >= 4).
169 saved_CFLAGS="$CFLAGS"
170 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
171 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
172 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])], [AC_MSG_RESULT([yes])
173     SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden"], [AC_MSG_RESULT([no])])
174 CFLAGS="$saved_CFLAGS"
175 AC_SUBST(SYMBOL_VISIBILITY)
176 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
177
178 # Disable C++0x compat warnings for GCC >= 4.6.0 until we build cleanly with that.
179 AC_LANG_PUSH(C++)
180 TMPCXXFLAGS=$CXXFLAGS
181 CXXFLAGS="-Wall -Werror"
182 AC_MSG_CHECKING([if we have to disable C++0x compat warnings for GCC >= 4.6.0])
183 AC_TRY_COMPILE([
184 namespace std {
185     class nullptr_t { };
186 }
187 extern std::nullptr_t nullptr;
188 ], [return 0;], disable_cxx0x_compat=no, disable_cxx0x_compat=yes)
189 AC_MSG_RESULT($disable_cxx0x_compat)
190 if test "$disable_cxx0x_compat" = yes; then
191     CXXFLAGS="$TMPCXXFLAGS -Wno-c++0x-compat"
192 else
193     CXXFLAGS="$TMPCXXFLAGS"
194 fi
195 AC_LANG_POP(C++)
196
197 # pthread (not needed on Windows)
198 if test "$os_win32" = "no"; then
199 AC_CHECK_HEADERS([pthread.h],
200     AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
201     AC_MSG_ERROR([pthread support is required to build WebKit]))
202 AC_CHECK_LIB(pthread, pthread_rwlock_init,
203     AC_DEFINE([HAVE_PTHREAD_RWLOCK],[1],[Define if pthread rwlock is present]),
204     AC_MSG_WARN([pthread rwlock support is not available]))
205 fi
206
207 # Check for libjpeg the way Gtk does it.
208 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress, jpeg_ok=yes, jpeg_ok=no AC_MSG_ERROR([JPEG library (libjpeg) not found]))
209 if test "$jpeg_ok" = yes; then
210     AC_MSG_CHECKING([for jpeglib])
211     AC_TRY_CPP([
212 #include <stdio.h>
213 #undef PACKAGE
214 #undef VERSION
215 #undef HAVE_STDLIB_H
216 #include <jpeglib.h>
217 ], jpeg_ok=yes, jpeg_ok=no)
218     AC_MSG_RESULT($jpeg_ok)
219     if test "$jpeg_ok" = yes; then
220         JPEG_LIBS="-ljpeg"
221         # Should we check for progressive JPEG like GTK+ as well?
222     else
223         AC_MSG_ERROR([JPEG library (libjpeg) not found])
224     fi
225 fi
226 AC_SUBST([JPEG_LIBS])
227
228 # Check for libpng the way Gtk+ does it.
229 for l in libpng libpng14 libpng12; do
230     AC_MSG_CHECKING(for $l)
231     if $PKG_CONFIG --exists $l ; then
232         AC_MSG_RESULT(yes)
233         PNG_LIBS=`$PKG_CONFIG --libs $l`
234         png_ok=yes
235         break
236     else
237         AC_MSG_RESULT(no)
238         png_ok=no
239     fi
240 done
241 if test "$png_ok" != yes; then
242     AC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=no)],
243         AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
244    if test "$png_ok" = yes; then
245         AC_MSG_CHECKING([for png_structp in png.h])
246         AC_TRY_COMPILE([
247 #include <png.h>
248 ], [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;], png_ok=yes, png_ok=no)
249         AC_MSG_RESULT($png_ok)
250         if test "$png_ok" = yes; then
251             PNG_LIBS='-lpng -lz'
252         else
253             AC_MSG_ERROR([PNG library (libpng) not found])
254         fi
255     else
256         AC_MSG_ERROR([PNG library (libpng) not found])
257     fi
258 fi
259 AC_SUBST([PNG_LIBS])
260
261 # Check for WebP Image support.
262 AC_CHECK_HEADERS([webp/decode.h], [WEBP_LIBS='-lwebp'], [AC_MSG_ERROR([WebP library (libwebp) not found])])
263 AC_SUBST([WEBP_LIBS])
264
265 if test "$os_win32" = "yes"; then
266     WINMM_LIBS=-lwinmm
267     SHLWAPI_LIBS=-lshlwapi
268     OLE32_LIBS=-lole32
269 fi
270 AC_SUBST([WINMM_LIBS])
271 AC_SUBST([SHLWAPI_LIBS])
272 AC_SUBST([OLE32_LIBS])
273
274 # Check whether dlopen() is in the core libc like on FreeBSD, or in a separate
275 # libdl like on GNU/Linux (in which case we want to link to libdl).
276 AC_CHECK_FUNC([dlopen], [], [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
277 AC_SUBST([DLOPEN_LIBS])
278
279 # Determine the GTK+ version to use.
280 AC_MSG_CHECKING([the GTK+ version to use])
281 AC_ARG_WITH([gtk], [AS_HELP_STRING([--with-gtk=2.0|3.0], [the GTK+ version to use (default: 3.0)])],
282         [case "$with_gtk" in
283             2.0|3.0) ;;
284             *) AC_MSG_ERROR([invalid GTK+ version specified]) ;;
285         esac], [with_gtk=3.0])
286 AC_MSG_RESULT([$with_gtk])
287
288 GTK2_REQUIRED_VERSION=2.10
289 GAIL2_REQUIRED_VERSION=1.8
290 GTK3_REQUIRED_VERSION=3.4.0
291 GAIL3_REQUIRED_VERSION=3.0
292
293 case "$with_gtk" in
294     2.0) GTK_REQUIRED_VERSION=$GTK2_REQUIRED_VERSION
295         GTK_API_VERSION=2.0
296         WEBKITGTK_API_MAJOR_VERSION=1
297         WEBKITGTK_API_MINOR_VERSION=0
298         WEBKITGTK_API_VERSION=1.0
299         WEBKITGTK_PC_NAME=webkit
300         GAIL_PC_NAME=gail
301         GAIL_REQUIRED_VERSION=$GAIL2_REQUIRED_VERSION
302         ;;
303     3.0) GTK_REQUIRED_VERSION=$GTK3_REQUIRED_VERSION
304         GTK_API_VERSION=3.0
305         WEBKITGTK_API_MAJOR_VERSION=3
306         WEBKITGTK_API_MINOR_VERSION=0
307         WEBKITGTK_API_VERSION=3.0
308         WEBKITGTK_PC_NAME=webkitgtk
309         GAIL_PC_NAME=gail-3.0
310         GAIL_REQUIRED_VERSION=$GAIL3_REQUIRED_VERSION
311         ;;
312 esac
313
314 AC_SUBST([WEBKITGTK_API_MAJOR_VERSION])
315 AC_SUBST([WEBKITGTK_API_MINOR_VERSION])
316 AC_SUBST([WEBKITGTK_API_VERSION])
317 AC_SUBST([WEBKITGTK_PC_NAME])
318 AC_SUBST([GTK_API_VERSION])
319 AM_CONDITIONAL([GTK_API_VERSION_2],[test "$GTK_API_VERSION" = "2.0"])
320
321 # Determine the GDK/GTK+ target.
322 AC_MSG_CHECKING([the target windowing system])
323 AC_ARG_WITH(target, AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@], [Select webkit target [default=x11]]),
324     [],[with_target="x11"])
325
326 case "$with_target" in
327     x11|win32|quartz|directfb) ;;
328     *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
329 esac
330
331 AC_MSG_RESULT([$with_target])
332
333 # Minimum base dependencies.
334 CAIRO_REQUIRED_VERSION=1.10
335 FONTCONFIG_REQUIRED_VERSION=2.4
336 FREETYPE2_REQUIRED_VERSION=9.0
337 GLIB_REQUIRED_VERSION=2.32.0
338 LIBSOUP_REQUIRED_VERSION=2.40.0
339 LIBXML_REQUIRED_VERSION=2.6
340 PANGO_REQUIRED_VERSION=1.21.0
341
342 # Optional modules.
343 LIBXSLT_REQUIRED_VERSION=1.1.7
344 SQLITE_REQUIRED_VERSION=3.0
345 ENCHANT_REQUIRED_VERSION=0.22
346 CLUTTER_REQUIRED_VERSION=1.8.2
347 CLUTTER_GTK_REQUIRED_VERSION=1.0.2
348 ATSPI2_REQUIRED_VERSION=2.2.1
349
350 # Check for glib and required utilities.
351 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION, :, :, gmodule gobject gthread gio)
352 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
353     AC_MSG_ERROR([You need the GLib dev tools in your path])
354 fi
355
356 # GResources
357 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG --variable glib_compile_resources gio-2.0`
358 AC_SUBST(GLIB_COMPILE_RESOURCES)
359
360 GLIB_GSETTINGS
361
362 # Check and identify which unicode backend to use.
363 AC_MSG_CHECKING([which Unicode backend to use])
364 AC_ARG_WITH(unicode_backend,
365     AC_HELP_STRING([--with-unicode-backend=@<:@icu/glib@:>@],
366         [Select Unicode backend (WARNING: the glib-based backend is slow, and incomplete) [default=icu]]),
367     [],[with_unicode_backend="icu"])
368
369 case "$with_unicode_backend" in
370     icu|glib) ;;
371     *) AC_MSG_ERROR([Invalid Unicode backend: must be icu or glib.]) ;;
372 esac
373
374 AC_MSG_RESULT([$with_unicode_backend])
375
376 if test "$with_unicode_backend" = "icu"; then
377     # TODO: use pkg-config (after CFLAGS in their .pc files are cleaned up).
378     case "$host" in
379         *-*-darwin*)
380             UNICODE_CFLAGS="-I$srcdir/Source/JavaScriptCore/icu -I$srcdir/Source/WebCore/icu"
381             UNICODE_LIBS="-licucore"
382             ;;
383         *-*-mingw*)
384             UNICODE_CFLAGS=""
385             UNICODE_LIBS="-licui18n -licuuc"
386             ;;
387         *)
388             AC_PATH_PROG(icu_config, icu-config, no)
389             if test "$icu_config" = "no"; then
390                 AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
391             fi
392
393             # We don't use --cflags as this gives us a lot of things that we don't necessarily want,
394             # like debugging and optimization flags. See man (1) icu-config for more info.
395             UNICODE_CFLAGS=`$icu_config --cppflags`
396             UNICODE_LIBS=`$icu_config --ldflags-libsonly`
397             ;;
398     esac
399 fi
400
401 if test "$with_unicode_backend" = "glib"; then
402     PKG_CHECK_MODULES([UNICODE], [glib-2.0 pango >= $PANGO_REQUIRED_VERSION])
403 fi
404
405 AC_SUBST([UNICODE_CFLAGS])
406 AC_SUBST([UNICODE_LIBS])
407
408 PKG_CHECK_MODULES([ZLIB], [zlib])
409 AC_SUBST([ZLIB_CFLAGS])
410 AC_SUBST([ZLIB_LIBS])
411
412 GETTEXT_PACKAGE=$PACKAGE-$GTK_API_VERSION
413 AC_SUBST(GETTEXT_PACKAGE)
414 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [The gettext catalog name])
415
416 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
417 AC_SUBST(LIBXML_CFLAGS)
418 AC_SUBST(LIBXML_LIBS)
419
420 PKG_CHECK_MODULES(PANGO, [pango >= $PANGO_REQUIRED_VERSION pangoft2])
421 AC_SUBST(PANGO_CFLAGS)
422 AC_SUBST(PANGO_LIBS)
423
424 AC_MSG_CHECKING([whether to enable spellcheck support])
425 AC_ARG_ENABLE([spellcheck], [AS_HELP_STRING([--enable-spellcheck],[enable support for spellcheck])],
426     [], [enable_spellcheck="yes"])
427 AC_MSG_RESULT([$enable_spellcheck])
428
429 if test "$enable_spellcheck" = "yes"; then
430     PKG_CHECK_MODULES(ENCHANT, enchant >= $ENCHANT_REQUIRED_VERSION, [], [enable_spellcheck="no"])
431     AC_SUBST(ENCHANT_CFLAGS)
432     AC_SUBST(ENCHANT_LIBS)
433 fi
434
435 PKG_CHECK_MODULES(GAIL, $GAIL_PC_NAME >= $GAIL_REQUIRED_VERSION)
436 AC_SUBST(GAIL_CFLAGS)
437 AC_SUBST(GAIL_LIBS)
438
439 # Check for target-specific dependencies.
440 if test "$with_target" = "directfb"; then
441     PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
442     PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
443     AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
444 else
445     PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
446     PKG_CHECK_MODULES(GTK, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED_VERSION)
447
448     if test "$with_target" = "x11" && test "$os_win32" = "no"; then
449         PKG_CHECK_MODULES([XT], [xt], [xt_has_pkg_config=yes], [xt_has_pkg_config=no])
450
451         # Some old versions of Xt do not provide xt.pc, so try to link against Xt
452         # and if it's installed fall back to just adding -lXt.
453         if test "$xt_has_pkg_config" = "no"; then
454             # Using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as we don't care
455             # about the XtOpenDisplay symbol but only about the existence of libXt.
456             AC_CHECK_LIB([Xt], [XtOpenDisplay], [XT_CFLAGS=""; XT_LIBS="-lXt"],
457                 [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
458         fi
459
460         AC_SUBST([XT_CFLAGS])
461         AC_SUBST([XT_LIBS])
462         AC_DEFINE([WTF_PLATFORM_X11], [1], [Define if target is X11])
463    fi
464 fi
465 AC_SUBST(GTK_CFLAGS)
466 AC_SUBST(GTK_LIBS)
467 AC_SUBST(CAIRO_CFLAGS)
468 AC_SUBST(CAIRO_LIBS)
469
470 # Check whether to build with debugging enabled.
471 AC_MSG_CHECKING([whether to do a debug build])
472 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [turn on debugging [default=no]]), [],[enable_debug="no"])
473 AC_MSG_RESULT([$enable_debug])
474
475 # Check whether to enable optimized builds.
476 AC_MSG_CHECKING([whether to enable optimized builds])
477 AC_ARG_ENABLE(optimizations, AC_HELP_STRING([--enable-optimizations], [turn on optimize builds (GCC only) [default=yes]]),
478     [enable_optimizations=$enableval],
479     [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
480 AC_MSG_RESULT([$enable_optimizations])
481
482 found_opengl=no
483 AC_ARG_ENABLE(glx, AC_HELP_STRING([--enable-glx], [enable support for GLX [default=auto]]), [], [enable_glx="auto"])
484 AC_ARG_ENABLE(egl, AC_HELP_STRING([--enable-egl], [enable support for EGL [default=auto]]), [], [enable_egl="auto"])
485 AC_ARG_ENABLE(gles2, AC_HELP_STRING([--enable-gles2], [enable support for OpenGL ES 2 [default=auto]]), [], [enable_gles2="auto"])
486
487 have_glx=no
488 AC_CHECK_HEADERS([GL/glx.h], [have_glx="yes"], [have_glx="no"])
489 AC_MSG_CHECKING([whether to enable GLX support])
490 if test "$enable_glx" != "no"; then
491     if test "$have_glx" = "no"; then
492         if test "$enable_glx" = "yes"; then
493             AC_MSG_ERROR([--enable-glx specified, but not available])
494         else
495             enable_glx=no
496         fi
497     elif test "$enable_gles2" != "yes"; then
498         enable_glx=yes
499     fi
500 fi
501 AC_MSG_RESULT([$enable_glx])
502
503 have_egl=no
504 AC_CHECK_HEADERS([EGL/egl.h], [have_egl="yes"], [have_egl="no"])
505 AC_MSG_CHECKING([whether to enable EGL support])
506 if test "$enable_egl" != "no"; then
507     if test "$have_egl" = "no"; then
508         if test "$enable_egl" = "yes"; then
509             AC_MSG_ERROR([--enable-egl specified, but not available])
510         else
511             enable_egl=no
512         fi
513     else
514         enable_egl=yes
515     fi
516 fi
517 AC_MSG_RESULT([$enable_egl])
518
519 have_gles2=no
520 AC_CHECK_HEADERS([GLES2/gl2.h], [have_gles2="yes"], [have_gles2="no"])
521 AC_MSG_CHECKING([whether to use OpenGL ES 2 support])
522 if test "$enable_glx" = "yes"; then
523     if test "$enable_gles2" = "yes"; then
524         AC_MSG_ERROR([Cannot enable OpenGL ES 2 support with GLX])
525     else
526         enable_gles2=no
527     fi
528 fi
529 if test "$enable_egl" = "no"; then
530     if test "$enable_gles2" = "yes"; then
531         AC_MSG_ERROR([Cannot enable OpenGL ES 2 support without EGL])
532     else
533         enable_gles2=no
534     fi
535 fi
536 if test "$enable_gles2" != "no"; then
537     if test "$have_gles2" = "no"; then
538         if test "$enable_gles2" = "yes"; then
539             AC_MSG_ERROR([--enable-gles2 specified, but not available])
540         else
541             enable_gles2=no
542         fi
543    else
544         enable_gles2=yes
545         found_opengl=yes
546    fi
547 fi
548 AC_MSG_RESULT([$enable_gles2])
549
550 if test "$enable_gles2" != "yes"; then
551     AC_CHECK_HEADERS([GL/gl.h], [found_opengl="yes"], [])
552 fi
553
554 AC_MSG_CHECKING([which GPU acceleration backend to use])
555 AC_ARG_WITH(acceleration_backend,
556     AC_HELP_STRING([--with-acceleration-backend=@<:@opengl/clutter/none@:>@],
557         [Select accelerated backend (Clutter currently unsupported, OpenGL autodetected) [default=autodetect]]), [],
558     [
559         if test "$found_opengl" = "yes"; then
560             with_acceleration_backend="opengl";
561         else
562             with_acceleration_backend="none";
563         fi
564     ])
565 AC_MSG_RESULT([$with_acceleration_backend])
566
567 if test "$with_acceleration_backend" = "opengl"; then
568     PKG_CHECK_MODULES([XCOMPOSITE], [xcomposite]);
569     PKG_CHECK_MODULES([XDAMAGE], [xdamage]);
570     AC_SUBST(XCOMPOSITE_CFLAGS)
571     AC_SUBST(XCOMPOSITE_LIBS)
572     AC_SUBST(XDAMAGE_CFLAGS)
573     AC_SUBST(XDAMAGE_LIBS)
574 fi
575
576 # OpenGL is turned on by default (along with WebGL and accelerated compositing), but if Clutter is chosen
577 # as the accelerated drawing backend, we want to disable it. COGL does not play well with OpenGL.
578 AC_MSG_CHECKING([whether to enable WebGL support])
579 AC_ARG_ENABLE(webgl, AC_HELP_STRING([--enable-webgl], [enable support for WebGL [default=check]]), [],
580     [
581         if test "$with_acceleration_backend" = "opengl"; then
582             enable_webgl="yes";
583         else
584             enable_webgl="no";
585         fi
586     ])
587 AC_MSG_RESULT([$enable_webgl])
588 if test "$enable_webgl" = "yes" && test "$with_acceleration_backend" != "opengl"; then
589     AC_MSG_ERROR([OpenGL must be active (and Clutter disabled) to use WebGL.])
590 fi;
591
592 AC_MSG_CHECKING([whether to enable accelerated compositing support])
593 AC_ARG_ENABLE(accelerated_compositing,
594     AC_HELP_STRING([--enable-accelerated-compositing], [enable support for accelerated compositing [default=check]]),
595     [
596         if test "$enableval" = "yes" && test "$with_acceleration_backend" = "none"; then
597             AC_MSG_ERROR([OpenGL or Clutter must be active to use accelerated compositing.])
598         fi
599         enable_accelerated_compositing=$enableval;
600     ],
601     [
602         if test "$with_acceleration_backend" != "none"; then
603             enable_accelerated_compositing="yes";
604         else
605             enable_accelerated_compositing="no";
606         fi
607     ])
608 AC_MSG_RESULT([$enable_accelerated_compositing])
609
610 # Check whether to enable Gamepad support.
611 AC_MSG_CHECKING([whether to enable Gamepad support])
612 AC_ARG_ENABLE(gamepad, AC_HELP_STRING([--enable-gamepad], [enable Gamepad support [default=no]]), [],[enable_gamepad="no"])
613 AC_MSG_RESULT([$enable_gamepad])
614
615 if test "$enable_gamepad" = "yes" && test "$os_linux" = no; then
616     AC_MSG_WARN([Gamepad support is only available on Linux. Disabling Gamepad support.])
617     enable_gamepad=no;
618 fi
619
620 # Check whether to enable HTML5 audio/video support.
621 AC_MSG_CHECKING([whether to enable HTML5 video support])
622 AC_ARG_ENABLE(video, AC_HELP_STRING([--enable-video], [enable HTML5 video support [default=yes]]), [],[enable_video="yes"])
623 AC_MSG_RESULT([$enable_video])
624
625 # Check whether to enable media stream support.
626 AC_MSG_CHECKING([whether to enable media stream support])
627 AC_ARG_ENABLE(media_stream, AC_HELP_STRING([--enable-media-stream], [enable media stream support (incomplete) [default=no]]),
628     [],[enable_media_stream="no"])
629 AC_MSG_RESULT([$enable_media_stream])
630
631 # Check whether to enable XSLT support.
632 AC_MSG_CHECKING([whether to enable XSLT support])
633 AC_ARG_ENABLE(xslt, AC_HELP_STRING([--enable-xslt], [enable support for XSLT [default=yes]]), [],[enable_xslt="yes"])
634 AC_MSG_RESULT([$enable_xslt])
635
636 # Check whether to enable geolocation support.
637 AC_MSG_CHECKING([whether to enable geolocation support])
638 AC_ARG_ENABLE(geolocation, AC_HELP_STRING([--enable-geolocation], [enable support for geolocation [default=yes]]),
639     [], [enable_geolocation="yes"])
640 AC_MSG_RESULT([$enable_geolocation])
641
642 # Check whether to enable SVG support.
643 AC_MSG_CHECKING([whether to enable SVG support])
644 AC_ARG_ENABLE(svg, AC_HELP_STRING([--enable-svg], [enable support for SVG [default=yes]]),
645     [], [enable_svg="yes"])
646 AC_MSG_RESULT([$enable_svg])
647
648 # Turn off svg features if --disable-svg is requested.
649 if test "$enable_svg" = "no"; then
650    enable_svg_fonts=no
651 fi
652
653 # Check whether to enable support for SVG fonts.
654 AC_MSG_CHECKING([whether to enable support for SVG fonts])
655 AC_ARG_ENABLE(svg_fonts, AC_HELP_STRING([--enable-svg-fonts], [enable support for SVG fonts (experimental) [default=yes]]),
656     [], [enable_svg_fonts="yes"])
657 AC_MSG_RESULT([$enable_svg_fonts])
658
659 # Check for SVG features, enabling SVG if necessary.
660 if test "$enable_svg_fonts" = "yes" && test "$enable_svg" = "no"; then
661     AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
662     enable_svg=yes
663 fi
664
665 # Check whether to enable Web Audio support.
666 AC_MSG_CHECKING([whether to enable Web Audio support])
667 AC_ARG_ENABLE(web_audio, AC_HELP_STRING([--enable-web-audio], [enable support for Web Audio [default=no]]),
668     [], [enable_web_audio="no"])
669 AC_MSG_RESULT([$enable_web_audio])
670
671 # Check whether to enable code coverage.
672 AC_MSG_CHECKING([whether to enable code coverage support])
673 AC_ARG_ENABLE(coverage, AC_HELP_STRING([--enable-coverage], [enable code coverage support [default=no]]),
674     [], [enable_coverage="no"])
675 AC_MSG_RESULT([$enable_coverage])
676
677 # Check whether to enable FastMalloc.
678 AC_MSG_CHECKING([whether to enable optimized memory allocator])
679 AC_ARG_ENABLE(fast_malloc, AC_HELP_STRING([--enable-fast-malloc],
680                             [enable optimized memory allocator default=yes, default=no for debug builds]),
681     [], [if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
682 AC_MSG_RESULT([$enable_fast_malloc])
683
684 # Check whether to enable debug symbols.
685 AC_MSG_CHECKING([whether to enable debug symbols])
686 AC_ARG_ENABLE(debug_symbols,
687     AC_HELP_STRING([--enable-debug-symbols=yes|no|min|full], [enable debug symbols default=no, default=yes for debug builds]),
688     [], [if test "$enable_debug" = "yes"; then enable_debug_symbols="yes"; else enable_debug_symbols="no"; fi])
689
690 case "$enable_debug_symbols" in
691     yes) enable_debug_symbols="full" ;;
692     no|min|full) ;;
693     *) AC_MSG_ERROR([Invalid debug symbols option: must be yes, no, min or full.]) ;;
694 esac
695 AC_MSG_RESULT([$enable_debug_symbols])
696
697 # Selecting GStreamer version.
698 AC_MSG_CHECKING([the GStreamer version to use])
699 AC_ARG_WITH([gstreamer],
700     AS_HELP_STRING([--with-gstreamer=1.0|0.10|auto],
701         [the GStreamer version to use (default: auto, tries 1.0 first, 0.10 is fallback)]),
702     [
703         case "$with_gstreamer" in
704             0.10|1.0|auto) ;;
705             *) AC_MSG_ERROR([invalid GStreamer version specified]) ;;
706         esac
707     ], [with_gstreamer=auto])
708 AC_MSG_RESULT([$with_gstreamer])
709
710 GSTREAMER_0_10_REQUIRED_VERSION=0.10
711 GSTREAMER_0_10_PLUGINS_BASE_REQUIRED_VERSION=0.10.30
712 GSTREAMER_1_0_REQUIRED_VERSION=1.0.3
713 GSTREAMER_1_0_PLUGINS_BASE_REQUIRED_VERSION=1.0.3
714
715 if test "$enable_video" = "yes" || test "$enable_web_audio" = "yes"; then
716     if test "$with_gstreamer" = "auto"; then
717         gstreamer_modules="gstreamer-1.0 >= $GSTREAMER_1_0_REQUIRED_VERSION gstreamer-app-1.0 gstreamer-audio-1.0
718             gstreamer-fft-1.0 gstreamer-base-1.0 gstreamer-pbutils-1.0
719             gstreamer-plugins-base-1.0 >= $GSTREAMER_1_0_PLUGINS_BASE_REQUIRED_VERSION gstreamer-video-1.0";
720         PKG_CHECK_MODULES([GSTREAMER_1_0], [$gstreamer_modules], [with_gstreamer=1.0], [with_gstreamer=0.10])
721         AC_MSG_NOTICE([Selected GStreamer $with_gstreamer])
722     fi
723 else
724     if test "$with_gstreamer" != "auto"; then
725         AC_MSG_WARN([You have specified GStreamer $with_gstreamer version but it will not be used
726             because neither HTML5 Video nor Web Audio are enabled])
727     fi
728 fi
729
730 case "$with_gstreamer" in
731     0.10) GSTREAMER_REQUIRED_VERSION=$GSTREAMER_0_10_REQUIRED_VERSION
732         GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION=$GSTREAMER_0_10_PLUGINS_BASE_REQUIRED_VERSION
733         GST_API_VERSION=0.10
734         ;;
735     1.0) GSTREAMER_REQUIRED_VERSION=$GSTREAMER_1_0_REQUIRED_VERSION
736         GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION=$GSTREAMER_1_0_PLUGINS_BASE_REQUIRED_VERSION
737         GST_API_VERSION=1.0
738         ;;
739 esac
740
741 AC_SUBST([GST_API_VERSION])
742 if test "$GST_API_VERSION" = "1.0"; then
743     AC_DEFINE([GST_API_VERSION_1],[1], [Using GStreamer 1.0])
744 fi
745
746 # Check whether to enable debug features.
747 AC_MSG_CHECKING([whether to enable debug features])
748 AC_ARG_ENABLE(debug_features,
749     AC_HELP_STRING([--enable-debug-features], [enable debug features default=no, default=yes for debug builds]),
750     [],[if test "$enable_debug" = "yes"; then enable_debug_features="yes"; else enable_debug_features="no"; fi])
751 AC_MSG_RESULT([$enable_debug_features])
752
753 AC_MSG_CHECKING([whether to enable JIT compilation])
754 AC_ARG_ENABLE(jit, AS_HELP_STRING([--enable-jit], [Enable JIT compilation (default: autodetect)]))
755 case "$enable_jit" in
756     yes) JSC_CPPFLAGS="-DENABLE_JIT=1" ;;
757     no) JSC_CPPFLAGS="-DENABLE_JIT=0" ;;
758     *) enable_jit="autodetect" ;;
759 esac
760 AC_SUBST(JSC_CPPFLAGS)
761 AC_MSG_RESULT([$enable_jit])
762
763 # Opcode stats.
764 AC_MSG_CHECKING([whether to enable opcode stats])
765 AC_ARG_ENABLE([opcode-stats], AS_HELP_STRING([--enable-opcode-stats], [Enable Opcode statistics (default: disabled)]),
766     [], [enable_opcode_stats=no])
767 AC_MSG_RESULT([$enable_opcode_stats])
768
769 if test "$enable_opcode_stats" = "yes"; then
770     if test "$enable_jit" = "yes"; then
771         AC_MSG_ERROR([JIT must be disabled for Opcode stats to work.])
772     fi
773     AC_DEFINE([ENABLE_OPCODE_STATS], [1], [Define to enable Opcode statistics])
774 fi
775
776 # GObject Introspection.
777 AC_MSG_CHECKING([whether to enable GObject introspection support])
778 AC_ARG_ENABLE([introspection], AS_HELP_STRING([--enable-introspection],[Enable GObject introspection (default: disabled)]),
779     [],[enable_introspection=no])
780 AC_MSG_RESULT([$enable_introspection])
781
782 # Enable CSS Filters and Shaders if accelerated_compositing is turned on.
783 enable_css_filters=no;
784 enable_css_shaders=no;
785 AC_MSG_CHECKING([whether to enable CSS Filters and Shaders])
786 if test "$enable_accelerated_compositing" = "yes" && test "$with_acceleration_backend" = "opengl"; then
787     enable_css_filters=yes;
788     enable_css_shaders=yes;
789 fi
790 AC_MSG_RESULT([$enable_css_filters])
791
792 G_IR_SCANNER=
793 G_IR_COMPILER=
794 G_IR_GENERATE=
795 GIRDIR=
796 GIRTYPELIBDIR=
797
798 if test "$enable_introspection" = "yes"; then
799     GOBJECT_INTROSPECTION_REQUIRED=0.9.5
800     PKG_CHECK_MODULES([INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
801
802     G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
803     G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
804     G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
805     AC_DEFINE([ENABLE_INTROSPECTION], [1], [Define to enable GObject introspection support])
806 fi
807
808 AC_SUBST([G_IR_SCANNER])
809 AC_SUBST([G_IR_COMPILER])
810 AC_SUBST([G_IR_GENERATE])
811
812 if test "$host_cpu" = "sh4"; then
813     CXXFLAGS="$CXXFLAGS -mieee -w"
814     CFLAGS="$CFLAGS -mieee -w"
815 fi
816
817 # Add '-g' flag to gcc to build with debug symbols.
818 if test "$enable_debug_symbols" = "min"; then
819     CXXFLAGS="$CXXFLAGS -g1"
820     CFLAGS="$CFLAGS -g1"
821 elif test "$enable_debug_symbols" != "no"; then
822     CXXFLAGS="$CXXFLAGS -g"
823     CFLAGS="$CFLAGS -g"
824 fi
825
826 if test "$enable_debug_features" = "no"; then
827     AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
828 fi
829
830 # Add the appropriate 'O' level for optimized builds.
831 if test "$enable_optimizations" = "yes"; then
832     CXXFLAGS="$CXXFLAGS -O2"
833     CFLAGS="$CFLAGS -O2"
834 else
835     CXXFLAGS="$CXXFLAGS -O0"
836     CFLAGS="$CFLAGS -O0"
837 fi
838
839 PKG_CHECK_MODULES([LIBSOUP], [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
840 AC_SUBST([LIBSOUP_CFLAGS])
841 AC_SUBST([LIBSOUP_LIBS])
842
843 PKG_CHECK_MODULES([LIBSECRET], [libsecret-1])
844 AC_SUBST([LIBSECRET_CFLAGS])
845 AC_SUBST([LIBSECRET_LIBS])
846
847 # Check if FreeType/FontConfig are available.
848 if test "$with_target" = "directfb"; then
849     PKG_CHECK_MODULES([FREETYPE],
850         [fontconfig >= $FONTCONFIG_REQUIRED_VERSION freetype2 >= $FREETYPE2_REQUIRED_VERSION harfbuzz])
851 else
852     PKG_CHECK_MODULES([FREETYPE],
853         [cairo-ft fontconfig >= $FONTCONFIG_REQUIRED_VERSION freetype2 >= $FREETYPE2_REQUIRED_VERSION harfbuzz])
854 fi
855 AC_SUBST([FREETYPE_CFLAGS])
856 AC_SUBST([FREETYPE_LIBS])
857
858 # Check if SQLite3 is available. Error out only if one of the features hard-depending
859 # on it is enabled while SQLite3 is unavailable.
860 PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION], [sqlite3_has_pkg_config=yes], [sqlite3_has_pkg_config=no])
861 if test "$sqlite3_has_pkg_config" = "no"; then
862     AC_SEARCH_LIBS([sqlite3_open16], [sqlite3],
863         [sqlite3_found=yes; SQLITE3_LIBS="$LIBS"; SQLITE3_CFLAGS="-I $srcdir/WebKitLibraries/WebCoreSQLite3"], [sqlite3_found=no])
864 fi
865 AC_SUBST([SQLITE3_CFLAGS])
866 AC_SUBST([SQLITE3_LIBS])
867
868 if (test "$sqlite3_found" = "no"); then
869     AC_MSG_ERROR([SQLite3 is required for the Database related features])
870 fi
871
872 # Check if libxslt is available.
873 if test "$enable_xslt" = "yes"; then
874     PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
875     AC_SUBST([LIBXSLT_CFLAGS])
876     AC_SUBST([LIBXSLT_LIBS])
877 fi
878
879 # Check if geoclue is available.
880 if test "$enable_geolocation" = "yes"; then
881     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
882     AC_SUBST([GEOCLUE_CFLAGS])
883     AC_SUBST([GEOCLUE_LIBS])
884 fi
885
886 # Check for XRender under Linux/Unix. Some linkers require explicit linkage (like GNU Gold),
887 # so we cannot rely on GTK+ pulling XRender.
888 if test "$os_win32" = "no"; then
889     PKG_CHECK_MODULES([XRENDER], [xrender])
890     AC_SUBST([XRENDER_CFLAGS])
891     AC_SUBST([XRENDER_LIBS])
892 fi
893
894 # Check if Gstreamer is available.
895 if test "$enable_video" = "yes" || test "$enable_web_audio" = "yes"; then
896     gstreamer_modules="gstreamer-$GST_API_VERSION >= $GSTREAMER_REQUIRED_VERSION gstreamer-app-$GST_API_VERSION
897         gstreamer-audio-$GST_API_VERSION gstreamer-fft-$GST_API_VERSION gstreamer-base-$GST_API_VERSION
898         gstreamer-pbutils-$GST_API_VERSION gstreamer-plugins-base-$GST_API_VERSION >= $GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION
899         gstreamer-video-$GST_API_VERSION";
900     if test "$GST_API_VERSION" != "1.0"; then
901         gstreamer_modules="$gstreamer_modules gstreamer-interfaces-$GST_API_VERSION";
902     fi
903     PKG_CHECK_MODULES([GSTREAMER], [$gstreamer_modules], [have_gstreamer=yes])
904     AC_SUBST([GSTREAMER_CFLAGS])
905     AC_SUBST([GSTREAMER_LIBS])
906 fi
907
908 acceleration_backend_description=$with_acceleration_backend
909 if test "$with_acceleration_backend" = "clutter"; then
910     PKG_CHECK_MODULES(CLUTTER, clutter-1.0 >= $CLUTTER_REQUIRED_VERSION)
911     PKG_CHECK_MODULES([CLUTTER_GTK], [clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED_VERSION])
912
913     AC_SUBST(CLUTTER_CFLAGS)
914     AC_SUBST(CLUTTER_LIBS)
915     AC_SUBST(CLUTTER_GTK_CFLAGS)
916     AC_SUBST(CLUTTER_GTK_LIBS)
917
918     enable_gles2=no
919     enable_glx=no
920     enable_egl=no
921 fi
922
923 if test "$with_acceleration_backend" = "opengl"; then
924     if test "$enable_gles2" = "yes"; then
925         acceleration_backend_description+= "(gles2"
926         OPENGL_LIBS="-lGLESv2"
927     else
928         acceleration_backend_description+="(gl"
929         OPENGL_LIBS="-lGL"
930     fi
931     if test "$enable_egl" = "yes"; then
932         acceleration_backend_description+=", egl"
933         OPENGL_LIBS+=" -lEGL"
934     fi
935     if test "$enable_glx" = "yes"; then
936         acceleration_backend_description+=", glx"
937     fi
938     OPENGL_LIBS+=" $DLOPEN_LIBS"
939     acceleration_backend_description+=")"
940 fi
941 AC_SUBST([OPENGL_LIBS])
942
943 if test "$enable_gamepad" = "yes"; then
944     PKG_CHECK_MODULES([GAMEPAD], [gio-unix-2.0 gudev-1.0])
945
946     AC_SUBST(GAMEPAD_CFLAGS)
947     AC_SUBST(GAMEPAD_LIBS)
948 fi
949
950 # Check whether to enable code coverage support.
951 if test "$enable_coverage" = "yes"; then
952     COVERAGE_CFLAGS="-MD"
953     COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
954     AC_SUBST([COVERAGE_CFLAGS])
955     AC_SUBST([COVERAGE_LDFLAGS])
956 fi
957
958 # WebKit1
959 AC_MSG_CHECKING([whether to build WebKit1])
960 AC_ARG_ENABLE(webkit1, AC_HELP_STRING([--enable-webkit1], [build WebKit1 [default=yes]]), [], [enable_webkit1="yes"])
961 AC_MSG_RESULT([$enable_webkit1])
962
963 # WebKit2
964 # If you change the default here, please also make sure the assumptions made
965 # in Tools/Scripts/webkitdirs.pm:buildAutotoolsProject still make sense.
966 AC_MSG_CHECKING([whether to build WebKit2])
967 AC_ARG_ENABLE(webkit2, AC_HELP_STRING([--enable-webkit2], [build WebKit2 [default=yes]]), [], [enable_webkit2="yes"])
968 AC_MSG_RESULT([$enable_webkit2])
969 if test "$enable_webkit2" = "yes"; then
970     if test "$GTK_API_VERSION" = "2.0"; then
971         AC_MSG_ERROR([WebKit2 requires GTK+ 3.x, use --with-gtk=3.0])
972     fi
973
974     # Make sure we have GTK+ 2.x to build the plugin process.
975     PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= $GTK2_REQUIRED_VERSION gail >= $GAIL2_REQUIRED_VERSION)
976     AC_SUBST(GTK2_CFLAGS)
977     AC_SUBST(GTK2_LIBS)
978
979     # Check Unix printing
980     PKG_CHECK_MODULES(GTK_UNIX_PRINTING, gtk+-unix-print-3.0, [have_gtk_unix_printing=yes], [have_gtk_unix_printing=no])
981     AC_SUBST(GTK_UNIX_PRINTING_CFLAGS)
982     AC_SUBST(GTK_UNIX_PRINTING_LIBS)
983     if test "$have_gtk_unix_printing" = "yes"; then
984         AC_DEFINE([HAVE_GTK_UNIX_PRINTING], [1], [Define if GTK+ UNIX Printing is available])
985     fi
986
987     # On some Linux/Unix platforms, shm_* may only be available if linking
988     # against librt
989     if test "$os_win32" = "no"; then
990         AC_SEARCH_LIBS([shm_open], [rt], [SHM_LIBS="-lrt"])
991         AC_SUBST(SHM_LIBS)
992     fi
993 fi
994
995 GTK_DOC_CHECK([1.10])
996
997 # We need atspi2 for Webkit2 unit tests
998 if test "$enable_webkit2" = "yes"; then
999    PKG_CHECK_MODULES([ATSPI2], [atspi-2 >= $ATSPI2_REQUIRED_VERSION], [have_atspi2=yes], [have_atspi2=no])
1000    AC_SUBST([ATSPI2_CFLAGS])
1001    AC_SUBST([ATSPI2_LIBS])
1002 fi
1003
1004 # For the moment we need to check whether or not indexed database is enabled because it determines if we build leveldb or not.
1005 AM_WEBKIT_FEATURE_CONDITIONAL([ENABLE_INDEXED_DATABASE])
1006
1007 # OS conditionals.
1008 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
1009 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
1010 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
1011 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
1012 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
1013
1014 # Target conditionals.
1015 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
1016 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
1017 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
1018 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
1019
1020 # Unicode backend conditionals.
1021 AM_CONDITIONAL([USE_ICU_UNICODE], [test "$with_unicode_backend" = "icu"])
1022 AM_CONDITIONAL([USE_GLIB_UNICODE], [test "$with_unicode_backend" = "glib"])
1023
1024 # GStreamer feature conditionals.
1025 AM_CONDITIONAL([USE_GSTREAMER], [test "$have_gstreamer" = "yes"])
1026 AM_CONDITIONAL([USE_WEBAUDIO_GSTREAMER], [test "$enable_web_audio" = "yes"])
1027
1028 # ATSPI2 conditional.
1029 AM_CONDITIONAL([HAVE_ATSPI2], [test "$have_atspi2" = "yes"])
1030
1031 # Accelerated compositing conditionals.
1032 AM_CONDITIONAL([USE_ACCELERATED_COMPOSITING], [test "$enable_accelerated_compositing" = "yes"])
1033 AM_CONDITIONAL([USE_TEXTURE_MAPPER_CAIRO],
1034     [test "$enable_accelerated_compositing" = "yes" && test "$with_acceleration_backend" = "none"])
1035 AM_CONDITIONAL([USE_TEXTURE_MAPPER_GL],
1036     [test "$enable_accelerated_compositing" = "yes" && test "$with_acceleration_backend" = "opengl"])
1037 AM_CONDITIONAL([USE_CLUTTER], [test "$with_acceleration_backend" = "clutter"])
1038
1039 # These are the same for now, but they will soon be separate.
1040 AM_CONDITIONAL([USE_OPENGL], [test "$with_acceleration_backend" = "opengl"])
1041 AM_CONDITIONAL([USE_EGL], [test "$enable_egl" = "yes"])
1042 AM_CONDITIONAL([USE_GLES2], [test "$enable_gles2" = "yes"])
1043 AM_CONDITIONAL([USE_GLX], [test "$enable_glx" = "yes"])
1044
1045 # Farstream feature conditional.
1046 AM_CONDITIONAL([USE_FARSTREAM], [test "$have_farstream" = "yes"])
1047
1048 #######################################################################################
1049 #                                     ATTENTION                                       #
1050 # Please refer to the following guidelines if you're about to add an Automake         #
1051 # conditional that reflects any configuration option you've probably also added.      #
1052 # Chances are neither of these changes are required.                                  #
1053 # http://trac.webkit.org/wiki/AddingFeatures#ActivatingafeatureforAutotoolsbasedports #
1054 #######################################################################################
1055
1056 # WebKit feature conditionals.
1057 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug_features" = "yes"])
1058 AM_CONDITIONAL([ENABLE_WEBGL],[test "$enable_webgl" = "yes"])
1059 AM_CONDITIONAL([ENABLE_GAMEPAD],[test "$enable_gamepad" = "yes"])
1060 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
1061 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
1062 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
1063 AM_CONDITIONAL([ENABLE_MEDIA_STREAM],[test "$enable_media_stream" = "yes"])
1064 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
1065 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
1066 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
1067 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
1068 AM_CONDITIONAL([ENABLE_WEB_AUDIO],[test "$enable_web_audio" = "yes"])
1069 AM_CONDITIONAL([ENABLE_OPCODE_STATS],[test "$enable_opcode_stats" = "yes"])
1070 AM_CONDITIONAL([ENABLE_WEBKIT1],[test "$enable_webkit1" = "yes"])
1071 AM_CONDITIONAL([ENABLE_WEBKIT2],[test "$enable_webkit2" = "yes"])
1072 AM_CONDITIONAL([ENABLE_SPELLCHECK],[test "$enable_spellcheck" = "yes"])
1073 AM_CONDITIONAL([ENABLE_CSS_FILTERS],[test "$enable_css_filters" = "yes"])
1074 AM_CONDITIONAL([ENABLE_CSS_SHADERS],[test "$enable_css_shaders" = "yes"])
1075
1076 # Introspection conditional.
1077 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
1078
1079 AC_CONFIG_FILES([GNUmakefile])
1080 AC_CONFIG_FILES([DerivedSources/WebCore/UserAgentGtk.h:Source/WebCore/platform/gtk/UserAgentGtk.h.in])
1081 AC_CONFIG_FILES(
1082     [Source/JavaScriptCore/javascriptcoregtk-${WEBKITGTK_API_VERSION}.pc:Source/JavaScriptCore/javascriptcoregtk.pc.in
1083         Source/WebKit/gtk/JSCore-${WEBKITGTK_API_VERSION}.gir:Source/WebKit/gtk/JSCore.gir.in],
1084     [WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME])
1085
1086 if test "$enable_webkit1" = "yes"; then
1087     AC_CONFIG_FILES([Source/WebKit/gtk/webkit/webkitversion.h Source/WebKit/gtk/po/POTFILES])
1088
1089     AC_CONFIG_FILES([Source/WebKit/gtk/${WEBKITGTK_PC_NAME}-${WEBKITGTK_API_VERSION}.pc:Source/WebKit/gtk/webkit.pc.in],
1090         [WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME])
1091 fi
1092
1093 if test "$enable_webkit2" = "yes"; then
1094     AC_CONFIG_FILES(
1095         [DerivedSources/WebKit2/webkit2gtk/webkit2/WebKitVersion.h:Source/WebKit2/UIProcess/API/gtk/WebKitVersion.h.in])
1096
1097     AC_CONFIG_FILES([Source/WebKit2/webkit2gtk-${WEBKITGTK_API_VERSION}.pc:Source/WebKit2/webkit2gtk.pc.in],
1098         [WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME])
1099 fi
1100
1101 AC_OUTPUT
1102
1103 echo "
1104 WebKit was configured with the following options:
1105
1106 Build configuration:
1107  Enable debugging (slow)                                  : $enable_debug
1108  Compile with debug symbols (slow)                        : $enable_debug_symbols
1109  Enable debug features (slow)                             : $enable_debug_features
1110  Enable GCC build optimization                            : $enable_optimizations
1111  Code coverage support                                    : $enable_coverage
1112  Unicode backend                                          : $with_unicode_backend
1113  Optimized memory allocator                               : $enable_fast_malloc
1114  Accelerated rendering backend                            : $acceleration_backend_description
1115
1116 Features:
1117 =======
1118  WebKit1 support                                          : $enable_webkit1
1119  WebKit2 support                                          : $enable_webkit2
1120  Accelerated Compositing                                  : $enable_accelerated_compositing
1121  Gamepad support                                          : $enable_gamepad
1122  Geolocation support                                      : $enable_geolocation
1123  HTML5 video element support                              : $enable_video
1124  JIT compilation                                          : $enable_jit
1125  Media stream support                                     : $enable_media_stream
1126  Opcode stats                                             : $enable_opcode_stats
1127  SVG fonts support                                        : $enable_svg_fonts
1128  SVG support                                              : $enable_svg
1129  Spellcheck support                                       : $enable_spellcheck
1130  Web Audio support                                        : $enable_web_audio
1131  WebGL                                                    : $enable_webgl
1132  XSLT support                                             : $enable_xslt
1133
1134
1135 GTK+ configuration:
1136  GTK+ version                                             : $with_gtk
1137  GDK target                                               : $with_target
1138  GStreamer version                                        : $with_gstreamer
1139  Introspection support                                    : $enable_introspection
1140  Generate documentation                                   : $enable_gtk_doc
1141 "
1142 if test "$with_unicode_backend" = "glib"; then
1143     echo "     >> WARNING: the glib-based unicode backend is slow and incomplete <<"
1144     echo
1145     echo
1146 fi