2010-08-12 Gustavo Noronha Silva <gustavo.noronha@collabora.co.uk>
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.59)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [3])
5 m4_define([webkit_micro_version], [3])
6
7 # This is the version we'll be using as part of our User-Agent string
8 # e.g., AppleWebKit/$(webkit_user_agent_version) ...
9 #
10 # Sourced from WebCore/Configurations/Version.xcconfig
11 m4_define([webkit_user_agent_major_version], [531])
12 m4_define([webkit_user_agent_minor_version], [2])
13
14 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
15
16 AC_CONFIG_MACRO_DIR([autotools])
17 AC_CONFIG_AUX_DIR([autotools])
18 AC_SUBST(ACLOCAL_AMFLAGS, "-I autotools")
19
20 AC_CONFIG_HEADERS([autotoolsconfig.h])
21 AC_CANONICAL_HOST
22
23 WEBKIT_MAJOR_VERSION=webkit_major_version
24 WEBKIT_MINOR_VERSION=webkit_minor_version
25 WEBKIT_MICRO_VERSION=webkit_micro_version
26 WEBKIT_USER_AGENT_MAJOR_VERSION=webkit_user_agent_major_version
27 WEBKIT_USER_AGENT_MINOR_VERSION=webkit_user_agent_minor_version
28 AC_SUBST(WEBKIT_MAJOR_VERSION)
29 AC_SUBST(WEBKIT_MINOR_VERSION)
30 AC_SUBST(WEBKIT_MICRO_VERSION)
31 AC_SUBST(WEBKIT_USER_AGENT_MAJOR_VERSION)
32 AC_SUBST(WEBKIT_USER_AGENT_MINOR_VERSION)
33
34 AC_CONFIG_SRCDIR([WebCore/config.h])
35
36 dnl # Libtool library version, not to confuse with API version
37 dnl # see http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html#Libtool-versioning
38 LIBWEBKITGTK_VERSION=0:1:0
39 AC_SUBST([LIBWEBKITGTK_VERSION])
40
41 AM_INIT_AUTOMAKE([foreign subdir-objects tar-ustar])
42
43 # Use AM_SILENT_RULES if present
44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
45
46 # host checking - inspired by the GTK+ configure.in
47 # TODO: move these to webkit.m4?
48 AC_MSG_CHECKING([for native Win32])
49 case "$host" in
50      *-*-mingw*)
51        os_win32=yes
52        ;;
53      *)
54        os_win32=no
55        ;;
56 esac
57 AC_MSG_RESULT([$os_win32])
58
59 case "$host" in
60      *-*-linux*)
61        os_linux=yes
62        ;;
63      *-*-freebsd*)
64        os_freebsd=yes
65        ;;
66      *-*-darwin*)
67        os_darwin=yes
68        ;;
69 esac
70
71 case "$host_os" in
72      gnu* | linux* | k*bsd*-gnu)
73        os_gnu=yes
74        ;;
75      *)
76        os_gnu=no
77        ;;
78 esac
79
80 # initialize webkit options
81 WEBKIT_INIT
82 AC_DISABLE_STATIC
83 AC_LIBTOOL_WIN32_DLL
84 AC_PROG_LIBTOOL
85 # use dolt to speedup the build
86 DOLT
87
88 AC_PATH_PROG(FLEX, flex)
89 if test -z "$FLEX"; then
90    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
91 else
92    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
93    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
94       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
95 fi
96
97 AC_PATH_PROG(GPERF, gperf)
98 if test -z "$GPERF"; then
99    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
100 fi
101
102 # pthread (not needed on Windows)
103 if test "$os_win32" = "no"; then
104 AC_CHECK_HEADERS([pthread.h],
105                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
106                  AC_MSG_ERROR([pthread support is required to build WebKit]))
107 fi
108
109 # check for libjpeg the way Gtk does it.
110 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
111                    jpeg_ok=yes, jpeg_ok=no
112                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
113 if test "$jpeg_ok" = yes; then
114    AC_MSG_CHECKING([for jpeglib])
115    AC_TRY_CPP(
116 [#include <stdio.h>
117 #undef PACKAGE
118 #undef VERSION
119 #undef HAVE_STDLIB_H
120 #include <jpeglib.h>],
121          jpeg_ok=yes,
122          jpeg_ok=no)
123    AC_MSG_RESULT($jpeg_ok)
124    if test "$jpeg_ok" = yes; then
125       JPEG_LIBS="-ljpeg"
126       # should we check for progressive JPEG like GTK+ as well?
127    else
128       AC_MSG_ERROR([JPEG library (libjpeg) not found])
129    fi
130 fi
131 AC_SUBST([JPEG_LIBS])
132
133 # Check for libpng the way Gtk+ does it
134 for l in libpng libpng14 libpng12; do
135   AC_MSG_CHECKING(for $l)
136   if $PKG_CONFIG --exists $l ; then
137     AC_MSG_RESULT(yes)
138     PNG_LIBS=`$PKG_CONFIG --libs $l`
139     png_ok=yes
140     break
141   else
142     AC_MSG_RESULT(no)
143     png_ok=no
144   fi
145 done
146 if test "$png_ok" != yes; then
147   AC_CHECK_LIB(png, png_read_info,
148     [AC_CHECK_HEADER(png.h,
149       png_ok=yes,
150       png_ok=no)],
151     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
152   if test "$png_ok" = yes; then
153     AC_MSG_CHECKING([for png_structp in png.h])
154     AC_TRY_COMPILE([#include <png.h>],
155       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
156       png_ok=yes,
157       png_ok=no)
158     AC_MSG_RESULT($png_ok)
159     if test "$png_ok" = yes; then
160       PNG_LIBS='-lpng -lz'
161     else
162       AC_MSG_ERROR([PNG library (libpng) not found])
163     fi
164   else
165     AC_MSG_ERROR([PNG library (libpng) not found])
166   fi
167 fi
168 AC_SUBST([PNG_LIBS])
169
170 # determine the GTK+ version to use
171 AC_MSG_CHECKING([the GTK+ version to use])
172 AC_ARG_WITH([gtk],
173         [AS_HELP_STRING([--with-gtk=2.0|3.0], [the GTK+ version to use (default: 2.0)])],
174         [case "$with_gtk" in
175         2.0|3.0) ;;
176         *) AC_MSG_ERROR([invalid GTK+ version specified]) ;;
177         esac],
178         [with_gtk=2.0])
179 AC_MSG_RESULT([$with_gtk])
180
181 case "$with_gtk" in
182      2.0) GTK_REQUIRED_VERSION=2.10
183           GTK_API_VERSION=2.0
184           WEBKITGTK_API_MAJOR_VERSION=1
185           WEBKITGTK_API_MINOR_VERSION=0
186           WEBKITGTK_API_VERSION=1.0
187           WEBKITGTK_PC_NAME=webkit
188           GAIL_PC_NAME=gail
189           GAIL_REQUIRED_VERSION=1.8
190           ;;
191      3.0) GTK_REQUIRED_VERSION=2.90
192           GTK_API_VERSION=3.0
193           WEBKITGTK_API_MAJOR_VERSION=3
194           WEBKITGTK_API_MINOR_VERSION=0
195           WEBKITGTK_API_VERSION=3.0
196           WEBKITGTK_PC_NAME=webkitgtk
197           GAIL_PC_NAME=gail-3.0
198           GAIL_REQUIRED_VERSION=2.90.4
199           ;;
200 esac
201
202 AC_SUBST([WEBKITGTK_API_MAJOR_VERSION])
203 AC_SUBST([WEBKITGTK_API_MINOR_VERSION])
204 AC_SUBST([WEBKITGTK_API_VERSION])
205 AC_SUBST([WEBKITGTK_PC_NAME])
206 AC_SUBST([GTK_API_VERSION])
207 AM_CONDITIONAL([GTK_API_VERSION_2],[test "$GTK_API_VERSION" = "2.0"])
208
209 # determine the GDK/GTK+ target
210 AC_MSG_CHECKING([the target windowing system])
211 AC_ARG_WITH(target,
212             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
213                            [Select webkit target [default=x11]]),
214             [],[with_target="x11"])
215
216 case "$with_target" in
217      x11|win32|quartz|directfb) ;;
218      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
219 esac
220
221 AC_MSG_RESULT([$with_target])
222
223 AC_MSG_CHECKING([for Hildon UI extensions])
224 AC_ARG_WITH(hildon,
225             AC_HELP_STRING([--with-hildon],
226                            [Use Hildon UI extensions [default=no]]),
227             [],[with_hildon="no"])
228 AC_MSG_RESULT([$with_hildon])
229
230 if test "$with_hildon" = "yes"; then
231     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
232     PKG_CHECK_MODULES([HILDON], [hildon-1])
233     AC_SUBST([HILDON_CPPFLAGS])
234     AC_SUBST([HILDON_CFLAGS])
235     AC_SUBST([HILDON_LIBS])
236 fi
237
238 # minimum base dependencies
239 LIBSOUP_REQUIRED_VERSION=2.28.2
240 CAIRO_REQUIRED_VERSION=1.6
241 FONTCONFIG_REQUIRED_VERSION=2.4
242 FREETYPE2_REQUIRED_VERSION=9.0
243 LIBXML_REQUIRED_VERSION=2.6
244
245 # minimum GTK+ base dependencies
246 PANGO_REQUIRED_VERSION=1.12
247
248 # optional modules
249 LIBXSLT_REQUIRED_VERSION=1.1.7
250 SQLITE_REQUIRED_VERSION=3.0
251 GSTREAMER_REQUIRED_VERSION=0.10
252 GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION=0.10.25
253 ENCHANT_REQUIRED_VERSION=0.22
254
255 # Available modules
256 #
257 # glib - glib and includes gthread
258 # unicode - check and identify which unicode backend to use
259 #
260 # todo: webcore gtk
261 WEBKIT_CHECK_DEPENDENCIES([glib unicode])
262
263 # Check if we can use GSettings
264 PKG_CHECK_MODULES([GSETTINGS],
265                   [gio-2.0 >= 2.25.0],
266                   [have_gsettings=yes],
267                   [have_gsettings=no])
268 if test "$have_gsettings" = "yes"; then
269    AC_DEFINE([HAVE_GSETTINGS], 1, [Whether we can use GSettings])
270 fi
271
272 GETTEXT_PACKAGE=$PACKAGE-$GTK_API_VERSION
273 AC_SUBST(GETTEXT_PACKAGE)
274 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
275                    [The gettext catalog name])
276
277 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
278 AC_SUBST(LIBXML_CFLAGS)
279 AC_SUBST(LIBXML_LIBS)
280
281 PKG_CHECK_MODULES(PANGO, 
282                   [pango >= $PANGO_REQUIRED_VERSION
283                    pangoft2])
284 AC_SUBST(PANGO_CFLAGS)
285 AC_SUBST(PANGO_LIBS)
286
287 PKG_CHECK_MODULES(ENCHANT, enchant >= $ENCHANT_REQUIRED_VERSION)
288 AC_SUBST(ENCHANT_CFLAGS)
289 AC_SUBST(ENCHANT_LIBS)
290
291 PKG_CHECK_MODULES(GAIL, $GAIL_PC_NAME >= $GAIL_REQUIRED_VERSION)
292 AC_SUBST(GAIL_CFLAGS)
293 AC_SUBST(GAIL_LIBS)
294
295 # check for target-specific dependencies
296 if test "$with_target" = "directfb"; then
297    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
298    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
299    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
300 else
301    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
302    PKG_CHECK_MODULES(GTK, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED_VERSION)
303
304    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
305       # check for XT
306       PKG_CHECK_MODULES([XT],
307                         [xt],
308                         [xt_has_pkg_config=yes],
309                         [xt_has_pkg_config=no])
310       # some old versions of Xt do not provide xt.pc, so try to link against Xt
311       # and if it's installed fall back to just adding -lXt
312       if test "$xt_has_pkg_config" = "no"; then
313          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
314          # we don't care about the XtOpenDisplay symbol but only about the
315          # existence of libXt
316          AC_CHECK_LIB([Xt], [XtOpenDisplay],
317                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
318                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
319       fi
320       AC_SUBST([XT_CFLAGS])
321       AC_SUBST([XT_LIBS])
322       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
323    fi
324 fi
325 AC_SUBST(GTK_CFLAGS)
326 AC_SUBST(GTK_LIBS)
327 AC_SUBST(CAIRO_CFLAGS)
328 AC_SUBST(CAIRO_LIBS)
329
330 # check whether to build with debugging enabled
331 AC_MSG_CHECKING([whether to do a debug build])
332 AC_ARG_ENABLE(debug,
333               AC_HELP_STRING([--enable-debug],
334                              [turn on debugging [default=no]]),
335               [],[enable_debug="no"])
336 AC_MSG_RESULT([$enable_debug])
337
338 # check whether to enable optimized builds
339 AC_MSG_CHECKING([whether to enable optimized builds])
340 AC_ARG_ENABLE(optimizations,
341               AC_HELP_STRING([--enable-optimizations],
342                              [turn on optimize builds (GCC only)
343                              [default=yes]]),
344               [enable_optimizations=$enableval],
345               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
346 AC_MSG_RESULT([$enable_optimizations])
347
348 # check whether to enable 3D transforms support
349 AC_MSG_CHECKING([whether to enable support for 3D Transforms])
350 AC_ARG_ENABLE(3D_transforms,
351               AC_HELP_STRING([--enable-3D-transforms],
352                              [enable support for 3D transforms [default=no]]),
353               [],[enable_3D_transforms="no"])
354 AC_MSG_RESULT([$enable_3D_transforms])
355
356 # check whether to enable channel messaging support
357 AC_MSG_CHECKING([whether to enable HTML5 Channel Messaging support])
358 AC_ARG_ENABLE(channel_messaging,
359               AC_HELP_STRING([--enable-channel-messaging],
360                              [enable HTML5 channel messaging support [default=yes]]),
361               [],[enable_channel_messaging="yes"])
362 AC_MSG_RESULT([$enable_channel_messaging])
363
364 # check whether to enable JavaScript debugger/profiler support
365 AC_MSG_CHECKING([whether to enable JavaScript debugger/profiler support])
366 AC_ARG_ENABLE(javascript_debugger,
367               AC_HELP_STRING([--enable-javascript-debugger],
368                              [enable JavaScript debugger/profiler support [default=yes]]),
369               [],[enable_javascript_debugger="yes"])
370 AC_MSG_RESULT([$enable_javascript_debugger])
371
372 # check whether to enable HTML5 Offline Web Applications support
373 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
374 AC_ARG_ENABLE(offline_web_applications,
375               AC_HELP_STRING([--enable-offline-web-applications],
376                              [enable HTML5 offline web applications support [default=yes]]),
377               [],[enable_offline_web_applications="yes"])
378 AC_MSG_RESULT([$enable_offline_web_applications])
379
380 # check whether to enable HTML5 client-side session and persitent storage support
381 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
382 AC_ARG_ENABLE(dom_storage,
383               AC_HELP_STRING([--enable-dom-storage],
384                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
385               [],[enable_dom_storage="yes"])
386 AC_MSG_RESULT([$enable_dom_storage])
387
388 # check whether to enable the indexed database API
389 AC_MSG_CHECKING([whether to enable the indexed database API])
390 AC_ARG_ENABLE(indexed_database,
391               AC_HELP_STRING([--enable-indexeddb],
392                              [enable the indexed database API [default=no]]),
393               [],[enable_indexed_database="no"])
394 AC_MSG_RESULT([$enable_indexed_database])
395
396 # check whether to enable the speech input API
397 AC_MSG_CHECKING([whether to enable the speech input API])
398 AC_ARG_ENABLE(input_speech,
399               AC_HELP_STRING([--enable-input-speech],
400                              [enable the speech input API [default=no]]),
401               [],[enable_input_speech="no"])
402 AC_MSG_RESULT([$enable_input_speech])
403
404 # check whether to build with database support
405 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
406 AC_ARG_ENABLE(database,
407               AC_HELP_STRING([--enable-database],
408                              [enable HTML5 client-side database storage support [default=yes]]),
409               [],[enable_database="yes"])
410 AC_MSG_RESULT([$enable_database])
411
412 # check whether to build with server-sent events support
413 AC_MSG_CHECKING([whether to enable HTML5 server-sent events support])
414 AC_ARG_ENABLE(eventsource,
415               AC_HELP_STRING([--enable-eventsource],
416                              [enable HTML5 server-sent events support [default=yes]]),
417               [],[enable_eventsource="yes"])
418 AC_MSG_RESULT([$enable_eventsource])
419
420 # check whether to build with icon database support
421 AC_MSG_CHECKING([whether to enable icon database support])
422 AC_ARG_ENABLE(icon_database,
423               AC_HELP_STRING([--enable-icon-database],
424                              [enable icon database [default=yes]]),
425               [],[enable_icon_database="yes"])
426 AC_MSG_RESULT([$enable_icon_database])
427
428 # check whether to build with image resizer API support
429 AC_MSG_CHECKING([whether to enable image resizer API support])
430 AC_ARG_ENABLE(image_resizer,
431               AC_HELP_STRING([--enable-image-resizer],
432                              [enable image resizer [default=no]]),
433               [],[enable_image_resizer="no"])
434 AC_MSG_RESULT([$enable_image_resizer])
435
436 # check whether to enable HTML5 datalist support
437 AC_MSG_CHECKING([whether to enable HTML5 datalist support])
438 AC_ARG_ENABLE(datalist,
439               AC_HELP_STRING([--enable-datalist],
440                              [enable HTML5 datalist support [default=yes]]),
441               [],[enable_datalist="yes"])
442 AC_MSG_RESULT([$enable_datalist])
443
444 # check whether to enable HTML5 ruby support
445 AC_MSG_CHECKING([whether to enable HTML5 ruby support])
446 AC_ARG_ENABLE(ruby,
447               AC_HELP_STRING([--enable-ruby],
448                              [enable HTML5 ruby support [default=yes]]),
449               [],[enable_ruby="yes"])
450 AC_MSG_RESULT([$enable_ruby])
451
452 # check whether to enable HTML5 sandbox iframe support
453 AC_MSG_CHECKING([whether to enable HTML5 sandboxed iframe support])
454 AC_ARG_ENABLE(sandbox,
455               AC_HELP_STRING([--enable-sandbox],
456                              [enable HTML5 sandboxed iframe support [default=yes]]),
457               [],[enable_sandbox="yes"])
458 AC_MSG_RESULT([$enable_sandbox])
459
460 # check whether to enable HTML5 audio/video support
461 AC_MSG_CHECKING([whether to enable HTML5 video support])
462 AC_ARG_ENABLE(video,
463               AC_HELP_STRING([--enable-video],
464                              [enable HTML5 video support [default=yes]]),
465               [],[enable_video="yes"])
466 AC_MSG_RESULT([$enable_video])
467
468 # check whether to enable XHTML-MP support
469 AC_MSG_CHECKING([whether to enable XHTML-MP support])
470 AC_ARG_ENABLE(xhtmlmp,
471               AC_HELP_STRING([--enable-xhtmlmp],
472                              [enable support for XHTML-MP [default=no]]),
473               [],[enable_xhtmlmp="no"])
474 AC_MSG_RESULT([$enable_xhtmlmp])
475
476 # check whether to enable XPath support
477 AC_MSG_CHECKING([whether to enable XPath support])
478 AC_ARG_ENABLE(xpath,
479               AC_HELP_STRING([--enable-xpath],
480                              [enable support for XPath [default=yes]]),
481               [],[enable_xpath="yes"])
482 AC_MSG_RESULT([$enable_xpath])
483
484 # check whether to enable XSLT support
485 AC_MSG_CHECKING([whether to enable XSLT support])
486 AC_ARG_ENABLE(xslt,
487               AC_HELP_STRING([--enable-xslt],
488                              [enable support for XSLT [default=yes]]),
489               [],[enable_xslt="yes"])
490 AC_MSG_RESULT([$enable_xslt])
491
492 # check whether to enable geolocation support
493 AC_MSG_CHECKING([whether to enable geolocation support])
494 AC_ARG_ENABLE(geolocation,
495               AC_HELP_STRING([--enable-geolocation],
496                              [enable support for geolocation [default=no]]),
497               [],[enable_geolocation="no"])
498 AC_MSG_RESULT([$enable_geolocation])
499
500 # check whether to enable MathML support
501 AC_MSG_CHECKING([whether to enable MathML support])
502 AC_ARG_ENABLE(mathml,
503               AC_HELP_STRING([--enable-mathml],
504                              [enable support for MathML [default=no]]),
505               [],[enable_mathml="no"])
506 AC_MSG_RESULT([$enable_mathml])
507
508 # check whether to enable SVG support
509 AC_MSG_CHECKING([whether to enable SVG support])
510 AC_ARG_ENABLE(svg,
511               AC_HELP_STRING([--enable-svg],
512                              [enable support for SVG [default=yes]]),
513               [],[enable_svg="yes"])
514 AC_MSG_RESULT([$enable_svg])
515
516 # check whether to enable WML support
517 AC_MSG_CHECKING([whether to enable WML support])
518 AC_ARG_ENABLE(wml,
519               AC_HELP_STRING([--enable-wml],
520                              [enable support for WML [default=no]]),
521               [],[enable_wml="no"])
522 AC_MSG_RESULT([$enable_wml])
523
524 # check whether to enable SharedWorkers support
525 AC_MSG_CHECKING([whether to enable SharedWorkers support])
526 AC_ARG_ENABLE(shared_workers,
527               AC_HELP_STRING([--enable-shared-workers],
528                              [enable support for SharedWorkers [default=yes]]),
529               [],[enable_shared_workers="yes"])
530 AC_MSG_RESULT([$enable_shared_workers])
531
532 # check whether to enable Web Workers support
533 AC_MSG_CHECKING([whether to enable Web Workers support])
534 AC_ARG_ENABLE(workers,
535               AC_HELP_STRING([--enable-workers],
536                              [enable support for Web Workers [default=yes]]),
537               [],[enable_workers="yes"])
538 AC_MSG_RESULT([$enable_workers])
539
540 # check whether to enable directory upload support
541 AC_MSG_CHECKING([whether to enable directory upload support])
542 AC_ARG_ENABLE(directory_upload,
543               AC_HELP_STRING([--enable-directory-upload],
544                              [enable support for directory upload [default=no]]),
545               [], [enable_directory_upload="no"])
546 AC_MSG_RESULT([$enable_directory_upload])
547
548 # check whether to enable HTML5 FileSystem API support
549 AC_MSG_CHECKING([whether to enable HTML5 FileSystem API support])
550 AC_ARG_ENABLE(file_system,
551               AC_HELP_STRING([--enable-file-system],
552                              [enable support for HTML5 FileSystem API [default=no]]),
553               [], [enable_file_system="no"])
554 AC_MSG_RESULT([$enable_file_system])
555
556 # turn off svg features if --disable-svg is requested
557 if test "$enable_svg" = "no"; then
558    enable_svg_animation=no
559    enable_svg_fonts=no
560    enable_svg_foreign_object=no
561    enable_svg_as_image=no
562    enable_svg_use=no
563 fi
564
565 # check whether to enable support for SVG animation
566 AC_MSG_CHECKING([whether to enable support for SVG animation])
567 AC_ARG_ENABLE(svg_animation,
568               AC_HELP_STRING([--enable-svg-animation],
569                              [enable support for SVG animation (experimental) [default=yes]]),
570               [],[enable_svg_animation="yes"])
571 AC_MSG_RESULT([$enable_svg_animation])
572
573 # check whether to enable support for filters
574 AC_MSG_CHECKING([whether to enable support for filters])
575 AC_ARG_ENABLE(filters,
576               AC_HELP_STRING([--enable-filters],
577                              [enable support for filters (experimental) [default=yes]]),
578               [],[enable_filters="yes"])
579 AC_MSG_RESULT([$enable_filters])
580
581 # check whether to enable support for SVG fonts
582 AC_MSG_CHECKING([whether to enable support for SVG fonts])
583 AC_ARG_ENABLE(svg_fonts,
584               AC_HELP_STRING([--enable-svg-fonts],
585                              [enable support for SVG fonts (experimental) [default=yes]]),
586               [],[enable_svg_fonts="yes"])
587 AC_MSG_RESULT([$enable_svg_fonts])
588
589 # check whether to enable foreign objects support for SVG
590 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
591 AC_ARG_ENABLE(svg_foreign_object,
592               AC_HELP_STRING([--enable-svg-foreign-object],
593                              [enable support for SVG foreign objects (experimental) [default=yes]]),
594               [],[enable_svg_foreign_object="yes"])
595 AC_MSG_RESULT([$enable_svg_foreign_object])
596
597 # check whether to enable SVG As Image support
598 AC_MSG_CHECKING([whether to enable SVG as Image support])
599 AC_ARG_ENABLE(svg_as_image,
600               AC_HELP_STRING([--enable-svg-as-image],
601                              [enable SVG as Image support (experimental) [default=yes]]),
602               [],[enable_svg_as_image="yes"])
603 AC_MSG_RESULT([$enable_svg_as_image])
604
605 # check whether to enable SVG USE element support
606 AC_MSG_CHECKING([whether to enable support for SVG use element])
607 AC_ARG_ENABLE(svg_use,
608               AC_HELP_STRING([--enable-svg-use],
609                              [enable SVG use element support (experimental) [default=yes]]),
610               [],[enable_svg_use="yes"])
611 AC_MSG_RESULT([$enable_svg_use])
612
613 # check for SVG features, enabling SVG if necessary
614 if test "$enable_svg_animation" = "yes" || \
615    test "$enable_svg_fonts" = "yes" || \
616    test "$enable_svg_foreign_object" = "yes" || \
617    test "$enable_svg_as_image" = "yes" || \
618    test "$enable_svg_use" = "yes"; then
619    svg_flags=yes
620    if test "$enable_svg" = "no"; then
621        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
622        enable_svg=yes
623    fi
624 fi
625
626 # check whether to enable Web Socket support
627 AC_MSG_CHECKING([whether to enable Web Sockets support])
628 AC_ARG_ENABLE(web_sockets,
629               AC_HELP_STRING([--enable-web-sockets],
630                              [enable support for Web Sockets [default=no]]),
631               [],[enable_web_sockets="no"])
632 AC_MSG_RESULT([$enable_web_sockets])
633
634 # check whether to enable Web Timing support
635 AC_MSG_CHECKING([whether to enable Web Timing support])
636 AC_ARG_ENABLE(web_timing,
637               AC_HELP_STRING([--enable-web-timing],
638                              [enable support for Web Timing [default=no]]),
639               [],[enable_web_timing="no"])
640 AC_MSG_RESULT([$enable_web_timing])
641
642 # check whether to enable Blob support
643 AC_MSG_CHECKING([whether to enable Blob support])
644 AC_ARG_ENABLE(blob,
645               AC_HELP_STRING([--enable-blob],
646                              [enable support for Blob [default=no]]),
647               [],[enable_blob="no"])
648 AC_MSG_RESULT([$enable_blob])
649
650 # check whether to enable Fast Mobile Scrolling support
651 AC_MSG_CHECKING([whether to enable Fast Mobile Scrolling])
652 AC_ARG_ENABLE(fast_mobile_scrolling,
653               AC_HELP_STRING([--enable-fast-mobile-scrolling],
654                              [enable support for Fast Mobile Scrolling [default=no]]),
655               [],[enable_fast_mobile_scrolling="no"])
656 AC_MSG_RESULT([$enable_fast_mobile_scrolling])
657
658 # check whether to enable FileWriter support
659 AC_MSG_CHECKING([whether to enable FileWriter support])
660 AC_ARG_ENABLE(file_writer,
661               AC_HELP_STRING([--enable-file-writer],
662                              [enable support for FileWriter [default=no]]),
663               [],[enable_file_writer="no"])
664 AC_MSG_RESULT([$enable_file_writer])
665
666 # check whether to enable code coverage
667 AC_MSG_CHECKING([whether to enable code coverage support])
668 AC_ARG_ENABLE(coverage,
669               AC_HELP_STRING([--enable-coverage],
670                              [enable code coverage support [default=no]]),
671               [],[enable_coverage="no"])
672 AC_MSG_RESULT([$enable_coverage])
673
674 # check whether to enable FastMalloc
675 AC_MSG_CHECKING([whether to enable optimized memory allocator])
676 AC_ARG_ENABLE(fast_malloc,
677               AC_HELP_STRING([--enable-fast-malloc],
678                              [enable optimized memory allocator default=yes, default=no for debug builds]),
679               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
680 AC_MSG_RESULT([$enable_fast_malloc])
681
682 AC_MSG_CHECKING([whether to enable JIT compilation])
683 AC_ARG_ENABLE([jit],
684               AC_HELP_STRING([--enable-jit],
685                              [Enable JIT compilation default=yes]),
686               [],[enable_jit="yes"])
687 if test "$enable_jit" = "yes"; then
688     case "$host_cpu" in
689         arm*)
690             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
691             AC_DEFINE([ENABLE_YARR], [1], [Define to enable YARR])
692             AC_DEFINE([ENABLE_YARR_JIT], [1], [Define to enable YARR JIT])
693         ;;
694         i*86|x86_64)
695             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
696             AC_DEFINE([ENABLE_YARR], [1], [Define to enable YARR])
697             AC_DEFINE([ENABLE_YARR_JIT], [1], [Define to enable YARR JIT])
698             AC_DEFINE([ENABLE_JIT_OPTIMIZE_CALL], [1], [Define to enable optimizing calls])
699             AC_DEFINE([ENABLE_JIT_OPTIMIZE_PROPERTY_ACCESS], [1], [Define to enable optimized property access])
700             AC_DEFINE([ENABLE_JIT_OPTIMIZE_ARITHMETIC], [1], [Define to enable optimized arithmetic])
701             case "$host_cpu" in
702                 i*86)
703                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_VA_LIST], [1], [Use stub va_list])
704                 ;;
705                 x86_64)
706                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_REGISTER], [1], [Use stub register])
707                     AC_DEFINE([WTF_USE_ALTERNATE_JSIMMEDIATE], [1], [Use alternate JSImmediate])
708                 ;;
709             esac
710         ;;
711         *)
712             enable_jit="no (CPU '$host_cpu' not supported)"
713         ;;
714     esac
715 fi
716 AC_MSG_RESULT([$enable_jit])
717
718 # GObject Introspection
719 AC_MSG_CHECKING([whether to enable GObject introspection support])
720 AC_ARG_ENABLE([introspection],
721   [AS_HELP_STRING([--enable-introspection],[Enable GObject introspection (default: disabled)])],
722   [],[enable_introspection=no])
723 AC_MSG_RESULT([$enable_introspection])
724
725 G_IR_SCANNER=
726 G_IR_COMPILER=
727 G_IR_GENERATE=
728 GIRDIR=
729 GIRTYPELIBDIR=
730
731 if test "$enable_introspection" = "yes"; then
732   GOBJECT_INTROSPECTION_REQUIRED=0.6.15
733   PKG_CHECK_MODULES([INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
734   
735   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
736   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
737   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
738   AC_DEFINE([ENABLE_INTROSPECTION],[1],[Define to enable GObject introspection support])
739 fi
740
741 AC_SUBST([G_IR_SCANNER])
742 AC_SUBST([G_IR_COMPILER])
743 AC_SUBST([G_IR_GENERATE])
744
745 # determine the font backend
746 AC_MSG_CHECKING([the font backend to use])
747 AC_ARG_WITH(font_backend,
748             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
749                            [Select font backend [default=freetype]]),
750             [],[with_font_backend="freetype"])
751
752 case "$with_font_backend" in
753      freetype|pango) ;;
754      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
755 esac
756 AC_MSG_RESULT([$with_font_backend])
757
758 # Add '-g' flag to gcc if it's debug build
759 if test "$enable_debug" = "yes"; then
760    CXXFLAGS="$CXXFLAGS -g"
761    CFLAGS="$CFLAGS -g"
762 else
763    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
764 fi
765
766 # Add the appropriate 'O' level for optimized builds
767 if test "$enable_optimizations" = "yes"; then
768    CXXFLAGS="$CXXFLAGS -O2"
769    CFLAGS="$CFLAGS -O2"
770 else
771    CXXFLAGS="$CXXFLAGS -O0"
772    CFLAGS="$CFLAGS -O0"
773 fi
774
775 PKG_CHECK_MODULES([LIBSOUP],
776                   [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
777 AC_SUBST([LIBSOUP_CFLAGS])
778 AC_SUBST([LIBSOUP_LIBS])
779
780 # check if we can use libSoup 2.29.90 features
781 PKG_CHECK_MODULES([LIBSOUP_2_29_90],
782                   [libsoup-2.4 >= 2.29.90],
783                   [have_libsoup_2_29_90=yes],
784                   [have_libsoup_2_29_90=no])
785 if test "$have_libsoup_2_29_90" = "yes"; then
786    AC_DEFINE([HAVE_LIBSOUP_2_29_90], 1, [Whether libSoup 2.29.90 features are available])
787 fi
788
789 # check if FreeType/FontConfig are available
790 if test "$with_font_backend" = "freetype"; then
791    if test "$with_target" = "directfb"; then
792    PKG_CHECK_MODULES([FREETYPE],
793                      [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
794                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
795    else
796    PKG_CHECK_MODULES([FREETYPE],
797                      [cairo-ft
798                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
799                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
800    fi
801    AC_SUBST([FREETYPE_CFLAGS])
802    AC_SUBST([FREETYPE_LIBS])
803 fi
804
805 # check if sqlite 3 is available
806 if test "$enable_icon_database" = "yes" || \
807    test "$enable_database" = "yes" || \
808    test "$enable_offline_web_applications" = "yes" || \
809    test "$enable_dom_storage" = "yes"; then
810    PKG_CHECK_MODULES([SQLITE3],
811                      [sqlite3 >= $SQLITE_REQUIRED_VERSION],
812                      [sqlite3_has_pkg_config=yes],
813                      [sqlite3_has_pkg_config=no])
814    if test "$sqlite3_has_pkg_config" = "no"; then
815       AC_SEARCH_LIBS([sqlite3_open16], [sqlite3],
816                      [SQLITE3_LIBS="$LIBS";SQLITE3_CFLAGS="-I $srcdir/WebKitLibraries/WebCoreSQLite3"],
817                      [AC_MSG_ERROR([SQLite3 is required to enable Database support])])
818    fi
819    AC_SUBST([SQLITE3_CFLAGS])
820    AC_SUBST([SQLITE3_LIBS])
821 fi
822
823 # check if libxslt is available
824 if test "$enable_xslt" = "yes"; then
825    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
826    AC_SUBST([LIBXSLT_CFLAGS])
827    AC_SUBST([LIBXSLT_LIBS])
828 fi
829
830 # check if geoclue is available
831 if test "$enable_geolocation" = "yes"; then
832     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
833     AC_SUBST([GEOCLUE_CFLAGS])
834     AC_SUBST([GEOCLUE_LIBS])
835 fi
836
837 # GSettings
838 GLIB_GSETTINGS
839
840 # check if gstreamer is available
841 if test "$enable_video" = "yes"; then
842    PKG_CHECK_MODULES([GSTREAMER],
843                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
844                      gstreamer-app-0.10
845                      gstreamer-base-0.10
846                      gstreamer-pbutils-0.10
847                      gstreamer-plugins-base-0.10 >= $GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION
848                      gstreamer-video-0.10])
849    AC_SUBST([GSTREAMER_CFLAGS])
850    AC_SUBST([GSTREAMER_LIBS])
851 fi
852
853 # check for code coverage support
854 if test "$enable_coverage" = "yes"; then
855    COVERAGE_CFLAGS="-MD"
856    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
857    AC_SUBST([COVERAGE_CFLAGS])
858    AC_SUBST([COVERAGE_LDFLAGS])
859 fi
860
861 # check for HTML features
862 if test "$enable_video" = "yes"; then
863     html_flags=yes
864 fi
865
866 GTK_DOC_CHECK([1.10])
867
868 # OS conditionals
869 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
870 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
871 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
872 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
873 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
874
875 # target conditionals
876 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
877 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
878 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
879 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
880
881 # Unicode backend conditionals
882 AM_CONDITIONAL([USE_ICU_UNICODE], [test "$with_unicode_backend" = "icu"])
883 AM_CONDITIONAL([USE_GLIB_UNICODE], [test "$with_unicode_backend" = "glib"])
884
885 # Font backend conditionals
886 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
887 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
888
889 # GLib/GIO feature conditionals
890 AM_CONDITIONAL([USE_GSETTINGS], [test "$have_gsettings" = "yes"])
891
892 # WebKit feature conditionals
893 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
894 AM_CONDITIONAL([ENABLE_3D_TRANSFORMS],[test "$enable_3D_transforms" = "yes"])
895 AM_CONDITIONAL([ENABLE_BLOB],[test "$enable_blob" = "yes"])
896 AM_CONDITIONAL([ENABLE_CHANNEL_MESSAGING],[test "$enable_channel_messaging" = "yes"])
897 AM_CONDITIONAL([ENABLE_JAVASCRIPT_DEBUGGER],[test "$enable_javascript_debugger" = "yes"])
898 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
899 AM_CONDITIONAL([ENABLE_DIRECTORY_UPLOAD],[test "$enable_directory_upload" = "yes"])
900 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
901 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
902 AM_CONDITIONAL([ENABLE_DATALIST],[test "$enable_datalist" = "yes"])
903 AM_CONDITIONAL([ENABLE_EVENTSOURCE],[test "$enable_eventsource" = "yes"])
904 AM_CONDITIONAL([ENABLE_FAST_MOBILE_SCROLLING],[test "$enable_fast_mobile_scrolling" = "yes"])
905 AM_CONDITIONAL([ENABLE_FILE_SYSTEM],[test "$enable_file_system" = "yes"])
906 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
907 AM_CONDITIONAL([ENABLE_IMAGE_RESIZER],[test "$enable_image_resizer" = "yes"])
908 AM_CONDITIONAL([ENABLE_INDEXED_DATABASE],[test "$enable_indexed_database" = "yes"])
909 AM_CONDITIONAL([ENABLE_INPUT_SPEECH],[test "$enable_input_speech" = "yes"])
910 AM_CONDITIONAL([ENABLE_XHTMLMP],[test "$enable_xhtmlmp" = "yes"])
911 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
912 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
913 AM_CONDITIONAL([ENABLE_FILTERS],[test "$enable_filters" = "yes"])
914 AM_CONDITIONAL([ENABLE_FILE_WRITER],[test "$enable_file_writer" = "yes"])
915 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
916 AM_CONDITIONAL([ENABLE_MATHML], [test "$enable_mathml" = "yes"])
917 AM_CONDITIONAL([ENABLE_RUBY],[test "$enable_ruby" = "yes"])
918 AM_CONDITIONAL([ENABLE_SANDBOX],[test "$enable_sandbox" = "yes"])
919 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
920 AM_CONDITIONAL([ENABLE_NOTIFICATIONS],[test "$enable_notifications" = "yes"])
921 AM_CONDITIONAL([ENABLE_ORIENTATION_EVENTS],[test "$enable_orientation_events" = "yes"])
922 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
923 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
924 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
925 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
926 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
927 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use" = "yes"])
928 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
929 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
930 AM_CONDITIONAL([ENABLE_WML],[test "$enable_wml" = "yes"])
931 AM_CONDITIONAL([ENABLE_WORKERS],[test "$enable_workers" = "yes"])
932 AM_CONDITIONAL([ENABLE_SHARED_WORKERS],[test "$enable_shared_workers" = "yes"])
933 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
934 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
935 AM_CONDITIONAL([ENABLE_WEB_SOCKETS],[test "$enable_web_sockets" = "yes"])
936 AM_CONDITIONAL([ENABLE_WEB_TIMING],[test "$enable_web_timing" = "yes"])
937
938 # Gtk conditionals
939 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
940
941
942 AC_CONFIG_FILES([
943 GNUmakefile
944 WebKit/gtk/webkit/webkitversion.h
945 WebKit/gtk/docs/GNUmakefile
946 WebKit/gtk/docs/version.xml
947 ]
948 )
949
950 AC_CONFIG_FILES([
951 WebKit/gtk/${WEBKITGTK_PC_NAME}-${WEBKITGTK_API_VERSION}.pc:WebKit/gtk/webkit.pc.in
952 WebKit/gtk/JSCore-${WEBKITGTK_API_VERSION}.gir:WebKit/gtk/JSCore.gir.in
953 WebKit/gtk/org.webkitgtk-${WEBKITGTK_API_VERSION}.gschema.xml:WebKit/gtk/org.webkitgtk.gschema.xml.in
954 ]
955 ,[WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME]
956 )
957
958 AC_OUTPUT
959
960 echo "
961 WebKit was configured with the following options:
962
963 Build configuration:
964  Enable debugging (slow)                                  : $enable_debug
965  Enable GCC build optimization                            : $enable_optimizations
966  Code coverage support                                    : $enable_coverage
967  Unicode backend                                          : $with_unicode_backend
968  Font backend                                             : $with_font_backend
969  Optimized memory allocator                               : $enable_fast_malloc
970 Features:
971  3D Transforms                                            : $enable_3D_transforms
972  Blob support                                             : $enable_blob
973  Directory upload                                         : $enable_directory_upload
974  Fast Mobile Scrolling                                    : $enable_fast_mobile_scrolling
975  JIT compilation                                          : $enable_jit
976  Filters support                                          : $enable_filters
977  FileWriter support                                       : $enable_file_writer
978  Geolocation support                                      : $enable_geolocation
979  JavaScript debugger/profiler support                     : $enable_javascript_debugger
980  MathML support                                           : $enable_mathml
981  HTML5 offline web applications support                   : $enable_offline_web_applications
982  HTML5 channel messaging support                          : $enable_channel_messaging
983  HTML5 client-side session and persistent storage support : $enable_dom_storage
984  HTML5 client-side database storage support               : $enable_database
985  HTML5 FileSystem API support                             : $enable_file_system
986  HTML5 ruby support                                       : $enable_ruby
987  HTML5 sandboxed iframe support                           : $enable_sandbox
988  HTML5 server-sent events support                         : $enable_eventsource
989  HTML5 video element support                              : $enable_video
990  Icon database support                                    : $enable_icon_database
991  Image resizer support                                    : $enable_image_resizer
992  SharedWorkers support                                    : $enable_shared_workers
993  Speech input support                                     : $enable_input_speech
994  SVG support                                              : $enable_svg
995  SVG animation support                                    : $enable_svg_animation
996  SVG fonts support                                        : $enable_svg_fonts
997  SVG foreign object support                               : $enable_svg_foreign_object
998  SVG as image support                                     : $enable_svg_as_image
999  SVG use element support                                  : $enable_svg_use
1000  WML support                                              : $enable_wml
1001  Web Sockets support                                      : $enable_web_sockets
1002  Web Timing support                                       : $enable_web_timing
1003  Web Workers support                                      : $enable_workers
1004  XHTML-MP support                                         : $enable_xhtmlmp
1005  XPATH support                                            : $enable_xpath
1006  XSLT support                                             : $enable_xslt
1007 GTK+ configuration:
1008  GTK+ version                                             : $with_gtk
1009  GDK target                                               : $with_target
1010  Hildon UI extensions                                     : $with_hildon
1011  Introspection support                                    : $enable_introspection
1012 "
1013 if test "$with_unicode_backend" = "glib"; then
1014    echo "     >> WARNING: the glib-based unicode backend is slow and incomplete <<"
1015    echo
1016    echo
1017 fi