Implement CSS parsing for CSS transitions unprefixed.
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.60)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [11])
5 m4_define([webkit_micro_version], [2])
6
7 # This is the version we'll be using as part of our User-Agent string
8 # e.g., AppleWebKit/$(webkit_user_agent_version) ...
9 #
10 # Sourced from Source/WebCore/Configurations/Version.xcconfig
11 m4_define([webkit_user_agent_major_version], [537])
12 m4_define([webkit_user_agent_minor_version], [20])
13
14 AC_INIT([WebKitGTK],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
15
16 AC_CONFIG_MACRO_DIR([Source/autotools])
17 AC_CONFIG_AUX_DIR([Source/autotools])
18 AC_SUBST(ACLOCAL_AMFLAGS, "-I Source/autotools")
19
20 AC_CONFIG_HEADERS([autotoolsconfig.h])
21 AC_CANONICAL_HOST
22
23 WEBKIT_MAJOR_VERSION=webkit_major_version
24 WEBKIT_MINOR_VERSION=webkit_minor_version
25 WEBKIT_MICRO_VERSION=webkit_micro_version
26 WEBKIT_USER_AGENT_MAJOR_VERSION=webkit_user_agent_major_version
27 WEBKIT_USER_AGENT_MINOR_VERSION=webkit_user_agent_minor_version
28 AC_SUBST(WEBKIT_MAJOR_VERSION)
29 AC_SUBST(WEBKIT_MINOR_VERSION)
30 AC_SUBST(WEBKIT_MICRO_VERSION)
31 AC_SUBST(WEBKIT_USER_AGENT_MAJOR_VERSION)
32 AC_SUBST(WEBKIT_USER_AGENT_MINOR_VERSION)
33
34 AC_CONFIG_SRCDIR([Source/WebCore/config.h])
35
36 dnl # Libtool library version, not to confuse with API version
37 dnl # see http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
38 LIBWEBKITGTK_VERSION=17:1:17
39 AC_SUBST([LIBWEBKITGTK_VERSION])
40
41 LIBJAVASCRIPTCOREGTK_VERSION=13:7:13
42 AC_SUBST([LIBJAVASCRIPTCOREGTK_VERSION])
43
44 LIBWEBKIT2GTK_VERSION=19:0:19
45 AC_SUBST([LIBWEBKIT2GTK_VERSION])
46
47 AM_INIT_AUTOMAKE([foreign subdir-objects dist-xz no-dist-gzip tar-ustar])
48
49 # Use AM_SILENT_RULES if present
50 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
51
52 # host checking - inspired by the GTK+ configure.in
53 # TODO: move these to webkit.m4?
54 AC_MSG_CHECKING([for native Win32])
55 case "$host" in
56      *-*-mingw*)
57        os_win32=yes
58        ;;
59      *)
60        os_win32=no
61        ;;
62 esac
63 AC_MSG_RESULT([$os_win32])
64
65 case "$host" in
66      *-*-linux*)
67        os_linux=yes
68        ;;
69      *-*-freebsd*)
70        os_freebsd=yes
71        ;;
72      *-*-darwin*)
73        os_darwin=yes
74        ;;
75 esac
76
77 case "$host_os" in
78      gnu* | linux* | k*bsd*-gnu)
79        os_gnu=yes
80        ;;
81      *)
82        os_gnu=no
83        ;;
84 esac
85
86 # If CFLAGS and CXXFLAGS are unset, default to empty.
87 # This is to tell automake not to include '-g' if C{XX,}FLAGS is not set
88 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
89 if test -z "$CXXFLAGS"; then
90    CXXFLAGS=""
91 fi
92 if test -z "$CFLAGS"; then
93    CFLAGS=""
94 fi
95
96 PKG_PROG_PKG_CONFIG
97
98 AC_PATH_PROG(PERL, perl)
99 if test -z "$PERL"; then
100    AC_MSG_ERROR([You need 'perl' to compile WebKit])
101 fi
102
103 AC_PATH_PROG(PYTHON, python)
104 if test -z "$PYTHON"; then
105    AC_MSG_ERROR([You need 'python' to compile WebKit])
106 fi
107
108 AC_PATH_PROG(RUBY, ruby)
109 if test -z "$RUBY"; then
110    AC_MSG_ERROR([You need 'ruby' to compile WebKit])
111 fi
112
113 AC_PATH_PROG(BISON, bison)
114 if test -z "$BISON"; then
115    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
116 fi
117
118 AC_PATH_PROG(MV, mv)
119 if test -z "$MV"; then
120    AC_MSG_ERROR([You need 'mv' to compile WebKit])
121 fi
122
123 AC_PROG_CC
124 AC_PROG_CXX
125 AM_PROG_CC_C_O
126 AC_PROG_INSTALL
127 AC_SYS_LARGEFILE
128
129 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
130 # doesn't exist)
131 AC_LANG_PUSH([C++])
132 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
133 AC_LANG_POP([C++])
134
135 # C/C++ Language Features
136 AC_C_CONST
137 AC_C_INLINE
138 AC_C_VOLATILE
139
140 # C/C++ Headers
141 AC_HEADER_STDC
142 AC_HEADER_STDBOOL
143
144 # Linker
145 AC_DISABLE_STATIC
146 AC_LIBTOOL_WIN32_DLL
147 AC_PROG_LIBTOOL
148 # use dolt to speedup the build
149 DOLT
150
151 AC_PATH_PROG(FLEX, flex)
152 if test -z "$FLEX"; then
153    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
154 else
155    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
156    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
157       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
158 fi
159
160 AC_PATH_PROG(GPERF, gperf)
161 if test -z "$GPERF"; then
162    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
163 fi
164
165 # check for -fvisibility=hidden compiler support (GCC >= 4)
166 saved_CFLAGS="$CFLAGS"
167 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
168 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
169 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
170       [ AC_MSG_RESULT([yes])
171         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
172         AC_MSG_RESULT([no]))
173 CFLAGS="$saved_CFLAGS"
174 AC_SUBST(SYMBOL_VISIBILITY)
175 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
176
177 # Disable C++0x compat warnings for GCC >= 4.6.0 until we build
178 # cleanly with that.
179 AC_LANG_PUSH(C++)
180 TMPCXXFLAGS=$CXXFLAGS
181 CXXFLAGS="-Wall -Werror"
182 AC_MSG_CHECKING([if we have to disable C++0x compat warnings for GCC >= 4.6.0])
183 AC_TRY_COMPILE([
184 namespace std {
185     class nullptr_t { };
186 }
187 extern std::nullptr_t nullptr;
188 ], [return 0;],
189 disable_cxx0x_compat=no,
190 disable_cxx0x_compat=yes)
191 AC_MSG_RESULT($disable_cxx0x_compat)
192 if test "$disable_cxx0x_compat" = yes; then
193   CXXFLAGS="$TMPCXXFLAGS -Wno-c++0x-compat"
194 else
195   CXXFLAGS="$TMPCXXFLAGS"
196 fi
197 AC_LANG_POP(C++)
198
199 # pthread (not needed on Windows)
200 if test "$os_win32" = "no"; then
201 AC_CHECK_HEADERS([pthread.h],
202                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
203                  AC_MSG_ERROR([pthread support is required to build WebKit]))
204 AC_CHECK_LIB(pthread, pthread_rwlock_init,
205                  AC_DEFINE([HAVE_PTHREAD_RWLOCK],[1],[Define if pthread rwlock is present]),
206                  AC_MSG_WARN([pthread rwlock support is not available]))
207 fi
208
209 # check for libjpeg the way Gtk does it.
210 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
211                    jpeg_ok=yes, jpeg_ok=no
212                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
213 if test "$jpeg_ok" = yes; then
214    AC_MSG_CHECKING([for jpeglib])
215    AC_TRY_CPP(
216 [#include <stdio.h>
217 #undef PACKAGE
218 #undef VERSION
219 #undef HAVE_STDLIB_H
220 #include <jpeglib.h>],
221          jpeg_ok=yes,
222          jpeg_ok=no)
223    AC_MSG_RESULT($jpeg_ok)
224    if test "$jpeg_ok" = yes; then
225       JPEG_LIBS="-ljpeg"
226       # should we check for progressive JPEG like GTK+ as well?
227    else
228       AC_MSG_ERROR([JPEG library (libjpeg) not found])
229    fi
230 fi
231 AC_SUBST([JPEG_LIBS])
232
233 # Check for libpng the way Gtk+ does it
234 for l in libpng libpng14 libpng12; do
235   AC_MSG_CHECKING(for $l)
236   if $PKG_CONFIG --exists $l ; then
237     AC_MSG_RESULT(yes)
238     PNG_LIBS=`$PKG_CONFIG --libs $l`
239     png_ok=yes
240     break
241   else
242     AC_MSG_RESULT(no)
243     png_ok=no
244   fi
245 done
246 if test "$png_ok" != yes; then
247   AC_CHECK_LIB(png, png_read_info,
248     [AC_CHECK_HEADER(png.h,
249       png_ok=yes,
250       png_ok=no)],
251     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
252   if test "$png_ok" = yes; then
253     AC_MSG_CHECKING([for png_structp in png.h])
254     AC_TRY_COMPILE([#include <png.h>],
255       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
256       png_ok=yes,
257       png_ok=no)
258     AC_MSG_RESULT($png_ok)
259     if test "$png_ok" = yes; then
260       PNG_LIBS='-lpng -lz'
261     else
262       AC_MSG_ERROR([PNG library (libpng) not found])
263     fi
264   else
265     AC_MSG_ERROR([PNG library (libpng) not found])
266   fi
267 fi
268 AC_SUBST([PNG_LIBS])
269
270
271 if test "$os_win32" = "yes"; then
272   WINMM_LIBS=-lwinmm
273   SHLWAPI_LIBS=-lshlwapi
274   OLE32_LIBS=-lole32
275 fi
276 AC_SUBST([WINMM_LIBS])
277 AC_SUBST([SHLWAPI_LIBS])
278 AC_SUBST([OLE32_LIBS])
279
280
281 # determine the GTK+ version to use
282 AC_MSG_CHECKING([the GTK+ version to use])
283 AC_ARG_WITH([gtk],
284         [AS_HELP_STRING([--with-gtk=2.0|3.0], [the GTK+ version to use (default: 3.0)])],
285         [case "$with_gtk" in
286         2.0|3.0) ;;
287         *) AC_MSG_ERROR([invalid GTK+ version specified]) ;;
288         esac],
289         [with_gtk=3.0])
290 AC_MSG_RESULT([$with_gtk])
291
292 GTK2_REQUIRED_VERSION=2.10
293 GAIL2_REQUIRED_VERSION=1.8
294 GTK3_REQUIRED_VERSION=3.4.0
295 GAIL3_REQUIRED_VERSION=3.0
296
297 case "$with_gtk" in
298      2.0) GTK_REQUIRED_VERSION=$GTK2_REQUIRED_VERSION
299           GTK_API_VERSION=2.0
300           WEBKITGTK_API_MAJOR_VERSION=1
301           WEBKITGTK_API_MINOR_VERSION=0
302           WEBKITGTK_API_VERSION=1.0
303           WEBKITGTK_PC_NAME=webkit
304           GAIL_PC_NAME=gail
305           GAIL_REQUIRED_VERSION=$GAIL2_REQUIRED_VERSION
306           ;;
307      3.0) GTK_REQUIRED_VERSION=$GTK3_REQUIRED_VERSION
308           GTK_API_VERSION=3.0
309           WEBKITGTK_API_MAJOR_VERSION=3
310           WEBKITGTK_API_MINOR_VERSION=0
311           WEBKITGTK_API_VERSION=3.0
312           WEBKITGTK_PC_NAME=webkitgtk
313           GAIL_PC_NAME=gail-3.0
314           GAIL_REQUIRED_VERSION=$GAIL3_REQUIRED_VERSION
315           ;;
316 esac
317
318 AC_SUBST([WEBKITGTK_API_MAJOR_VERSION])
319 AC_SUBST([WEBKITGTK_API_MINOR_VERSION])
320 AC_SUBST([WEBKITGTK_API_VERSION])
321 AC_SUBST([WEBKITGTK_PC_NAME])
322 AC_SUBST([GTK_API_VERSION])
323 AM_CONDITIONAL([GTK_API_VERSION_2],[test "$GTK_API_VERSION" = "2.0"])
324
325 # determine the GDK/GTK+ target
326 AC_MSG_CHECKING([the target windowing system])
327 AC_ARG_WITH(target,
328             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
329                            [Select webkit target [default=x11]]),
330             [],[with_target="x11"])
331
332 case "$with_target" in
333      x11|win32|quartz|directfb) ;;
334      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
335 esac
336
337 AC_MSG_RESULT([$with_target])
338
339 # minimum base dependencies
340 CAIRO_REQUIRED_VERSION=1.10
341 FONTCONFIG_REQUIRED_VERSION=2.4
342 FREETYPE2_REQUIRED_VERSION=9.0
343 GLIB_REQUIRED_VERSION=2.32.0
344 LIBSOUP_REQUIRED_VERSION=2.40.0
345 LIBXML_REQUIRED_VERSION=2.6
346 PANGO_REQUIRED_VERSION=1.21.0
347
348 # optional modules
349 LIBXSLT_REQUIRED_VERSION=1.1.7
350 SQLITE_REQUIRED_VERSION=3.0
351 ENCHANT_REQUIRED_VERSION=0.22
352 CLUTTER_REQUIRED_VERSION=1.8.2
353 CLUTTER_GTK_REQUIRED_VERSION=1.0.2
354 ATSPI2_REQUIRED_VERSION=2.2.1
355
356 # Check for glib and required utilities
357 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION, :, :, gmodule gobject gthread gio)
358 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
359    AC_MSG_ERROR([You need the GLib dev tools in your path])
360 fi
361
362 # GResources
363 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG --variable glib_compile_resources gio-2.0`
364 AC_SUBST(GLIB_COMPILE_RESOURCES)
365
366 GLIB_GSETTINGS
367
368 # Check and identify which unicode backend to use
369 AC_MSG_CHECKING([which Unicode backend to use])
370 AC_ARG_WITH(unicode_backend,
371             AC_HELP_STRING([--with-unicode-backend=@<:@icu/glib@:>@],
372                            [Select Unicode backend (WARNING: the glib-based backend is slow, and incomplete) [default=icu]]),
373             [],[with_unicode_backend="icu"])
374
375 case "$with_unicode_backend" in
376      icu|glib) ;;
377      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu or glib.]) ;;
378 esac
379
380 AC_MSG_RESULT([$with_unicode_backend])
381
382 if test "$with_unicode_backend" = "icu"; then
383     # TODO: use pkg-config (after CFLAGS in their .pc files are cleaned up)
384     case "$host" in
385         *-*-darwin*)
386             UNICODE_CFLAGS="-I$srcdir/Source/JavaScriptCore/icu -I$srcdir/Source/WebCore/icu"
387             UNICODE_LIBS="-licucore"
388             ;;
389         *-*-mingw*)
390             UNICODE_CFLAGS=""
391             UNICODE_LIBS="-licui18n -licuuc"
392             ;;
393         *)
394             AC_PATH_PROG(icu_config, icu-config, no)
395             if test "$icu_config" = "no"; then
396                 AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
397             fi
398
399             # We don't use --cflags as this gives us a lot of things that we don't
400             # necessarily want, like debugging and optimization flags
401             # See man (1) icu-config for more info.
402             UNICODE_CFLAGS=`$icu_config --cppflags`
403             UNICODE_LIBS=`$icu_config --ldflags-libsonly`
404             ;;
405     esac
406 fi
407
408 if test "$with_unicode_backend" = "glib"; then
409     PKG_CHECK_MODULES([UNICODE], [glib-2.0 pango >= $PANGO_REQUIRED_VERSION])
410 fi
411
412 AC_SUBST([UNICODE_CFLAGS])
413 AC_SUBST([UNICODE_LIBS])
414
415 PKG_CHECK_MODULES([ZLIB], [zlib])
416 AC_SUBST([ZLIB_CFLAGS])
417 AC_SUBST([ZLIB_LIBS])
418
419 GETTEXT_PACKAGE=$PACKAGE-$GTK_API_VERSION
420 AC_SUBST(GETTEXT_PACKAGE)
421 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
422                    [The gettext catalog name])
423
424 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
425 AC_SUBST(LIBXML_CFLAGS)
426 AC_SUBST(LIBXML_LIBS)
427
428 PKG_CHECK_MODULES(PANGO, 
429                   [pango >= $PANGO_REQUIRED_VERSION
430                    pangoft2])
431 AC_SUBST(PANGO_CFLAGS)
432 AC_SUBST(PANGO_LIBS)
433
434 AC_MSG_CHECKING([whether to enable spellcheck support])
435 AC_ARG_ENABLE([spellcheck],
436   [AS_HELP_STRING([--enable-spellcheck],[enable support for spellcheck])],
437   [],[enable_spellcheck="yes"])
438 AC_MSG_RESULT([$enable_spellcheck])
439
440 if test "$enable_spellcheck" = "yes"; then
441 PKG_CHECK_MODULES(ENCHANT, enchant >= $ENCHANT_REQUIRED_VERSION, [], [enable_spellcheck="no"])
442 AC_SUBST(ENCHANT_CFLAGS)
443 AC_SUBST(ENCHANT_LIBS)
444 fi
445
446 PKG_CHECK_MODULES(GAIL, $GAIL_PC_NAME >= $GAIL_REQUIRED_VERSION)
447 AC_SUBST(GAIL_CFLAGS)
448 AC_SUBST(GAIL_LIBS)
449
450 # check for target-specific dependencies
451 if test "$with_target" = "directfb"; then
452    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
453    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
454    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
455 else
456    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
457    PKG_CHECK_MODULES(GTK, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED_VERSION)
458
459    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
460       # check for XT
461       PKG_CHECK_MODULES([XT],
462                         [xt],
463                         [xt_has_pkg_config=yes],
464                         [xt_has_pkg_config=no])
465       # some old versions of Xt do not provide xt.pc, so try to link against Xt
466       # and if it's installed fall back to just adding -lXt
467       if test "$xt_has_pkg_config" = "no"; then
468          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
469          # we don't care about the XtOpenDisplay symbol but only about the
470          # existence of libXt
471          AC_CHECK_LIB([Xt], [XtOpenDisplay],
472                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
473                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
474       fi
475       AC_SUBST([XT_CFLAGS])
476       AC_SUBST([XT_LIBS])
477       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
478    fi
479 fi
480 AC_SUBST(GTK_CFLAGS)
481 AC_SUBST(GTK_LIBS)
482 AC_SUBST(CAIRO_CFLAGS)
483 AC_SUBST(CAIRO_LIBS)
484
485 # check whether to build with debugging enabled
486 AC_MSG_CHECKING([whether to do a debug build])
487 AC_ARG_ENABLE(debug,
488               AC_HELP_STRING([--enable-debug],
489                              [turn on debugging [default=no]]),
490               [],[enable_debug="no"])
491 AC_MSG_RESULT([$enable_debug])
492
493 # check whether to enable optimized builds
494 AC_MSG_CHECKING([whether to enable optimized builds])
495 AC_ARG_ENABLE(optimizations,
496               AC_HELP_STRING([--enable-optimizations],
497                              [turn on optimize builds (GCC only)
498                              [default=yes]]),
499               [enable_optimizations=$enableval],
500               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
501 AC_MSG_RESULT([$enable_optimizations])
502
503 # check whether to enable unstable features
504 AC_MSG_CHECKING([whether to enable unstable features])
505 AC_ARG_ENABLE(unstable_features,
506               AC_HELP_STRING([--enable-unstable-features],
507                              [enable unstable features [default=no]]),
508               [],[enable_unstable_features="no"])
509 AC_MSG_RESULT([$enable_unstable_features])
510
511 found_opengl=no
512 AC_ARG_ENABLE(glx,
513               AC_HELP_STRING([--enable-glx], [enable support for GLX [default=auto]]),
514               [], [enable_glx="auto"])
515 AC_ARG_ENABLE(egl,
516               AC_HELP_STRING([--enable-egl], [enable support for EGL [default=auto]]),
517               [], [enable_egl="auto"])
518 AC_ARG_ENABLE(gles2,
519               AC_HELP_STRING([--enable-gles2], [enable support for OpenGL ES 2 [default=auto]]),
520               [], [enable_gles2="auto"])
521
522 have_glx=no
523 AC_CHECK_HEADERS([GL/glx.h], [have_glx="yes"], [have_glx="no"])
524 AC_MSG_CHECKING([whether to enable GLX support])
525 if test "$enable_glx" != "no"; then
526    if test "$have_glx" = "no"; then
527       if test "$enable_glx" = "yes"; then
528          AC_MSG_ERROR([--enable-glx specified, but not available])
529       else
530          enable_glx=no
531       fi
532    elif test "$enable_gles2" != "yes"; then
533       enable_glx=yes
534    fi
535 fi
536 AC_MSG_RESULT([$enable_glx])
537
538 have_egl=no
539 AC_CHECK_HEADERS([EGL/egl.h], [have_egl="yes"], [have_egl="no"])
540 AC_MSG_CHECKING([whether to enable EGL support])
541 if test "$enable_egl" != "no"; then
542    if test "$have_egl" = "no"; then
543       if test "$enable_egl" = "yes"; then
544          AC_MSG_ERROR([--enable-egl specified, but not available])
545       else
546          enable_egl=no
547       fi
548    else
549       enable_egl=yes
550    fi
551 fi
552 AC_MSG_RESULT([$enable_egl])
553
554 have_gles2=no
555 AC_CHECK_HEADERS([GLES2/gl2.h], [have_gles2="yes"], [have_gles2="no"])
556 AC_MSG_CHECKING([whether to use OpenGL ES 2 support])
557 if test "$enable_glx" = "yes"; then
558    if test "$enable_gles2" = "yes"; then
559       AC_MSG_ERROR([Cannot enable OpenGL ES 2 support with GLX])
560    else
561       enable_gles2=no
562    fi
563 fi
564 if test "$enable_egl" = "no"; then
565    if test "$enable_gles2" = "yes"; then
566       AC_MSG_ERROR([Cannot enable OpenGL ES 2 support without EGL])
567    else
568       enable_gles2=no
569    fi
570 fi
571 if test "$enable_gles2" != "no"; then
572    if test "$have_gles2" = "no"; then
573       if test "$enable_gles2" = "yes"; then
574          AC_MSG_ERROR([--enable-gles2 specified, but not available])
575       else
576          enable_gles2=no
577       fi
578    else
579       enable_gles2=yes
580       found_opengl=yes
581    fi
582 fi
583 AC_MSG_RESULT([$enable_gles2])
584
585 if test "$enable_gles2" != "yes"; then
586     AC_CHECK_HEADERS([GL/gl.h], [found_opengl="yes"], [])
587 fi
588
589 AC_MSG_CHECKING([which GPU acceleration backend to use])
590 AC_ARG_WITH(acceleration_backend,
591             AC_HELP_STRING([--with-acceleration-backend=@<:@opengl/clutter/none@:>@],
592                            [Select accelerated backend (Clutter currently unsupported, OpenGL autodetected) [default=autodetect]]), [],
593                            [
594                                 if test "$found_opengl" = "yes"; then
595                                    with_acceleration_backend="opengl";
596                                 else
597                                    with_acceleration_backend="none";
598                                 fi
599                            ])
600 AC_MSG_RESULT([$with_acceleration_backend])
601
602 if test "$with_acceleration_backend" = "opengl"; then
603     PKG_CHECK_MODULES([XCOMPOSITE], [xcomposite]);
604     PKG_CHECK_MODULES([XDAMAGE], [xdamage]);
605     AC_SUBST(XCOMPOSITE_CFLAGS)
606     AC_SUBST(XCOMPOSITE_LIBS)
607     AC_SUBST(XDAMAGE_CFLAGS)
608     AC_SUBST(XDAMAGE_LIBS)
609 fi
610
611 # OpenGL is turned on by default (along with WebGL and accelerated compositing), but if
612 # Clutter is chosen as the accelerated drawing backend, we want to disable it. COGL does 
613 # not play well with OpenGL.
614 AC_MSG_CHECKING([whether to enable WebGL support])
615 AC_ARG_ENABLE(webgl,
616               AC_HELP_STRING([--enable-webgl], [enable support for WebGL [default=check]]), [],
617               [
618                 if test "$with_acceleration_backend" = "opengl"; then
619                     enable_webgl="yes";
620                 else
621                     enable_webgl="no";
622                 fi
623              ])
624 AC_MSG_RESULT([$enable_webgl])
625 if test "$enable_webgl" = "yes" && test "$with_acceleration_backend" != "opengl"; then
626     AC_MSG_ERROR([OpenGL must be active (and Clutter disabled) to use WebGL.])
627 fi;
628
629 AC_MSG_CHECKING([whether to enable accelerated compositing support])
630 AC_ARG_ENABLE(accelerated_compositing,
631             AC_HELP_STRING([--enable-accelerated-compositing], [enable support for accelerated compositing [default=check]]),
632             [
633                 if test "$enableval" = "yes" && test "$with_acceleration_backend" = "none"; then
634                     AC_MSG_ERROR([OpenGL or Clutter must be active to use accelerated compositing.])
635                 fi
636                 enable_accelerated_compositing=$enableval;
637             ],
638             [
639                 if test "$with_acceleration_backend" != "none"; then
640                     enable_accelerated_compositing="yes";
641                 else
642                     enable_accelerated_compositing="no";
643                 fi
644             ])
645 AC_MSG_RESULT([$enable_accelerated_compositing])
646
647 # check whether to enable Gamepad support
648 AC_MSG_CHECKING([whether to enable Gamepad support])
649 AC_ARG_ENABLE(gamepad,
650               AC_HELP_STRING([--enable-gamepad],
651                              [enable Gamepad support [default=no]]),
652               [],[enable_gamepad=$enable_unstable_features])
653 AC_MSG_RESULT([$enable_gamepad])
654
655 if test "$enable_gamepad" = "yes" && test "$os_linux" = no; then
656    AC_MSG_WARN([Gamepad support is only available on Linux. Disabling Gamepad support.])
657    enable_gamepad=no;
658 fi
659
660 # check whether to enable HTML5 audio/video support
661 AC_MSG_CHECKING([whether to enable HTML5 video support])
662 AC_ARG_ENABLE(video,
663               AC_HELP_STRING([--enable-video],
664                              [enable HTML5 video support [default=yes]]),
665               [],[enable_video="yes"])
666 AC_MSG_RESULT([$enable_video])
667
668 # check whether to enable media stream support
669 AC_MSG_CHECKING([whether to enable media stream support])
670 AC_ARG_ENABLE(media_stream,
671               AC_HELP_STRING([--enable-media-stream],
672                              [enable media stream support (incomplete) [default=no]]),
673               [],[enable_media_stream=$enable_unstable_features])
674 AC_MSG_RESULT([$enable_media_stream])
675
676 # check whether to enable XSLT support
677 AC_MSG_CHECKING([whether to enable XSLT support])
678 AC_ARG_ENABLE(xslt,
679               AC_HELP_STRING([--enable-xslt],
680                              [enable support for XSLT [default=yes]]),
681               [],[enable_xslt="yes"])
682 AC_MSG_RESULT([$enable_xslt])
683
684 # check whether to enable unprefixed support for CSS Transforms, Animations and Transitions
685 AC_MSG_CHECKING([whether to enable support for unprefixed CSS Transforms, Animations and Transitions])
686 AC_ARG_ENABLE(xslt,
687               AC_HELP_STRING([--enable-unprefixed-css-transforms-animations-transitions],
688                              [enable support for for unprefixed CSS Transforms, Animations and Transitions [default=yes]]),
689               [],[enable_css_transforms_animations_transitions_unprefixed="yes"])
690 AC_MSG_RESULT([$enable_css_transforms_animations_transitions_unprefixed])
691
692 # check whether to enable geolocation support
693 AC_MSG_CHECKING([whether to enable geolocation support])
694 AC_ARG_ENABLE(geolocation,
695               AC_HELP_STRING([--enable-geolocation],
696                              [enable support for geolocation [default=yes]]),
697               [],[enable_geolocation="yes"])
698 AC_MSG_RESULT([$enable_geolocation])
699
700 # check whether to enable SVG support
701 AC_MSG_CHECKING([whether to enable SVG support])
702 AC_ARG_ENABLE(svg,
703               AC_HELP_STRING([--enable-svg],
704                              [enable support for SVG [default=yes]]),
705               [],[enable_svg="yes"])
706 AC_MSG_RESULT([$enable_svg])
707
708 # turn off svg features if --disable-svg is requested
709 if test "$enable_svg" = "no"; then
710    enable_svg_fonts=no
711 fi
712
713 # check whether to enable support for SVG fonts
714 AC_MSG_CHECKING([whether to enable support for SVG fonts])
715 AC_ARG_ENABLE(svg_fonts,
716               AC_HELP_STRING([--enable-svg-fonts],
717                              [enable support for SVG fonts (experimental) [default=yes]]),
718               [],[enable_svg_fonts="yes"])
719 AC_MSG_RESULT([$enable_svg_fonts])
720
721 # check for SVG features, enabling SVG if necessary
722 if test "$enable_svg_fonts" = "yes" && test "$enable_svg" = "no"; then
723    AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
724    enable_svg=yes
725 fi
726
727 # check whether to enable Web Audio support
728 AC_MSG_CHECKING([whether to enable Web Audio support])
729 AC_ARG_ENABLE(web_audio,
730               AC_HELP_STRING([--enable-web-audio],
731                              [enable support for Web Audio [default=no]]),
732               [],[enable_web_audio="no"])
733 AC_MSG_RESULT([$enable_web_audio])
734
735 # check whether to enable code coverage
736 AC_MSG_CHECKING([whether to enable code coverage support])
737 AC_ARG_ENABLE(coverage,
738               AC_HELP_STRING([--enable-coverage],
739                              [enable code coverage support [default=no]]),
740               [],[enable_coverage="no"])
741 AC_MSG_RESULT([$enable_coverage])
742
743 # check whether to enable FastMalloc
744 AC_MSG_CHECKING([whether to enable optimized memory allocator])
745 AC_ARG_ENABLE(fast_malloc,
746               AC_HELP_STRING([--enable-fast-malloc],
747                              [enable optimized memory allocator default=yes, default=no for debug builds]),
748               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
749 AC_MSG_RESULT([$enable_fast_malloc])
750
751 # check whether to enable debug symbols
752 AC_MSG_CHECKING([whether to enable debug symbols])
753 AC_ARG_ENABLE(debug_symbols,
754               AC_HELP_STRING([--enable-debug-symbols=yes|no|min|full],
755                              [enable debug symbols default=no, default=yes for debug builds]),
756               [],[if test "$enable_debug" = "yes"; then enable_debug_symbols="yes"; else enable_debug_symbols="no"; fi])
757
758 case "$enable_debug_symbols" in
759   yes) enable_debug_symbols="full" ;;
760   no|min|full) ;;
761   *) AC_MSG_ERROR([Invalid debug symbols option: must be yes, no, min or full.]) ;;
762 esac
763 AC_MSG_RESULT([$enable_debug_symbols])
764
765 #selecting GStreamer version
766 AC_MSG_CHECKING([the GStreamer version to use])
767 AC_ARG_WITH([gstreamer],
768         [AS_HELP_STRING([--with-gstreamer=1.0|0.10|auto], [the GStreamer version to use (default: auto, tries 1.0 first, 0.10 is fallback)])],
769         [case "$with_gstreamer" in
770         0.10|1.0|auto) ;;
771         *) AC_MSG_ERROR([invalid GStreamer version specified]) ;;
772         esac],
773         [with_gstreamer=auto])
774 AC_MSG_RESULT([$with_gstreamer])
775
776 GSTREAMER_0_10_REQUIRED_VERSION=0.10
777 GSTREAMER_0_10_PLUGINS_BASE_REQUIRED_VERSION=0.10.30
778 GSTREAMER_1_0_REQUIRED_VERSION=1.0.3
779 GSTREAMER_1_0_PLUGINS_BASE_REQUIRED_VERSION=1.0.3
780
781 if test "$enable_video" = "yes" || test "$enable_web_audio" = "yes"; then
782    if test "$with_gstreamer" = "auto"; then
783        gstreamer_modules="gstreamer-1.0 >= $GSTREAMER_1_0_REQUIRED_VERSION
784                           gstreamer-app-1.0
785                           gstreamer-audio-1.0
786                           gstreamer-fft-1.0
787                           gstreamer-base-1.0
788                           gstreamer-pbutils-1.0
789                           gstreamer-plugins-base-1.0 >= $GSTREAMER_1_0_PLUGINS_BASE_REQUIRED_VERSION
790                           gstreamer-video-1.0";
791        PKG_CHECK_MODULES([GSTREAMER_1_0], [$gstreamer_modules], [with_gstreamer=1.0], [with_gstreamer=0.10])
792        AC_MSG_NOTICE([Selected GStreamer $with_gstreamer])
793    fi
794 else
795    if test "$with_gstreamer" != "auto"; then
796        AC_MSG_WARN([You have specified GStreamer $with_gstreamer version but it will not be used because neither HTML5 Video nor Web Audio are enabled])
797    fi
798 fi
799
800 case "$with_gstreamer" in
801      0.10) GSTREAMER_REQUIRED_VERSION=$GSTREAMER_0_10_REQUIRED_VERSION
802            GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION=$GSTREAMER_0_10_PLUGINS_BASE_REQUIRED_VERSION
803            GST_API_VERSION=0.10
804            ;;
805      1.0) GSTREAMER_REQUIRED_VERSION=$GSTREAMER_1_0_REQUIRED_VERSION
806            GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION=$GSTREAMER_1_0_PLUGINS_BASE_REQUIRED_VERSION
807            GST_API_VERSION=1.0
808            ;;
809 esac
810
811 AC_SUBST([GST_API_VERSION])
812 if test "$GST_API_VERSION" = "1.0"; then
813    AC_DEFINE([GST_API_VERSION_1],[1], [Using GStreamer 1.0])
814 fi
815
816 # check whether to enable debug features
817 AC_MSG_CHECKING([whether to enable debug features])
818 AC_ARG_ENABLE(debug_features,
819               AC_HELP_STRING([--enable-debug-features],
820                              [enable debug features default=no, default=yes for debug builds]),
821               [],[if test "$enable_debug" = "yes"; then enable_debug_features="yes"; else enable_debug_features="no"; fi])
822 AC_MSG_RESULT([$enable_debug_features])
823
824 AC_MSG_CHECKING([whether to enable JIT compilation])
825 AC_ARG_ENABLE(jit,
826               AS_HELP_STRING([--enable-jit],
827                              [Enable JIT compilation (default: autodetect)]))
828 case "$enable_jit" in
829   yes) JSC_CPPFLAGS="-DENABLE_JIT=1" ;;
830   no) JSC_CPPFLAGS="-DENABLE_JIT=0" ;;
831   *) enable_jit="autodetect" ;;
832 esac
833 AC_SUBST(JSC_CPPFLAGS)
834 AC_MSG_RESULT([$enable_jit])
835
836 # Opcode stats
837 AC_MSG_CHECKING([whether to enable opcode stats])
838 AC_ARG_ENABLE([opcode-stats],
839   [AS_HELP_STRING([--enable-opcode-stats], [Enable Opcode statistics (default: disabled)])],
840   [], [enable_opcode_stats=no])
841 AC_MSG_RESULT([$enable_opcode_stats])
842
843 if test "$enable_opcode_stats" = "yes"; then
844   if test "$enable_jit" = "yes"; then
845     AC_MSG_ERROR([JIT must be disabled for Opcode stats to work.])
846   fi
847   AC_DEFINE([ENABLE_OPCODE_STATS], [1], [Define to enable Opcode statistics])
848 fi
849
850 # GObject Introspection
851 AC_MSG_CHECKING([whether to enable GObject introspection support])
852 AC_ARG_ENABLE([introspection],
853   [AS_HELP_STRING([--enable-introspection],[Enable GObject introspection (default: disabled)])],
854   [],[enable_introspection=no])
855 AC_MSG_RESULT([$enable_introspection])
856
857 # Enable CSS Filters and Shaders if unstable_features and accelerated_compositing are turned on.
858 enable_css_filters=no;
859 enable_css_shaders=no;
860 AC_MSG_CHECKING([whether to enable CSS Filters and Shaders])
861 if test "$enable_unstable_features" = "yes" && test "$enable_accelerated_compositing" = "yes" && test "$with_acceleration_backend" = "opengl"; then
862     enable_css_filters=yes;
863     enable_css_shaders=yes;
864 fi
865 AC_MSG_RESULT([$enable_css_filters])
866
867 G_IR_SCANNER=
868 G_IR_COMPILER=
869 G_IR_GENERATE=
870 GIRDIR=
871 GIRTYPELIBDIR=
872
873 if test "$enable_introspection" = "yes"; then
874   GOBJECT_INTROSPECTION_REQUIRED=0.9.5
875   PKG_CHECK_MODULES([INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
876   
877   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
878   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
879   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
880   AC_DEFINE([ENABLE_INTROSPECTION],[1],[Define to enable GObject introspection support])
881 fi
882
883 AC_SUBST([G_IR_SCANNER])
884 AC_SUBST([G_IR_COMPILER])
885 AC_SUBST([G_IR_GENERATE])
886
887 if test "$host_cpu" = "sh4"; then
888    CXXFLAGS="$CXXFLAGS -mieee -w"
889    CFLAGS="$CFLAGS -mieee -w"
890 fi
891
892 # Add '-g' flag to gcc to build with debug symbols
893 if test "$enable_debug_symbols" = "min"; then
894    CXXFLAGS="$CXXFLAGS -g1"
895    CFLAGS="$CFLAGS -g1"
896 elif test "$enable_debug_symbols" != "no"; then
897    CXXFLAGS="$CXXFLAGS -g"
898    CFLAGS="$CFLAGS -g"
899 fi
900
901 if test "$enable_debug_features" = "no"; then
902    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
903 fi
904
905 # Add the appropriate 'O' level for optimized builds
906 if test "$enable_optimizations" = "yes"; then
907    CXXFLAGS="$CXXFLAGS -O2"
908    CFLAGS="$CFLAGS -O2"
909 else
910    CXXFLAGS="$CXXFLAGS -O0"
911    CFLAGS="$CFLAGS -O0"
912 fi
913
914 PKG_CHECK_MODULES([LIBSOUP],
915                   [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
916 AC_SUBST([LIBSOUP_CFLAGS])
917 AC_SUBST([LIBSOUP_LIBS])
918
919 PKG_CHECK_MODULES([LIBSECRET], [libsecret-1])
920 AC_SUBST([LIBSECRET_CFLAGS])
921 AC_SUBST([LIBSECRET_LIBS])
922
923 # check if FreeType/FontConfig are available
924 if test "$with_target" = "directfb"; then
925 PKG_CHECK_MODULES([FREETYPE],
926                   [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
927                   freetype2 >= $FREETYPE2_REQUIRED_VERSION
928                   harfbuzz])
929 else
930 PKG_CHECK_MODULES([FREETYPE],
931                   [cairo-ft
932                   fontconfig >= $FONTCONFIG_REQUIRED_VERSION
933                   freetype2 >= $FREETYPE2_REQUIRED_VERSION
934                   harfbuzz])
935 fi
936 AC_SUBST([FREETYPE_CFLAGS])
937 AC_SUBST([FREETYPE_LIBS])
938
939 # check if SQLite3 is available. Error out only if one of the
940 # features hard-depending on it is enabled while SQLite3 is
941 # unavailable.
942 PKG_CHECK_MODULES([SQLITE3],
943                   [sqlite3 >= $SQLITE_REQUIRED_VERSION],
944                   [sqlite3_has_pkg_config=yes],
945                   [sqlite3_has_pkg_config=no])
946 if test "$sqlite3_has_pkg_config" = "no"; then
947    AC_SEARCH_LIBS([sqlite3_open16], [sqlite3],
948                   [sqlite3_found=yes;SQLITE3_LIBS="$LIBS";SQLITE3_CFLAGS="-I $srcdir/WebKitLibraries/WebCoreSQLite3"],
949                   [sqlite3_found=no])
950 fi
951 AC_SUBST([SQLITE3_CFLAGS])
952 AC_SUBST([SQLITE3_LIBS])
953
954 if (test "$sqlite3_found" = "no"); then
955    AC_MSG_ERROR([SQLite3 is required for the Database related features])
956 fi
957
958 # check if libxslt is available
959 if test "$enable_xslt" = "yes"; then
960    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
961    AC_SUBST([LIBXSLT_CFLAGS])
962    AC_SUBST([LIBXSLT_LIBS])
963 fi
964
965 # check if geoclue is available
966 if test "$enable_geolocation" = "yes"; then
967     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
968     AC_SUBST([GEOCLUE_CFLAGS])
969     AC_SUBST([GEOCLUE_LIBS])
970 fi
971
972 # check for XRender under Linux/Unix. Some linkers require explicit
973 # linkage (like GNU Gold), so we cannot rely on GTK+ pulling XRender
974 if test "$os_win32" = "no"; then
975    PKG_CHECK_MODULES([XRENDER], [xrender])
976    AC_SUBST([XRENDER_CFLAGS])
977    AC_SUBST([XRENDER_LIBS])
978 fi
979
980 # check if gstreamer is available
981 if test "$enable_video" = "yes" || test "$enable_web_audio" = "yes"; then
982     gstreamer_modules="gstreamer-$GST_API_VERSION >= $GSTREAMER_REQUIRED_VERSION
983                        gstreamer-app-$GST_API_VERSION
984                        gstreamer-audio-$GST_API_VERSION
985                        gstreamer-fft-$GST_API_VERSION
986                        gstreamer-base-$GST_API_VERSION
987                        gstreamer-pbutils-$GST_API_VERSION
988                        gstreamer-plugins-base-$GST_API_VERSION >= $GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION
989                        gstreamer-video-$GST_API_VERSION";
990    if test "$GST_API_VERSION" != "1.0"; then
991        gstreamer_modules="$gstreamer_modules gstreamer-interfaces-$GST_API_VERSION";
992    fi
993    PKG_CHECK_MODULES([GSTREAMER], [$gstreamer_modules], [have_gstreamer=yes])
994    AC_SUBST([GSTREAMER_CFLAGS])
995    AC_SUBST([GSTREAMER_LIBS])
996 fi
997
998 # farstream-0.1 depends on gstreamer 0.10 currently. Disable
999 # media_stream if gstreamer 1.0 build support is enabled.
1000 if test "$have_gstreamer" != "yes" || test "$GST_API_VERSION" = "1.0"; then
1001    if test "$enable_media_stream" = "yes"; then
1002       AC_MSG_WARN([Disabling Media Stream because no GStreamer 0.10 support is enabled])
1003    fi
1004    enable_media_stream=false
1005 fi
1006 if test "$enable_media_stream" = "yes"; then
1007    PKG_CHECK_MODULES([FARSTREAM], [farstream-0.1],
1008                      [have_farstream=yes], [enable_media_stream=false])
1009    AC_SUBST([FARSTREAM_CFLAGS])
1010    AC_SUBST([FARSTREAM_LIBS])
1011 fi
1012
1013 acceleration_backend_description=$with_acceleration_backend
1014 if test "$with_acceleration_backend" = "clutter"; then
1015    PKG_CHECK_MODULES(CLUTTER, clutter-1.0 >= $CLUTTER_REQUIRED_VERSION)
1016    PKG_CHECK_MODULES([CLUTTER_GTK],
1017                      [clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED_VERSION])
1018
1019    AC_SUBST(CLUTTER_CFLAGS)
1020    AC_SUBST(CLUTTER_LIBS)
1021    AC_SUBST(CLUTTER_GTK_CFLAGS)
1022    AC_SUBST(CLUTTER_GTK_LIBS)
1023
1024    enable_gles2=no
1025    enable_glx=no
1026    enable_egl=no
1027 fi
1028
1029 if test "$with_acceleration_backend" = "opengl"; then
1030    if test "$enable_gles2" = "yes"; then
1031     acceleration_backend_description+= "(gles2"
1032     OPENGL_LIBS="-lGLESv2"
1033    else
1034     acceleration_backend_description+="(gl"
1035     OPENGL_LIBS="-lGL"
1036    fi
1037    if test "$enable_egl" = "yes"; then
1038     acceleration_backend_description+=", egl"
1039     OPENGL_LIBS+=" -lEGL"
1040    fi
1041    if test "$enable_glx" = "yes"; then
1042     acceleration_backend_description+=", glx"
1043    fi
1044    OPENGL_LIBS+=" -ldl"
1045    acceleration_backend_description+=")"
1046 fi
1047 AC_SUBST([OPENGL_LIBS])
1048
1049 if test "$enable_gamepad" = "yes"; then
1050    PKG_CHECK_MODULES([GAMEPAD], [gio-unix-2.0 gudev-1.0])
1051
1052    AC_SUBST(GAMEPAD_CFLAGS)
1053    AC_SUBST(GAMEPAD_LIBS)
1054 fi
1055
1056 # check for code coverage support
1057 if test "$enable_coverage" = "yes"; then
1058    COVERAGE_CFLAGS="-MD"
1059    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
1060    AC_SUBST([COVERAGE_CFLAGS])
1061    AC_SUBST([COVERAGE_LDFLAGS])
1062 fi
1063
1064 # WebKit2
1065 # If you change the default here, please also make sure the assumptions made
1066 # in Tools/Scripts/webkitdirs.pm:buildAutotoolsProject still make sense.
1067 AC_MSG_CHECKING([whether to build Webkit2])
1068 AC_ARG_ENABLE(webkit2,
1069     AC_HELP_STRING([--enable-webkit2], [build webkit2 [default=yes]]),
1070     [], [enable_webkit2="yes"])
1071 AC_MSG_RESULT([$enable_webkit2])
1072 if test "$enable_webkit2" = "yes"; then
1073    if test "$GTK_API_VERSION" = "2.0"; then
1074       AC_MSG_ERROR([WebKit2 requires GTK+ 3.x, use --with-gtk=3.0])
1075    fi
1076
1077    # Check Unix printing
1078    PKG_CHECK_MODULES(GTK_UNIX_PRINTING, gtk+-unix-print-3.0,
1079                      [have_gtk_unix_printing=yes],
1080                      [have_gtk_unix_printing=no])
1081    AC_SUBST(GTK_UNIX_PRINTING_CFLAGS)
1082    AC_SUBST(GTK_UNIX_PRINTING_LIBS)
1083    if test "$have_gtk_unix_printing" = "yes"; then
1084        AC_DEFINE([HAVE_GTK_UNIX_PRINTING], [1], [Define if GTK+ UNIX Printing is available])
1085    fi
1086
1087    # On some Linux/Unix platforms, shm_* may only be available if linking
1088    # against librt
1089    if test "$os_win32" = "no"; then
1090        AC_SEARCH_LIBS([shm_open], [rt], [SHM_LIBS="-lrt"])
1091        AC_SUBST(SHM_LIBS)
1092    fi
1093 fi
1094
1095 # Plugin Process
1096 AC_MSG_CHECKING([whether to build plugin process for WebKit2])
1097 AC_ARG_ENABLE(plugin_process,
1098             AC_HELP_STRING([--enable-plugin-process], [build plugin process for WebKit2 [default=yes]]),
1099                            [], [enable_plugin_process="yes"])
1100 AC_MSG_RESULT([$enable_plugin_process])
1101
1102 # Build the plugin process only when building Webkit2.
1103 if test "$enable_webkit2" = "no"; then
1104     enable_plugin_process=no
1105 fi
1106
1107 # Make sure we have GTK+ 2.x to build the plugin process.
1108 if test "$enable_plugin_process" = "yes"; then
1109    PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= $GTK2_REQUIRED_VERSION gail >= $GAIL2_REQUIRED_VERSION)
1110 fi
1111 AC_SUBST(GTK2_CFLAGS)
1112 AC_SUBST(GTK2_LIBS)
1113
1114 GTK_DOC_CHECK([1.10])
1115
1116 # We need atspi2 for Webkit2 unit tests
1117 if test "$enable_webkit2" = "yes"; then
1118    PKG_CHECK_MODULES([ATSPI2],
1119                      [atspi-2 >= $ATSPI2_REQUIRED_VERSION],
1120                      [have_atspi2=yes], [have_atspi2=no])
1121
1122    AC_SUBST([ATSPI2_CFLAGS])
1123    AC_SUBST([ATSPI2_LIBS])
1124 fi
1125
1126 # OS conditionals
1127 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
1128 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
1129 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
1130 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
1131 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
1132
1133 # target conditionals
1134 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
1135 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
1136 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
1137 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
1138
1139 # Unicode backend conditionals
1140 AM_CONDITIONAL([USE_ICU_UNICODE], [test "$with_unicode_backend" = "icu"])
1141 AM_CONDITIONAL([USE_GLIB_UNICODE], [test "$with_unicode_backend" = "glib"])
1142
1143 # GStreamer feature conditional
1144 AM_CONDITIONAL([USE_GSTREAMER], [test "$have_gstreamer" = "yes"])
1145 AM_CONDITIONAL([USE_WEBAUDIO_GSTREAMER], [test "$enable_web_audio" = "yes"])
1146
1147 # ATSPI2 conditional
1148 AM_CONDITIONAL([HAVE_ATSPI2], [test "$have_atspi2" = "yes"])
1149
1150 # Accelerated compositing conditional
1151 AM_CONDITIONAL([USE_ACCELERATED_COMPOSITING], [test "$enable_accelerated_compositing" = "yes"])
1152 AM_CONDITIONAL([USE_TEXTURE_MAPPER_CAIRO], [test "$enable_accelerated_compositing" = "yes" && test "$with_acceleration_backend" = "none"])
1153 AM_CONDITIONAL([USE_TEXTURE_MAPPER_GL], [test "$enable_accelerated_compositing" = "yes" && test "$with_acceleration_backend" = "opengl"])
1154 AM_CONDITIONAL([USE_CLUTTER], [test "$with_acceleration_backend" = "clutter"])
1155
1156 # These are the same now, but they will soon be separate.
1157 AM_CONDITIONAL([USE_OPENGL], [test "$with_acceleration_backend" = "opengl"])
1158 AM_CONDITIONAL([USE_EGL], [test "$enable_egl" = "yes"])
1159 AM_CONDITIONAL([USE_GLES2], [test "$enable_gles2" = "yes"])
1160 AM_CONDITIONAL([USE_GLX], [test "$enable_glx" = "yes"])
1161
1162 # Farstream feature conditional
1163 AM_CONDITIONAL([USE_FARSTREAM], [test "$have_farstream" = "yes"])
1164
1165 # WebKit feature conditionals
1166 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug_features" = "yes"])
1167 AM_CONDITIONAL([ENABLE_UNSTABLE_FEATURES],[test "$enable_unstable_features" = "yes"])
1168 AM_CONDITIONAL([ENABLE_WEBGL],[test "$enable_webgl" = "yes"])
1169 AM_CONDITIONAL([ENABLE_GAMEPAD],[test "$enable_gamepad" = "yes"])
1170 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
1171 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
1172 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
1173 AM_CONDITIONAL([ENABLE_MEDIA_STREAM],[test "$enable_media_stream" = "yes"])
1174 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
1175 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
1176 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
1177 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
1178 AM_CONDITIONAL([ENABLE_WEB_AUDIO],[test "$enable_web_audio" = "yes"])
1179 AM_CONDITIONAL([ENABLE_OPCODE_STATS],[test "$enable_opcode_stats" = "yes"])
1180 AM_CONDITIONAL([ENABLE_WEBKIT2],[test "$enable_webkit2" = "yes"])
1181 AM_CONDITIONAL([ENABLE_PLUGIN_PROCESS],[test "$enable_plugin_process" = "yes"])
1182 AM_CONDITIONAL([ENABLE_SPELLCHECK],[test "$enable_spellcheck" = "yes"])
1183 AM_CONDITIONAL([ENABLE_CSS_FILTERS],[test "$enable_css_filters" = "yes"])
1184 AM_CONDITIONAL([ENABLE_CSS_SHADERS],[test "$enable_css_shaders" = "yes"])
1185 AM_CONDITIONAL([ENABLE_CSS_TRANSFORMS_ANIMATIONS_TRANSITIONS_UNPREFIXED],[test "$enable_css_transforms_animations_transitions_unprefixed" = "yes"])
1186
1187 # Gtk conditionals
1188 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
1189
1190 AC_CONFIG_FILES([
1191 GNUmakefile
1192 ])
1193  
1194
1195 AC_CONFIG_FILES([
1196 Source/WebKit/gtk/webkit/webkitversion.h
1197 Source/WebKit/gtk/po/POTFILES
1198 DerivedSources/WebCore/UserAgentGtk.h:Source/WebCore/platform/gtk/UserAgentGtk.h.in
1199 ])
1200
1201 AC_CONFIG_FILES([
1202 Source/WebKit/gtk/${WEBKITGTK_PC_NAME}-${WEBKITGTK_API_VERSION}.pc:Source/WebKit/gtk/webkit.pc.in
1203 Source/WebKit/gtk/JSCore-${WEBKITGTK_API_VERSION}.gir:Source/WebKit/gtk/JSCore.gir.in
1204 Source/JavaScriptCore/javascriptcoregtk-${WEBKITGTK_API_VERSION}.pc:Source/JavaScriptCore/javascriptcoregtk.pc.in
1205 ]
1206 ,[WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME]
1207 )
1208
1209
1210 if test "$enable_webkit2" = "yes"; then
1211     AC_CONFIG_FILES([
1212     DerivedSources/WebKit2/webkit2gtk/webkit2/WebKitVersion.h:Source/WebKit2/UIProcess/API/gtk/WebKitVersion.h.in
1213     ])
1214
1215     AC_CONFIG_FILES([
1216     Source/WebKit2/webkit2gtk-${WEBKITGTK_API_VERSION}.pc:Source/WebKit2/webkit2gtk.pc.in
1217     ]
1218     ,[WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME]
1219     )
1220 fi
1221
1222 AC_OUTPUT
1223
1224 echo "
1225 WebKit was configured with the following options:
1226
1227 Build configuration:
1228  Enable debugging (slow)                                  : $enable_debug
1229  Compile with debug symbols (slow)                        : $enable_debug_symbols
1230  Enable debug features (slow)                             : $enable_debug_features
1231  Enable GCC build optimization                            : $enable_optimizations
1232  Code coverage support                                    : $enable_coverage
1233  Unicode backend                                          : $with_unicode_backend
1234  Optimized memory allocator                               : $enable_fast_malloc
1235  Accelerated rendering backend                            : $acceleration_backend_description
1236
1237 Features:
1238 =======
1239  Accelerated Compositing                                  : $enable_accelerated_compositing
1240  Gamepad support                                          : $enable_gamepad
1241  Geolocation support                                      : $enable_geolocation
1242  HTML5 video element support                              : $enable_video
1243  JIT compilation                                          : $enable_jit
1244  Media stream support                                     : $enable_media_stream
1245  Opcode stats                                             : $enable_opcode_stats
1246  SVG fonts support                                        : $enable_svg_fonts
1247  SVG support                                              : $enable_svg
1248  Spellcheck support                                       : $enable_spellcheck
1249  Unprefixed support for CSS Transforms, animations and transtions : enable_css_transforms_animations_transitions_unprefixed
1250  Web Audio support                                        : $enable_web_audio
1251  WebGL                                                    : $enable_webgl
1252  XSLT support                                             : $enable_xslt
1253
1254 WebKit2 support:
1255  WebKit2 support                                          : $enable_webkit2
1256  WebKit2 plugin process                                   : $enable_plugin_process
1257
1258 GTK+ configuration:
1259  GTK+ version                                             : $with_gtk
1260  GDK target                                               : $with_target
1261  GStreamer version                                        : $with_gstreamer
1262  Introspection support                                    : $enable_introspection
1263  Generate documentation                                   : $enable_gtk_doc
1264 "
1265 if test "$with_unicode_backend" = "glib"; then
1266    echo "     >> WARNING: the glib-based unicode backend is slow and incomplete <<"
1267    echo
1268    echo
1269 fi