2010-06-28 Xan Lopez <xlopez@igalia.com>
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.59)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [3])
5 m4_define([webkit_micro_version], [1])
6
7 # This is the version we'll be using as part of our User-Agent string
8 # e.g., AppleWebKit/$(webkit_user_agent_version) ...
9 #
10 # Sourced from WebCore/Configurations/Version.xcconfig
11 m4_define([webkit_user_agent_major_version], [531])
12 m4_define([webkit_user_agent_minor_version], [2])
13
14 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
15
16 AC_CONFIG_MACRO_DIR([autotools])
17 AC_CONFIG_AUX_DIR([autotools])
18 AC_SUBST(ACLOCAL_AMFLAGS, "-I autotools")
19
20 AC_CONFIG_HEADERS([autotoolsconfig.h])
21 AC_CANONICAL_HOST
22
23 WEBKIT_MAJOR_VERSION=webkit_major_version
24 WEBKIT_MINOR_VERSION=webkit_minor_version
25 WEBKIT_MICRO_VERSION=webkit_micro_version
26 WEBKIT_USER_AGENT_MAJOR_VERSION=webkit_user_agent_major_version
27 WEBKIT_USER_AGENT_MINOR_VERSION=webkit_user_agent_minor_version
28 AC_SUBST(WEBKIT_MAJOR_VERSION)
29 AC_SUBST(WEBKIT_MINOR_VERSION)
30 AC_SUBST(WEBKIT_MICRO_VERSION)
31 AC_SUBST(WEBKIT_USER_AGENT_MAJOR_VERSION)
32 AC_SUBST(WEBKIT_USER_AGENT_MINOR_VERSION)
33
34 AC_CONFIG_SRCDIR([WebCore/config.h])
35
36 dnl # Libtool library version, not to confuse with API version
37 dnl # see http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html#Libtool-versioning
38 LIBWEBKITGTK_VERSION=0:0:0
39 AC_SUBST([LIBWEBKITGTK_VERSION])
40
41 AM_INIT_AUTOMAKE([foreign subdir-objects tar-ustar])
42
43 # Use AM_SILENT_RULES if present
44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
45
46 # host checking - inspired by the GTK+ configure.in
47 # TODO: move these to webkit.m4?
48 AC_MSG_CHECKING([for native Win32])
49 case "$host" in
50      *-*-mingw*)
51        os_win32=yes
52        ;;
53      *)
54        os_win32=no
55        ;;
56 esac
57 AC_MSG_RESULT([$os_win32])
58
59 case "$host" in
60      *-*-linux*)
61        os_linux=yes
62        ;;
63      *-*-freebsd*)
64        os_freebsd=yes
65        ;;
66      *-*-darwin*)
67        os_darwin=yes
68        ;;
69 esac
70
71 case "$host_os" in
72      gnu* | linux* | k*bsd*-gnu)
73        os_gnu=yes
74        ;;
75      *)
76        os_gnu=no
77        ;;
78 esac
79
80 # initialize webkit options
81 WEBKIT_INIT
82 AC_DISABLE_STATIC
83 AC_LIBTOOL_WIN32_DLL
84 AC_PROG_LIBTOOL
85 # use dolt to speedup the build
86 DOLT
87
88 AC_PATH_PROG(FLEX, flex)
89 if test -z "$FLEX"; then
90    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
91 else
92    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
93    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
94       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
95 fi
96
97 AC_PATH_PROG(GPERF, gperf)
98 if test -z "$GPERF"; then
99    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
100 fi
101
102 # pthread (not needed on Windows)
103 if test "$os_win32" = "no"; then
104 AC_CHECK_HEADERS([pthread.h],
105                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
106                  AC_MSG_ERROR([pthread support is required to build WebKit]))
107 fi
108
109 # check for libjpeg the way Gtk does it.
110 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
111                    jpeg_ok=yes, jpeg_ok=no
112                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
113 if test "$jpeg_ok" = yes; then
114    AC_MSG_CHECKING([for jpeglib])
115    AC_TRY_CPP(
116 [#include <stdio.h>
117 #undef PACKAGE
118 #undef VERSION
119 #undef HAVE_STDLIB_H
120 #include <jpeglib.h>],
121          jpeg_ok=yes,
122          jpeg_ok=no)
123    AC_MSG_RESULT($jpeg_ok)
124    if test "$jpeg_ok" = yes; then
125       JPEG_LIBS="-ljpeg"
126       # should we check for progressive JPEG like GTK+ as well?
127    else
128       AC_MSG_ERROR([JPEG library (libjpeg) not found])
129    fi
130 fi
131 AC_SUBST([JPEG_LIBS])
132
133 # Check for libpng the way Gtk+ does it
134 for l in libpng libpng14 libpng12; do
135   AC_MSG_CHECKING(for $l)
136   if $PKG_CONFIG --exists $l ; then
137     AC_MSG_RESULT(yes)
138     PNG_LIBS=`$PKG_CONFIG --libs $l`
139     png_ok=yes
140     break
141   else
142     AC_MSG_RESULT(no)
143     png_ok=no
144   fi
145 done
146 if test "$png_ok" != yes; then
147   AC_CHECK_LIB(png, png_read_info,
148     [AC_CHECK_HEADER(png.h,
149       png_ok=yes,
150       png_ok=no)],
151     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
152   if test "$png_ok" = yes; then
153     AC_MSG_CHECKING([for png_structp in png.h])
154     AC_TRY_COMPILE([#include <png.h>],
155       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
156       png_ok=yes,
157       png_ok=no)
158     AC_MSG_RESULT($png_ok)
159     if test "$png_ok" = yes; then
160       PNG_LIBS='-lpng -lz'
161     else
162       AC_MSG_ERROR([PNG library (libpng) not found])
163     fi
164   else
165     AC_MSG_ERROR([PNG library (libpng) not found])
166   fi
167 fi
168 AC_SUBST([PNG_LIBS])
169
170 # determine the GTK+ version to use
171 AC_MSG_CHECKING([the GTK+ version to use])
172 AC_ARG_WITH([gtk],
173         [AS_HELP_STRING([--with-gtk=2.0|3.0], [the GTK+ version to use (default: 2.0)])],
174         [case "$with_gtk" in
175         2.0|3.0) ;;
176         *) AC_MSG_ERROR([invalid GTK+ version specified]) ;;
177         esac],
178         [with_gtk=2.0])
179 AC_MSG_RESULT([$with_gtk])
180
181 case "$with_gtk" in
182      2.0) GTK_REQUIRED_VERSION=2.10
183           GTK_API_VERSION=2.0
184           WEBKITGTK_API_MAJOR_VERSION=1
185           WEBKITGTK_API_MINOR_VERSION=0
186           WEBKITGTK_API_VERSION=1.0
187           WEBKITGTK_PC_NAME=webkit
188           GAIL_PC_NAME=gail
189           GAIL_REQUIRED_VERSION=1.8
190           ;;
191      3.0) GTK_REQUIRED_VERSION=2.90
192           GTK_API_VERSION=3.0
193           WEBKITGTK_API_MAJOR_VERSION=3
194           WEBKITGTK_API_MINOR_VERSION=0
195           WEBKITGTK_API_VERSION=3.0
196           WEBKITGTK_PC_NAME=webkitgtk
197           GAIL_PC_NAME=gail-3.0
198           GAIL_REQUIRED_VERSION=2.90.4
199           ;;
200 esac
201
202 AC_SUBST([WEBKITGTK_API_MAJOR_VERSION])
203 AC_SUBST([WEBKITGTK_API_MINOR_VERSION])
204 AC_SUBST([WEBKITGTK_API_VERSION])
205 AC_SUBST([WEBKITGTK_PC_NAME])
206 AC_SUBST([GTK_API_VERSION])
207
208 # determine the GDK/GTK+ target
209 AC_MSG_CHECKING([the target windowing system])
210 AC_ARG_WITH(target,
211             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
212                            [Select webkit target [default=x11]]),
213             [],[with_target="x11"])
214
215 case "$with_target" in
216      x11|win32|quartz|directfb) ;;
217      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
218 esac
219
220 AC_MSG_RESULT([$with_target])
221
222 AC_MSG_CHECKING([for Hildon UI extensions])
223 AC_ARG_WITH(hildon,
224             AC_HELP_STRING([--with-hildon],
225                            [Use Hildon UI extensions [default=no]]),
226             [],[with_hildon="no"])
227 AC_MSG_RESULT([$with_hildon])
228
229 if test "$with_hildon" = "yes"; then
230     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
231     PKG_CHECK_MODULES([HILDON], [hildon-1])
232     AC_SUBST([HILDON_CPPFLAGS])
233     AC_SUBST([HILDON_CFLAGS])
234     AC_SUBST([HILDON_LIBS])
235 fi
236
237 # minimum base dependencies
238 LIBSOUP_REQUIRED_VERSION=2.28.2
239 CAIRO_REQUIRED_VERSION=1.6
240 FONTCONFIG_REQUIRED_VERSION=2.4
241 FREETYPE2_REQUIRED_VERSION=9.0
242 LIBXML_REQUIRED_VERSION=2.6
243
244 # minimum GTK+ base dependencies
245 PANGO_REQUIRED_VERSION=1.12
246
247 # optional modules
248 LIBXSLT_REQUIRED_VERSION=1.1.7
249 SQLITE_REQUIRED_VERSION=3.0
250 GSTREAMER_REQUIRED_VERSION=0.10
251 GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION=0.10.25
252 ENCHANT_REQUIRED_VERSION=0.22
253
254 # Available modules
255 #
256 # glib - glib and includes gthread
257 # unicode - check and identify which unicode backend to use
258 #
259 # todo: webcore gtk
260 WEBKIT_CHECK_DEPENDENCIES([glib unicode])
261
262 GETTEXT_PACKAGE=$PACKAGE
263 AC_SUBST(GETTEXT_PACKAGE)
264 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
265                    [The gettext catalog name])
266
267 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
268 AC_SUBST(LIBXML_CFLAGS)
269 AC_SUBST(LIBXML_LIBS)
270
271 PKG_CHECK_MODULES(PANGO, 
272                   [pango >= $PANGO_REQUIRED_VERSION
273                    pangoft2])
274 AC_SUBST(PANGO_CFLAGS)
275 AC_SUBST(PANGO_LIBS)
276
277 PKG_CHECK_MODULES(ENCHANT, enchant >= $ENCHANT_REQUIRED_VERSION)
278 AC_SUBST(ENCHANT_CFLAGS)
279 AC_SUBST(ENCHANT_LIBS)
280
281 PKG_CHECK_MODULES(GAIL, $GAIL_PC_NAME >= $GAIL_REQUIRED_VERSION)
282 AC_SUBST(GAIL_CFLAGS)
283 AC_SUBST(GAIL_LIBS)
284
285 # check for target-specific dependencies
286 if test "$with_target" = "directfb"; then
287    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
288    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
289    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
290 else
291    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
292    PKG_CHECK_MODULES(GTK, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED_VERSION)
293
294    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
295       # check for XT
296       PKG_CHECK_MODULES([XT],
297                         [xt],
298                         [xt_has_pkg_config=yes],
299                         [xt_has_pkg_config=no])
300       # some old versions of Xt do not provide xt.pc, so try to link against Xt
301       # and if it's installed fall back to just adding -lXt
302       if test "$xt_has_pkg_config" = "no"; then
303          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
304          # we don't care about the XtOpenDisplay symbol but only about the
305          # existence of libXt
306          AC_CHECK_LIB([Xt], [XtOpenDisplay],
307                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
308                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
309       fi
310       AC_SUBST([XT_CFLAGS])
311       AC_SUBST([XT_LIBS])
312       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
313    fi
314 fi
315 AC_SUBST(GTK_CFLAGS)
316 AC_SUBST(GTK_LIBS)
317 AC_SUBST(CAIRO_CFLAGS)
318 AC_SUBST(CAIRO_LIBS)
319
320 # check whether to build with debugging enabled
321 AC_MSG_CHECKING([whether to do a debug build])
322 AC_ARG_ENABLE(debug,
323               AC_HELP_STRING([--enable-debug],
324                              [turn on debugging [default=no]]),
325               [],[enable_debug="no"])
326 AC_MSG_RESULT([$enable_debug])
327
328 # check whether to enable optimized builds
329 AC_MSG_CHECKING([whether to enable optimized builds])
330 AC_ARG_ENABLE(optimizations,
331               AC_HELP_STRING([--enable-optimizations],
332                              [turn on optimize builds (GCC only)
333                              [default=yes]]),
334               [enable_optimizations=$enableval],
335               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
336 AC_MSG_RESULT([$enable_optimizations])
337
338 # check whether to enable 3D transforms support
339 AC_MSG_CHECKING([whether to enable support for 3D Transforms])
340 AC_ARG_ENABLE(3D_transforms,
341               AC_HELP_STRING([--enable-3D-transforms],
342                              [enable support for 3D transforms [default=no]]),
343               [],[enable_3D_transforms="no"])
344 AC_MSG_RESULT([$enable_3D_transforms])
345
346 # check whether to enable channel messaging support
347 AC_MSG_CHECKING([whether to enable HTML5 Channel Messaging support])
348 AC_ARG_ENABLE(channel_messaging,
349               AC_HELP_STRING([--enable-channel-messaging],
350                              [enable HTML5 channel messaging support [default=yes]]),
351               [],[enable_channel_messaging="yes"])
352 AC_MSG_RESULT([$enable_channel_messaging])
353
354 # check whether to enable JavaScript debugger/profiler support
355 AC_MSG_CHECKING([whether to enable JavaScript debugger/profiler support])
356 AC_ARG_ENABLE(javascript_debugger,
357               AC_HELP_STRING([--enable-javascript-debugger],
358                              [enable JavaScript debugger/profiler support [default=yes]]),
359               [],[enable_javascript_debugger="yes"])
360 AC_MSG_RESULT([$enable_javascript_debugger])
361
362 # check whether to enable HTML5 Offline Web Applications support
363 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
364 AC_ARG_ENABLE(offline_web_applications,
365               AC_HELP_STRING([--enable-offline-web-applications],
366                              [enable HTML5 offline web applications support [default=yes]]),
367               [],[enable_offline_web_applications="yes"])
368 AC_MSG_RESULT([$enable_offline_web_applications])
369
370 # check whether to enable HTML5 client-side session and persitent storage support
371 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
372 AC_ARG_ENABLE(dom_storage,
373               AC_HELP_STRING([--enable-dom-storage],
374                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
375               [],[enable_dom_storage="yes"])
376 AC_MSG_RESULT([$enable_dom_storage])
377
378 # check whether to enable the indexed database API
379 AC_MSG_CHECKING([whether to enable the indexed database API])
380 AC_ARG_ENABLE(indexed_database,
381               AC_HELP_STRING([--enable-indexeddb],
382                              [enable the indexed database API [default=no]]),
383               [],[enable_indexed_database="no"])
384 AC_MSG_RESULT([$enable_indexed_database])
385
386 # check whether to enable the speech input API
387 AC_MSG_CHECKING([whether to enable the speech input API])
388 AC_ARG_ENABLE(input_speech,
389               AC_HELP_STRING([--enable-input-speech],
390                              [enable the speech input API [default=no]]),
391               [],[enable_input_speech="no"])
392 AC_MSG_RESULT([$enable_input_speech])
393
394 # check whether to build with database support
395 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
396 AC_ARG_ENABLE(database,
397               AC_HELP_STRING([--enable-database],
398                              [enable HTML5 client-side database storage support [default=yes]]),
399               [],[enable_database="yes"])
400 AC_MSG_RESULT([$enable_database])
401
402 # check whether to build with server-sent events support
403 AC_MSG_CHECKING([whether to enable HTML5 server-sent events support])
404 AC_ARG_ENABLE(eventsource,
405               AC_HELP_STRING([--enable-eventsource],
406                              [enable HTML5 server-sent events support [default=yes]]),
407               [],[enable_eventsource="yes"])
408 AC_MSG_RESULT([$enable_eventsource])
409
410 # check whether to build with icon database support
411 AC_MSG_CHECKING([whether to enable icon database support])
412 AC_ARG_ENABLE(icon_database,
413               AC_HELP_STRING([--enable-icon-database],
414                              [enable icon database [default=yes]]),
415               [],[enable_icon_database="yes"])
416 AC_MSG_RESULT([$enable_icon_database])
417
418 # check whether to build with image resizer API support
419 AC_MSG_CHECKING([whether to enable image resizer API support])
420 AC_ARG_ENABLE(image_resizer,
421               AC_HELP_STRING([--enable-image-resizer],
422                              [enable image resizer [default=no]]),
423               [],[enable_image_resizer="no"])
424 AC_MSG_RESULT([$enable_image_resizer])
425
426 # check whether to enable HTML5 datalist support
427 AC_MSG_CHECKING([whether to enable HTML5 datalist support])
428 AC_ARG_ENABLE(datalist,
429               AC_HELP_STRING([--enable-datalist],
430                              [enable HTML5 datalist support [default=yes]]),
431               [],[enable_datalist="yes"])
432 AC_MSG_RESULT([$enable_datalist])
433
434 # check whether to enable HTML5 ruby support
435 AC_MSG_CHECKING([whether to enable HTML5 ruby support])
436 AC_ARG_ENABLE(ruby,
437               AC_HELP_STRING([--enable-ruby],
438                              [enable HTML5 ruby support [default=yes]]),
439               [],[enable_ruby="yes"])
440 AC_MSG_RESULT([$enable_ruby])
441
442 # check whether to enable HTML5 sandbox iframe support
443 AC_MSG_CHECKING([whether to enable HTML5 sandboxed iframe support])
444 AC_ARG_ENABLE(sandbox,
445               AC_HELP_STRING([--enable-sandbox],
446                              [enable HTML5 sandboxed iframe support [default=yes]]),
447               [],[enable_sandbox="yes"])
448 AC_MSG_RESULT([$enable_sandbox])
449
450 # check whether to enable HTML5 audio/video support
451 AC_MSG_CHECKING([whether to enable HTML5 video support])
452 AC_ARG_ENABLE(video,
453               AC_HELP_STRING([--enable-video],
454                              [enable HTML5 video support [default=yes]]),
455               [],[enable_video="yes"])
456 AC_MSG_RESULT([$enable_video])
457
458 # check whether to enable XHTML-MP support
459 AC_MSG_CHECKING([whether to enable XHTML-MP support])
460 AC_ARG_ENABLE(xhtmlmp,
461               AC_HELP_STRING([--enable-xhtmlmp],
462                              [enable support for XHTML-MP [default=no]]),
463               [],[enable_xhtmlmp="no"])
464 AC_MSG_RESULT([$enable_xhtmlmp])
465
466 # check whether to enable XPath support
467 AC_MSG_CHECKING([whether to enable XPath support])
468 AC_ARG_ENABLE(xpath,
469               AC_HELP_STRING([--enable-xpath],
470                              [enable support for XPath [default=yes]]),
471               [],[enable_xpath="yes"])
472 AC_MSG_RESULT([$enable_xpath])
473
474 # check whether to enable XSLT support
475 AC_MSG_CHECKING([whether to enable XSLT support])
476 AC_ARG_ENABLE(xslt,
477               AC_HELP_STRING([--enable-xslt],
478                              [enable support for XSLT [default=yes]]),
479               [],[enable_xslt="yes"])
480 AC_MSG_RESULT([$enable_xslt])
481
482 # check whether to enable geolocation support
483 AC_MSG_CHECKING([whether to enable geolocation support])
484 AC_ARG_ENABLE(geolocation,
485               AC_HELP_STRING([--enable-geolocation],
486                              [enable support for geolocation [default=no]]),
487               [],[enable_geolocation="no"])
488 AC_MSG_RESULT([$enable_geolocation])
489
490 # check whether to enable MathML support
491 AC_MSG_CHECKING([whether to enable MathML support])
492 AC_ARG_ENABLE(mathml,
493               AC_HELP_STRING([--enable-mathml],
494                              [enable support for MathML [default=no]]),
495               [],[enable_mathml="no"])
496 AC_MSG_RESULT([$enable_mathml])
497
498 # check whether to enable SVG support
499 AC_MSG_CHECKING([whether to enable SVG support])
500 AC_ARG_ENABLE(svg,
501               AC_HELP_STRING([--enable-svg],
502                              [enable support for SVG [default=yes]]),
503               [],[enable_svg="yes"])
504 AC_MSG_RESULT([$enable_svg])
505
506 # check whether to enable WML support
507 AC_MSG_CHECKING([whether to enable WML support])
508 AC_ARG_ENABLE(wml,
509               AC_HELP_STRING([--enable-wml],
510                              [enable support for WML [default=no]]),
511               [],[enable_wml="no"])
512 AC_MSG_RESULT([$enable_wml])
513
514 # check whether to enable SharedWorkers support
515 AC_MSG_CHECKING([whether to enable SharedWorkers support])
516 AC_ARG_ENABLE(shared_workers,
517               AC_HELP_STRING([--enable-shared-workers],
518                              [enable support for SharedWorkers [default=yes]]),
519               [],[enable_shared_workers="yes"])
520 AC_MSG_RESULT([$enable_shared_workers])
521
522 # check whether to enable Web Workers support
523 AC_MSG_CHECKING([whether to enable Web Workers support])
524 AC_ARG_ENABLE(workers,
525               AC_HELP_STRING([--enable-workers],
526                              [enable support for Web Workers [default=yes]]),
527               [],[enable_workers="yes"])
528 AC_MSG_RESULT([$enable_workers])
529
530 # turn off svg features if --disable-svg is requested
531 if test "$enable_svg" = "no"; then
532    enable_svg_animation=no
533    enable_svg_fonts=no
534    enable_svg_foreign_object=no
535    enable_svg_as_image=no
536    enable_svg_use=no
537 fi
538
539 # check whether to enable support for SVG animation
540 AC_MSG_CHECKING([whether to enable support for SVG animation])
541 AC_ARG_ENABLE(svg_animation,
542               AC_HELP_STRING([--enable-svg-animation],
543                              [enable support for SVG animation (experimental) [default=yes]]),
544               [],[enable_svg_animation="yes"])
545 AC_MSG_RESULT([$enable_svg_animation])
546
547 # check whether to enable support for filters
548 AC_MSG_CHECKING([whether to enable support for filters])
549 AC_ARG_ENABLE(filters,
550               AC_HELP_STRING([--enable-filters],
551                              [enable support for filters (experimental) [default=yes]]),
552               [],[enable_filters="yes"])
553 AC_MSG_RESULT([$enable_filters])
554
555 # check whether to enable support for SVG fonts
556 AC_MSG_CHECKING([whether to enable support for SVG fonts])
557 AC_ARG_ENABLE(svg_fonts,
558               AC_HELP_STRING([--enable-svg-fonts],
559                              [enable support for SVG fonts (experimental) [default=yes]]),
560               [],[enable_svg_fonts="yes"])
561 AC_MSG_RESULT([$enable_svg_fonts])
562
563 # check whether to enable foreign objects support for SVG
564 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
565 AC_ARG_ENABLE(svg_foreign_object,
566               AC_HELP_STRING([--enable-svg-foreign-object],
567                              [enable support for SVG foreign objects (experimental) [default=yes]]),
568               [],[enable_svg_foreign_object="yes"])
569 AC_MSG_RESULT([$enable_svg_foreign_object])
570
571 # check whether to enable SVG As Image support
572 AC_MSG_CHECKING([whether to enable SVG as Image support])
573 AC_ARG_ENABLE(svg_as_image,
574               AC_HELP_STRING([--enable-svg-as-image],
575                              [enable SVG as Image support (experimental) [default=yes]]),
576               [],[enable_svg_as_image="yes"])
577 AC_MSG_RESULT([$enable_svg_as_image])
578
579 # check whether to enable SVG USE element support
580 AC_MSG_CHECKING([whether to enable support for SVG use element])
581 AC_ARG_ENABLE(svg_use,
582               AC_HELP_STRING([--enable-svg-use],
583                              [enable SVG use element support (experimental) [default=yes]]),
584               [],[enable_svg_use="yes"])
585 AC_MSG_RESULT([$enable_svg_use])
586
587 # check for SVG features, enabling SVG if necessary
588 if test "$enable_svg_animation" = "yes" || \
589    test "$enable_svg_fonts" = "yes" || \
590    test "$enable_svg_foreign_object" = "yes" || \
591    test "$enable_svg_as_image" = "yes" || \
592    test "$enable_svg_use" = "yes"; then
593    svg_flags=yes
594    if test "$enable_svg" = "no"; then
595        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
596        enable_svg=yes
597    fi
598 fi
599
600 # check whether to enable Web Socket support
601 AC_MSG_CHECKING([whether to enable Web Sockets support])
602 AC_ARG_ENABLE(web_sockets,
603               AC_HELP_STRING([--enable-web-sockets],
604                              [enable support for Web Sockets [default=no]]),
605               [],[enable_web_sockets="no"])
606 AC_MSG_RESULT([$enable_web_sockets])
607
608 # check whether to enable Web Timing support
609 AC_MSG_CHECKING([whether to enable Web Timing support])
610 AC_ARG_ENABLE(web_timing,
611               AC_HELP_STRING([--enable-web-timing],
612                              [enable support for Web Timing [default=no]]),
613               [],[enable_web_timing="no"])
614 AC_MSG_RESULT([$enable_web_timing])
615
616 # check whether to enable Blob.slice support
617 AC_MSG_CHECKING([whether to enable Blob.slice support])
618 AC_ARG_ENABLE(blob_slice,
619               AC_HELP_STRING([--enable-blob-slice],
620                              [enable support for Blob.slice [default=no]]),
621               [],[enable_blob_slice="no"])
622 AC_MSG_RESULT([$enable_blob_slice])
623
624 # check whether to enable Fast Mobile Scrolling support
625 AC_MSG_CHECKING([whether to enable Fast Mobile Scrolling])
626 AC_ARG_ENABLE(fast_mobile_scrolling,
627               AC_HELP_STRING([--enable-fast-mobile-scrolling],
628                              [enable support for Fast Mobile Scrolling [default=no]]),
629               [],[enable_fast_mobile_scrolling="no"])
630 AC_MSG_RESULT([$enable_fast_mobile_scrolling])
631
632 # check whether to enable FileReader support
633 AC_MSG_CHECKING([whether to enable FileReader support])
634 AC_ARG_ENABLE(file_reader,
635               AC_HELP_STRING([--enable-file-reader],
636                              [enable support for FileReader [default=no]]),
637               [],[enable_file_reader="no"])
638 AC_MSG_RESULT([$enable_file_reader])
639
640 # check whether to enable FileWriter support
641 AC_MSG_CHECKING([whether to enable FileWriter support])
642 AC_ARG_ENABLE(file_writer,
643               AC_HELP_STRING([--enable-file-writer],
644                              [enable support for FileWriter [default=no]]),
645               [],[enable_file_writer="no"])
646 AC_MSG_RESULT([$enable_file_writer])
647
648 # check whether to enable code coverage
649 AC_MSG_CHECKING([whether to enable code coverage support])
650 AC_ARG_ENABLE(coverage,
651               AC_HELP_STRING([--enable-coverage],
652                              [enable code coverage support [default=no]]),
653               [],[enable_coverage="no"])
654 AC_MSG_RESULT([$enable_coverage])
655
656 # check whether to enable FastMalloc
657 AC_MSG_CHECKING([whether to enable optimized memory allocator])
658 AC_ARG_ENABLE(fast_malloc,
659               AC_HELP_STRING([--enable-fast-malloc],
660                              [enable optimized memory allocator default=yes, default=no for debug builds]),
661               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
662 AC_MSG_RESULT([$enable_fast_malloc])
663
664 AC_MSG_CHECKING([whether to enable JIT compilation])
665 AC_ARG_ENABLE([jit],
666               AC_HELP_STRING([--enable-jit],
667                              [Enable JIT compilation default=yes]),
668               [],[enable_jit="yes"])
669 if test "$enable_jit" = "yes"; then
670     case "$host_cpu" in
671         i*86|x86_64)
672             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
673             AC_DEFINE([ENABLE_YARR], [1], [Define to enable YARR])
674             AC_DEFINE([ENABLE_YARR_JIT], [1], [Define to enable YARR JIT])
675             AC_DEFINE([ENABLE_JIT_OPTIMIZE_CALL], [1], [Define to enable optimizing calls])
676             AC_DEFINE([ENABLE_JIT_OPTIMIZE_PROPERTY_ACCESS], [1], [Define to enable optimized property access])
677             AC_DEFINE([ENABLE_JIT_OPTIMIZE_ARITHMETIC], [1], [Define to enable optimized arithmetic])
678             case "$host_cpu" in
679                 i*86)
680                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_VA_LIST], [1], [Use stub va_list])
681                 ;;
682                 x86_64)
683                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_REGISTER], [1], [Use stub register])
684                     AC_DEFINE([WTF_USE_ALTERNATE_JSIMMEDIATE], [1], [Use alternate JSImmediate])
685                 ;;
686             esac
687         ;;
688         *)
689             enable_jit="no (CPU '$host_cpu' not supported)"
690         ;;
691     esac
692 fi
693 AC_MSG_RESULT([$enable_jit])
694
695 # GObject Introspection
696 AC_MSG_CHECKING([whether to enable GObject introspection support])
697 AC_ARG_ENABLE([introspection],
698   [AS_HELP_STRING([--enable-introspection],[Enable GObject introspection (default: disabled)])],
699   [],[enable_introspection=no])
700 AC_MSG_RESULT([$enable_introspection])
701
702 G_IR_SCANNER=
703 G_IR_COMPILER=
704 G_IR_GENERATE=
705 GIRDIR=
706 GIRTYPELIBDIR=
707
708 if test "$enable_introspection" = "yes"; then
709   GOBJECT_INTROSPECTION_REQUIRED=0.6.2
710   PKG_CHECK_MODULES([INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
711   
712   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
713   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
714   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
715   AC_DEFINE([ENABLE_INTROSPECTION],[1],[Define to enable GObject introspection support])
716 fi
717
718 AC_SUBST([G_IR_SCANNER])
719 AC_SUBST([G_IR_COMPILER])
720 AC_SUBST([G_IR_GENERATE])
721
722 # determine the font backend
723 AC_MSG_CHECKING([the font backend to use])
724 AC_ARG_WITH(font_backend,
725             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
726                            [Select font backend [default=freetype]]),
727             [],[with_font_backend="freetype"])
728
729 case "$with_font_backend" in
730      freetype|pango) ;;
731      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
732 esac
733 AC_MSG_RESULT([$with_font_backend])
734
735 # Add '-g' flag to gcc if it's debug build
736 if test "$enable_debug" = "yes"; then
737    CXXFLAGS="$CXXFLAGS -g"
738    CFLAGS="$CFLAGS -g"
739 else
740    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
741 fi
742
743 # Add the appropriate 'O' level for optimized builds
744 if test "$enable_optimizations" = "yes"; then
745    CXXFLAGS="$CXXFLAGS -O2"
746    CFLAGS="$CFLAGS -O2"
747 else
748    CXXFLAGS="$CXXFLAGS -O0"
749    CFLAGS="$CFLAGS -O0"
750 fi
751
752 PKG_CHECK_MODULES([LIBSOUP],
753                   [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
754 AC_SUBST([LIBSOUP_CFLAGS])
755 AC_SUBST([LIBSOUP_LIBS])
756
757 # check if we can use libSoup 2.29.90 features
758 PKG_CHECK_MODULES([LIBSOUP_2_29_90],
759                   [libsoup-2.4 >= 2.29.90],
760                   [have_libsoup_2_29_90=yes],
761                   [have_libsoup_2_29_90=no])
762 if test "$have_libsoup_2_29_90" = "yes"; then
763    AC_DEFINE([HAVE_LIBSOUP_2_29_90], 1, [Whether libSoup 2.29.90 features are available])
764 fi
765
766 # check if FreeType/FontConfig are available
767 if test "$with_font_backend" = "freetype"; then
768    if test "$with_target" = "directfb"; then
769    PKG_CHECK_MODULES([FREETYPE],
770                      [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
771                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
772    else
773    PKG_CHECK_MODULES([FREETYPE],
774                      [cairo-ft
775                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
776                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
777    fi
778    AC_SUBST([FREETYPE_CFLAGS])
779    AC_SUBST([FREETYPE_LIBS])
780 fi
781
782 # check if sqlite 3 is available
783 if test "$enable_icon_database" = "yes" || \
784    test "$enable_database" = "yes" || \
785    test "$enable_offline_web_applications" = "yes" || \
786    test "$enable_dom_storage" = "yes"; then
787    PKG_CHECK_MODULES([SQLITE3],
788                      [sqlite3 >= $SQLITE_REQUIRED_VERSION],
789                      [sqlite3_has_pkg_config=yes],
790                      [sqlite3_has_pkg_config=no])
791    if test "$sqlite3_has_pkg_config" = "no"; then
792       AC_SEARCH_LIBS([sqlite3_open16], [sqlite3],
793                      [SQLITE3_LIBS="$LIBS";SQLITE3_CFLAGS="-I $srcdir/WebKitLibraries/WebCoreSQLite3"],
794                      [AC_MSG_ERROR([SQLite3 is required to enable Database support])])
795    fi
796    AC_SUBST([SQLITE3_CFLAGS])
797    AC_SUBST([SQLITE3_LIBS])
798 fi
799
800 # check if libxslt is available
801 if test "$enable_xslt" = "yes"; then
802    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
803    AC_SUBST([LIBXSLT_CFLAGS])
804    AC_SUBST([LIBXSLT_LIBS])
805 fi
806
807 # check if geoclue is available
808 if test "$enable_geolocation" = "yes"; then
809     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
810     AC_SUBST([GEOCLUE_CFLAGS])
811     AC_SUBST([GEOCLUE_LIBS])
812 fi
813
814 # check if gstreamer is available
815 if test "$enable_video" = "yes"; then
816    PKG_CHECK_MODULES([GSTREAMER],
817                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
818                      gstreamer-app-0.10
819                      gstreamer-base-0.10
820                      gstreamer-pbutils-0.10
821                      gstreamer-plugins-base-0.10 >= $GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION
822                      gstreamer-video-0.10])
823    AC_SUBST([GSTREAMER_CFLAGS])
824    AC_SUBST([GSTREAMER_LIBS])
825 fi
826
827 # check for code coverage support
828 if test "$enable_coverage" = "yes"; then
829    COVERAGE_CFLAGS="-MD"
830    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
831    AC_SUBST([COVERAGE_CFLAGS])
832    AC_SUBST([COVERAGE_LDFLAGS])
833 fi
834
835 # check for HTML features
836 if test "$enable_video" = "yes"; then
837     html_flags=yes
838 fi
839
840 GTK_DOC_CHECK([1.10])
841
842 # OS conditionals
843 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
844 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
845 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
846 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
847 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
848
849 # target conditionals
850 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
851 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
852 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
853 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
854
855 # Unicode backend conditionals
856 AM_CONDITIONAL([USE_ICU_UNICODE], [test "$with_unicode_backend" = "icu"])
857 AM_CONDITIONAL([USE_GLIB_UNICODE], [test "$with_unicode_backend" = "glib"])
858
859 # Font backend conditionals
860 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
861 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
862
863 # WebKit feature conditionals
864 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
865 AM_CONDITIONAL([ENABLE_3D_TRANSFORMS],[test "$enable_3D_transforms" = "yes"])
866 AM_CONDITIONAL([ENABLE_BLOB_SLICE],[test "$enable_blob_slice" = "yes"])
867 AM_CONDITIONAL([ENABLE_CHANNEL_MESSAGING],[test "$enable_channel_messaging" = "yes"])
868 AM_CONDITIONAL([ENABLE_JAVASCRIPT_DEBUGGER],[test "$enable_javascript_debugger" = "yes"])
869 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
870 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
871 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
872 AM_CONDITIONAL([ENABLE_DATALIST],[test "$enable_datalist" = "yes"])
873 AM_CONDITIONAL([ENABLE_EVENTSOURCE],[test "$enable_eventsource" = "yes"])
874 AM_CONDITIONAL([ENABLE_FAST_MOBILE_SCROLLING],[test "$enable_fast_mobile_scrolling" = "yes"])
875 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
876 AM_CONDITIONAL([ENABLE_IMAGE_RESIZER],[test "$enable_image_resizer" = "yes"])
877 AM_CONDITIONAL([ENABLE_INDEXED_DATABASE],[test "$enable_indexed_database" = "yes"])
878 AM_CONDITIONAL([ENABLE_INPUT_SPEECH],[test "$enable_input_speech" = "yes"])
879 AM_CONDITIONAL([ENABLE_XHTMLMP],[test "$enable_xhtmlmp" = "yes"])
880 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
881 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
882 AM_CONDITIONAL([ENABLE_FILTERS],[test "$enable_filters" = "yes"])
883 AM_CONDITIONAL([ENABLE_FILE_READER],[test "$enable_file_reader" = "yes"])
884 AM_CONDITIONAL([ENABLE_FILE_WRITER],[test "$enable_file_writer" = "yes"])
885 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
886 AM_CONDITIONAL([ENABLE_MATHML], [test "$enable_mathml" = "yes"])
887 AM_CONDITIONAL([ENABLE_RUBY],[test "$enable_ruby" = "yes"])
888 AM_CONDITIONAL([ENABLE_SANDBOX],[test "$enable_sandbox" = "yes"])
889 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
890 AM_CONDITIONAL([ENABLE_NOTIFICATIONS],[test "$enable_notifications" = "yes"])
891 AM_CONDITIONAL([ENABLE_ORIENTATION_EVENTS],[test "$enable_orientation_events" = "yes"])
892 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
893 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
894 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
895 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
896 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
897 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use" = "yes"])
898 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
899 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
900 AM_CONDITIONAL([ENABLE_WML],[test "$enable_wml" = "yes"])
901 AM_CONDITIONAL([ENABLE_WORKERS],[test "$enable_workers" = "yes"])
902 AM_CONDITIONAL([ENABLE_SHARED_WORKERS],[test "$enable_shared_workers" = "yes"])
903 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
904 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
905 AM_CONDITIONAL([ENABLE_WEB_SOCKETS],[test "$enable_web_sockets" = "yes"])
906 AM_CONDITIONAL([ENABLE_WEB_TIMING],[test "$enable_web_timing" = "yes"])
907
908 # Gtk conditionals
909 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
910
911
912 AC_CONFIG_FILES([
913 GNUmakefile
914 WebKit/gtk/webkit/webkitversion.h
915 WebKit/gtk/docs/GNUmakefile
916 WebKit/gtk/docs/version.xml
917 ]
918 )
919
920 AC_CONFIG_FILES([
921 WebKit/gtk/${WEBKITGTK_PC_NAME}-${WEBKITGTK_API_VERSION}.pc:WebKit/gtk/webkit.pc.in
922 WebKit/gtk/JSCore-${WEBKITGTK_API_VERSION}.gir:WebKit/gtk/JSCore.gir.in]
923 ,[WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME]
924 )
925
926 AC_OUTPUT
927
928 echo "
929 WebKit was configured with the following options:
930
931 Build configuration:
932  Enable debugging (slow)                                  : $enable_debug
933  Enable GCC build optimization                            : $enable_optimizations
934  Code coverage support                                    : $enable_coverage
935  Unicode backend                                          : $with_unicode_backend
936  Font backend                                             : $with_font_backend
937  Optimized memory allocator                               : $enable_fast_malloc
938 Features:
939  3D Transforms                                            : $enable_3D_transforms
940  Blob.slice support                                       : $enable_blob_slice
941  Fast Mobile Scrolling                                    : $enable_fast_mobile_scrolling
942  JIT compilation                                          : $enable_jit
943  Filters support                                          : $enable_filters
944  FileReader support                                       : $enable_file_reader
945  FileWriter support                                       : $enable_file_writer
946  Geolocation support                                      : $enable_geolocation
947  JavaScript debugger/profiler support                     : $enable_javascript_debugger
948  MathML support                                           : $enable_mathml
949  HTML5 offline web applications support                   : $enable_offline_web_applications
950  HTML5 channel messaging support                          : $enable_channel_messaging
951  HTML5 client-side session and persistent storage support : $enable_dom_storage
952  HTML5 client-side database storage support               : $enable_database
953  HTML5 ruby support                                       : $enable_ruby
954  HTML5 sandboxed iframe support                           : $enable_sandbox
955  HTML5 server-sent events support                         : $enable_eventsource
956  HTML5 video element support                              : $enable_video
957  Icon database support                                    : $enable_icon_database
958  Image resizer support                                    : $enable_image_resizer
959  SharedWorkers support                                    : $enable_shared_workers
960  Speech input support                                     : $enable_input_speech
961  SVG support                                              : $enable_svg
962  SVG animation support                                    : $enable_svg_animation
963  SVG fonts support                                        : $enable_svg_fonts
964  SVG foreign object support                               : $enable_svg_foreign_object
965  SVG as image support                                     : $enable_svg_as_image
966  SVG use element support                                  : $enable_svg_use
967  WML support                                              : $enable_wml
968  Web Sockets support                                      : $enable_web_sockets
969  Web Timing support                                       : $enable_web_timing
970  Web Workers support                                      : $enable_workers
971  XHTML-MP support                                         : $enable_xhtmlmp
972  XPATH support                                            : $enable_xpath
973  XSLT support                                             : $enable_xslt
974 GTK+ configuration:
975  GTK+ version                                             : $with_gtk
976  GDK target                                               : $with_target
977  Hildon UI extensions                                     : $with_hildon
978  Introspection support                                    : $enable_introspection
979 "
980 if test "$with_unicode_backend" = "glib"; then
981    echo "     >> WARNING: the glib-based unicode backend is slow and incomplete <<"
982    echo
983    echo
984 fi