2010-11-11 Alejandro G. Castro <alex@igalia.com>
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.59)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [3])
5 m4_define([webkit_micro_version], [6])
6
7 # This is the version we'll be using as part of our User-Agent string
8 # e.g., AppleWebKit/$(webkit_user_agent_version) ...
9 #
10 # Sourced from WebCore/Configurations/Version.xcconfig
11 m4_define([webkit_user_agent_major_version], [534])
12 m4_define([webkit_user_agent_minor_version], [7])
13
14 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
15
16 AC_CONFIG_MACRO_DIR([autotools])
17 AC_CONFIG_AUX_DIR([autotools])
18 AC_SUBST(ACLOCAL_AMFLAGS, "-I autotools")
19
20 AC_CONFIG_HEADERS([autotoolsconfig.h])
21 AC_CANONICAL_HOST
22
23 WEBKIT_MAJOR_VERSION=webkit_major_version
24 WEBKIT_MINOR_VERSION=webkit_minor_version
25 WEBKIT_MICRO_VERSION=webkit_micro_version
26 WEBKIT_USER_AGENT_MAJOR_VERSION=webkit_user_agent_major_version
27 WEBKIT_USER_AGENT_MINOR_VERSION=webkit_user_agent_minor_version
28 AC_SUBST(WEBKIT_MAJOR_VERSION)
29 AC_SUBST(WEBKIT_MINOR_VERSION)
30 AC_SUBST(WEBKIT_MICRO_VERSION)
31 AC_SUBST(WEBKIT_USER_AGENT_MAJOR_VERSION)
32 AC_SUBST(WEBKIT_USER_AGENT_MINOR_VERSION)
33
34 AC_CONFIG_SRCDIR([WebCore/config.h])
35
36 dnl # Libtool library version, not to confuse with API version
37 dnl # see http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
38 LIBWEBKITGTK_VERSION=3:1:3
39 AC_SUBST([LIBWEBKITGTK_VERSION])
40
41 AM_INIT_AUTOMAKE([foreign subdir-objects tar-ustar])
42
43 # Use AM_SILENT_RULES if present
44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
45
46 # host checking - inspired by the GTK+ configure.in
47 # TODO: move these to webkit.m4?
48 AC_MSG_CHECKING([for native Win32])
49 case "$host" in
50      *-*-mingw*)
51        os_win32=yes
52        ;;
53      *)
54        os_win32=no
55        ;;
56 esac
57 AC_MSG_RESULT([$os_win32])
58
59 case "$host" in
60      *-*-linux*)
61        os_linux=yes
62        ;;
63      *-*-freebsd*)
64        os_freebsd=yes
65        ;;
66      *-*-darwin*)
67        os_darwin=yes
68        ;;
69 esac
70
71 case "$host_os" in
72      gnu* | linux* | k*bsd*-gnu)
73        os_gnu=yes
74        ;;
75      *)
76        os_gnu=no
77        ;;
78 esac
79
80 # initialize webkit options
81 WEBKIT_INIT
82 AC_DISABLE_STATIC
83 AC_LIBTOOL_WIN32_DLL
84 AC_PROG_LIBTOOL
85 # use dolt to speedup the build
86 DOLT
87
88 AC_PATH_PROG(FLEX, flex)
89 if test -z "$FLEX"; then
90    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
91 else
92    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
93    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
94       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
95 fi
96
97 AC_PATH_PROG(GPERF, gperf)
98 if test -z "$GPERF"; then
99    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
100 fi
101
102 # pthread (not needed on Windows)
103 if test "$os_win32" = "no"; then
104 AC_CHECK_HEADERS([pthread.h],
105                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
106                  AC_MSG_ERROR([pthread support is required to build WebKit]))
107 fi
108
109 # check for libjpeg the way Gtk does it.
110 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
111                    jpeg_ok=yes, jpeg_ok=no
112                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
113 if test "$jpeg_ok" = yes; then
114    AC_MSG_CHECKING([for jpeglib])
115    AC_TRY_CPP(
116 [#include <stdio.h>
117 #undef PACKAGE
118 #undef VERSION
119 #undef HAVE_STDLIB_H
120 #include <jpeglib.h>],
121          jpeg_ok=yes,
122          jpeg_ok=no)
123    AC_MSG_RESULT($jpeg_ok)
124    if test "$jpeg_ok" = yes; then
125       JPEG_LIBS="-ljpeg"
126       # should we check for progressive JPEG like GTK+ as well?
127    else
128       AC_MSG_ERROR([JPEG library (libjpeg) not found])
129    fi
130 fi
131 AC_SUBST([JPEG_LIBS])
132
133 # Check for libpng the way Gtk+ does it
134 for l in libpng libpng14 libpng12; do
135   AC_MSG_CHECKING(for $l)
136   if $PKG_CONFIG --exists $l ; then
137     AC_MSG_RESULT(yes)
138     PNG_LIBS=`$PKG_CONFIG --libs $l`
139     png_ok=yes
140     break
141   else
142     AC_MSG_RESULT(no)
143     png_ok=no
144   fi
145 done
146 if test "$png_ok" != yes; then
147   AC_CHECK_LIB(png, png_read_info,
148     [AC_CHECK_HEADER(png.h,
149       png_ok=yes,
150       png_ok=no)],
151     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
152   if test "$png_ok" = yes; then
153     AC_MSG_CHECKING([for png_structp in png.h])
154     AC_TRY_COMPILE([#include <png.h>],
155       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
156       png_ok=yes,
157       png_ok=no)
158     AC_MSG_RESULT($png_ok)
159     if test "$png_ok" = yes; then
160       PNG_LIBS='-lpng -lz'
161     else
162       AC_MSG_ERROR([PNG library (libpng) not found])
163     fi
164   else
165     AC_MSG_ERROR([PNG library (libpng) not found])
166   fi
167 fi
168 AC_SUBST([PNG_LIBS])
169
170
171 if test "$os_win32" = "yes"; then
172   WINMM_LIBS=-lwinmm
173   SHLWAPI_LIBS=-lshlwapi
174   OLE32_LIBS=-lole32
175 fi
176 AC_SUBST([WINMM_LIBS])
177 AC_SUBST([SHLWAPI_LIBS])
178 AC_SUBST([OLE32_LIBS])
179
180
181 # determine the GTK+ version to use
182 AC_MSG_CHECKING([the GTK+ version to use])
183 AC_ARG_WITH([gtk],
184         [AS_HELP_STRING([--with-gtk=2.0|3.0], [the GTK+ version to use (default: 2.0)])],
185         [case "$with_gtk" in
186         2.0|3.0) ;;
187         *) AC_MSG_ERROR([invalid GTK+ version specified]) ;;
188         esac],
189         [with_gtk=2.0])
190 AC_MSG_RESULT([$with_gtk])
191
192 case "$with_gtk" in
193      2.0) GTK_REQUIRED_VERSION=2.10
194           GTK_API_VERSION=2.0
195           WEBKITGTK_API_MAJOR_VERSION=1
196           WEBKITGTK_API_MINOR_VERSION=0
197           WEBKITGTK_API_VERSION=1.0
198           WEBKITGTK_PC_NAME=webkit
199           GAIL_PC_NAME=gail
200           GAIL_REQUIRED_VERSION=1.8
201           ;;
202      3.0) GTK_REQUIRED_VERSION=2.91
203           GTK_API_VERSION=3.0
204           WEBKITGTK_API_MAJOR_VERSION=3
205           WEBKITGTK_API_MINOR_VERSION=0
206           WEBKITGTK_API_VERSION=3.0
207           WEBKITGTK_PC_NAME=webkitgtk
208           GAIL_PC_NAME=gail-3.0
209           GAIL_REQUIRED_VERSION=2.90.4
210           ;;
211 esac
212
213 AC_SUBST([WEBKITGTK_API_MAJOR_VERSION])
214 AC_SUBST([WEBKITGTK_API_MINOR_VERSION])
215 AC_SUBST([WEBKITGTK_API_VERSION])
216 AC_SUBST([WEBKITGTK_PC_NAME])
217 AC_SUBST([GTK_API_VERSION])
218 AM_CONDITIONAL([GTK_API_VERSION_2],[test "$GTK_API_VERSION" = "2.0"])
219
220 # determine the GDK/GTK+ target
221 AC_MSG_CHECKING([the target windowing system])
222 AC_ARG_WITH(target,
223             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
224                            [Select webkit target [default=x11]]),
225             [],[with_target="x11"])
226
227 case "$with_target" in
228      x11|win32|quartz|directfb) ;;
229      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
230 esac
231
232 AC_MSG_RESULT([$with_target])
233
234 AC_MSG_CHECKING([for Hildon UI extensions])
235 AC_ARG_WITH(hildon,
236             AC_HELP_STRING([--with-hildon],
237                            [Use Hildon UI extensions [default=no]]),
238             [],[with_hildon="no"])
239 AC_MSG_RESULT([$with_hildon])
240
241 if test "$with_hildon" = "yes"; then
242     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
243     PKG_CHECK_MODULES([HILDON], [hildon-1])
244     AC_SUBST([HILDON_CPPFLAGS])
245     AC_SUBST([HILDON_CFLAGS])
246     AC_SUBST([HILDON_LIBS])
247 fi
248
249 # minimum base dependencies
250 LIBSOUP_REQUIRED_VERSION=2.28.2
251 CAIRO_REQUIRED_VERSION=1.6
252 FONTCONFIG_REQUIRED_VERSION=2.4
253 FREETYPE2_REQUIRED_VERSION=9.0
254 LIBXML_REQUIRED_VERSION=2.6
255
256 # minimum GTK+ base dependencies
257 PANGO_REQUIRED_VERSION=1.12
258
259 # optional modules
260 LIBXSLT_REQUIRED_VERSION=1.1.7
261 SQLITE_REQUIRED_VERSION=3.0
262 GSTREAMER_REQUIRED_VERSION=0.10
263 GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION=0.10.25
264 ENCHANT_REQUIRED_VERSION=0.22
265
266 # Available modules
267 #
268 # glib - glib and includes gthread
269 # unicode - check and identify which unicode backend to use
270 #
271 # todo: webcore gtk
272 WEBKIT_CHECK_DEPENDENCIES([glib unicode])
273
274 # Check if we can use GSettings
275 PKG_CHECK_MODULES([GSETTINGS],
276                   [gio-2.0 >= 2.25.0],
277                   [have_gsettings=yes],
278                   [have_gsettings=no])
279 if test "$have_gsettings" = "yes"; then
280    AC_DEFINE([HAVE_GSETTINGS], 1, [Whether we can use GSettings])
281    GLIB_GSETTINGS
282 fi
283
284 GETTEXT_PACKAGE=$PACKAGE-$GTK_API_VERSION
285 AC_SUBST(GETTEXT_PACKAGE)
286 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
287                    [The gettext catalog name])
288
289 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
290 AC_SUBST(LIBXML_CFLAGS)
291 AC_SUBST(LIBXML_LIBS)
292
293 PKG_CHECK_MODULES(PANGO, 
294                   [pango >= $PANGO_REQUIRED_VERSION
295                    pangoft2])
296 AC_SUBST(PANGO_CFLAGS)
297 AC_SUBST(PANGO_LIBS)
298
299 PKG_CHECK_MODULES(ENCHANT, enchant >= $ENCHANT_REQUIRED_VERSION)
300 AC_SUBST(ENCHANT_CFLAGS)
301 AC_SUBST(ENCHANT_LIBS)
302
303 PKG_CHECK_MODULES(GAIL, $GAIL_PC_NAME >= $GAIL_REQUIRED_VERSION)
304 AC_SUBST(GAIL_CFLAGS)
305 AC_SUBST(GAIL_LIBS)
306
307 # check for target-specific dependencies
308 if test "$with_target" = "directfb"; then
309    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
310    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
311    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
312 else
313    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
314    PKG_CHECK_MODULES(GTK, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED_VERSION)
315
316    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
317       # check for XT
318       PKG_CHECK_MODULES([XT],
319                         [xt],
320                         [xt_has_pkg_config=yes],
321                         [xt_has_pkg_config=no])
322       # some old versions of Xt do not provide xt.pc, so try to link against Xt
323       # and if it's installed fall back to just adding -lXt
324       if test "$xt_has_pkg_config" = "no"; then
325          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
326          # we don't care about the XtOpenDisplay symbol but only about the
327          # existence of libXt
328          AC_CHECK_LIB([Xt], [XtOpenDisplay],
329                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
330                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
331       fi
332       AC_SUBST([XT_CFLAGS])
333       AC_SUBST([XT_LIBS])
334       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
335    fi
336 fi
337 AC_SUBST(GTK_CFLAGS)
338 AC_SUBST(GTK_LIBS)
339 AC_SUBST(CAIRO_CFLAGS)
340 AC_SUBST(CAIRO_LIBS)
341
342 # check whether to build with debugging enabled
343 AC_MSG_CHECKING([whether to do a debug build])
344 AC_ARG_ENABLE(debug,
345               AC_HELP_STRING([--enable-debug],
346                              [turn on debugging [default=no]]),
347               [],[enable_debug="no"])
348 AC_MSG_RESULT([$enable_debug])
349
350 # check whether to enable optimized builds
351 AC_MSG_CHECKING([whether to enable optimized builds])
352 AC_ARG_ENABLE(optimizations,
353               AC_HELP_STRING([--enable-optimizations],
354                              [turn on optimize builds (GCC only)
355                              [default=yes]]),
356               [enable_optimizations=$enableval],
357               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
358 AC_MSG_RESULT([$enable_optimizations])
359
360 # check whether to enable 3D transforms support
361 AC_MSG_CHECKING([whether to enable support for 3D Transforms])
362 AC_ARG_ENABLE(3D_transforms,
363               AC_HELP_STRING([--enable-3D-transforms],
364                              [enable support for 3D transforms [default=no]]),
365               [],[enable_3D_transforms="no"])
366 AC_MSG_RESULT([$enable_3D_transforms])
367
368 # check whether to enable channel messaging support
369 AC_MSG_CHECKING([whether to enable HTML5 Channel Messaging support])
370 AC_ARG_ENABLE(channel_messaging,
371               AC_HELP_STRING([--enable-channel-messaging],
372                              [enable HTML5 channel messaging support [default=yes]]),
373               [],[enable_channel_messaging="yes"])
374 AC_MSG_RESULT([$enable_channel_messaging])
375
376 # check whether to enable JavaScript debugger/profiler support
377 AC_MSG_CHECKING([whether to enable JavaScript debugger/profiler support])
378 AC_ARG_ENABLE(javascript_debugger,
379               AC_HELP_STRING([--enable-javascript-debugger],
380                              [enable JavaScript debugger/profiler support [default=yes]]),
381               [],[enable_javascript_debugger="yes"])
382 AC_MSG_RESULT([$enable_javascript_debugger])
383
384 # check whether to enable HTML5 Offline Web Applications support
385 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
386 AC_ARG_ENABLE(offline_web_applications,
387               AC_HELP_STRING([--enable-offline-web-applications],
388                              [enable HTML5 offline web applications support [default=yes]]),
389               [],[enable_offline_web_applications="yes"])
390 AC_MSG_RESULT([$enable_offline_web_applications])
391
392 # check whether to enable HTML5 client-side session and persitent storage support
393 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
394 AC_ARG_ENABLE(dom_storage,
395               AC_HELP_STRING([--enable-dom-storage],
396                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
397               [],[enable_dom_storage="yes"])
398 AC_MSG_RESULT([$enable_dom_storage])
399
400 # check whether to enable the indexed database API
401 AC_MSG_CHECKING([whether to enable the indexed database API])
402 AC_ARG_ENABLE(indexed_database,
403               AC_HELP_STRING([--enable-indexeddb],
404                              [enable the indexed database API [default=no]]),
405               [],[enable_indexed_database="no"])
406 AC_MSG_RESULT([$enable_indexed_database])
407
408 # check whether to enable the speech input API
409 AC_MSG_CHECKING([whether to enable the speech input API])
410 AC_ARG_ENABLE(input_speech,
411               AC_HELP_STRING([--enable-input-speech],
412                              [enable the speech input API [default=no]]),
413               [],[enable_input_speech="no"])
414 AC_MSG_RESULT([$enable_input_speech])
415
416 # check whether to build with database support
417 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
418 AC_ARG_ENABLE(database,
419               AC_HELP_STRING([--enable-database],
420                              [enable HTML5 client-side database storage support [default=yes]]),
421               [],[enable_database="yes"])
422 AC_MSG_RESULT([$enable_database])
423
424 # check whether to build with server-sent events support
425 AC_MSG_CHECKING([whether to enable HTML5 server-sent events support])
426 AC_ARG_ENABLE(eventsource,
427               AC_HELP_STRING([--enable-eventsource],
428                              [enable HTML5 server-sent events support [default=yes]]),
429               [],[enable_eventsource="yes"])
430 AC_MSG_RESULT([$enable_eventsource])
431
432 # check whether to build with icon database support
433 AC_MSG_CHECKING([whether to enable icon database support])
434 AC_ARG_ENABLE(icon_database,
435               AC_HELP_STRING([--enable-icon-database],
436                              [enable icon database [default=yes]]),
437               [],[enable_icon_database="yes"])
438 AC_MSG_RESULT([$enable_icon_database])
439
440 # check whether to build with image resizer API support
441 AC_MSG_CHECKING([whether to enable image resizer API support])
442 AC_ARG_ENABLE(image_resizer,
443               AC_HELP_STRING([--enable-image-resizer],
444                              [enable image resizer [default=no]]),
445               [],[enable_image_resizer="no"])
446 AC_MSG_RESULT([$enable_image_resizer])
447
448 # check whether to enable HTML5 datalist support
449 AC_MSG_CHECKING([whether to enable HTML5 datalist support])
450 AC_ARG_ENABLE(datalist,
451               AC_HELP_STRING([--enable-datalist],
452                              [enable HTML5 datalist support [default=yes]]),
453               [],[enable_datalist="yes"])
454 AC_MSG_RESULT([$enable_datalist])
455
456 # check whether to enable HTML5 sandbox iframe support
457 AC_MSG_CHECKING([whether to enable HTML5 sandboxed iframe support])
458 AC_ARG_ENABLE(sandbox,
459               AC_HELP_STRING([--enable-sandbox],
460                              [enable HTML5 sandboxed iframe support [default=yes]]),
461               [],[enable_sandbox="yes"])
462 AC_MSG_RESULT([$enable_sandbox])
463
464 # check whether to enable HTML5 audio/video support
465 AC_MSG_CHECKING([whether to enable HTML5 video support])
466 AC_ARG_ENABLE(video,
467               AC_HELP_STRING([--enable-video],
468                              [enable HTML5 video support [default=yes]]),
469               [],[enable_video="yes"])
470 AC_MSG_RESULT([$enable_video])
471
472 # check whether to enable XHTML-MP support
473 AC_MSG_CHECKING([whether to enable XHTML-MP support])
474 AC_ARG_ENABLE(xhtmlmp,
475               AC_HELP_STRING([--enable-xhtmlmp],
476                              [enable support for XHTML-MP [default=no]]),
477               [],[enable_xhtmlmp="no"])
478 AC_MSG_RESULT([$enable_xhtmlmp])
479
480 # check whether to enable XPath support
481 AC_MSG_CHECKING([whether to enable XPath support])
482 AC_ARG_ENABLE(xpath,
483               AC_HELP_STRING([--enable-xpath],
484                              [enable support for XPath [default=yes]]),
485               [],[enable_xpath="yes"])
486 AC_MSG_RESULT([$enable_xpath])
487
488 # check whether to enable XSLT support
489 AC_MSG_CHECKING([whether to enable XSLT support])
490 AC_ARG_ENABLE(xslt,
491               AC_HELP_STRING([--enable-xslt],
492                              [enable support for XSLT [default=yes]]),
493               [],[enable_xslt="yes"])
494 AC_MSG_RESULT([$enable_xslt])
495
496 # check whether to enable geolocation support
497 AC_MSG_CHECKING([whether to enable geolocation support])
498 AC_ARG_ENABLE(geolocation,
499               AC_HELP_STRING([--enable-geolocation],
500                              [enable support for geolocation [default=no]]),
501               [],[enable_geolocation="no"])
502 AC_MSG_RESULT([$enable_geolocation])
503
504 # check whether to enable MathML support
505 AC_MSG_CHECKING([whether to enable MathML support])
506 AC_ARG_ENABLE(mathml,
507               AC_HELP_STRING([--enable-mathml],
508                              [enable support for MathML [default=no]]),
509               [],[enable_mathml="no"])
510 AC_MSG_RESULT([$enable_mathml])
511
512 # check whether to enable SVG support
513 AC_MSG_CHECKING([whether to enable SVG support])
514 AC_ARG_ENABLE(svg,
515               AC_HELP_STRING([--enable-svg],
516                              [enable support for SVG [default=yes]]),
517               [],[enable_svg="yes"])
518 AC_MSG_RESULT([$enable_svg])
519
520 # check whether to enable WML support
521 AC_MSG_CHECKING([whether to enable WML support])
522 AC_ARG_ENABLE(wml,
523               AC_HELP_STRING([--enable-wml],
524                              [enable support for WML [default=no]]),
525               [],[enable_wml="no"])
526 AC_MSG_RESULT([$enable_wml])
527
528 # check whether to enable SharedWorkers support
529 AC_MSG_CHECKING([whether to enable SharedWorkers support])
530 AC_ARG_ENABLE(shared_workers,
531               AC_HELP_STRING([--enable-shared-workers],
532                              [enable support for SharedWorkers [default=yes]]),
533               [],[enable_shared_workers="yes"])
534 AC_MSG_RESULT([$enable_shared_workers])
535
536 # check whether to enable Web Workers support
537 AC_MSG_CHECKING([whether to enable Web Workers support])
538 AC_ARG_ENABLE(workers,
539               AC_HELP_STRING([--enable-workers],
540                              [enable support for Web Workers [default=yes]]),
541               [],[enable_workers="yes"])
542 AC_MSG_RESULT([$enable_workers])
543
544 # check whether to enable directory upload support
545 AC_MSG_CHECKING([whether to enable directory upload support])
546 AC_ARG_ENABLE(directory_upload,
547               AC_HELP_STRING([--enable-directory-upload],
548                              [enable support for directory upload [default=no]]),
549               [], [enable_directory_upload="no"])
550 AC_MSG_RESULT([$enable_directory_upload])
551
552 # check whether to enable HTML5 FileSystem API support
553 AC_MSG_CHECKING([whether to enable HTML5 FileSystem API support])
554 AC_ARG_ENABLE(file_system,
555               AC_HELP_STRING([--enable-file-system],
556                              [enable support for HTML5 FileSystem API [default=no]]),
557               [], [enable_file_system="no"])
558 AC_MSG_RESULT([$enable_file_system])
559
560 # turn off svg features if --disable-svg is requested
561 if test "$enable_svg" = "no"; then
562    enable_svg_animation=no
563    enable_svg_fonts=no
564    enable_svg_foreign_object=no
565    enable_svg_as_image=no
566    enable_svg_use=no
567 fi
568
569 # check whether to enable support for SVG animation
570 AC_MSG_CHECKING([whether to enable support for SVG animation])
571 AC_ARG_ENABLE(svg_animation,
572               AC_HELP_STRING([--enable-svg-animation],
573                              [enable support for SVG animation (experimental) [default=yes]]),
574               [],[enable_svg_animation="yes"])
575 AC_MSG_RESULT([$enable_svg_animation])
576
577 # check whether to enable support for filters
578 AC_MSG_CHECKING([whether to enable support for filters])
579 AC_ARG_ENABLE(filters,
580               AC_HELP_STRING([--enable-filters],
581                              [enable support for filters (experimental) [default=yes]]),
582               [],[enable_filters="yes"])
583 AC_MSG_RESULT([$enable_filters])
584
585 # check whether to enable support for SVG fonts
586 AC_MSG_CHECKING([whether to enable support for SVG fonts])
587 AC_ARG_ENABLE(svg_fonts,
588               AC_HELP_STRING([--enable-svg-fonts],
589                              [enable support for SVG fonts (experimental) [default=yes]]),
590               [],[enable_svg_fonts="yes"])
591 AC_MSG_RESULT([$enable_svg_fonts])
592
593 # check whether to enable foreign objects support for SVG
594 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
595 AC_ARG_ENABLE(svg_foreign_object,
596               AC_HELP_STRING([--enable-svg-foreign-object],
597                              [enable support for SVG foreign objects (experimental) [default=yes]]),
598               [],[enable_svg_foreign_object="yes"])
599 AC_MSG_RESULT([$enable_svg_foreign_object])
600
601 # check whether to enable SVG As Image support
602 AC_MSG_CHECKING([whether to enable SVG as Image support])
603 AC_ARG_ENABLE(svg_as_image,
604               AC_HELP_STRING([--enable-svg-as-image],
605                              [enable SVG as Image support (experimental) [default=yes]]),
606               [],[enable_svg_as_image="yes"])
607 AC_MSG_RESULT([$enable_svg_as_image])
608
609 # check whether to enable SVG USE element support
610 AC_MSG_CHECKING([whether to enable support for SVG use element])
611 AC_ARG_ENABLE(svg_use,
612               AC_HELP_STRING([--enable-svg-use],
613                              [enable SVG use element support (experimental) [default=yes]]),
614               [],[enable_svg_use="yes"])
615 AC_MSG_RESULT([$enable_svg_use])
616
617 # check for SVG features, enabling SVG if necessary
618 if test "$enable_svg_animation" = "yes" || \
619    test "$enable_svg_fonts" = "yes" || \
620    test "$enable_svg_foreign_object" = "yes" || \
621    test "$enable_svg_as_image" = "yes" || \
622    test "$enable_svg_use" = "yes"; then
623    svg_flags=yes
624    if test "$enable_svg" = "no"; then
625        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
626        enable_svg=yes
627    fi
628 fi
629
630 # check whether to enable Web Socket support
631 AC_MSG_CHECKING([whether to enable Web Sockets support])
632 AC_ARG_ENABLE(web_sockets,
633               AC_HELP_STRING([--enable-web-sockets],
634                              [enable support for Web Sockets [default=yes]]),
635               [],[enable_web_sockets="yes"])
636 AC_MSG_RESULT([$enable_web_sockets])
637
638 # check whether to enable Web Timing support
639 AC_MSG_CHECKING([whether to enable Web Timing support])
640 AC_ARG_ENABLE(web_timing,
641               AC_HELP_STRING([--enable-web-timing],
642                              [enable support for Web Timing [default=no]]),
643               [],[enable_web_timing="no"])
644 AC_MSG_RESULT([$enable_web_timing])
645
646 # check whether to enable Blob support
647 AC_MSG_CHECKING([whether to enable Blob support])
648 AC_ARG_ENABLE(blob,
649               AC_HELP_STRING([--enable-blob],
650                              [enable support for Blob [default=no]]),
651               [],[enable_blob="no"])
652 AC_MSG_RESULT([$enable_blob])
653
654 # check whether to enable Fast Mobile Scrolling support
655 AC_MSG_CHECKING([whether to enable Fast Mobile Scrolling])
656 AC_ARG_ENABLE(fast_mobile_scrolling,
657               AC_HELP_STRING([--enable-fast-mobile-scrolling],
658                              [enable support for Fast Mobile Scrolling [default=no]]),
659               [],[enable_fast_mobile_scrolling="no"])
660 AC_MSG_RESULT([$enable_fast_mobile_scrolling])
661
662 # check whether to enable code coverage
663 AC_MSG_CHECKING([whether to enable code coverage support])
664 AC_ARG_ENABLE(coverage,
665               AC_HELP_STRING([--enable-coverage],
666                              [enable code coverage support [default=no]]),
667               [],[enable_coverage="no"])
668 AC_MSG_RESULT([$enable_coverage])
669
670 # check whether to enable FastMalloc
671 AC_MSG_CHECKING([whether to enable optimized memory allocator])
672 AC_ARG_ENABLE(fast_malloc,
673               AC_HELP_STRING([--enable-fast-malloc],
674                              [enable optimized memory allocator default=yes, default=no for debug builds]),
675               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
676 AC_MSG_RESULT([$enable_fast_malloc])
677
678 AC_MSG_CHECKING([whether to enable JIT compilation])
679 AC_ARG_ENABLE([jit],
680               AC_HELP_STRING([--enable-jit],
681                              [Enable JIT compilation default=yes]),
682               [],[enable_jit="yes"])
683 if test "$enable_jit" = "yes"; then
684     case "$host_cpu" in
685         arm*)
686             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
687             AC_DEFINE([ENABLE_YARR], [1], [Define to enable YARR])
688             AC_DEFINE([ENABLE_YARR_JIT], [1], [Define to enable YARR JIT])
689         ;;
690         i*86|x86_64)
691             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
692             AC_DEFINE([ENABLE_YARR], [1], [Define to enable YARR])
693             AC_DEFINE([ENABLE_YARR_JIT], [1], [Define to enable YARR JIT])
694             AC_DEFINE([ENABLE_JIT_OPTIMIZE_CALL], [1], [Define to enable optimizing calls])
695             AC_DEFINE([ENABLE_JIT_OPTIMIZE_PROPERTY_ACCESS], [1], [Define to enable optimized property access])
696             AC_DEFINE([ENABLE_JIT_OPTIMIZE_ARITHMETIC], [1], [Define to enable optimized arithmetic])
697             case "$host_cpu" in
698                 i*86)
699                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_VA_LIST], [1], [Use stub va_list])
700                 ;;
701                 x86_64)
702                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_REGISTER], [1], [Use stub register])
703                     AC_DEFINE([WTF_USE_ALTERNATE_JSIMMEDIATE], [1], [Use alternate JSImmediate])
704                 ;;
705             esac
706         ;;
707         *)
708             enable_jit="no (CPU '$host_cpu' not supported)"
709         ;;
710     esac
711 else
712         AC_DEFINE([ENABLE_JIT], [0], [Define to enable JIT])
713 fi
714 AC_MSG_RESULT([$enable_jit])
715
716 # Opcode stats
717 AC_MSG_CHECKING([whether to enable opcode stats])
718 AC_ARG_ENABLE([opcode-stats],
719   [AS_HELP_STRING([--enable-opcode-stats], [Enable Opcode statistics (default: disabled)])],
720   [], [enable_opcode_stats=no])
721 AC_MSG_RESULT([$enable_opcode_stats])
722
723 if test "$enable_opcode_stats" = "yes"; then
724   if test "$enable_jit" = "yes"; then
725     AC_MSG_ERROR([JIT must be disabled for Opcode stats to work.])
726   fi
727   AC_DEFINE([ENABLE_OPCODE_STATS], [1], [Define to enable Opcode statistics])
728 fi
729
730 # Link prefetch
731 AC_MSG_CHECKING([whether to enable link prefetch support])
732 AC_ARG_ENABLE([link-prefetch],
733   [AS_HELP_STRING([--enable-link-prefetch], [Enable Link prefetch support (default: disabled)])],
734   [],[enable_link_prefetch=no])
735 AC_MSG_RESULT([$enable_link_prefetch])
736
737 if test "$enable_link_prefetch" = "yes"; then 
738   AC_DEFINE([ENABLE_LINK_PREFETCH], [1], [Define to enable link prefetch support])
739 fi
740
741 # GObject Introspection
742 AC_MSG_CHECKING([whether to enable GObject introspection support])
743 AC_ARG_ENABLE([introspection],
744   [AS_HELP_STRING([--enable-introspection],[Enable GObject introspection (default: disabled)])],
745   [],[enable_introspection=no])
746 AC_MSG_RESULT([$enable_introspection])
747
748 G_IR_SCANNER=
749 G_IR_COMPILER=
750 G_IR_GENERATE=
751 GIRDIR=
752 GIRTYPELIBDIR=
753
754 if test "$enable_introspection" = "yes"; then
755   GOBJECT_INTROSPECTION_REQUIRED=0.9.5
756   PKG_CHECK_MODULES([INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
757   
758   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
759   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
760   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
761   AC_DEFINE([ENABLE_INTROSPECTION],[1],[Define to enable GObject introspection support])
762 fi
763
764 AC_SUBST([G_IR_SCANNER])
765 AC_SUBST([G_IR_COMPILER])
766 AC_SUBST([G_IR_GENERATE])
767
768 # determine the font backend
769 AC_MSG_CHECKING([the font backend to use])
770 AC_ARG_WITH(font_backend,
771             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
772                            [Select font backend [default=freetype]]),
773             [],[with_font_backend="freetype"])
774
775 case "$with_font_backend" in
776      freetype|pango) ;;
777      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
778 esac
779 AC_MSG_RESULT([$with_font_backend])
780
781 # Add '-g' flag to gcc if it's debug build
782 if test "$enable_debug" = "yes"; then
783    CXXFLAGS="$CXXFLAGS -g"
784    CFLAGS="$CFLAGS -g"
785 else
786    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
787 fi
788
789 # Add the appropriate 'O' level for optimized builds
790 if test "$enable_optimizations" = "yes"; then
791    CXXFLAGS="$CXXFLAGS -O2"
792    CFLAGS="$CFLAGS -O2"
793 else
794    CXXFLAGS="$CXXFLAGS -O0"
795    CFLAGS="$CFLAGS -O0"
796 fi
797
798 PKG_CHECK_MODULES([LIBSOUP],
799                   [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
800 AC_SUBST([LIBSOUP_CFLAGS])
801 AC_SUBST([LIBSOUP_LIBS])
802
803 # check if we can use libSoup 2.29.90 features
804 PKG_CHECK_MODULES([LIBSOUP_2_29_90],
805                   [libsoup-2.4 >= 2.29.90],
806                   [have_libsoup_2_29_90=yes],
807                   [have_libsoup_2_29_90=no])
808 if test "$have_libsoup_2_29_90" = "yes"; then
809    AC_DEFINE([HAVE_LIBSOUP_2_29_90], 1, [Whether libSoup 2.29.90 features are available])
810 fi
811
812 # check if FreeType/FontConfig are available
813 if test "$with_font_backend" = "freetype"; then
814    if test "$with_target" = "directfb"; then
815    PKG_CHECK_MODULES([FREETYPE],
816                      [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
817                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
818    else
819    PKG_CHECK_MODULES([FREETYPE],
820                      [cairo-ft
821                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
822                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
823    fi
824    AC_SUBST([FREETYPE_CFLAGS])
825    AC_SUBST([FREETYPE_LIBS])
826 fi
827
828 # check if sqlite 3 is available
829 if test "$enable_icon_database" = "yes" || \
830    test "$enable_database" = "yes" || \
831    test "$enable_offline_web_applications" = "yes" || \
832    test "$enable_dom_storage" = "yes"; then
833    PKG_CHECK_MODULES([SQLITE3],
834                      [sqlite3 >= $SQLITE_REQUIRED_VERSION],
835                      [sqlite3_has_pkg_config=yes],
836                      [sqlite3_has_pkg_config=no])
837    if test "$sqlite3_has_pkg_config" = "no"; then
838       AC_SEARCH_LIBS([sqlite3_open16], [sqlite3],
839                      [SQLITE3_LIBS="$LIBS";SQLITE3_CFLAGS="-I $srcdir/WebKitLibraries/WebCoreSQLite3"],
840                      [AC_MSG_ERROR([SQLite3 is required to enable Database support])])
841    fi
842    AC_SUBST([SQLITE3_CFLAGS])
843    AC_SUBST([SQLITE3_LIBS])
844 fi
845
846 # check if libxslt is available
847 if test "$enable_xslt" = "yes"; then
848    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
849    AC_SUBST([LIBXSLT_CFLAGS])
850    AC_SUBST([LIBXSLT_LIBS])
851 fi
852
853 # check if geoclue is available
854 if test "$enable_geolocation" = "yes"; then
855     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
856     AC_SUBST([GEOCLUE_CFLAGS])
857     AC_SUBST([GEOCLUE_LIBS])
858 fi
859
860 # check if gstreamer is available
861 if test "$enable_video" = "yes"; then
862    PKG_CHECK_MODULES([GSTREAMER],
863                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
864                      gstreamer-app-0.10
865                      gstreamer-base-0.10
866                      gstreamer-interfaces-0.10
867                      gstreamer-pbutils-0.10
868                      gstreamer-plugins-base-0.10 >= $GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION
869                      gstreamer-video-0.10],
870                      [have_gstreamer=yes],
871                      [have_gstreamer=no])
872
873    AC_SUBST([GSTREAMER_CFLAGS])
874    AC_SUBST([GSTREAMER_LIBS])
875 fi
876
877 # check for code coverage support
878 if test "$enable_coverage" = "yes"; then
879    COVERAGE_CFLAGS="-MD"
880    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
881    AC_SUBST([COVERAGE_CFLAGS])
882    AC_SUBST([COVERAGE_LDFLAGS])
883 fi
884
885 # check for HTML features
886 if test "$enable_video" = "yes"; then
887     html_flags=yes
888 fi
889
890 GTK_DOC_CHECK([1.10])
891
892 # OS conditionals
893 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
894 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
895 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
896 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
897 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
898
899 # target conditionals
900 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
901 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
902 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
903 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
904
905 # Unicode backend conditionals
906 AM_CONDITIONAL([USE_ICU_UNICODE], [test "$with_unicode_backend" = "icu"])
907 AM_CONDITIONAL([USE_GLIB_UNICODE], [test "$with_unicode_backend" = "glib"])
908
909 # Font backend conditionals
910 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
911 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
912
913 # GLib/GIO feature conditionals
914 AM_CONDITIONAL([USE_GSETTINGS], [test "$have_gsettings" = "yes"])
915
916 # GStreamer feature conditional
917 AM_CONDITIONAL([USE_GSTREAMER], [test "$have_gstreamer" = "yes"])
918
919 # WebKit feature conditionals
920 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
921 AM_CONDITIONAL([ENABLE_3D_TRANSFORMS],[test "$enable_3D_transforms" = "yes"])
922 AM_CONDITIONAL([ENABLE_BLOB],[test "$enable_blob" = "yes"])
923 AM_CONDITIONAL([ENABLE_CHANNEL_MESSAGING],[test "$enable_channel_messaging" = "yes"])
924 AM_CONDITIONAL([ENABLE_JAVASCRIPT_DEBUGGER],[test "$enable_javascript_debugger" = "yes"])
925 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
926 AM_CONDITIONAL([ENABLE_DIRECTORY_UPLOAD],[test "$enable_directory_upload" = "yes"])
927 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
928 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
929 AM_CONDITIONAL([ENABLE_DATALIST],[test "$enable_datalist" = "yes"])
930 AM_CONDITIONAL([ENABLE_EVENTSOURCE],[test "$enable_eventsource" = "yes"])
931 AM_CONDITIONAL([ENABLE_FAST_MOBILE_SCROLLING],[test "$enable_fast_mobile_scrolling" = "yes"])
932 AM_CONDITIONAL([ENABLE_FILE_SYSTEM],[test "$enable_file_system" = "yes"])
933 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
934 AM_CONDITIONAL([ENABLE_IMAGE_RESIZER],[test "$enable_image_resizer" = "yes"])
935 AM_CONDITIONAL([ENABLE_INDEXED_DATABASE],[test "$enable_indexed_database" = "yes"])
936 AM_CONDITIONAL([ENABLE_INPUT_SPEECH],[test "$enable_input_speech" = "yes"])
937 AM_CONDITIONAL([ENABLE_XHTMLMP],[test "$enable_xhtmlmp" = "yes"])
938 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
939 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
940 AM_CONDITIONAL([ENABLE_FILTERS],[test "$enable_filters" = "yes"])
941 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
942 AM_CONDITIONAL([ENABLE_MATHML], [test "$enable_mathml" = "yes"])
943 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
944 AM_CONDITIONAL([ENABLE_NOTIFICATIONS],[test "$enable_notifications" = "yes"])
945 AM_CONDITIONAL([ENABLE_ORIENTATION_EVENTS],[test "$enable_orientation_events" = "yes"])
946 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
947 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
948 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
949 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
950 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
951 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use" = "yes"])
952 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
953 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
954 AM_CONDITIONAL([ENABLE_WML],[test "$enable_wml" = "yes"])
955 AM_CONDITIONAL([ENABLE_WORKERS],[test "$enable_workers" = "yes"])
956 AM_CONDITIONAL([ENABLE_SHARED_WORKERS],[test "$enable_shared_workers" = "yes"])
957 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
958 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
959 AM_CONDITIONAL([ENABLE_WEB_SOCKETS],[test "$enable_web_sockets" = "yes"])
960 AM_CONDITIONAL([ENABLE_WEB_TIMING],[test "$enable_web_timing" = "yes"])
961 AM_CONDITIONAL([ENABLE_OPCODE_STATS],[test "$enable_opcode_stats" = "yes"])
962
963 # Gtk conditionals
964 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
965
966
967 AC_CONFIG_FILES([
968 GNUmakefile
969 WebKit/gtk/webkit/webkitversion.h
970 WebKit/gtk/docs/GNUmakefile
971 WebKit/gtk/docs/version.xml
972 ]
973 )
974
975 AC_CONFIG_FILES([
976 WebKit/gtk/${WEBKITGTK_PC_NAME}-${WEBKITGTK_API_VERSION}.pc:WebKit/gtk/webkit.pc.in
977 WebKit/gtk/JSCore-${WEBKITGTK_API_VERSION}.gir:WebKit/gtk/JSCore.gir.in
978 WebKit/gtk/org.webkitgtk-${WEBKITGTK_API_VERSION}.gschema.xml:WebKit/gtk/org.webkitgtk.gschema.xml.in
979 ]
980 ,[WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME]
981 )
982
983 AC_OUTPUT
984
985 echo "
986 WebKit was configured with the following options:
987
988 Build configuration:
989  Enable debugging (slow)                                  : $enable_debug
990  Enable GCC build optimization                            : $enable_optimizations
991  Code coverage support                                    : $enable_coverage
992  Unicode backend                                          : $with_unicode_backend
993  Font backend                                             : $with_font_backend
994  Optimized memory allocator                               : $enable_fast_malloc
995 Features:
996  3D Transforms                                            : $enable_3D_transforms
997  Blob support                                             : $enable_blob
998  Directory upload                                         : $enable_directory_upload
999  Fast Mobile Scrolling                                    : $enable_fast_mobile_scrolling
1000  JIT compilation                                          : $enable_jit
1001  Filters support                                          : $enable_filters
1002  Geolocation support                                      : $enable_geolocation
1003  JavaScript debugger/profiler support                     : $enable_javascript_debugger
1004  MathML support                                           : $enable_mathml
1005  HTML5 offline web applications support                   : $enable_offline_web_applications
1006  HTML5 channel messaging support                          : $enable_channel_messaging
1007  HTML5 client-side session and persistent storage support : $enable_dom_storage
1008  HTML5 client-side database storage support               : $enable_database
1009  HTML5 FileSystem API support                             : $enable_file_system
1010  HTML5 sandboxed iframe support                           : $enable_sandbox
1011  HTML5 server-sent events support                         : $enable_eventsource
1012  HTML5 video element support                              : $enable_video
1013  Icon database support                                    : $enable_icon_database
1014  Image resizer support                                    : $enable_image_resizer
1015  Link prefetch support                                    : $enable_link_prefetch
1016  Opcode stats                                             : $enable_opcode_stats
1017  SharedWorkers support                                    : $enable_shared_workers
1018  Speech input support                                     : $enable_input_speech
1019  SVG support                                              : $enable_svg
1020  SVG animation support                                    : $enable_svg_animation
1021  SVG fonts support                                        : $enable_svg_fonts
1022  SVG foreign object support                               : $enable_svg_foreign_object
1023  SVG as image support                                     : $enable_svg_as_image
1024  SVG use element support                                  : $enable_svg_use
1025  WML support                                              : $enable_wml
1026  Web Sockets support                                      : $enable_web_sockets
1027  Web Timing support                                       : $enable_web_timing
1028  Web Workers support                                      : $enable_workers
1029  XHTML-MP support                                         : $enable_xhtmlmp
1030  XPATH support                                            : $enable_xpath
1031  XSLT support                                             : $enable_xslt
1032
1033 GTK+ configuration:
1034  GTK+ version                                             : $with_gtk
1035  GDK target                                               : $with_target
1036  Hildon UI extensions                                     : $with_hildon
1037  Introspection support                                    : $enable_introspection
1038 "
1039 if test "$with_unicode_backend" = "glib"; then
1040    echo "     >> WARNING: the glib-based unicode backend is slow and incomplete <<"
1041    echo
1042    echo
1043 fi