[Gtk] add options for 3D transforms and HTML5 channel messaging to the build
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.59)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [1])
5 m4_define([webkit_micro_version], [0])
6
7 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
8
9 AC_CONFIG_MACRO_DIR([autotools])
10 AC_CONFIG_AUX_DIR([autotools])
11 AC_SUBST(ACLOCAL_AMFLAGS, "-I autotools")
12
13 AC_CONFIG_HEADERS([autotoolsconfig.h])
14 AC_CANONICAL_SYSTEM
15
16 WEBKIT_MAJOR_VERSION=webkit_major_version
17 WEBKIT_MINOR_VERSION=webkit_minor_version
18 WEBKIT_MICRO_VERSION=webkit_micro_version
19 AC_SUBST(WEBKIT_MAJOR_VERSION)
20 AC_SUBST(WEBKIT_MINOR_VERSION)
21 AC_SUBST(WEBKIT_MICRO_VERSION)
22
23 AC_CONFIG_SRCDIR([WebCore/config.h])
24
25 dnl # Libtool library version, not to confuse with API version
26 dnl # see http://www.gnu.org/software/libtool/manual.html#Versioning
27 LIBWEBKITGTK_VERSION=1:0:0
28 AC_SUBST([LIBWEBKITGTK_VERSION])
29
30 AM_INIT_AUTOMAKE([foreign subdir-objects tar-ustar])
31
32 # host checking - inspired by the GTK+ configure.in
33 # TODO: move these to webkit.m4?
34 AC_MSG_CHECKING([for native Win32])
35 case "$host" in
36      *-*-mingw*)
37        os_win32=yes
38        ;;
39      *)
40        os_win32=no
41        ;;
42 esac
43 AC_MSG_RESULT([$os_win32])
44
45 case "$host" in
46      *-*-linux*)
47        os_linux=yes
48        ;;
49      *-*-freebsd*)
50        os_freebsd=yes
51        ;;
52      *-*-darwin*)
53        os_darwin=yes
54        ;;
55 esac
56
57 case "$host_os" in
58      gnu* | linux* | k*bsd*-gnu)
59        os_gnu=yes
60        ;;
61      *)
62        os_gnu=no
63        ;;
64 esac
65
66 # initialize webkit options
67 WEBKIT_INIT
68 AC_DISABLE_STATIC
69 AC_LIBTOOL_WIN32_DLL
70 AC_PROG_LIBTOOL
71 # use dolt to speedup the build
72 DOLT
73
74 AC_PATH_PROG(FLEX, flex)
75 if test -z "$FLEX"; then
76    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
77 else
78    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
79    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
80       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
81 fi
82
83 AC_PATH_PROG(GPERF, gperf)
84 if test -z "$GPERF"; then
85    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
86 fi
87
88 # pthread (not needed on Windows)
89 if test "$os_win32" = "no"; then
90 AC_CHECK_HEADERS([pthread.h],
91                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
92                  AC_MSG_ERROR([pthread support is required to build WebKit]))
93 fi
94
95 # check for libjpeg the way Gtk does it.
96 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
97                    jpeg_ok=yes, jpeg_ok=no
98                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
99 if test "$jpeg_ok" = yes; then
100    AC_MSG_CHECKING([for jpeglib])
101    AC_TRY_CPP(
102 [#include <stdio.h>
103 #undef PACKAGE
104 #undef VERSION
105 #undef HAVE_STDLIB_H
106 #include <jpeglib.h>],
107          jpeg_ok=yes,
108          jpeg_ok=no)
109    AC_MSG_RESULT($jpeg_ok)
110    if test "$jpeg_ok" = yes; then
111       JPEG_LIBS="-ljpeg"
112       # should we check for progressive JPEG like GTK+ as well?
113    else
114       AC_MSG_ERROR([JPEG library (libjpeg) not found])
115    fi
116 fi
117 AC_SUBST([JPEG_LIBS])
118
119 # Check for libpng the way Gtk+ does it
120 AC_MSG_CHECKING(for libpng12)
121 if $PKG_CONFIG --exists libpng12 ; then
122     AC_MSG_RESULT(yes)
123     PNG_LIBS=`$PKG_CONFIG --libs libpng12`
124 else
125   AC_MSG_RESULT(no)
126   AC_CHECK_LIB(png, png_read_info,
127     [AC_CHECK_HEADER(png.h,
128       png_ok=yes,
129       png_ok=no)],
130     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
131   if test "$png_ok" = yes; then
132     AC_MSG_CHECKING([for png_structp in png.h])
133     AC_TRY_COMPILE([#include <png.h>],
134       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
135       png_ok=yes,
136       png_ok=no)
137     AC_MSG_RESULT($png_ok)
138     if test "$png_ok" = yes; then
139       PNG_LIBS='-lpng -lz'
140     else
141       AC_MSG_ERROR([PNG library (libpng) not found])
142     fi
143   else
144    AC_MSG_ERROR([PNG library (libpng) not found])
145   fi
146 fi
147 AC_SUBST([PNG_LIBS])
148
149 # determine the GDK/GTK+ target
150 AC_MSG_CHECKING([the target windowing system])
151 AC_ARG_WITH(target,
152             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
153                            [Select webkit target [default=x11]]),
154             [],[with_target="x11"])
155
156 case "$with_target" in
157      x11|win32|quartz|directfb) ;;
158      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
159 esac
160
161 AC_MSG_RESULT([$with_target])
162
163 AC_MSG_CHECKING([for Hildon UI extensions])
164 AC_ARG_WITH(hildon,
165             AC_HELP_STRING([--with-hildon],
166                            [Use Hildon UI extensions [default=no]]),
167             [],[with_hildon="no"])
168 AC_MSG_RESULT([$with_hildon])
169
170 if test "$with_hildon" = "yes"; then
171     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
172     PKG_CHECK_MODULES([HILDON], [hildon-1])
173     AC_SUBST([HILDON_CPPFLAGS])
174     AC_SUBST([HILDON_CFLAGS])
175     AC_SUBST([HILDON_LIBS])
176 fi
177
178 # minimum base dependencies
179 CAIRO_REQUIRED_VERSION=1.2
180 FONTCONFIG_REQUIRED_VERSION=2.4
181 FREETYPE2_REQUIRED_VERSION=9.0
182 LIBXML_REQUIRED_VERSION=2.6
183
184 # minimum GTK+ base dependencies
185 PANGO_REQUIRED_VERSION=1.0
186 GTK_REQUIRED_VERSION=2.8
187
188 # optional modules
189 LIBSOUP_REQUIRED_VERSION=2.25.4
190 LIBXSLT_REQUIRED_VERSION=1.1.7
191 SQLITE_REQUIRED_VERSION=3.0
192 GSTREAMER_REQUIRED_VERSION=0.10
193
194 # Available modules
195 #
196 # glib - glib and includes gthread
197 # unicode - check and identify which unicode backend to use
198 #
199 # todo: webcore gtk
200 WEBKIT_CHECK_DEPENDENCIES([glib unicode])
201                           
202 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
203 AC_SUBST(LIBXML_CFLAGS)
204 AC_SUBST(LIBXML_LIBS)
205
206 PKG_CHECK_MODULES(PANGO, pango >= $PANGO_REQUIRED_VERSION)
207 AC_SUBST(PANGO_CFLAGS)
208 AC_SUBST(PANGO_LIBS)
209
210 # check for target-specific dependencies
211 if test "$with_target" = "directfb"; then
212    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
213    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
214    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
215 else
216    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
217    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED_VERSION)
218
219    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
220       # check for XT
221       PKG_CHECK_MODULES([XT],
222                         [xt],
223                         [xt_has_pkg_config=yes],
224                         [xt_has_pkg_config=no])
225       # some old versions of Xt do not provide xt.pc, so try to link against Xt
226       # and if it's installed fall back to just adding -lXt
227       if test "$xt_has_pkg_config" = "no"; then
228          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
229          # we don't care about the XtOpenDisplay symbol but only about the
230          # existence of libXt
231          AC_CHECK_LIB([Xt], [XtOpenDisplay],
232                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
233                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
234       fi
235       AC_SUBST([XT_CFLAGS])
236       AC_SUBST([XT_LIBS])
237       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
238    fi
239 fi
240 AC_SUBST(GTK_CFLAGS)
241 AC_SUBST(GTK_LIBS)
242 AC_SUBST(CAIRO_CFLAGS)
243 AC_SUBST(CAIRO_LIBS)
244
245 # check whether to build with debugging enabled
246 AC_MSG_CHECKING([whether to do a debug build])
247 AC_ARG_ENABLE(debug,
248               AC_HELP_STRING([--enable-debug],
249                              [turn on debugging [default=no]]),
250               [],[enable_debug="no"])
251 AC_MSG_RESULT([$enable_debug])
252
253 # check whether to enable optimized builds
254 AC_MSG_CHECKING([whether to enable optimized builds])
255 AC_ARG_ENABLE(optimizations,
256               AC_HELP_STRING([--enable-optimizations],
257                              [turn on optimize builds (GCC only)
258                              [default=yes]]),
259               [enable_optimizations=$enableval],
260               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
261 AC_MSG_RESULT([$enable_optimizations])
262
263 # check whether to enable dashboard support
264 AC_MSG_CHECKING([whether to enable Dashboard support])
265 AC_ARG_ENABLE(dashboard_support,
266               AC_HELP_STRING([--enable-dashboard-support],
267                              [enable Dashboard support [default=yes]]),
268               [],[enable_dashboard_support="yes"])
269 AC_MSG_RESULT([$enable_dashboard_support])
270
271 # check whether to enable 3D transforms support
272 AC_MSG_CHECKING([whether to enable support for 3D Transforms])
273 AC_ARG_ENABLE(3D_transforms,
274               AC_HELP_STRING([--enable-3D-transforms],
275                              [enable support for 3D transforms [default=no]]),
276               [],[enable_3D_transforms="no"])
277 AC_MSG_RESULT([$enable_3D_transforms])
278
279 # check whether to enable channel messaging support
280 AC_MSG_CHECKING([whether to enable HTML5 Channel Messaging support])
281 AC_ARG_ENABLE(channel_messaging,
282               AC_HELP_STRING([--enable-channel-messaging],
283                              [enable HTML5 channel messaging support [default=no]]),
284               [],[enable_channel_messaging="no"])
285 AC_MSG_RESULT([$enable_channel_messaging])
286
287 # check whether to enable HTML5 Offline Web Applications support
288 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
289 AC_ARG_ENABLE(offline_web_applications,
290               AC_HELP_STRING([--enable-offline-web-applications],
291                              [enable HTML5 offline web applications support [default=yes]]),
292               [],[enable_offline_web_applications="yes"])
293 AC_MSG_RESULT([$enable_offline_web_applications])
294
295 # check whether to enable HTML5 client-side session and persitent storage support
296 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
297 AC_ARG_ENABLE(dom_storage,
298               AC_HELP_STRING([--enable-dom-storage],
299                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
300               [],[enable_dom_storage="yes"])
301 AC_MSG_RESULT([$enable_dom_storage])
302
303 # check whether to build with database support
304 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
305 AC_ARG_ENABLE(database,
306               AC_HELP_STRING([--enable-database],
307                              [enable HTML5 client-side database storage support [default=yes]]),
308               [],[enable_database="yes"])
309 AC_MSG_RESULT([$enable_database])
310
311 # check whether to build with icon database support
312 AC_MSG_CHECKING([whether to enable icon database support])
313 AC_ARG_ENABLE(icon_database,
314               AC_HELP_STRING([--enable-icon-database],
315                              [enable icon database [default=yes]]),
316               [],[enable_icon_database="yes"])
317 AC_MSG_RESULT([$enable_icon_database])
318
319 # check whether to enable HTML5 audio/video support
320 AC_MSG_CHECKING([whether to enable HTML5 video support])
321 AC_ARG_ENABLE(video,
322               AC_HELP_STRING([--enable-video],
323                              [enable HTML5 video support [default=no]]),
324               [],[enable_video="no"])
325 AC_MSG_RESULT([$enable_video])
326
327 # check whether to enable XPath support
328 AC_MSG_CHECKING([whether to enable XPath support])
329 AC_ARG_ENABLE(xpath,
330               AC_HELP_STRING([--enable-xpath],
331                              [enable support for XPath [default=yes]]),
332               [],[enable_xpath="yes"])
333 AC_MSG_RESULT([$enable_xpath])
334
335 # check whether to enable XSLT support
336 AC_MSG_CHECKING([whether to enable XSLT support])
337 AC_ARG_ENABLE(xslt,
338               AC_HELP_STRING([--enable-xslt],
339                              [enable support for XSLT [default=yes]]),
340               [],[enable_xslt="yes"])
341 AC_MSG_RESULT([$enable_xslt])
342
343 # check whether to enable geolocation support
344 AC_MSG_CHECKING([whether to enable geolocation support])
345 AC_ARG_ENABLE(geolocation,
346               AC_HELP_STRING([--enable-geolocation],
347                              [enable support for geolocation [default=no]]),
348               [],[enable_geolocation="no"])
349 AC_MSG_RESULT([$enable_geolocation])
350
351 # check whether to enable SVG support
352 AC_MSG_CHECKING([whether to enable SVG support])
353 AC_ARG_ENABLE(svg,
354               AC_HELP_STRING([--enable-svg],
355                              [enable support for SVG [default=yes]]),
356               [],[enable_svg="yes"])
357 AC_MSG_RESULT([$enable_svg])
358
359 # check whether to enable WML support
360 AC_MSG_CHECKING([whether to enable WML support])
361 AC_ARG_ENABLE(wml,
362               AC_HELP_STRING([--enable-wml],
363                              [enable support for WML [default=no]]),
364               [],[enable_wml="no"])
365 AC_MSG_RESULT([$enable_wml])
366
367 # check whether to enable Web Workers support
368 AC_MSG_CHECKING([whether to enable Web Workers support])
369 AC_ARG_ENABLE(web_workers,
370               AC_HELP_STRING([--enable-web-workers],
371                              [enable support for Web Workers [default=yes]]),
372               [],[enable_web_workers="yes"])
373 AC_MSG_RESULT([$enable_web_workers])
374
375 # turn off svg features if --disable-svg is requested
376 if test "$enable_svg" = "no"; then
377    enable_svg_animation=no
378    enable_svg_filters=no
379    enable_svg_fonts=no
380    enable_svg_foreign_object=no
381    enable_svg_as_image=no
382    enable_svg_use_element=no
383 fi
384
385 # check whether to enable support for SVG animation
386 AC_MSG_CHECKING([whether to enable support for SVG animation])
387 AC_ARG_ENABLE(svg_animation,
388               AC_HELP_STRING([--enable-svg-animation],
389                              [enable support for SVG animation (experimental) [default=yes]]),
390               [],[enable_svg_animation="yes"])
391 AC_MSG_RESULT([$enable_svg_animation])
392
393 # check whether to enable support for SVG filters
394 AC_MSG_CHECKING([whether to enable support for SVG filters])
395 AC_ARG_ENABLE(svg_filters,
396               AC_HELP_STRING([--enable-svg-filters],
397                              [enable support for SVG filters (experimental) [default=no]]),
398               [],[enable_svg_filters="no"])
399 AC_MSG_RESULT([$enable_svg_filters])
400
401 # check whether to enable support for SVG fonts
402 AC_MSG_CHECKING([whether to enable support for SVG fonts])
403 AC_ARG_ENABLE(svg_fonts,
404               AC_HELP_STRING([--enable-svg-fonts],
405                              [enable support for SVG fonts (experimental) [default=yes]]),
406               [],[enable_svg_fonts="yes"])
407 AC_MSG_RESULT([$enable_svg_fonts])
408
409 # check whether to enable foreign objects support for SVG
410 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
411 AC_ARG_ENABLE(svg_foreign_object,
412               AC_HELP_STRING([--enable-svg-foreign-object],
413                              [enable support for SVG foreign objects (experimental) [default=yes]]),
414               [],[enable_svg_foreign_object="yes"])
415 AC_MSG_RESULT([$enable_svg_foreign_object])
416
417 # check whether to enable SVG As Image support
418 AC_MSG_CHECKING([whether to enable SVG as Image support])
419 AC_ARG_ENABLE(svg_as_image,
420               AC_HELP_STRING([--enable-svg-as-image],
421                              [enable SVG as Image support (experimental) [default=yes]]),
422               [],[enable_svg_as_image="yes"])
423 AC_MSG_RESULT([$enable_svg_as_image])
424
425 # check whether to enable SVG USE element support
426 AC_MSG_CHECKING([whether to enable support for SVG use element])
427 AC_ARG_ENABLE(svg_use_element,
428               AC_HELP_STRING([--enable-svg-use-element],
429                              [enable SVG use element support (experimental) [default=yes]]),
430               [],[enable_svg_use_element="yes"])
431 AC_MSG_RESULT([$enable_svg_use_element])
432
433 # check for SVG features, enabling SVG if necessary
434 if test "$enable_svg_animation" = "yes" || \
435    test "$enable_svg_filters" = "yes" || \
436    test "$enable_svg_fonts" = "yes" || \
437    test "$enable_svg_foreign_object" = "yes" || \
438    test "$enable_svg_as_image" = "yes" || \
439    test "$enable_svg_use_element" = "yes"; then
440    svg_flags=yes
441    if test "$enable_svg" = "no"; then
442        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
443        enable_svg=yes
444    fi
445 fi
446
447 # check whether to enable code coverage
448 AC_MSG_CHECKING([whether to enable code coverage support])
449 AC_ARG_ENABLE(coverage,
450               AC_HELP_STRING([--enable-coverage],
451                              [enable code coverage support [default=no]]),
452               [],[enable_coverage="no"])
453 AC_MSG_RESULT([$enable_coverage])
454
455 # check whether to enable FastMalloc
456 AC_MSG_CHECKING([whether to enable optimized memory allocator])
457 AC_ARG_ENABLE(fast_malloc,
458               AC_HELP_STRING([--enable-fast-malloc],
459                              [enable optimized memory allocator default=yes, default=no for debug builds]),
460               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
461 AC_MSG_RESULT([$enable_fast_malloc])
462
463 AC_MSG_CHECKING([whether to enable JIT compilation])
464 AC_ARG_ENABLE([jit],
465               AC_HELP_STRING([--enable-jit],
466                              [Enable JIT compilation default=yes]),
467               [],[enable_jit="yes"])
468 if test "$enable_jit" = "yes"; then
469     case "$target_cpu" in
470         i*86)
471             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
472             AC_DEFINE([ENABLE_WREC], [1], [Define to enable WREC])
473             AC_DEFINE([ENABLE_JIT_OPTIMIZE_CALL], [1], [Define to enable optimizing calls])
474             AC_DEFINE([ENABLE_JIT_OPTIMIZE_PROPERTY_ACCESS], [1], [Define to enable optimized property access])
475             AC_DEFINE([ENABLE_JIT_OPTIMIZE_ARITHMETIC], [1], [Define to enable optimized arithmetic])
476             AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_VA_LIST], [1], [Use stub va_list])
477         ;;
478         *)
479             enable_jit="no (CPU '$target_cpu' not supported)"
480         ;;
481     esac
482 fi
483 AC_MSG_RESULT([$enable_jit])
484
485 # determine the font backend
486 AC_MSG_CHECKING([the font backend to use])
487 AC_ARG_WITH(font_backend,
488             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
489                            [Select font backend [default=freetype]]),
490             [],[with_font_backend="freetype"])
491
492 case "$with_font_backend" in
493      freetype|pango) ;;
494      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
495 esac
496 AC_MSG_RESULT([$with_font_backend])
497
498 # Add '-g' flag to gcc if it's debug build
499 if test "$enable_debug" = "yes"; then
500    CXXFLAGS="$CXXFLAGS -g"
501    CFLAGS="$CFLAGS -g"
502 else
503    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
504 fi
505
506 # Add the appropriate 'O' level for optimized builds
507 if test "$enable_optimizations" = "yes"; then
508    CXXFLAGS="$CXXFLAGS -O2"
509    CFLAGS="$CFLAGS -O2"
510 else
511    CXXFLAGS="$CXXFLAGS -O0"
512    CFLAGS="$CFLAGS -O0"
513 fi
514
515 PKG_CHECK_MODULES([LIBSOUP],
516                   [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
517 AC_SUBST([LIBSOUP_CFLAGS])
518 AC_SUBST([LIBSOUP_LIBS])
519
520 # check if FreeType/FontConfig are available
521 if test "$with_font_backend" = "freetype"; then
522    if test "$with_target" = "directfb"; then
523    PKG_CHECK_MODULES([FREETYPE],
524                      [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
525                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
526    else
527    PKG_CHECK_MODULES([FREETYPE],
528                      [cairo-ft
529                      pangoft2
530                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
531                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
532    fi
533    AC_SUBST([FREETYPE_CFLAGS])
534    AC_SUBST([FREETYPE_LIBS])
535 fi
536
537 # check if sqlite 3 is available
538 if test "$enable_icon_database" = "yes" || \
539    test "$enable_database" = "yes" || \
540    test "$enable_offline_web_applications" = "yes" || \
541    test "$enable_dom_storage" = "yes"; then
542    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
543    AC_SUBST([SQLITE3_CFLAGS])
544    AC_SUBST([SQLITE3_LIBS])
545 fi
546
547 # check if libxslt is available
548 if test "$enable_xslt" = "yes"; then
549    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
550    AC_SUBST([LIBXSLT_CFLAGS])
551    AC_SUBST([LIBXSLT_LIBS])
552 fi
553
554 # check if geoclue is available
555 if test "$enable_geolocation" = "yes"; then
556     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
557     AC_SUBST([GEOCLUE_CFLAGS])
558     AC_SUBST([GEOCLUE_LIBS])
559 fi
560
561 # check if gstreamer is available
562 if test "$enable_video" = "yes"; then
563    PKG_CHECK_MODULES([GSTREAMER],
564                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
565                      gstreamer-base-0.10,
566                      gstreamer-plugins-base-0.10])
567    AC_SUBST([GSTREAMER_CFLAGS])
568    AC_SUBST([GSTREAMER_LIBS])
569 fi
570
571 # check for code coverage support
572 if test "$enable_coverage" = "yes"; then
573    COVERAGE_CFLAGS="-MD"
574    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
575    AC_SUBST([COVERAGE_CFLAGS])
576    AC_SUBST([COVERAGE_LDFLAGS])
577 fi
578
579 # check for HTML features
580 if test "$enable_video" = "yes"; then
581     html_flags=yes
582 fi
583
584 # OS conditionals
585 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
586 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
587 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
588 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
589 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
590
591 # target conditionals
592 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
593 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
594 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
595 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
596
597 # Font backend conditionals
598 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
599 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
600
601 # WebKit feature conditionals
602 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
603 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
604 AM_CONDITIONAL([ENABLE_3D_TRANSFORMS],[test "$enable_3D_transforms" = "yes"])
605 AM_CONDITIONAL([ENABLE_CHANNEL_MESSAGING],[test "$enable_channel_messaging" = "yes"])
606 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
607 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
608 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
609 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
610 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
611 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
612 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
613 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
614 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
615 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
616 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
617 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
618 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
619 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
620 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
621 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
622 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
623 AM_CONDITIONAL([ENABLE_WML],[test "$enable_wml" = "yes"])
624 AM_CONDITIONAL([ENABLE_WORKERS],[test "$enable_web_workers" = "yes"])
625 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
626 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
627
628 AC_CONFIG_FILES([
629 GNUmakefile
630 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
631 WebKit/gtk/webkit/webkitversion.h
632 ]
633 )
634
635 AC_OUTPUT
636
637 echo "
638 WebKit was configured with the following options:
639
640 Build configuration:
641  Enable debugging (slow)                                  : $enable_debug
642  Enable GCC build optimization                            : $enable_optimizations
643  Code coverage support                                    : $enable_coverage
644  Unicode backend                                          : $unicode_backend
645  Font backend                                             : $with_font_backend
646  Optimized memory allocator                               : $enable_fast_malloc
647 Features:
648  3D Transforms                                            : $enable_3D_transforms
649  JIT compilation                                          : $enable_jit
650  Dashboard support                                        : $enable_dashboard_support
651  Geolocation support                                      : $enable_geolocation
652  HTML5 offline web applications support                   : $enable_offline_web_applications
653  HTML5 channel messaging support                          : $enable_channel_messaging
654  HTML5 client-side session and persistent storage support : $enable_dom_storage
655  HTML5 client-side database storage support               : $enable_database
656  HTML5 video element support                              : $enable_video
657  Icon database support                                    : $enable_icon_database
658  SVG support                                              : $enable_svg
659  SVG animation support                                    : $enable_svg_animation
660  SVG filters support                                      : $enable_svg_filters
661  SVG fonts support                                        : $enable_svg_fonts
662  SVG foreign object support                               : $enable_svg_foreign_object
663  SVG as image support                                     : $enable_svg_as_image
664  SVG use element support                                  : $enable_svg_use_element
665  WML support                                              : $enable_wml
666  Web Workers support                                      : $enable_web_workers
667  XPATH support                                            : $enable_xpath
668  XSLT support                                             : $enable_xslt
669 GTK+ configuration:
670  GDK target                                               : $with_target
671  Hildon UI extensions                                     : $with_hildon
672 "