2009-05-28 Xan Lopez <xlopez@igalia.com>
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.59)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [1])
5 m4_define([webkit_micro_version], [8])
6
7 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
8
9 AC_CONFIG_MACRO_DIR([autotools])
10 AC_CONFIG_AUX_DIR([autotools])
11 AC_SUBST(ACLOCAL_AMFLAGS, "-I autotools")
12
13 AC_CONFIG_HEADERS([autotoolsconfig.h])
14 AC_CANONICAL_HOST
15
16 WEBKIT_MAJOR_VERSION=webkit_major_version
17 WEBKIT_MINOR_VERSION=webkit_minor_version
18 WEBKIT_MICRO_VERSION=webkit_micro_version
19 AC_SUBST(WEBKIT_MAJOR_VERSION)
20 AC_SUBST(WEBKIT_MINOR_VERSION)
21 AC_SUBST(WEBKIT_MICRO_VERSION)
22
23 AC_CONFIG_SRCDIR([WebCore/config.h])
24
25 dnl # Libtool library version, not to confuse with API version
26 dnl # see http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html#Libtool-versioning
27 LIBWEBKITGTK_VERSION=8:0:6
28 AC_SUBST([LIBWEBKITGTK_VERSION])
29
30 AM_INIT_AUTOMAKE([foreign subdir-objects tar-ustar])
31
32 # host checking - inspired by the GTK+ configure.in
33 # TODO: move these to webkit.m4?
34 AC_MSG_CHECKING([for native Win32])
35 case "$host" in
36      *-*-mingw*)
37        os_win32=yes
38        ;;
39      *)
40        os_win32=no
41        ;;
42 esac
43 AC_MSG_RESULT([$os_win32])
44
45 case "$host" in
46      *-*-linux*)
47        os_linux=yes
48        ;;
49      *-*-freebsd*)
50        os_freebsd=yes
51        ;;
52      *-*-darwin*)
53        os_darwin=yes
54        ;;
55 esac
56
57 case "$host_os" in
58      gnu* | linux* | k*bsd*-gnu)
59        os_gnu=yes
60        ;;
61      *)
62        os_gnu=no
63        ;;
64 esac
65
66 # initialize webkit options
67 WEBKIT_INIT
68 AC_DISABLE_STATIC
69 AC_LIBTOOL_WIN32_DLL
70 AC_PROG_LIBTOOL
71 # use dolt to speedup the build
72 DOLT
73
74 AC_PATH_PROG(FLEX, flex)
75 if test -z "$FLEX"; then
76    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
77 else
78    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
79    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
80       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
81 fi
82
83 AC_PATH_PROG(GPERF, gperf)
84 if test -z "$GPERF"; then
85    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
86 fi
87
88 # pthread (not needed on Windows)
89 if test "$os_win32" = "no"; then
90 AC_CHECK_HEADERS([pthread.h],
91                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
92                  AC_MSG_ERROR([pthread support is required to build WebKit]))
93 fi
94
95 # check for libjpeg the way Gtk does it.
96 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
97                    jpeg_ok=yes, jpeg_ok=no
98                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
99 if test "$jpeg_ok" = yes; then
100    AC_MSG_CHECKING([for jpeglib])
101    AC_TRY_CPP(
102 [#include <stdio.h>
103 #undef PACKAGE
104 #undef VERSION
105 #undef HAVE_STDLIB_H
106 #include <jpeglib.h>],
107          jpeg_ok=yes,
108          jpeg_ok=no)
109    AC_MSG_RESULT($jpeg_ok)
110    if test "$jpeg_ok" = yes; then
111       JPEG_LIBS="-ljpeg"
112       # should we check for progressive JPEG like GTK+ as well?
113    else
114       AC_MSG_ERROR([JPEG library (libjpeg) not found])
115    fi
116 fi
117 AC_SUBST([JPEG_LIBS])
118
119 # Check for libpng the way Gtk+ does it
120 AC_MSG_CHECKING(for libpng12)
121 if $PKG_CONFIG --exists libpng12 ; then
122     AC_MSG_RESULT(yes)
123     PNG_LIBS=`$PKG_CONFIG --libs libpng12`
124 else
125   AC_MSG_RESULT(no)
126   AC_CHECK_LIB(png, png_read_info,
127     [AC_CHECK_HEADER(png.h,
128       png_ok=yes,
129       png_ok=no)],
130     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
131   if test "$png_ok" = yes; then
132     AC_MSG_CHECKING([for png_structp in png.h])
133     AC_TRY_COMPILE([#include <png.h>],
134       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
135       png_ok=yes,
136       png_ok=no)
137     AC_MSG_RESULT($png_ok)
138     if test "$png_ok" = yes; then
139       PNG_LIBS='-lpng -lz'
140     else
141       AC_MSG_ERROR([PNG library (libpng) not found])
142     fi
143   else
144    AC_MSG_ERROR([PNG library (libpng) not found])
145   fi
146 fi
147 AC_SUBST([PNG_LIBS])
148
149 # determine the GDK/GTK+ target
150 AC_MSG_CHECKING([the target windowing system])
151 AC_ARG_WITH(target,
152             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
153                            [Select webkit target [default=x11]]),
154             [],[with_target="x11"])
155
156 case "$with_target" in
157      x11|win32|quartz|directfb) ;;
158      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
159 esac
160
161 AC_MSG_RESULT([$with_target])
162
163 AC_MSG_CHECKING([for Hildon UI extensions])
164 AC_ARG_WITH(hildon,
165             AC_HELP_STRING([--with-hildon],
166                            [Use Hildon UI extensions [default=no]]),
167             [],[with_hildon="no"])
168 AC_MSG_RESULT([$with_hildon])
169
170 if test "$with_hildon" = "yes"; then
171     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
172     PKG_CHECK_MODULES([HILDON], [hildon-1])
173     AC_SUBST([HILDON_CPPFLAGS])
174     AC_SUBST([HILDON_CFLAGS])
175     AC_SUBST([HILDON_LIBS])
176 fi
177
178 # minimum base dependencies
179 CAIRO_REQUIRED_VERSION=1.2
180 FONTCONFIG_REQUIRED_VERSION=2.4
181 FREETYPE2_REQUIRED_VERSION=9.0
182 LIBXML_REQUIRED_VERSION=2.6
183
184 # minimum GTK+ base dependencies
185 PANGO_REQUIRED_VERSION=1.0
186 GTK_REQUIRED_VERSION=2.10
187
188 # optional modules
189 LIBSOUP_REQUIRED_VERSION=2.25.91
190 LIBXSLT_REQUIRED_VERSION=1.1.7
191 SQLITE_REQUIRED_VERSION=3.0
192 GSTREAMER_REQUIRED_VERSION=0.10
193 GNOME_KEYRING_REQUIRED_VERSION=2.26.0
194 ENCHANT_REQUIRED_VERSION=0.22
195
196 # Available modules
197 #
198 # glib - glib and includes gthread
199 # unicode - check and identify which unicode backend to use
200 #
201 # todo: webcore gtk
202 WEBKIT_CHECK_DEPENDENCIES([glib unicode])
203
204 GETTEXT_PACKAGE=$PACKAGE
205 AC_SUBST(GETTEXT_PACKAGE)
206 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
207                    [The gettext catalog name])
208
209 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
210 AC_SUBST(LIBXML_CFLAGS)
211 AC_SUBST(LIBXML_LIBS)
212
213 PKG_CHECK_MODULES(PANGO, 
214                   [pango >= $PANGO_REQUIRED_VERSION
215                    pangoft2])
216 AC_SUBST(PANGO_CFLAGS)
217 AC_SUBST(PANGO_LIBS)
218
219 PKG_CHECK_MODULES(ENCHANT, enchant >= $ENCHANT_REQUIRED_VERSION)
220 AC_SUBST(ENCHANT_CFLAGS)
221 AC_SUBST(ENCHANT_LIBS)
222
223 # check for target-specific dependencies
224 if test "$with_target" = "directfb"; then
225    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
226    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
227    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
228 else
229    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
230    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED_VERSION)
231
232    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
233       # check for XT
234       PKG_CHECK_MODULES([XT],
235                         [xt],
236                         [xt_has_pkg_config=yes],
237                         [xt_has_pkg_config=no])
238       # some old versions of Xt do not provide xt.pc, so try to link against Xt
239       # and if it's installed fall back to just adding -lXt
240       if test "$xt_has_pkg_config" = "no"; then
241          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
242          # we don't care about the XtOpenDisplay symbol but only about the
243          # existence of libXt
244          AC_CHECK_LIB([Xt], [XtOpenDisplay],
245                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
246                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
247       fi
248       AC_SUBST([XT_CFLAGS])
249       AC_SUBST([XT_LIBS])
250       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
251    fi
252 fi
253 AC_SUBST(GTK_CFLAGS)
254 AC_SUBST(GTK_LIBS)
255 AC_SUBST(CAIRO_CFLAGS)
256 AC_SUBST(CAIRO_LIBS)
257
258 # check whether to build with debugging enabled
259 AC_MSG_CHECKING([whether to do a debug build])
260 AC_ARG_ENABLE(debug,
261               AC_HELP_STRING([--enable-debug],
262                              [turn on debugging [default=no]]),
263               [],[enable_debug="no"])
264 AC_MSG_RESULT([$enable_debug])
265
266 # check whether to enable optimized builds
267 AC_MSG_CHECKING([whether to enable optimized builds])
268 AC_ARG_ENABLE(optimizations,
269               AC_HELP_STRING([--enable-optimizations],
270                              [turn on optimize builds (GCC only)
271                              [default=yes]]),
272               [enable_optimizations=$enableval],
273               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
274 AC_MSG_RESULT([$enable_optimizations])
275
276 # check whether to enable dashboard support
277 AC_MSG_CHECKING([whether to enable Dashboard support])
278 AC_ARG_ENABLE(dashboard_support,
279               AC_HELP_STRING([--enable-dashboard-support],
280                              [enable Dashboard support [default=yes]]),
281               [],[enable_dashboard_support="yes"])
282 AC_MSG_RESULT([$enable_dashboard_support])
283
284 # check whether to enable 3D transforms support
285 AC_MSG_CHECKING([whether to enable support for 3D Transforms])
286 AC_ARG_ENABLE(3D_transforms,
287               AC_HELP_STRING([--enable-3D-transforms],
288                              [enable support for 3D transforms [default=no]]),
289               [],[enable_3D_transforms="no"])
290 AC_MSG_RESULT([$enable_3D_transforms])
291
292 # check whether to enable channel messaging support
293 AC_MSG_CHECKING([whether to enable HTML5 Channel Messaging support])
294 AC_ARG_ENABLE(channel_messaging,
295               AC_HELP_STRING([--enable-channel-messaging],
296                              [enable HTML5 channel messaging support [default=no]]),
297               [],[enable_channel_messaging="no"])
298 AC_MSG_RESULT([$enable_channel_messaging])
299
300 # check whether to enable JavaScript debugger/profiler support
301 AC_MSG_CHECKING([whether to enable JavaScript debugger/profiler support])
302 AC_ARG_ENABLE(javascript_debugger,
303               AC_HELP_STRING([--enable-javascript-debugger],
304                              [enable JavaScript debugger/profiler support [default=yes]]),
305               [],[enable_javascript_debugger="yes"])
306 AC_MSG_RESULT([$enable_javascript_debugger])
307
308 # check whether to enable HTML5 Offline Web Applications support
309 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
310 AC_ARG_ENABLE(offline_web_applications,
311               AC_HELP_STRING([--enable-offline-web-applications],
312                              [enable HTML5 offline web applications support [default=yes]]),
313               [],[enable_offline_web_applications="yes"])
314 AC_MSG_RESULT([$enable_offline_web_applications])
315
316 # check whether to enable HTML5 client-side session and persitent storage support
317 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
318 AC_ARG_ENABLE(dom_storage,
319               AC_HELP_STRING([--enable-dom-storage],
320                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
321               [],[enable_dom_storage="yes"])
322 AC_MSG_RESULT([$enable_dom_storage])
323
324 # check whether to build with database support
325 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
326 AC_ARG_ENABLE(database,
327               AC_HELP_STRING([--enable-database],
328                              [enable HTML5 client-side database storage support [default=yes]]),
329               [],[enable_database="yes"])
330 AC_MSG_RESULT([$enable_database])
331
332 # check whether to build with icon database support
333 AC_MSG_CHECKING([whether to enable icon database support])
334 AC_ARG_ENABLE(icon_database,
335               AC_HELP_STRING([--enable-icon-database],
336                              [enable icon database [default=yes]]),
337               [],[enable_icon_database="yes"])
338 AC_MSG_RESULT([$enable_icon_database])
339
340 # check whether to enable HTML5 audio/video support
341 AC_MSG_CHECKING([whether to enable HTML5 video support])
342 AC_ARG_ENABLE(video,
343               AC_HELP_STRING([--enable-video],
344                              [enable HTML5 video support [default=yes]]),
345               [],[enable_video="yes"])
346 AC_MSG_RESULT([$enable_video])
347
348 # check whether to enable XPath support
349 AC_MSG_CHECKING([whether to enable XPath support])
350 AC_ARG_ENABLE(xpath,
351               AC_HELP_STRING([--enable-xpath],
352                              [enable support for XPath [default=yes]]),
353               [],[enable_xpath="yes"])
354 AC_MSG_RESULT([$enable_xpath])
355
356 # check whether to enable XSLT support
357 AC_MSG_CHECKING([whether to enable XSLT support])
358 AC_ARG_ENABLE(xslt,
359               AC_HELP_STRING([--enable-xslt],
360                              [enable support for XSLT [default=yes]]),
361               [],[enable_xslt="yes"])
362 AC_MSG_RESULT([$enable_xslt])
363
364 # check whether to enable geolocation support
365 AC_MSG_CHECKING([whether to enable geolocation support])
366 AC_ARG_ENABLE(geolocation,
367               AC_HELP_STRING([--enable-geolocation],
368                              [enable support for geolocation [default=no]]),
369               [],[enable_geolocation="no"])
370 AC_MSG_RESULT([$enable_geolocation])
371
372 # check whether to enable gnomekeyring support
373 AC_MSG_CHECKING([whether to enable gnomekeyring support])
374 AC_ARG_ENABLE(gnomekeyring,
375               AC_HELP_STRING([--enable-gnomekeyring],
376                              [enable support for gnomekeyring [default=no]]),
377               [],[enable_gnomekeyring="no"])
378 AC_MSG_RESULT([$enable_gnomekeyring])
379
380 # check whether to enable SVG support
381 AC_MSG_CHECKING([whether to enable SVG support])
382 AC_ARG_ENABLE(svg,
383               AC_HELP_STRING([--enable-svg],
384                              [enable support for SVG [default=yes]]),
385               [],[enable_svg="yes"])
386 AC_MSG_RESULT([$enable_svg])
387
388 # check whether to enable WML support
389 AC_MSG_CHECKING([whether to enable WML support])
390 AC_ARG_ENABLE(wml,
391               AC_HELP_STRING([--enable-wml],
392                              [enable support for WML [default=no]]),
393               [],[enable_wml="no"])
394 AC_MSG_RESULT([$enable_wml])
395
396 # check whether to enable Web Workers support
397 AC_MSG_CHECKING([whether to enable Web Workers support])
398 AC_ARG_ENABLE(web_workers,
399               AC_HELP_STRING([--enable-web-workers],
400                              [enable support for Web Workers [default=yes]]),
401               [],[enable_web_workers="yes"])
402 AC_MSG_RESULT([$enable_web_workers])
403
404 # turn off svg features if --disable-svg is requested
405 if test "$enable_svg" = "no"; then
406    enable_svg_animation=no
407    enable_svg_filters=no
408    enable_svg_fonts=no
409    enable_svg_foreign_object=no
410    enable_svg_as_image=no
411    enable_svg_use_element=no
412 fi
413
414 # check whether to enable support for SVG animation
415 AC_MSG_CHECKING([whether to enable support for SVG animation])
416 AC_ARG_ENABLE(svg_animation,
417               AC_HELP_STRING([--enable-svg-animation],
418                              [enable support for SVG animation (experimental) [default=yes]]),
419               [],[enable_svg_animation="yes"])
420 AC_MSG_RESULT([$enable_svg_animation])
421
422 # check whether to enable support for SVG filters
423 AC_MSG_CHECKING([whether to enable support for SVG filters])
424 AC_ARG_ENABLE(svg_filters,
425               AC_HELP_STRING([--enable-svg-filters],
426                              [enable support for SVG filters (experimental) [default=no]]),
427               [],[enable_svg_filters="no"])
428 AC_MSG_RESULT([$enable_svg_filters])
429
430 # check whether to enable support for SVG fonts
431 AC_MSG_CHECKING([whether to enable support for SVG fonts])
432 AC_ARG_ENABLE(svg_fonts,
433               AC_HELP_STRING([--enable-svg-fonts],
434                              [enable support for SVG fonts (experimental) [default=yes]]),
435               [],[enable_svg_fonts="yes"])
436 AC_MSG_RESULT([$enable_svg_fonts])
437
438 # check whether to enable foreign objects support for SVG
439 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
440 AC_ARG_ENABLE(svg_foreign_object,
441               AC_HELP_STRING([--enable-svg-foreign-object],
442                              [enable support for SVG foreign objects (experimental) [default=yes]]),
443               [],[enable_svg_foreign_object="yes"])
444 AC_MSG_RESULT([$enable_svg_foreign_object])
445
446 # check whether to enable SVG As Image support
447 AC_MSG_CHECKING([whether to enable SVG as Image support])
448 AC_ARG_ENABLE(svg_as_image,
449               AC_HELP_STRING([--enable-svg-as-image],
450                              [enable SVG as Image support (experimental) [default=yes]]),
451               [],[enable_svg_as_image="yes"])
452 AC_MSG_RESULT([$enable_svg_as_image])
453
454 # check whether to enable SVG USE element support
455 AC_MSG_CHECKING([whether to enable support for SVG use element])
456 AC_ARG_ENABLE(svg_use_element,
457               AC_HELP_STRING([--enable-svg-use-element],
458                              [enable SVG use element support (experimental) [default=yes]]),
459               [],[enable_svg_use_element="yes"])
460 AC_MSG_RESULT([$enable_svg_use_element])
461
462 # check for SVG features, enabling SVG if necessary
463 if test "$enable_svg_animation" = "yes" || \
464    test "$enable_svg_filters" = "yes" || \
465    test "$enable_svg_fonts" = "yes" || \
466    test "$enable_svg_foreign_object" = "yes" || \
467    test "$enable_svg_as_image" = "yes" || \
468    test "$enable_svg_use_element" = "yes"; then
469    svg_flags=yes
470    if test "$enable_svg" = "no"; then
471        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
472        enable_svg=yes
473    fi
474 fi
475
476 # check whether to enable code coverage
477 AC_MSG_CHECKING([whether to enable code coverage support])
478 AC_ARG_ENABLE(coverage,
479               AC_HELP_STRING([--enable-coverage],
480                              [enable code coverage support [default=no]]),
481               [],[enable_coverage="no"])
482 AC_MSG_RESULT([$enable_coverage])
483
484 # check whether to enable FastMalloc
485 AC_MSG_CHECKING([whether to enable optimized memory allocator])
486 AC_ARG_ENABLE(fast_malloc,
487               AC_HELP_STRING([--enable-fast-malloc],
488                              [enable optimized memory allocator default=yes, default=no for debug builds]),
489               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
490 AC_MSG_RESULT([$enable_fast_malloc])
491
492 AC_MSG_CHECKING([whether to enable JIT compilation])
493 AC_ARG_ENABLE([jit],
494               AC_HELP_STRING([--enable-jit],
495                              [Enable JIT compilation default=yes]),
496               [],[enable_jit="yes"])
497 if test "$enable_jit" = "yes"; then
498     case "$host_cpu" in
499         i*86|x86_64)
500             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
501             AC_DEFINE([ENABLE_YARR], [1], [Define to enable YARR])
502             AC_DEFINE([ENABLE_YARR_JIT], [1], [Define to enable YARR JIT])
503             AC_DEFINE([ENABLE_JIT_OPTIMIZE_CALL], [1], [Define to enable optimizing calls])
504             AC_DEFINE([ENABLE_JIT_OPTIMIZE_PROPERTY_ACCESS], [1], [Define to enable optimized property access])
505             AC_DEFINE([ENABLE_JIT_OPTIMIZE_ARITHMETIC], [1], [Define to enable optimized arithmetic])
506             case "$host_cpu" in
507                 i*86)
508                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_VA_LIST], [1], [Use stub va_list])
509                 ;;
510                 x86_64)
511                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_REGISTER], [1], [Use stub register])
512                     AC_DEFINE([WTF_USE_ALTERNATE_JSIMMEDIATE], [1], [Use alternate JSImmediate])
513                 ;;
514             esac
515         ;;
516         *)
517             enable_jit="no (CPU '$host_cpu' not supported)"
518         ;;
519     esac
520 fi
521 AC_MSG_RESULT([$enable_jit])
522
523 # determine the font backend
524 AC_MSG_CHECKING([the font backend to use])
525 AC_ARG_WITH(font_backend,
526             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
527                            [Select font backend [default=freetype]]),
528             [],[with_font_backend="freetype"])
529
530 case "$with_font_backend" in
531      freetype|pango) ;;
532      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
533 esac
534 AC_MSG_RESULT([$with_font_backend])
535
536 # Add '-g' flag to gcc if it's debug build
537 if test "$enable_debug" = "yes"; then
538    CXXFLAGS="$CXXFLAGS -g"
539    CFLAGS="$CFLAGS -g"
540 else
541    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
542 fi
543
544 # Add the appropriate 'O' level for optimized builds
545 if test "$enable_optimizations" = "yes"; then
546    CXXFLAGS="$CXXFLAGS -O2"
547    CFLAGS="$CFLAGS -O2"
548 else
549    CXXFLAGS="$CXXFLAGS -O0"
550    CFLAGS="$CFLAGS -O0"
551 fi
552
553 PKG_CHECK_MODULES([LIBSOUP],
554                   [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
555 AC_SUBST([LIBSOUP_CFLAGS])
556 AC_SUBST([LIBSOUP_LIBS])
557
558 if test "$enable_gnomekeyring" = "yes"; then
559    PKG_CHECK_MODULES([GNOMEKEYRING],
560                      [gnome-keyring-1 >= $GNOME_KEYRING_REQUIRED_VERSION])
561    AC_SUBST([GNOMEKEYRING_CFLAGS])
562    AC_SUBST([GNOMEKEYRING_LIBS])
563 fi
564
565 # check if FreeType/FontConfig are available
566 if test "$with_font_backend" = "freetype"; then
567    if test "$with_target" = "directfb"; then
568    PKG_CHECK_MODULES([FREETYPE],
569                      [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
570                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
571    else
572    PKG_CHECK_MODULES([FREETYPE],
573                      [cairo-ft
574                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
575                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
576    fi
577    AC_SUBST([FREETYPE_CFLAGS])
578    AC_SUBST([FREETYPE_LIBS])
579 fi
580
581 # check if sqlite 3 is available
582 if test "$enable_icon_database" = "yes" || \
583    test "$enable_database" = "yes" || \
584    test "$enable_offline_web_applications" = "yes" || \
585    test "$enable_dom_storage" = "yes"; then
586    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
587    AC_SUBST([SQLITE3_CFLAGS])
588    AC_SUBST([SQLITE3_LIBS])
589 fi
590
591 # check if libxslt is available
592 if test "$enable_xslt" = "yes"; then
593    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
594    AC_SUBST([LIBXSLT_CFLAGS])
595    AC_SUBST([LIBXSLT_LIBS])
596 fi
597
598 # check if geoclue is available
599 if test "$enable_geolocation" = "yes"; then
600     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
601     AC_SUBST([GEOCLUE_CFLAGS])
602     AC_SUBST([GEOCLUE_LIBS])
603 fi
604
605 # check if gstreamer is available
606 if test "$enable_video" = "yes"; then
607    PKG_CHECK_MODULES([GSTREAMER],
608                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
609                      gstreamer-base-0.10,
610                      gstreamer-plugins-base-0.10,
611                      gstreamer-video-0.10])
612    AC_SUBST([GSTREAMER_CFLAGS])
613    AC_SUBST([GSTREAMER_LIBS])
614 fi
615
616 # check for code coverage support
617 if test "$enable_coverage" = "yes"; then
618    COVERAGE_CFLAGS="-MD"
619    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
620    AC_SUBST([COVERAGE_CFLAGS])
621    AC_SUBST([COVERAGE_LDFLAGS])
622 fi
623
624 # check for HTML features
625 if test "$enable_video" = "yes"; then
626     html_flags=yes
627 fi
628
629 GTK_DOC_CHECK([1.10])
630
631 # OS conditionals
632 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
633 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
634 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
635 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
636 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
637
638 # target conditionals
639 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
640 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
641 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
642 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
643
644 # Unicode backend conditionals
645 AM_CONDITIONAL([USE_ICU_UNICODE], [test "$with_unicode_backend" = "icu"])
646 AM_CONDITIONAL([USE_GLIB_UNICODE], [test "$with_unicode_backend" = "glib"])
647
648 # Auth backend conditionals
649 AM_CONDITIONAL([USE_GNOMEKEYRING], [test "$enable_gnomekeyring" = "yes"])
650
651 # Font backend conditionals
652 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
653 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
654
655 # WebKit feature conditionals
656 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
657 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
658 AM_CONDITIONAL([ENABLE_3D_TRANSFORMS],[test "$enable_3D_transforms" = "yes"])
659 AM_CONDITIONAL([ENABLE_CHANNEL_MESSAGING],[test "$enable_channel_messaging" = "yes"])
660 AM_CONDITIONAL([ENABLE_JAVASCRIPT_DEBUGGER],[test "$enable_javascript_debugger" = "yes"])
661 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
662 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
663 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
664 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
665 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
666 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
667 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
668 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
669 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
670 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
671 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
672 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
673 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
674 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
675 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
676 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
677 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
678 AM_CONDITIONAL([ENABLE_WML],[test "$enable_wml" = "yes"])
679 AM_CONDITIONAL([ENABLE_WORKERS],[test "$enable_web_workers" = "yes"])
680 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
681 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
682
683 AC_CONFIG_FILES([
684 GNUmakefile
685 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
686 WebKit/gtk/webkit/webkitversion.h
687 WebKit/gtk/docs/GNUmakefile
688 WebKit/gtk/docs/version.xml
689 ]
690 )
691
692 AC_OUTPUT
693
694 echo "
695 WebKit was configured with the following options:
696
697 Build configuration:
698  Enable debugging (slow)                                  : $enable_debug
699  Enable GCC build optimization                            : $enable_optimizations
700  Code coverage support                                    : $enable_coverage
701  Unicode backend                                          : $with_unicode_backend
702  Font backend                                             : $with_font_backend
703  Optimized memory allocator                               : $enable_fast_malloc
704 Features:
705  3D Transforms                                            : $enable_3D_transforms
706  JIT compilation                                          : $enable_jit
707  Dashboard support                                        : $enable_dashboard_support
708  Geolocation support                                      : $enable_geolocation
709  GNOME Keyring support                                    : $enable_gnomekeyring
710  JavaScript debugger/profiler support                     : $enable_javascript_debugger
711  HTML5 offline web applications support                   : $enable_offline_web_applications
712  HTML5 channel messaging support                          : $enable_channel_messaging
713  HTML5 client-side session and persistent storage support : $enable_dom_storage
714  HTML5 client-side database storage support               : $enable_database
715  HTML5 video element support                              : $enable_video
716  Icon database support                                    : $enable_icon_database
717  SVG support                                              : $enable_svg
718  SVG animation support                                    : $enable_svg_animation
719  SVG filters support                                      : $enable_svg_filters
720  SVG fonts support                                        : $enable_svg_fonts
721  SVG foreign object support                               : $enable_svg_foreign_object
722  SVG as image support                                     : $enable_svg_as_image
723  SVG use element support                                  : $enable_svg_use_element
724  WML support                                              : $enable_wml
725  Web Workers support                                      : $enable_web_workers
726  XPATH support                                            : $enable_xpath
727  XSLT support                                             : $enable_xslt
728 GTK+ configuration:
729  GDK target                                               : $with_target
730  Hildon UI extensions                                     : $with_hildon
731 "
732 if test "$with_unicode_backend" = "glib"; then
733    echo "     >> WARNING: the glib-based unicode backend is slow and incomplete <<"
734    echo
735    echo
736 fi