Build fix, rubber-stamped and landed by ap.
[WebKit-https.git] / configure.ac
1 AC_INIT([WebKit],[0.1],[http://bugs.webkit.org/])
2
3 AC_PREREQ(2.59)
4
5 AC_CONFIG_HEADERS([aconfig.h])
6 AC_CONFIG_SRCDIR([WebCore/config.h])
7
8 # see http://www.gnu.org/software/libtool/manual.html#Versioning
9 LIBWEBKITGTK_VERSION=1:0:0
10 AC_SUBST([LIBWEBKITGTK_VERSION])
11
12 AM_INIT_AUTOMAKE([foreign subdir-objects])
13
14 AC_CANONICAL_HOST
15
16 # host checking - inspired by the GTK+ configure.in
17 # TODO: os_mac, os_bsd
18 AC_MSG_CHECKING([for native Win32])
19 case "$host" in
20      *-*-mingw*)
21        os_win32=yes
22        ;;
23      *)
24        os_win32=no
25        ;;
26 esac
27 AC_MSG_RESULT([$os_win32])
28
29 case "$host" in
30      *-*-linux*)
31        os_linux=yes
32        ;;
33      *-*-freebsd*)
34        os_freebsd=yes
35        ;;
36      *-*-darwin*)
37        os_darwin=yes
38        ;;
39 esac
40
41 # If CXXFLAGS and CFLAGS are unset, default to -O2
42 # This is to tell automake not to include '-g' if CXXFLAGS is not set
43 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
44 if test -z "$CXXFLAGS"; then
45    CXXFLAGS="-O2"
46 fi
47 if test -z "$CFLAGS"; then
48    CFLAGS="-O2"
49 fi
50
51 # programs
52 AC_DISABLE_STATIC
53 AM_PROG_LIBTOOL
54 AC_PROG_INSTALL
55 AM_PROG_CC_STDC
56 AC_PROG_CXX
57 AM_PROG_CC_C_O
58
59 # check for -fvisibility=hidden compiler support (GCC >= 4)
60 saved_CFLAGS="$CFLAGS"
61 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
62 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
63 AC_COMPILE_IFELSE([char foo;],
64       [ AC_MSG_RESULT([yes])
65         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
66         AC_MSG_RESULT([no]))
67 CFLAGS="$saved_CFLAGS"
68 AC_SUBST(SYMBOL_VISIBILITY)
69 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
70
71 AC_PATH_PROG(PERL, perl)
72 if test -z "$PERL"; then
73    AC_MSG_ERROR([You need 'perl' to compile WebKit])
74 fi
75
76 AC_PATH_PROG(BISON, bison)
77 if test -z "$BISON"; then
78    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
79 fi
80
81 AC_PATH_PROG(FLEX, flex)
82 if test -z "$FLEX"; then
83    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
84 fi
85
86 AC_PATH_PROG(GPERF, gperf)
87 if test -z "$GPERF"; then
88    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
89 fi
90
91 AC_PATH_PROG(MV, mv)
92 if test -z "$MV"; then
93    AC_MSG_ERROR([You need 'mv' to compile WebKit])
94 fi
95
96 # GTK+ port only
97 # Check for glib-genmarshal and glib-mkenums
98 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
99 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
100
101 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
102 # doesn't exist)
103 AC_LANG_PUSH([C++])
104 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
105 AC_LANG_POP([C++])
106
107 # C/C++ Language Features
108 AC_C_CONST
109 AC_C_INLINE
110 AC_C_VOLATILE
111
112 # C/C++ Headers
113 AC_HEADER_STDC
114 AC_HEADER_STDBOOL
115
116 # pthread (not needed on Windows)
117 if test "$os_win32" = "no"; then
118 AC_CHECK_HEADERS([pthread.h],
119                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exist]),
120                  AC_MSG_ERROR([pthread support is required to build WebKit]))
121 fi
122
123 # libjpeg headers
124 AC_CHECK_HEADERS([jpeglib.h])
125
126 # check for pkg-config
127 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
128 if test "$PKG_CONFIG" = "no"; then
129    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
130 fi
131
132 # determine the Unicode backend
133 AC_MSG_CHECKING([the Unicode backend to use])
134 AC_ARG_WITH(unicode_backend,
135             AC_HELP_STRING([--with-unicode-backend=@<:@icu@:>@],
136                            [Select Unicode backend [default=icu]]),
137             [],[unicode_backend="icu"])
138
139 case "$unicode_backend" in
140      icu) ;;
141      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu.]) ;;
142 esac
143
144 AC_MSG_RESULT([$unicode_backend])
145
146 if test "$unicode_backend" = "icu"; then
147         # check for icu-config
148         if test "$os_darwin" = "yes"; then
149                 UNICODE_CFLAGS="-I\$(srcdir)/JavaScriptCore/icu -I\$(srcdir)/WebCore/icu"
150                 UNICODE_LIBS="-licucore"
151         else
152                 AC_PATH_PROG(icu_config, icu-config, no)
153                 if test "$icu_config" = "no"; then
154                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
155                 fi
156
157                 # We don't use --cflags as this gives us a lot of things that we don't
158                 # necessarily want, like debugging and optimization flags
159                 # See man (1) icu-config for more info.
160                 UNICODE_CFLAGS=`$icu_config --cppflags`
161                 UNICODE_LIBS=`$icu_config --ldflags`
162         fi
163 fi
164
165 AC_SUBST([UNICODE_CFLAGS])
166 AC_SUBST([UNICODE_LIBS])
167
168 # determine the GDK/GTK+ target
169 AC_MSG_CHECKING([the target windowing system])
170 AC_ARG_WITH(target,
171             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
172                            [Select webkit target [default=x11]]),
173             [],[with_target="x11"])
174
175 case "$with_target" in
176      x11|win32|quartz|directfb) ;;
177      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
178 esac
179
180 AC_MSG_RESULT([$with_target])
181
182 AC_MSG_CHECKING([for Hildon UI extensions])
183 AC_ARG_WITH(hildon,
184             AC_HELP_STRING([--with-hildon],
185                            [Use Hildon UI extensions [default=no]]),
186             [],[with_hildon="no"])
187 AC_MSG_RESULT([$with_hildon])
188
189 if test "$with_hildon" = "yes"; then
190     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
191     PKG_CHECK_MODULES([HILDON], [hildon-1])
192     AC_SUBST([HILDON_CPPFLAGS])
193     AC_SUBST([HILDON_CFLAGS])
194     AC_SUBST([HILDON_LIBS])
195 fi
196
197 # determine the http backend
198 AC_MSG_CHECKING([the HTTP backend to use])
199 AC_ARG_WITH(http_backend,
200             AC_HELP_STRING([--with-http-backend=@<:@curl/soup@:>@],
201                            [Select HTTP backend [default=curl]]),
202             [],[with_http_backend="curl"])
203
204 case "$with_http_backend" in
205      curl|soup) ;;
206      *) AC_MSG_ERROR([Invalid HTTP backend: must be curl, soup.]) ;;
207 esac
208
209 AC_MSG_RESULT([$with_http_backend])
210
211 # minimum base dependencies
212 CAIRO_REQUIRED_VERSION=1.4
213 FONTCONFIG_REQUIRED_VERSION=2.4
214 FREETYPE2_REQUIRED_VERSION=9.0
215 LIBXML_REQUIRED_VERSION=2.6
216
217 # minimum GTK+ base dependencies
218 GLIB_REQUIRED_VERSION=2.0
219 GOBJECT_REQUIRED_VERSION=2.0
220 GTHREAD_REQUIRED_VERSION=2.0
221 PANGO_REQUIRED_VERSION=1.0
222 GTK_REQUIRED_VERSION=2.8
223
224 # optional modules
225 LIBCURL_REQUIRED_VERSION=7.15
226 LIBSOUP_REQUIRED_VERSION=2.4
227 LIBXSLT_REQUIRED_VERSION=1.1.7
228 SQLITE_REQUIRED_VERSION=3.0
229 GSTREAMER_REQUIRED_VERSION=0.10
230 GNOME_VFS_REQUIRED_VERSION=2.0
231
232 PKG_CHECK_MODULES([GLOBALDEPS],
233                   [glib-2.0 >= $GLIB_REQUIRED_VERSION
234                   gobject-2.0 >= $GOBJECT_REQUIRED_VERSION
235                   gthread-2.0 >= $GTHREAD_REQUIRED_VERSION])
236 AC_SUBST([GLOBALDEPS_CFLAGS])
237 AC_SUBST([GLOBALDEPS_LIBS])
238
239 PKG_CHECK_MODULES([WEBKITDEPS],
240                   [gtk+-2.0 >= $GTK_REQUIRED_VERSION
241                   pango >= $PANGO_REQUIRED_VERSION
242                   cairo >= $CAIRO_REQUIRED_VERSION
243                   cairo-ft,
244                   fontconfig >= $FONTCONFIG_REQUIRED_VERSION
245                   freetype2 >= $FREETYPE2_REQUIRED_VERSION
246                   libxml-2.0 >= $LIBXML_REQUIRED_VERSION])
247 AC_SUBST([WEBKITDEPS_CFLAGS])
248 AC_SUBST([WEBKITDEPS_LIBS])
249
250 # check whether to build with debugging enabled
251 AC_MSG_CHECKING([whether to do a debug build])
252 AC_ARG_ENABLE(debug,
253               AC_HELP_STRING([--enable-debug],
254                              [turn on debugging [default=no]]),
255               [],[enable_debug="no"])
256 AC_MSG_RESULT([$enable_debug])
257
258 # check whether to build with cross-document messaging support
259 AC_MSG_CHECKING([whether to enable HTML5 cross-document messaging support])
260 AC_ARG_ENABLE(cross_document_messaging,
261               AC_HELP_STRING([--enable-cross-document-messaging],
262                              [enable HTML5 cross-document messaging support [default=yes]]),
263               [],[enable_cross_document_messaging="yes"])
264 AC_MSG_RESULT([$enable_cross_document_messaging])
265
266 # check whether to enable HTML5 client-side session and persitent storage support
267 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
268 AC_ARG_ENABLE(dom_storage,
269               AC_HELP_STRING([--enable-dom-storage],
270                              [enable HTML5 client-side session and persistent storage support [default=no]]),
271               [],[enable_dom_storage="no"])
272 AC_MSG_RESULT([$enable_dom_storage])
273
274 # check whether to build with database support
275 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
276 AC_ARG_ENABLE(database,
277               AC_HELP_STRING([--enable-database],
278                              [enable HTML5 client-side database storage support [default=yes]]),
279               [],[enable_database="yes"])
280 AC_MSG_RESULT([$enable_database])
281
282 # check whether to build with icon database support
283 AC_MSG_CHECKING([whether to enable icon database support])
284 AC_ARG_ENABLE(icon_database,
285               AC_HELP_STRING([--enable-icon-database],
286                              [enable icon database [default=no]]),
287               [],[enable_icon_database="no"])
288 AC_MSG_RESULT([$enable_icon_database])
289
290 # check whether to enable HTML5 audio/video support
291 AC_MSG_CHECKING([whether to enable HTML5 video support])
292 AC_ARG_ENABLE(video,
293               AC_HELP_STRING([--enable-video],
294                              [enable HTML5 video support [default=no]]),
295               [],[enable_video="no"])
296 AC_MSG_RESULT([$enable_video])
297
298 # check whether to enable XPath support
299 AC_MSG_CHECKING([whether to enable XPath support])
300 AC_ARG_ENABLE(xpath,
301               AC_HELP_STRING([--enable-xpath],
302                              [enable support for XPath [default=yes]]),
303               [],[enable_xpath="yes"])
304 AC_MSG_RESULT([$enable_xpath])
305
306 # check whether to enable XSLT support
307 AC_MSG_CHECKING([whether to enable XSLT support])
308 AC_ARG_ENABLE(xslt,
309               AC_HELP_STRING([--enable-xslt],
310                              [enable support for XSLT [default=yes]]),
311               [],[enable_xslt="yes"])
312 AC_MSG_RESULT([$enable_xslt])
313
314 # check whether to enable SVG experimental features
315 # Enable all SVG if it is
316 AC_MSG_CHECKING([whether to enable SVG experimental features])
317 AC_ARG_ENABLE(svg_experimental,
318               AC_HELP_STRING([--enable-svg-experimental],
319                              [enable support for SVG experimental features [default=no]]),
320               [],[enable_svg_experimental="no"])
321 AC_MSG_RESULT([$enable_svg_experimental])
322
323 if test "$enable_svg_experimental" = "yes"; then
324    enable_svg=yes
325    enable_svg_animation=yes
326 #   enable_svg_filters=yes
327    enable_svg_fonts=yes
328    enable_svg_foreign_object=yes
329    enable_svg_as_image=yes
330    enable_svg_use_element=yes
331 fi
332
333 # check whether to enable SVG support
334 AC_MSG_CHECKING([whether to enable SVG support])
335 AC_ARG_ENABLE(svg,
336               AC_HELP_STRING([--enable-svg],
337                              [enable support for SVG [default=no]]),
338               [],[enable_svg="no"])
339 AC_MSG_RESULT([$enable_svg])
340
341 # check whether to enable support for SVG animation
342 AC_MSG_CHECKING([whether to enable support for SVG animation])
343 AC_ARG_ENABLE(svg_animation,
344               AC_HELP_STRING([--enable-svg-animation],
345                              [enable support for SVG animation (experimental) [default=no]]),
346               [],[enable_svg_animation="no"])
347 AC_MSG_RESULT([$enable_svg_animation])
348
349 # check whether to enable support for SVG filters
350 AC_MSG_CHECKING([whether to enable support for SVG filters])
351 AC_ARG_ENABLE(svg_filters,
352               AC_HELP_STRING([--enable-svg-filters],
353                              [enable support for SVG filters (experimental) [default=no]]),
354               [],[enable_svg_filters="no"])
355 AC_MSG_RESULT([$enable_svg_filters])
356
357 # check whether to enable support for SVG fonts
358 AC_MSG_CHECKING([whether to enable support for SVG fonts])
359 AC_ARG_ENABLE(svg_fonts,
360               AC_HELP_STRING([--enable-svg-fonts],
361                              [enable support for SVG fonts (experimental) [default=no]]),
362               [],[enable_svg_fonts="no"])
363 AC_MSG_RESULT([$enable_svg_fonts])
364
365 # check whether to enable foreign objects support for SVG
366 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
367 AC_ARG_ENABLE(svg_foreign_object,
368               AC_HELP_STRING([--enable-svg-foreign-object],
369                              [enable support for SVG foreign objects (experimental) [default=no]]),
370               [],[enable_svg_foreign_object="no"])
371 AC_MSG_RESULT([$enable_svg_foreign_object])
372
373 # check whether to enable SVG As Image support
374 AC_MSG_CHECKING([whether to enable SVG as Image support])
375 AC_ARG_ENABLE(svg_as_image,
376               AC_HELP_STRING([--enable-svg-as-image],
377                              [enable SVG as Image support (experimental) [default=no]]),
378               [],[enable_svg_as_image="no"])
379 AC_MSG_RESULT([$enable_svg_as_image])
380
381 # check whether to enable SVG USE element support
382 AC_MSG_CHECKING([whether to enable support for SVG use element])
383 AC_ARG_ENABLE(svg_use_element,
384               AC_HELP_STRING([--enable-svg-use-element],
385                              [enable SVG use element support (experimental) [default=no]]),
386               [],[enable_svg_use_element="no"])
387 AC_MSG_RESULT([$enable_svg_use_element])
388
389 # check whether to enable code coverage
390 AC_MSG_CHECKING([whether to enable code coverage support])
391 AC_ARG_ENABLE(coverage,
392               AC_HELP_STRING([--enable-coverage],
393                              [enable code coverage support [default=no]]),
394               [],[enable_coverage="no"])
395 AC_MSG_RESULT([$enable_coverage])
396
397 # check whether to enable FastMalloc
398 AC_MSG_CHECKING([whether to enable optimized memory allocator])
399 AC_ARG_ENABLE(fast_malloc,
400               AC_HELP_STRING([--enable-fast-malloc],
401                              [enable optimized memory allocator default=yes, default=no for debug builds]),
402               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
403 AC_MSG_RESULT([$enable_fast_malloc])
404
405 # determine the font backend
406 AC_MSG_CHECKING([the font backend to use])
407 AC_ARG_WITH(font_backend,
408             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
409                            [Select font backend [default=freetype]]),
410             [],[with_font_backend="freetype"])
411
412 case "$with_font_backend" in
413      freetype|pango) ;;
414      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
415 esac
416 AC_MSG_RESULT([$with_font_backend])
417
418 # Add '-g' flag to gcc if it's debug build
419 if test "$enable_debug" = "yes"; then
420    CXXFLAGS="$CXXFLAGS -g"
421    CFLAGS="$CFLAGS -g"
422 fi
423
424 # check if curl is available
425 if test "$with_http_backend" = "curl"; then
426    PKG_CHECK_MODULES([LIBCURL],
427                      [libcurl >= $LIBCURL_REQUIRED_VERSION])
428    AC_SUBST([LIBCURL_CFLAGS])
429    AC_SUBST([LIBCURL_LIBS])
430 fi
431
432 if test "$with_http_backend" = "soup"; then
433    PKG_CHECK_MODULES([LIBSOUP],
434                      [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
435    AC_SUBST([LIBSOUP_CFLAGS])
436    AC_SUBST([LIBSOUP_LIBS])
437 fi
438
439 # check if sqlite 3 is available
440 if test "$enable_icon_database" = "yes" || test "$enable_database" = "yes"; then
441    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
442    AC_SUBST([SQLITE3_CFLAGS])
443    AC_SUBST([SQLITE3_LIBS])
444 fi
445
446 # check if libxslt is available
447 if test "$enable_xslt" = "yes"; then
448    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
449    AC_SUBST([LIBXSLT_CFLAGS])
450    AC_SUBST([LIBXSLT_LIBS])
451 fi
452
453 # check if gstreamer is available
454 if test "$enable_video" = "yes"; then
455    PKG_CHECK_MODULES([GSTREAMER],
456                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
457                      gstreamer-base-0.10,
458                      gstreamer-plugins-base-0.10,
459                      gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED_VERSION])
460    AC_SUBST([GSTREAMER_CFLAGS])
461    AC_SUBST([GSTREAMER_LIBS])
462 fi
463
464 # check for code coverage support
465 if test "$enable_coverage" = "yes"; then
466    COVERAGE_CFLAGS="-MD"
467    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
468    AC_SUBST([COVERAGE_CFLAGS])
469    AC_SUBST([COVERAGE_LDFLAGS])
470 fi
471
472 # check for SVG features, enabling SVG if necessary
473 if test "$enable_svg_animation" = "yes" || \
474    test "$enable_svg_filters" = "yes" || \
475    test "$enable_svg_fonts" = "yes" || \
476    test "$enable_svg_foreign_object" = "yes" || \
477    test "$enable_svg_as_image" = "yes" || \
478    test "$enable_svg_use_element" = "yes"; then
479    svg_flags=yes
480    if test "$enable_svg" = "no"; then
481        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
482        enable_svg=yes
483    fi
484 fi
485
486 # OS conditionals
487 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
488 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
489 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
490 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
491
492 # target conditionals
493 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
494 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
495 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
496 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
497
498 # HTTP backend conditionals
499 AM_CONDITIONAL([USE_CURL], [test "$with_http_backend" = "curl"])
500 AM_CONDITIONAL([USE_SOUP], [test "$with_http_backend" = "soup"])
501
502 # Font backend conditionals
503 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
504 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
505
506 # WebKit feature conditionals
507 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
508 AM_CONDITIONAL([ENABLE_CROSS_DOCUMENT_MESSAGING],[test "$enable_cross_document_messaging" = "yes"])
509 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
510 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
511 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
512 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
513 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
514 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
515 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
516 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
517 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
518 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
519 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
520 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
521 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
522 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
523 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
524 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
525
526 AC_CONFIG_FILES([
527 GNUmakefile
528 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
529 ]
530 )
531
532 AC_OUTPUT
533
534 echo "
535 WebKit was configured with the following options:
536
537 Build configuration:
538  Enable debugging (slow)                                  : $enable_debug
539  Code coverage support                                    : $enable_coverage
540  Unicode backend                                          : $unicode_backend
541  HTTP backend                                             : $with_http_backend
542  Font backend                                             : $with_font_backend
543  Optimized memory allocator                               : $enable_fast_malloc
544 Features:
545  HTML5 cross-document messaging                           : $enable_cross_document_messaging
546  HTML5 client-side session and persistent storage support : $enable_dom_storage
547  HTML5 client-side database storage support               : $enable_database
548  HTML5 video element support                              : $enable_video
549  Icon database support                                    : $enable_icon_database
550  SVG support                                              : $enable_svg
551  SVG animation support                                    : $enable_svg_animation
552  SVG filters support                                      : $enable_svg_filters
553  SVG fonts support                                        : $enable_svg_fonts
554  SVG foreign object support                               : $enable_svg_foreign_object
555  SVG as image support                                     : $enable_svg_as_image
556  SVG use element support                                  : $enable_svg_use_element
557  XPATH support                                            : $enable_xpath
558  XSLT support                                             : $enable_xslt
559 GTK+ configuration:
560  GDK target                                               : $with_target
561  Hildon UI extensions                                     : $with_hildon
562 "