2008-03-09 J?rg Billeter <j@bitron.ch>
[WebKit-https.git] / configure.ac
1 AC_INIT([WebKit],[0.1],[http://bugs.webkit.org/])
2
3 AC_PREREQ(2.59)
4
5 AC_CONFIG_HEADERS([aconfig.h])
6 AC_CONFIG_SRCDIR([WebCore/config.h])
7
8 # see http://www.gnu.org/software/libtool/manual.html#Versioning
9 LIBWEBKITGTK_VERSION=1:0:0
10 AC_SUBST([LIBWEBKITGTK_VERSION])
11
12 AM_INIT_AUTOMAKE([foreign subdir-objects])
13
14 AC_CANONICAL_HOST
15
16 # host checking - inspired by the GTK+ configure.in
17 # TODO: os_mac, os_bsd
18 AC_MSG_CHECKING([for native Win32])
19 case "$host" in
20      *-*-mingw*)
21        os_win32=yes
22        ;;
23      *)
24        os_win32=no
25        ;;
26 esac
27 AC_MSG_RESULT([$os_win32])
28
29 case "$host" in
30      *-*-linux*)
31        os_linux=yes
32        ;;
33      *-*-freebsd*)
34        os_freebsd=yes
35        ;;
36      *-*-darwin*)
37        os_darwin=yes
38        ;;
39 esac
40
41 # If CXXFLAGS and CFLAGS are unset, default to -O2
42 # This is to tell automake not to include '-g' if CXXFLAGS is not set
43 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
44 if test -z "$CXXFLAGS"; then
45    CXXFLAGS="-O2"
46 fi
47 if test -z "$CFLAGS"; then
48    CFLAGS="-O2"
49 fi
50
51 # programs
52 AC_DISABLE_STATIC
53 AM_PROG_LIBTOOL
54 AC_PROG_INSTALL
55 AM_PROG_CC_STDC
56 AC_PROG_CXX
57 AM_PROG_CC_C_O
58
59 # check for -fvisibility=hidden compiler support (GCC >= 4)
60 saved_CFLAGS="$CFLAGS"
61 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
62 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
63 AC_COMPILE_IFELSE([char foo;],
64       [ AC_MSG_RESULT([yes])
65         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
66         AC_MSG_RESULT([no]))
67 CFLAGS="$saved_CFLAGS"
68 AC_SUBST(SYMBOL_VISIBILITY)
69 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
70
71 AC_PATH_PROG(PERL, perl)
72 if test -z "$PERL"; then
73    AC_MSG_ERROR([You need 'perl' to compile WebKit])
74 fi
75
76 AC_PATH_PROG(BISON, bison)
77 if test -z "$BISON"; then
78    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
79 fi
80
81 AC_PATH_PROG(FLEX, flex)
82 if test -z "$FLEX"; then
83    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
84 fi
85
86 AC_PATH_PROG(GPERF, gperf)
87 if test -z "$GPERF"; then
88    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
89 fi
90
91 AC_PATH_PROG(MV, mv)
92 if test -z "$MV"; then
93    AC_MSG_ERROR([You need 'mv' to compile WebKit])
94 fi
95
96 # GTK+ port only
97 # Check for glib-genmarshal and glib-mkenums
98 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
99 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
100
101 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
102 # doesn't exist)
103 AC_LANG_PUSH([C++])
104 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
105 AC_LANG_POP([C++])
106
107 # C/C++ Language Features
108 AC_C_CONST
109 AC_C_INLINE
110 AC_C_VOLATILE
111
112 # C/C++ Headers
113 AC_HEADER_STDC
114 AC_HEADER_STDBOOL
115
116 # pthread (not needed on Windows)
117 if test "$os_win32" = "no"; then
118 AC_CHECK_HEADERS([pthread.h],
119                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exist]),
120                  AC_MSG_ERROR([pthread support is required to build WebKit]))
121 fi
122
123 # libjpeg headers
124 AC_CHECK_HEADERS([jpeglib.h])
125
126 # check for pkg-config
127 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
128 if test "$PKG_CONFIG" = "no"; then
129    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
130 fi
131
132 # determine the Unicode backend
133 AC_MSG_CHECKING([the Unicode backend to use])
134 AC_ARG_WITH(unicode_backend,
135             AC_HELP_STRING([--with-unicode-backend=@<:@icu@:>@],
136                            [Select Unicode backend [default=icu]]),
137             [],[unicode_backend="icu"])
138
139 case "$unicode_backend" in
140      icu) ;;
141      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu.]) ;;
142 esac
143
144 AC_MSG_RESULT([$unicode_backend])
145
146 if test "$unicode_backend" = "icu"; then
147         # check for icu-config
148         if test "$os_darwin" = "yes"; then
149                 UNICODE_CFLAGS="-I\$(srcdir)/JavaScriptCore/icu -I\$(srcdir)/WebCore/icu"
150                 UNICODE_LIBS="-licucore"
151         else
152                 AC_PATH_PROG(icu_config, icu-config, no)
153                 if test "$icu_config" = "no"; then
154                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
155                 fi
156
157                 # We don't use --cflags as this gives us a lot of things that we don't
158                 # necessarily want, like debugging and optimization flags
159                 # See man (1) icu-config for more info.
160                 UNICODE_CFLAGS=`$icu_config --cppflags`
161                 UNICODE_LIBS=`$icu_config --ldflags`
162         fi
163 fi
164
165 AC_SUBST([UNICODE_CFLAGS])
166 AC_SUBST([UNICODE_LIBS])
167
168 # determine the GDK/GTK+ target
169 AC_MSG_CHECKING([the target windowing system])
170 AC_ARG_WITH(target,
171             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
172                            [Select webkit target [default=x11]]),
173             [],[with_target="x11"])
174
175 case "$with_target" in
176      x11|win32|quartz|directfb) ;;
177      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
178 esac
179
180 AC_MSG_RESULT([$with_target])
181
182 AC_MSG_CHECKING([for Hildon UI extensions])
183 AC_ARG_WITH(hildon,
184             AC_HELP_STRING([--with-hildon],
185                            [Use Hildon UI extensions [default=no]]),
186             [],[with_hildon="no"])
187 AC_MSG_RESULT([$with_hildon])
188
189 if test "$with_hildon" = "yes"; then
190     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
191     PKG_CHECK_MODULES([HILDON], [hildon-1])
192     AC_SUBST([HILDON_CPPFLAGS])
193     AC_SUBST([HILDON_CFLAGS])
194     AC_SUBST([HILDON_LIBS])
195 fi
196
197 # determine the http backend
198 AC_MSG_CHECKING([the HTTP backend to use])
199 AC_ARG_WITH(http_backend,
200             AC_HELP_STRING([--with-http-backend=@<:@curl@:>@],
201                            [Select HTTP backend [default=curl]]),
202             [],[http_backend="curl"])
203
204 case "$http_backend" in
205      curl) ;;
206      *) AC_MSG_ERROR([Invalid HTTP backend: must be curl.]) ;;
207 esac
208
209 AC_MSG_RESULT([$http_backend])
210
211 # minimum base dependencies
212 CAIRO_REQUIRED_VERSION=1.4
213 FONTCONFIG_REQUIRED_VERSION=2.4
214 FREETYPE2_REQUIRED_VERSION=9.0
215 LIBXML_REQUIRED_VERSION=2.6
216
217 # minimum GTK+ base dependencies
218 GLIB_REQUIRED_VERSION=2.0
219 GOBJECT_REQUIRED_VERSION=2.0
220 GTHREAD_REQUIRED_VERSION=2.0
221 PANGO_REQUIRED_VERSION=1.0
222 GTK_REQUIRED_VERSION=2.8
223
224 # optional modules
225 LIBCURL_REQUIRED_VERSION=7.15
226 LIBXSLT_REQUIRED_VERSION=1.1.7
227 SQLITE_REQUIRED_VERSION=3.0
228 GSTREAMER_REQUIRED_VERSION=0.10
229 GNOME_VFS_REQUIRED_VERSION=2.0
230
231 PKG_CHECK_MODULES([GLOBALDEPS],
232                   [glib-2.0 >= $GLIB_REQUIRED_VERSION
233                   gobject-2.0 >= $GOBJECT_REQUIRED_VERSION
234                   gthread-2.0 >= $GTHREAD_REQUIRED_VERSION])
235 AC_SUBST([GLOBALDEPS_CFLAGS])
236 AC_SUBST([GLOBALDEPS_LIBS])
237
238 PKG_CHECK_MODULES([WEBKITDEPS],
239                   [gtk+-2.0 >= $GTK_REQUIRED_VERSION
240                   pango >= $PANGO_REQUIRED_VERSION
241                   cairo >= $CAIRO_REQUIRED_VERSION
242                   cairo-ft,
243                   fontconfig >= $FONTCONFIG_REQUIRED_VERSION
244                   freetype2 >= $FREETYPE2_REQUIRED_VERSION
245                   libxml-2.0 >= $LIBXML_REQUIRED_VERSION])
246 AC_SUBST([WEBKITDEPS_CFLAGS])
247 AC_SUBST([WEBKITDEPS_LIBS])
248
249 # check whether to build with debugging enabled
250 AC_MSG_CHECKING([whether to do a debug build])
251 AC_ARG_ENABLE(debug,
252               AC_HELP_STRING([--enable-debug],
253                              [turn on debugging [default=no]]),
254               [],[enable_debug="no"])
255 AC_MSG_RESULT([$enable_debug])
256
257 # check whether to build with cross-document messaging support
258 AC_MSG_CHECKING([whether to enable HTML5 cross-document messaging support])
259 AC_ARG_ENABLE(cross_document_messaging,
260               AC_HELP_STRING([--enable-cross-document-messaging],
261                              [enable HTML5 cross-document messaging support [default=yes]]),
262               [],[enable_cross_document_messaging="yes"])
263 AC_MSG_RESULT([$enable_cross_document_messaging])
264
265 # check whether to build with database support
266 AC_MSG_CHECKING([whether to enable HTML5 client-side storage support])
267 AC_ARG_ENABLE(database,
268               AC_HELP_STRING([--enable-database],
269                              [enable HTML5 client-side storage support [default=yes]]),
270               [],[enable_database="yes"])
271 AC_MSG_RESULT([$enable_database])
272
273 # check whether to build with icon database support
274 AC_MSG_CHECKING([whether to enable icon database support])
275 AC_ARG_ENABLE(icon_database,
276               AC_HELP_STRING([--enable-icon-database],
277                              [enable icon database [default=no]]),
278               [],[enable_icon_database="no"])
279 AC_MSG_RESULT([$enable_icon_database])
280
281 # check whether to enable HTML5 audio/video support
282 AC_MSG_CHECKING([whether to enable HTML5 video support])
283 AC_ARG_ENABLE(video,
284               AC_HELP_STRING([--enable-video],
285                              [enable HTML5 video support [default=no]]),
286               [],[enable_video="no"])
287 AC_MSG_RESULT([$enable_video])
288
289 # check whether to enable XPath support
290 AC_MSG_CHECKING([whether to enable XPath support])
291 AC_ARG_ENABLE(xpath,
292               AC_HELP_STRING([--enable-xpath],
293                              [enable support for XPath [default=yes]]),
294               [],[enable_xpath="yes"])
295 AC_MSG_RESULT([$enable_xpath])
296
297 # check whether to enable XSLT support
298 AC_MSG_CHECKING([whether to enable XSLT support])
299 AC_ARG_ENABLE(xslt,
300               AC_HELP_STRING([--enable-xslt],
301                              [enable support for XSLT [default=yes]]),
302               [],[enable_xslt="yes"])
303 AC_MSG_RESULT([$enable_xslt])
304
305 # check whether to enable SVG experimental features
306 # Enable all SVG if it is
307 AC_MSG_CHECKING([whether to enable SVG experimental features])
308 AC_ARG_ENABLE(svg_experimental,
309               AC_HELP_STRING([--enable-svg-experimental],
310                              [enable support for SVG experimental features [default=no]]),
311               [],[enable_svg_experimental="no"])
312 AC_MSG_RESULT([$enable_svg_experimental])
313
314 if test "$enable_svg_experimental" = "yes"; then
315    enable_svg=yes
316    enable_svg_animation=yes
317 #   enable_svg_filters=yes
318    enable_svg_fonts=yes
319    enable_svg_foreign_object=yes
320    enable_svg_as_image=yes
321    enable_svg_use_element=yes
322 fi
323
324 # check whether to enable SVG support
325 AC_MSG_CHECKING([whether to enable SVG support])
326 AC_ARG_ENABLE(svg,
327               AC_HELP_STRING([--enable-svg],
328                              [enable support for SVG [default=no]]),
329               [],[enable_svg="no"])
330 AC_MSG_RESULT([$enable_svg])
331
332 # check whether to enable support for SVG animation
333 AC_MSG_CHECKING([whether to enable support for SVG animation])
334 AC_ARG_ENABLE(svg_animation,
335               AC_HELP_STRING([--enable-svg-animation],
336                              [enable support for SVG animation (experimental) [default=no]]),
337               [],[enable_svg_animation="no"])
338 AC_MSG_RESULT([$enable_svg_animation])
339
340 # check whether to enable support for SVG filters
341 AC_MSG_CHECKING([whether to enable support for SVG filters])
342 AC_ARG_ENABLE(svg_filters,
343               AC_HELP_STRING([--enable-svg-filters],
344                              [enable support for SVG filters (experimental) [default=no]]),
345               [],[enable_svg_filters="no"])
346 AC_MSG_RESULT([$enable_svg_filters])
347
348 # check whether to enable support for SVG fonts
349 AC_MSG_CHECKING([whether to enable support for SVG fonts])
350 AC_ARG_ENABLE(svg_fonts,
351               AC_HELP_STRING([--enable-svg-fonts],
352                              [enable support for SVG fonts (experimental) [default=no]]),
353               [],[enable_svg_fonts="no"])
354 AC_MSG_RESULT([$enable_svg_fonts])
355
356 # check whether to enable foreign objects support for SVG
357 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
358 AC_ARG_ENABLE(svg_foreign_object,
359               AC_HELP_STRING([--enable-svg-foreign-object],
360                              [enable support for SVG foreign objects (experimental) [default=no]]),
361               [],[enable_svg_foreign_object="no"])
362 AC_MSG_RESULT([$enable_svg_foreign_object])
363
364 # check whether to enable SVG As Image support
365 AC_MSG_CHECKING([whether to enable SVG as Image support])
366 AC_ARG_ENABLE(svg_as_image,
367               AC_HELP_STRING([--enable-svg-as-image],
368                              [enable SVG as Image support (experimental) [default=no]]),
369               [],[enable_svg_as_image="no"])
370 AC_MSG_RESULT([$enable_svg_as_image])
371
372 # check whether to enable SVG USE element support
373 AC_MSG_CHECKING([whether to enable support for SVG use element])
374 AC_ARG_ENABLE(svg_use_element,
375               AC_HELP_STRING([--enable-svg-use-element],
376                              [enable SVG use element support (experimental) [default=no]]),
377               [],[enable_svg_use_element="no"])
378 AC_MSG_RESULT([$enable_svg_use_element])
379
380 # check whether to enable code coverage
381 AC_MSG_CHECKING([whether to enable code coverage support])
382 AC_ARG_ENABLE(coverage,
383               AC_HELP_STRING([--enable-coverage],
384                              [enable code coverage support [default=no]]),
385               [],[enable_coverage="no"])
386 AC_MSG_RESULT([$enable_coverage])
387
388 # check whether to enable FastMalloc
389 AC_MSG_CHECKING([whether to enable optimized memory allocator])
390 AC_ARG_ENABLE(fast_malloc,
391               AC_HELP_STRING([--enable-fast-malloc],
392                              [enable optimized memory allocator default=yes, default=no for debug builds]),
393               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
394 AC_MSG_RESULT([$enable_fast_malloc])
395
396 # Add '-g' flag to gcc if it's debug build
397 if test "$enable_debug" = "yes"; then
398    CXXFLAGS="$CXXFLAGS -g"
399    CFLAGS="$CFLAGS -g"
400 fi
401
402 # check if curl is available
403 if test "$http_backend" = "curl"; then
404    PKG_CHECK_MODULES([LIBCURL],
405                      [libcurl >= $LIBCURL_REQUIRED_VERSION])
406    AC_SUBST([LIBCURL_CFLAGS])
407    AC_SUBST([LIBCURL_LIBS])
408 fi
409
410 # check if sqlite 3 is available
411 if test "$enable_icon_database" = "yes" || test "$enable_database" = "yes"; then
412    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
413    AC_SUBST([SQLITE3_CFLAGS])
414    AC_SUBST([SQLITE3_LIBS])
415 fi
416
417 # check if libxslt is available
418 if test "$enable_xslt" = "yes"; then
419    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
420    AC_SUBST([LIBXSLT_CFLAGS])
421    AC_SUBST([LIBXSLT_LIBS])
422 fi
423
424 # check if gstreamer is available
425 if test "$enable_video" = "yes"; then
426    PKG_CHECK_MODULES([GSTREAMER],
427                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
428                      gstreamer-base-0.10,
429                      gstreamer-plugins-base-0.10,
430                      gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED_VERSION])
431    AC_SUBST([GSTREAMER_CFLAGS])
432    AC_SUBST([GSTREAMER_LIBS])
433 fi
434
435 # check for code coverage support
436 if test "$enable_coverage" = "yes"; then
437    COVERAGE_CFLAGS="-MD"
438    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
439    AC_SUBST([COVERAGE_CFLAGS])
440    AC_SUBST([COVERAGE_LDFLAGS])
441 fi
442
443 # check for SVG features, enabling SVG if necessary
444 if test "$enable_svg_animation" = "yes" || \
445    test "$enable_svg_filters" = "yes" || \
446    test "$enable_svg_fonts" = "yes" || \
447    test "$enable_svg_foreign_object" = "yes" || \
448    test "$enable_svg_as_image" = "yes" || \
449    test "$enable_svg_use_element" = "yes"; then
450    svg_flags=yes
451    if test "$enable_svg" = "no"; then
452        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
453        enable_svg=yes
454    fi
455 fi
456
457 # OS conditionals
458 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
459 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
460 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
461 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
462
463 # target conditionals
464 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
465 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
466 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
467 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
468
469 # HTTP backend conditionals
470 AM_CONDITIONAL([USE_CURL], [test "$http_backend" = "curl"])
471
472 # WebKit feature conditionals
473 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
474 AM_CONDITIONAL([ENABLE_CROSS_DOCUMENT_MESSAGING],[test "$enable_cross_document_messaging" = "yes"])
475 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
476 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
477 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
478 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
479 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
480 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
481 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
482 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
483 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
484 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
485 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
486 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
487 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
488 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
489 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
490
491 AC_CONFIG_FILES([
492 GNUmakefile
493 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
494 ]
495 )
496
497 AC_OUTPUT
498
499 echo "
500 WebKit was configured with the following options:
501
502 Build configuration:
503  Enable debugging (slow)           : $enable_debug
504  Code coverage support             : $enable_coverage
505  Unicode backend                   : $unicode_backend
506  HTTP backend                      : $http_backend
507  Optimized memory allocator        : $enable_fast_malloc
508 Features:
509  HTML5 cross-document messaging    : $enable_cross_document_messaging
510  HTML5 client-side storage support : $enable_database
511  HTML5 video element support       : $enable_video
512  Icon database support             : $enable_icon_database
513  SVG support                       : $enable_svg
514  SVG animation support             : $enable_svg_animation
515  SVG filters support               : $enable_svg_filters
516  SVG fonts support                 : $enable_svg_fonts
517  SVG foreign object support        : $enable_svg_foreign_object
518  SVG as image support              : $enable_svg_as_image
519  SVG use element support           : $enable_svg_use_element
520  XPATH support                     : $enable_xpath
521  XSLT support                      : $enable_xslt
522 GTK+ configuration:
523  GDK target                        : $with_target
524  Hildon UI extensions              : $with_hildon
525 "